Contract Address Details

// SPDX-License-Identifier: UNLICENSED
/// @custom:security-contact dev@helgo.io

pragma solidity ^0.8.9;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";

import "config/Settings.sol";
import "contracts/Heldao.sol";

import "interfaces/Helgo.sol";
import "interfaces/HEX.sol";
import "interfaces/IHelfactory.sol";
import "interfaces/IEmissions.sol";
import "interfaces/IUniswapV2Factory.sol";
import "interfaces/IUniswapV2Router02.sol";

import { ABDKMath64x64 as Math } from "abdk-libraries-solidity/ABDKMath64x64.sol";

contract Helgo is ERC20, Founders { 

    uint64 immutable public DAYZERO;
    uint64 immutable public DAYLAUNCH;
    bool public launched;

    Heldao immutable public HELDAO;

    IHelfactory immutable private HELFACTORY;
    IEmissions public HELGAS;
    IEmissions public HELLP;

    // HEX contract
    IHEX private HEX;
    IERC20 public PAIR;

    // Uniswap / PulseX factory
    IUniswapV2Router02 private ROUTER;
    IUniswapV2Factory private FACTORY;

    // Addreses that participate in launch phase
    address[] public participants; 

    // Total deposited
    uint256 public totalHEX; 
    uint256 public deposited; 
    uint256 public claimable; 
    uint256 public claimedHELGO; 
    uint256 public claimedHELLP; 

    // Track launch deposits    
    mapping(address => uint256) public deposits;
    mapping(address => bool) public claimers;

    event Deposited(address indexed addr, uint256 amount);    
    event Claimed(address indexed addr, uint256 amount, uint256 amountHELLP);
    event Locked(address indexed addr, uint256 amount);
    event Launched(uint256 timestamp);

    struct Globals {
        uint64 dayzero;
        uint64 daylaunch;
        uint64 today;
        uint64 day;
        bool launched;
        uint256 balance;
        uint256 deposit; 
        uint256 deposited;
        uint256 claimable; 
        uint256 claimedHELGO;
        uint256 claimedHELLP;
        uint256 participants;
    }

    struct Totals {
        uint256 supply;    // 100% HELGO total supply
        uint256 emissions; // 45% HELGO retained for emissions
        uint256 locked;    // 35% HELGO locked for 365 + 5555
        uint256 liquidity; // 10% HELGO for lquidity (contract retains 50%)
        uint256 liquid;    // 5% HELGO liquid 
        uint256 DAO;       // 5% HELGO retained in DAO
        uint256 HEX;       // HEX held by the contract at time of launch (desposited)
    }

    constructor(address payable hexAddr, address routerAddr, address factoryAddr) 
        ERC20("HELGO", "HELGO")
    {
        // Contract has total supply
        _mint(address(this), 55557777369 * 10 ** decimals());

        // Just use IERC20 for HEX
        HEX = IHEX(payable(hexAddr));

        // Set router 
        ROUTER = IUniswapV2Router02(routerAddr);
        FACTORY = IUniswapV2Factory(ROUTER.factory()); 
        
        // Emissions factories
        HELFACTORY = IHelfactory(factoryAddr);

        // Used to lock founders allocation + votes
        HELDAO = new Heldao(address(this), routerAddr, hexAddr);

        // Contract day zero (UTC)
        DAYZERO = today();

        // Launch date
        DAYLAUNCH = today() + HELGO_LAUNCH_LENGTH;
    }

    ///////////////
    // VIEW ONLY //
    ///////////////

    function globals() public view returns (Globals memory) {
        return Globals(
            DAYZERO,
            DAYLAUNCH,
            today(),
            day(),
            launched,
            balanceOf(msg.sender),
            deposits[msg.sender],
            deposited,
            claimable,
            claimedHELGO,
            claimedHELLP,            
            participants.length
        );
    }

    function totals() public view returns (Totals memory) {
        return Totals(
            totalSupply(),
            totalEmissions(),
            totalLocked(),
            totalLiquidity(),
            totalLiquid(),
            totalDAO(),
            totalHEX 
        );
    }

    function today() public view returns (uint64) {
        return uint64((block.timestamp / 1 days) * 1 days);
    }

    function day() public view returns (uint64) {
        uint64 diff = (today() - DAYZERO);
        if(diff == 0) {
            return 0;
        }
        return diff / 1 days;
    }

    function getDeposit(address addr) public view returns(uint256) {
        return deposits[addr];
    }

    function getParticipant(uint i) public view returns (address) {
        return participants[i];
    }

    function totalParticipants() public view returns(uint count){
        return participants.length;
    }

    function totalEmissions() public view returns(uint256){
        return (totalSupply() / 20) * 9; // 45
    }

    function totalLocked() public view returns(uint256){
        return (totalSupply() / 20) * 7; // 35
    }    

    function totalLiquidity() public view returns(uint256){
        return (totalSupply() / 20) * 2; // 10
    }    

    function totalDAO() public view returns(uint256){
        return (totalSupply() / 20) * 1; // 5
    }

    function totalLiquid() public view returns(uint256){
        return (totalSupply() / 20) * 1; // 5
    }    

    function balanceHEX() public view returns(uint256){
        return HEX.balanceOf(address(this));
    }

    /////////////
    // PUBLIC  //
    /////////////

    function burn(uint256 amount) public virtual {
        _burn(_msgSender(), amount);
    }

    // @dev allow caller to claim
    function claim() external returns(uint256, uint256){
        return _distribute(msg.sender);
    }

    // @dev distribute launch allocation to an address
    function distribute(address addr) external returns(uint256, uint256){
        return _distribute(addr);
    }

    // @notifiy deposit HEX for launch
    function deposit(uint256 amount) public {

        // Deposit
        _deposit(msg.sender, amount);

        // Transfer the HEX
        HEX.transferFrom(msg.sender, address(this), amount);  
    }

    // @notifiy transform Pulse for HEX and deposit
    function transform() public payable {
        _transform(msg.sender, msg.value);
    }

    function launch() public {
        _launch();
    }
    
    function fundHELGAS(uint256 amount) public {
        _transfer(msg.sender, address(this), amount);
        HELGAS.fund(amount);
    }

    function fundHELLP(uint256 amount) public {
        PAIR.transferFrom(msg.sender, address(this), amount);
        HELLP.fund(amount);
    }

    function lock(uint256 amount, uint64 start, uint64 duration) public returns(bool) {
        return _lock(msg.sender, amount, start, duration);
    }

    /****************************
        P r i v a t e
    /****************************/   

    function _lock(address addr, uint256 amount, uint64 start, uint64 duration) private returns(bool) {
        // Get / create a vault for the addr
        address vault = HELDAO.initVault(msg.sender, start, duration);

        // Lock the HELGO
        _transfer(addr, vault, amount);

        emit Locked(addr, amount);

        return true;
    }

    // @dev deposit HEX into launch phase
    function _deposit(address addr, uint256 amount) private {
        require(amount > 0, "Deposit amount must be greater than zero");
        require(!launched, "Already launched, deposits closed");

        // Add address to 
        if(deposits[addr] == 0) {
            participants.push(addr);
        }

        // Internal
        deposited += amount;
        deposits[addr] += amount;

        emit Deposited(addr, amount);
    }

    // @dev deposit Pulse, swapped for HEX and deposited
    function _transform(address addr, uint256 value) private {
        require(value > 0, 'Amount must be greater than zero');

        // Swap path
        address[] memory path;
        path = new address[](2);
        path[0] = address(ROUTER) == ROUTERPULSEX ? WPLS : WETH;
        path[1] = address(HEX);

        // Get amounts
        uint[] memory amounts = ROUTER.getAmountsOut(value, path);

        // Expected amount
        uint256 amount = amounts[amounts.length - 1];

        // Swap for HEX exact amount
        ROUTER.swapExactETHForTokens{value: value}(amount, path, address(this), block.timestamp + 10000);

        // Now deposit
        _deposit(addr, amount);
    }

    // @dev distribute allocation for an address
    function _distribute(address addr) private returns(uint256, uint256){
        require(launched, "Not launched");
        require(!claimers[addr], "Already claimed");
        
        // Record claim
        claimers[addr] = true;

        // Amount of HELLP
        uint256 amountHELLP; 

        // Amount of HELGO
        uint256 amountHELGO; 

        if(deposits[addr] > 0){

            // Share of deposits
            int128 share = Math.divu(deposits[addr], deposited);

            // HELLP
            amountHELLP = Math.mulu(share, claimable / 2);

            // HELGO
            amountHELGO = Math.mulu(share, totalLiquid() / 2);
        }

        // Check if founder
        if(founder[addr]) {

            // Include founder allocations
            amountHELLP += claimable / (2 * HELGO_FOUNDERS.length);
            amountHELGO += totalLiquid() / (2 * HELGO_FOUNDERS.length);

            // Lock founder allocation
            uint256 locked = totalLocked() / HELGO_FOUNDERS.length;
            _transfer(address(this), addr, locked);
            _lock(addr, locked, DAYZERO + FOUNDERS_CLIFF, FOUNDERS_VESTING);
        }
        else {
            require(deposits[addr] > 0, "No deposit");
        }

        // Increased claim totals
        claimedHELLP += amountHELLP;
        claimedHELGO += amountHELGO;

        // Release PAIR
        if(amountHELLP > 0) {
            PAIR.transfer(addr, amountHELLP);
        }

        // Release HELGO
        if(amountHELGO > 0) {
           _transfer(address(this), addr, amountHELGO);
        }

        // Emit claimed event
        emit Claimed(addr, amountHELGO, amountHELLP);

        return (amountHELGO, amountHELLP);
    }

    // @dev end launch phase
    function _launch() private {
        require(!launched, "Already launched");
        require(today() >= DAYLAUNCH, "Too soon to launch");

        launched = true;

        // Snapshot launch HEX
        totalHEX = HEX.balanceOf(address(this));        

        // DAO 
        _launchHELDAO();

        // HELGO
        _launchHELGO();

        // HELLP
        _launchHELLP();

        // Emit event
        emit Launched(block.timestamp);        
    }    

    // @dev launch DAO and fund
    function _launchHELDAO() private {
        // Fund HELDAO with HELGO
        _transfer(address(this), address(HELDAO), totalDAO());

        // Fund HELDAO with HEX
        HEX.transfer(address(HELDAO), totalHEX / 20);
    }

    // @dev launch HELGAS and fund
    function _launchHELGO() private {
        // Populate emissions
        HELGAS = IEmissions(HELFACTORY.newHelgas(address(this)));

        // Approve HELGO for funding emissions
        _approve(address(this), address(HELGAS), type(uint256).max);

        // Fund emissions
        HELGAS.fund(totalEmissions());
    }

    // @dev launch HELLP and fund
    function _launchHELLP() private {
        // Get or create the pair via the factory
        address token0 = address(this);
        address token1 = address(HEX);
        address pair = FACTORY.getPair(token0, token1);

        // Create pair if needed
        if(pair == address(0)) {
            pair = FACTORY.createPair(token0, token1);
        }

        // Approve HELGO for LP 
        _approve(address(this), address(ROUTER), totalLiquidity());

        uint256 liquidityHEX = HEX.balanceOf(address(this));

        // Approve HEX for LP
        HEX.approve(address(ROUTER), liquidityHEX);

        // Add liquidity to pair
        (, , uint liquidity) = ROUTER.addLiquidity(
            token0,
            token1,
            totalLiquidity(),
            liquidityHEX,
            totalLiquidity(),
            liquidityHEX,
            token0,
            block.timestamp + 1000000
        );

        // Populate PAIR emissions
        HELLP = IEmissions(HELFACTORY.newHellp(pair, address(ROUTER), token0, token1));

        //! This could potentially be IUniswapV2ERC20
        PAIR = IERC20(pair);

        // Approve HELLP for funding emissions
        PAIR.approve(address(HELLP), type(uint256).max);
        
        // Fund emissions
        HELLP.fund(liquidity / 2);

        // Retain claimable
        claimable = liquidity - (liquidity / 2);

        // Approve claimable
        PAIR.approve(address(this), claimable);

    }
}
        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/Clones.sol)

pragma solidity ^0.8.0;

/**
 * @dev https://eips.ethereum.org/EIPS/eip-1167[EIP 1167] is a standard for
 * deploying minimal proxy contracts, also known as "clones".
 *
 * > To simply and cheaply clone contract functionality in an immutable way, this standard specifies
 * > a minimal bytecode implementation that delegates all calls to a known, fixed address.
 *
 * The library includes functions to deploy a proxy using either `create` (traditional deployment) or `create2`
 * (salted deterministic deployment). It also includes functions to predict the addresses of clones deployed using the
 * deterministic method.
 *
 * _Available since v3.4._
 */
library Clones {
    /**
     * @dev Deploys and returns the address of a clone that mimics the behaviour of `implementation`.
     *
     * This function uses the create opcode, which should never revert.
     */
    function clone(address implementation) internal returns (address instance) {
        /// @solidity memory-safe-assembly
        assembly {
            // Cleans the upper 96 bits of the `implementation` word, then packs the first 3 bytes
            // of the `implementation` address with the bytecode before the address.
            mstore(0x00, or(shr(0xe8, shl(0x60, implementation)), 0x3d602d80600a3d3981f3363d3d373d3d3d363d73000000))
            // Packs the remaining 17 bytes of `implementation` with the bytecode after the address.
            mstore(0x20, or(shl(0x78, implementation), 0x5af43d82803e903d91602b57fd5bf3))
            instance := create(0, 0x09, 0x37)
        }
        require(instance != address(0), "ERC1167: create failed");
    }

    /**
     * @dev Deploys and returns the address of a clone that mimics the behaviour of `implementation`.
     *
     * This function uses the create2 opcode and a `salt` to deterministically deploy
     * the clone. Using the same `implementation` and `salt` multiple time will revert, since
     * the clones cannot be deployed twice at the same address.
     */
    function cloneDeterministic(address implementation, bytes32 salt) internal returns (address instance) {
        /// @solidity memory-safe-assembly
        assembly {
            // Cleans the upper 96 bits of the `implementation` word, then packs the first 3 bytes
            // of the `implementation` address with the bytecode before the address.
            mstore(0x00, or(shr(0xe8, shl(0x60, implementation)), 0x3d602d80600a3d3981f3363d3d373d3d3d363d73000000))
            // Packs the remaining 17 bytes of `implementation` with the bytecode after the address.
            mstore(0x20, or(shl(0x78, implementation), 0x5af43d82803e903d91602b57fd5bf3))
            instance := create2(0, 0x09, 0x37, salt)
        }
        require(instance != address(0), "ERC1167: create2 failed");
    }

    /**
     * @dev Computes the address of a clone deployed using {Clones-cloneDeterministic}.
     */
    function predictDeterministicAddress(
        address implementation,
        bytes32 salt,
        address deployer
    ) internal pure returns (address predicted) {
        /// @solidity memory-safe-assembly
        assembly {
            let ptr := mload(0x40)
            mstore(add(ptr, 0x38), deployer)
            mstore(add(ptr, 0x24), 0x5af43d82803e903d91602b57fd5bf3ff)
            mstore(add(ptr, 0x14), implementation)
            mstore(ptr, 0x3d602d80600a3d3981f3363d3d373d3d3d363d73)
            mstore(add(ptr, 0x58), salt)
            mstore(add(ptr, 0x78), keccak256(add(ptr, 0x0c), 0x37))
            predicted := keccak256(add(ptr, 0x43), 0x55)
        }
    }

    /**
     * @dev Computes the address of a clone deployed using {Clones-cloneDeterministic}.
     */
    function predictDeterministicAddress(
        address implementation,
        bytes32 salt
    ) internal view returns (address predicted) {
        return predictDeterministicAddress(implementation, salt, address(this));
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address from, address to, uint256 amount) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(address from, address to, uint256 amount) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 amount) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(address from, address to, uint256 amount) internal virtual {}
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Compatible with tokens that require the approval to be set to
     * 0 before setting it to a non-zero value.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
          

// SPDX-License-Identifier: BSD-4-Clause
/*
 * ABDK Math 64.64 Smart Contract Library.  Copyright © 2019 by ABDK Consulting.
 * Author: Mikhail Vladimirov <mikhail.vladimirov@gmail.com>
 */
pragma solidity ^0.8.0;

/**
 * Smart contract library of mathematical functions operating with signed
 * 64.64-bit fixed point numbers.  Signed 64.64-bit fixed point number is
 * basically a simple fraction whose numerator is signed 128-bit integer and
 * denominator is 2^64.  As long as denominator is always the same, there is no
 * need to store it, thus in Solidity signed 64.64-bit fixed point numbers are
 * represented by int128 type holding only the numerator.
 */

library ABDKMath64x64 {
  /*
   * Minimum value signed 64.64-bit fixed point number may have. 
   */
  int128 private constant MIN_64x64 = -0x80000000000000000000000000000000;

  /*
   * Maximum value signed 64.64-bit fixed point number may have. 
   */
  int128 private constant MAX_64x64 = 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF;

  /**
   * Convert signed 256-bit integer number into signed 64.64-bit fixed point
   * number.  Revert on overflow.
   *
   * @param x signed 256-bit integer number
   * @return signed 64.64-bit fixed point number
   */
  function fromInt (int256 x) internal pure returns (int128) {
    unchecked {
      require (x >= -0x8000000000000000 && x <= 0x7FFFFFFFFFFFFFFF);
      return int128 (x << 64);
    }
  }

  /**
   * Convert signed 64.64 fixed point number into signed 64-bit integer number
   * rounding down.
   *
   * @param x signed 64.64-bit fixed point number
   * @return signed 64-bit integer number
   */
  function toInt (int128 x) internal pure returns (int64) {
    unchecked {
      return int64 (x >> 64);
    }
  }

  /**
   * Convert unsigned 256-bit integer number into signed 64.64-bit fixed point
   * number.  Revert on overflow.
   *
   * @param x unsigned 256-bit integer number
   * @return signed 64.64-bit fixed point number
   */
  function fromUInt (uint256 x) internal pure returns (int128) {
    unchecked {
      require (x <= 0x7FFFFFFFFFFFFFFF);
      return int128 (int256 (x << 64));
    }
  }

  /**
   * Convert signed 64.64 fixed point number into unsigned 64-bit integer
   * number rounding down.  Revert on underflow.
   *
   * @param x signed 64.64-bit fixed point number
   * @return unsigned 64-bit integer number
   */
  function toUInt (int128 x) internal pure returns (uint64) {
    unchecked {
      require (x >= 0);
      return uint64 (uint128 (x >> 64));
    }
  }

  /**
   * Convert signed 128.128 fixed point number into signed 64.64-bit fixed point
   * number rounding down.  Revert on overflow.
   *
   * @param x signed 128.128-bin fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function from128x128 (int256 x) internal pure returns (int128) {
    unchecked {
      int256 result = x >> 64;
      require (result >= MIN_64x64 && result <= MAX_64x64);
      return int128 (result);
    }
  }

  /**
   * Convert signed 64.64 fixed point number into signed 128.128 fixed point
   * number.
   *
   * @param x signed 64.64-bit fixed point number
   * @return signed 128.128 fixed point number
   */
  function to128x128 (int128 x) internal pure returns (int256) {
    unchecked {
      return int256 (x) << 64;
    }
  }

  /**
   * Calculate x + y.  Revert on overflow.
   *
   * @param x signed 64.64-bit fixed point number
   * @param y signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function add (int128 x, int128 y) internal pure returns (int128) {
    unchecked {
      int256 result = int256(x) + y;
      require (result >= MIN_64x64 && result <= MAX_64x64);
      return int128 (result);
    }
  }

  /**
   * Calculate x - y.  Revert on overflow.
   *
   * @param x signed 64.64-bit fixed point number
   * @param y signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function sub (int128 x, int128 y) internal pure returns (int128) {
    unchecked {
      int256 result = int256(x) - y;
      require (result >= MIN_64x64 && result <= MAX_64x64);
      return int128 (result);
    }
  }

  /**
   * Calculate x * y rounding down.  Revert on overflow.
   *
   * @param x signed 64.64-bit fixed point number
   * @param y signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function mul (int128 x, int128 y) internal pure returns (int128) {
    unchecked {
      int256 result = int256(x) * y >> 64;
      require (result >= MIN_64x64 && result <= MAX_64x64);
      return int128 (result);
    }
  }

  /**
   * Calculate x * y rounding towards zero, where x is signed 64.64 fixed point
   * number and y is signed 256-bit integer number.  Revert on overflow.
   *
   * @param x signed 64.64 fixed point number
   * @param y signed 256-bit integer number
   * @return signed 256-bit integer number
   */
  function muli (int128 x, int256 y) internal pure returns (int256) {
    unchecked {
      if (x == MIN_64x64) {
        require (y >= -0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF &&
          y <= 0x1000000000000000000000000000000000000000000000000);
        return -y << 63;
      } else {
        bool negativeResult = false;
        if (x < 0) {
          x = -x;
          negativeResult = true;
        }
        if (y < 0) {
          y = -y; // We rely on overflow behavior here
          negativeResult = !negativeResult;
        }
        uint256 absoluteResult = mulu (x, uint256 (y));
        if (negativeResult) {
          require (absoluteResult <=
            0x8000000000000000000000000000000000000000000000000000000000000000);
          return -int256 (absoluteResult); // We rely on overflow behavior here
        } else {
          require (absoluteResult <=
            0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF);
          return int256 (absoluteResult);
        }
      }
    }
  }

  /**
   * Calculate x * y rounding down, where x is signed 64.64 fixed point number
   * and y is unsigned 256-bit integer number.  Revert on overflow.
   *
   * @param x signed 64.64 fixed point number
   * @param y unsigned 256-bit integer number
   * @return unsigned 256-bit integer number
   */
  function mulu (int128 x, uint256 y) internal pure returns (uint256) {
    unchecked {
      if (y == 0) return 0;

      require (x >= 0);

      uint256 lo = (uint256 (int256 (x)) * (y & 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF)) >> 64;
      uint256 hi = uint256 (int256 (x)) * (y >> 128);

      require (hi <= 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF);
      hi <<= 64;

      require (hi <=
        0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF - lo);
      return hi + lo;
    }
  }

  /**
   * Calculate x / y rounding towards zero.  Revert on overflow or when y is
   * zero.
   *
   * @param x signed 64.64-bit fixed point number
   * @param y signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function div (int128 x, int128 y) internal pure returns (int128) {
    unchecked {
      require (y != 0);
      int256 result = (int256 (x) << 64) / y;
      require (result >= MIN_64x64 && result <= MAX_64x64);
      return int128 (result);
    }
  }

  /**
   * Calculate x / y rounding towards zero, where x and y are signed 256-bit
   * integer numbers.  Revert on overflow or when y is zero.
   *
   * @param x signed 256-bit integer number
   * @param y signed 256-bit integer number
   * @return signed 64.64-bit fixed point number
   */
  function divi (int256 x, int256 y) internal pure returns (int128) {
    unchecked {
      require (y != 0);

      bool negativeResult = false;
      if (x < 0) {
        x = -x; // We rely on overflow behavior here
        negativeResult = true;
      }
      if (y < 0) {
        y = -y; // We rely on overflow behavior here
        negativeResult = !negativeResult;
      }
      uint128 absoluteResult = divuu (uint256 (x), uint256 (y));
      if (negativeResult) {
        require (absoluteResult <= 0x80000000000000000000000000000000);
        return -int128 (absoluteResult); // We rely on overflow behavior here
      } else {
        require (absoluteResult <= 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF);
        return int128 (absoluteResult); // We rely on overflow behavior here
      }
    }
  }

  /**
   * Calculate x / y rounding towards zero, where x and y are unsigned 256-bit
   * integer numbers.  Revert on overflow or when y is zero.
   *
   * @param x unsigned 256-bit integer number
   * @param y unsigned 256-bit integer number
   * @return signed 64.64-bit fixed point number
   */
  function divu (uint256 x, uint256 y) internal pure returns (int128) {
    unchecked {
      require (y != 0);
      uint128 result = divuu (x, y);
      require (result <= uint128 (MAX_64x64));
      return int128 (result);
    }
  }

  /**
   * Calculate -x.  Revert on overflow.
   *
   * @param x signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function neg (int128 x) internal pure returns (int128) {
    unchecked {
      require (x != MIN_64x64);
      return -x;
    }
  }

  /**
   * Calculate |x|.  Revert on overflow.
   *
   * @param x signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function abs (int128 x) internal pure returns (int128) {
    unchecked {
      require (x != MIN_64x64);
      return x < 0 ? -x : x;
    }
  }

  /**
   * Calculate 1 / x rounding towards zero.  Revert on overflow or when x is
   * zero.
   *
   * @param x signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function inv (int128 x) internal pure returns (int128) {
    unchecked {
      require (x != 0);
      int256 result = int256 (0x100000000000000000000000000000000) / x;
      require (result >= MIN_64x64 && result <= MAX_64x64);
      return int128 (result);
    }
  }

  /**
   * Calculate arithmetics average of x and y, i.e. (x + y) / 2 rounding down.
   *
   * @param x signed 64.64-bit fixed point number
   * @param y signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function avg (int128 x, int128 y) internal pure returns (int128) {
    unchecked {
      return int128 ((int256 (x) + int256 (y)) >> 1);
    }
  }

  /**
   * Calculate geometric average of x and y, i.e. sqrt (x * y) rounding down.
   * Revert on overflow or in case x * y is negative.
   *
   * @param x signed 64.64-bit fixed point number
   * @param y signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function gavg (int128 x, int128 y) internal pure returns (int128) {
    unchecked {
      int256 m = int256 (x) * int256 (y);
      require (m >= 0);
      require (m <
          0x4000000000000000000000000000000000000000000000000000000000000000);
      return int128 (sqrtu (uint256 (m)));
    }
  }

  /**
   * Calculate x^y assuming 0^0 is 1, where x is signed 64.64 fixed point number
   * and y is unsigned 256-bit integer number.  Revert on overflow.
   *
   * @param x signed 64.64-bit fixed point number
   * @param y uint256 value
   * @return signed 64.64-bit fixed point number
   */
  function pow (int128 x, uint256 y) internal pure returns (int128) {
    unchecked {
      bool negative = x < 0 && y & 1 == 1;

      uint256 absX = uint128 (x < 0 ? -x : x);
      uint256 absResult;
      absResult = 0x100000000000000000000000000000000;

      if (absX <= 0x10000000000000000) {
        absX <<= 63;
        while (y != 0) {
          if (y & 0x1 != 0) {
            absResult = absResult * absX >> 127;
          }
          absX = absX * absX >> 127;

          if (y & 0x2 != 0) {
            absResult = absResult * absX >> 127;
          }
          absX = absX * absX >> 127;

          if (y & 0x4 != 0) {
            absResult = absResult * absX >> 127;
          }
          absX = absX * absX >> 127;

          if (y & 0x8 != 0) {
            absResult = absResult * absX >> 127;
          }
          absX = absX * absX >> 127;

          y >>= 4;
        }

        absResult >>= 64;
      } else {
        uint256 absXShift = 63;
        if (absX < 0x1000000000000000000000000) { absX <<= 32; absXShift -= 32; }
        if (absX < 0x10000000000000000000000000000) { absX <<= 16; absXShift -= 16; }
        if (absX < 0x1000000000000000000000000000000) { absX <<= 8; absXShift -= 8; }
        if (absX < 0x10000000000000000000000000000000) { absX <<= 4; absXShift -= 4; }
        if (absX < 0x40000000000000000000000000000000) { absX <<= 2; absXShift -= 2; }
        if (absX < 0x80000000000000000000000000000000) { absX <<= 1; absXShift -= 1; }

        uint256 resultShift = 0;
        while (y != 0) {
          require (absXShift < 64);

          if (y & 0x1 != 0) {
            absResult = absResult * absX >> 127;
            resultShift += absXShift;
            if (absResult > 0x100000000000000000000000000000000) {
              absResult >>= 1;
              resultShift += 1;
            }
          }
          absX = absX * absX >> 127;
          absXShift <<= 1;
          if (absX >= 0x100000000000000000000000000000000) {
              absX >>= 1;
              absXShift += 1;
          }

          y >>= 1;
        }

        require (resultShift < 64);
        absResult >>= 64 - resultShift;
      }
      int256 result = negative ? -int256 (absResult) : int256 (absResult);
      require (result >= MIN_64x64 && result <= MAX_64x64);
      return int128 (result);
    }
  }

  /**
   * Calculate sqrt (x) rounding down.  Revert if x < 0.
   *
   * @param x signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function sqrt (int128 x) internal pure returns (int128) {
    unchecked {
      require (x >= 0);
      return int128 (sqrtu (uint256 (int256 (x)) << 64));
    }
  }

  /**
   * Calculate binary logarithm of x.  Revert if x <= 0.
   *
   * @param x signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function log_2 (int128 x) internal pure returns (int128) {
    unchecked {
      require (x > 0);

      int256 msb = 0;
      int256 xc = x;
      if (xc >= 0x10000000000000000) { xc >>= 64; msb += 64; }
      if (xc >= 0x100000000) { xc >>= 32; msb += 32; }
      if (xc >= 0x10000) { xc >>= 16; msb += 16; }
      if (xc >= 0x100) { xc >>= 8; msb += 8; }
      if (xc >= 0x10) { xc >>= 4; msb += 4; }
      if (xc >= 0x4) { xc >>= 2; msb += 2; }
      if (xc >= 0x2) msb += 1;  // No need to shift xc anymore

      int256 result = msb - 64 << 64;
      uint256 ux = uint256 (int256 (x)) << uint256 (127 - msb);
      for (int256 bit = 0x8000000000000000; bit > 0; bit >>= 1) {
        ux *= ux;
        uint256 b = ux >> 255;
        ux >>= 127 + b;
        result += bit * int256 (b);
      }

      return int128 (result);
    }
  }

  /**
   * Calculate natural logarithm of x.  Revert if x <= 0.
   *
   * @param x signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function ln (int128 x) internal pure returns (int128) {
    unchecked {
      require (x > 0);

      return int128 (int256 (
          uint256 (int256 (log_2 (x))) * 0xB17217F7D1CF79ABC9E3B39803F2F6AF >> 128));
    }
  }

  /**
   * Calculate binary exponent of x.  Revert on overflow.
   *
   * @param x signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function exp_2 (int128 x) internal pure returns (int128) {
    unchecked {
      require (x < 0x400000000000000000); // Overflow

      if (x < -0x400000000000000000) return 0; // Underflow

      uint256 result = 0x80000000000000000000000000000000;

      if (x & 0x8000000000000000 > 0)
        result = result * 0x16A09E667F3BCC908B2FB1366EA957D3E >> 128;
      if (x & 0x4000000000000000 > 0)
        result = result * 0x1306FE0A31B7152DE8D5A46305C85EDEC >> 128;
      if (x & 0x2000000000000000 > 0)
        result = result * 0x1172B83C7D517ADCDF7C8C50EB14A791F >> 128;
      if (x & 0x1000000000000000 > 0)
        result = result * 0x10B5586CF9890F6298B92B71842A98363 >> 128;
      if (x & 0x800000000000000 > 0)
        result = result * 0x1059B0D31585743AE7C548EB68CA417FD >> 128;
      if (x & 0x400000000000000 > 0)
        result = result * 0x102C9A3E778060EE6F7CACA4F7A29BDE8 >> 128;
      if (x & 0x200000000000000 > 0)
        result = result * 0x10163DA9FB33356D84A66AE336DCDFA3F >> 128;
      if (x & 0x100000000000000 > 0)
        result = result * 0x100B1AFA5ABCBED6129AB13EC11DC9543 >> 128;
      if (x & 0x80000000000000 > 0)
        result = result * 0x10058C86DA1C09EA1FF19D294CF2F679B >> 128;
      if (x & 0x40000000000000 > 0)
        result = result * 0x1002C605E2E8CEC506D21BFC89A23A00F >> 128;
      if (x & 0x20000000000000 > 0)
        result = result * 0x100162F3904051FA128BCA9C55C31E5DF >> 128;
      if (x & 0x10000000000000 > 0)
        result = result * 0x1000B175EFFDC76BA38E31671CA939725 >> 128;
      if (x & 0x8000000000000 > 0)
        result = result * 0x100058BA01FB9F96D6CACD4B180917C3D >> 128;
      if (x & 0x4000000000000 > 0)
        result = result * 0x10002C5CC37DA9491D0985C348C68E7B3 >> 128;
      if (x & 0x2000000000000 > 0)
        result = result * 0x1000162E525EE054754457D5995292026 >> 128;
      if (x & 0x1000000000000 > 0)
        result = result * 0x10000B17255775C040618BF4A4ADE83FC >> 128;
      if (x & 0x800000000000 > 0)
        result = result * 0x1000058B91B5BC9AE2EED81E9B7D4CFAB >> 128;
      if (x & 0x400000000000 > 0)
        result = result * 0x100002C5C89D5EC6CA4D7C8ACC017B7C9 >> 128;
      if (x & 0x200000000000 > 0)
        result = result * 0x10000162E43F4F831060E02D839A9D16D >> 128;
      if (x & 0x100000000000 > 0)
        result = result * 0x100000B1721BCFC99D9F890EA06911763 >> 128;
      if (x & 0x80000000000 > 0)
        result = result * 0x10000058B90CF1E6D97F9CA14DBCC1628 >> 128;
      if (x & 0x40000000000 > 0)
        result = result * 0x1000002C5C863B73F016468F6BAC5CA2B >> 128;
      if (x & 0x20000000000 > 0)
        result = result * 0x100000162E430E5A18F6119E3C02282A5 >> 128;
      if (x & 0x10000000000 > 0)
        result = result * 0x1000000B1721835514B86E6D96EFD1BFE >> 128;
      if (x & 0x8000000000 > 0)
        result = result * 0x100000058B90C0B48C6BE5DF846C5B2EF >> 128;
      if (x & 0x4000000000 > 0)
        result = result * 0x10000002C5C8601CC6B9E94213C72737A >> 128;
      if (x & 0x2000000000 > 0)
        result = result * 0x1000000162E42FFF037DF38AA2B219F06 >> 128;
      if (x & 0x1000000000 > 0)
        result = result * 0x10000000B17217FBA9C739AA5819F44F9 >> 128;
      if (x & 0x800000000 > 0)
        result = result * 0x1000000058B90BFCDEE5ACD3C1CEDC823 >> 128;
      if (x & 0x400000000 > 0)
        result = result * 0x100000002C5C85FE31F35A6A30DA1BE50 >> 128;
      if (x & 0x200000000 > 0)
        result = result * 0x10000000162E42FF0999CE3541B9FFFCF >> 128;
      if (x & 0x100000000 > 0)
        result = result * 0x100000000B17217F80F4EF5AADDA45554 >> 128;
      if (x & 0x80000000 > 0)
        result = result * 0x10000000058B90BFBF8479BD5A81B51AD >> 128;
      if (x & 0x40000000 > 0)
        result = result * 0x1000000002C5C85FDF84BD62AE30A74CC >> 128;
      if (x & 0x20000000 > 0)
        result = result * 0x100000000162E42FEFB2FED257559BDAA >> 128;
      if (x & 0x10000000 > 0)
        result = result * 0x1000000000B17217F7D5A7716BBA4A9AE >> 128;
      if (x & 0x8000000 > 0)
        result = result * 0x100000000058B90BFBE9DDBAC5E109CCE >> 128;
      if (x & 0x4000000 > 0)
        result = result * 0x10000000002C5C85FDF4B15DE6F17EB0D >> 128;
      if (x & 0x2000000 > 0)
        result = result * 0x1000000000162E42FEFA494F1478FDE05 >> 128;
      if (x & 0x1000000 > 0)
        result = result * 0x10000000000B17217F7D20CF927C8E94C >> 128;
      if (x & 0x800000 > 0)
        result = result * 0x1000000000058B90BFBE8F71CB4E4B33D >> 128;
      if (x & 0x400000 > 0)
        result = result * 0x100000000002C5C85FDF477B662B26945 >> 128;
      if (x & 0x200000 > 0)
        result = result * 0x10000000000162E42FEFA3AE53369388C >> 128;
      if (x & 0x100000 > 0)
        result = result * 0x100000000000B17217F7D1D351A389D40 >> 128;
      if (x & 0x80000 > 0)
        result = result * 0x10000000000058B90BFBE8E8B2D3D4EDE >> 128;
      if (x & 0x40000 > 0)
        result = result * 0x1000000000002C5C85FDF4741BEA6E77E >> 128;
      if (x & 0x20000 > 0)
        result = result * 0x100000000000162E42FEFA39FE95583C2 >> 128;
      if (x & 0x10000 > 0)
        result = result * 0x1000000000000B17217F7D1CFB72B45E1 >> 128;
      if (x & 0x8000 > 0)
        result = result * 0x100000000000058B90BFBE8E7CC35C3F0 >> 128;
      if (x & 0x4000 > 0)
        result = result * 0x10000000000002C5C85FDF473E242EA38 >> 128;
      if (x & 0x2000 > 0)
        result = result * 0x1000000000000162E42FEFA39F02B772C >> 128;
      if (x & 0x1000 > 0)
        result = result * 0x10000000000000B17217F7D1CF7D83C1A >> 128;
      if (x & 0x800 > 0)
        result = result * 0x1000000000000058B90BFBE8E7BDCBE2E >> 128;
      if (x & 0x400 > 0)
        result = result * 0x100000000000002C5C85FDF473DEA871F >> 128;
      if (x & 0x200 > 0)
        result = result * 0x10000000000000162E42FEFA39EF44D91 >> 128;
      if (x & 0x100 > 0)
        result = result * 0x100000000000000B17217F7D1CF79E949 >> 128;
      if (x & 0x80 > 0)
        result = result * 0x10000000000000058B90BFBE8E7BCE544 >> 128;
      if (x & 0x40 > 0)
        result = result * 0x1000000000000002C5C85FDF473DE6ECA >> 128;
      if (x & 0x20 > 0)
        result = result * 0x100000000000000162E42FEFA39EF366F >> 128;
      if (x & 0x10 > 0)
        result = result * 0x1000000000000000B17217F7D1CF79AFA >> 128;
      if (x & 0x8 > 0)
        result = result * 0x100000000000000058B90BFBE8E7BCD6D >> 128;
      if (x & 0x4 > 0)
        result = result * 0x10000000000000002C5C85FDF473DE6B2 >> 128;
      if (x & 0x2 > 0)
        result = result * 0x1000000000000000162E42FEFA39EF358 >> 128;
      if (x & 0x1 > 0)
        result = result * 0x10000000000000000B17217F7D1CF79AB >> 128;

      result >>= uint256 (int256 (63 - (x >> 64)));
      require (result <= uint256 (int256 (MAX_64x64)));

      return int128 (int256 (result));
    }
  }

  /**
   * Calculate natural exponent of x.  Revert on overflow.
   *
   * @param x signed 64.64-bit fixed point number
   * @return signed 64.64-bit fixed point number
   */
  function exp (int128 x) internal pure returns (int128) {
    unchecked {
      require (x < 0x400000000000000000); // Overflow

      if (x < -0x400000000000000000) return 0; // Underflow

      return exp_2 (
          int128 (int256 (x) * 0x171547652B82FE1777D0FFDA0D23A7D12 >> 128));
    }
  }

  /**
   * Calculate x / y rounding towards zero, where x and y are unsigned 256-bit
   * integer numbers.  Revert on overflow or when y is zero.
   *
   * @param x unsigned 256-bit integer number
   * @param y unsigned 256-bit integer number
   * @return unsigned 64.64-bit fixed point number
   */
  function divuu (uint256 x, uint256 y) private pure returns (uint128) {
    unchecked {
      require (y != 0);

      uint256 result;

      if (x <= 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF)
        result = (x << 64) / y;
      else {
        uint256 msb = 192;
        uint256 xc = x >> 192;
        if (xc >= 0x100000000) { xc >>= 32; msb += 32; }
        if (xc >= 0x10000) { xc >>= 16; msb += 16; }
        if (xc >= 0x100) { xc >>= 8; msb += 8; }
        if (xc >= 0x10) { xc >>= 4; msb += 4; }
        if (xc >= 0x4) { xc >>= 2; msb += 2; }
        if (xc >= 0x2) msb += 1;  // No need to shift xc anymore

        result = (x << 255 - msb) / ((y - 1 >> msb - 191) + 1);
        require (result <= 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF);

        uint256 hi = result * (y >> 128);
        uint256 lo = result * (y & 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF);

        uint256 xh = x >> 192;
        uint256 xl = x << 64;

        if (xl < lo) xh -= 1;
        xl -= lo; // We rely on overflow behavior here
        lo = hi << 128;
        if (xl < lo) xh -= 1;
        xl -= lo; // We rely on overflow behavior here

        assert (xh == hi >> 128);

        result += xl / y;
      }

      require (result <= 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF);
      return uint128 (result);
    }
  }

  /**
   * Calculate sqrt (x) rounding down, where x is unsigned 256-bit integer
   * number.
   *
   * @param x unsigned 256-bit integer number
   * @return unsigned 128-bit integer number
   */
  function sqrtu (uint256 x) private pure returns (uint128) {
    unchecked {
      if (x == 0) return 0;
      else {
        uint256 xx = x;
        uint256 r = 1;
        if (xx >= 0x100000000000000000000000000000000) { xx >>= 128; r <<= 64; }
        if (xx >= 0x10000000000000000) { xx >>= 64; r <<= 32; }
        if (xx >= 0x100000000) { xx >>= 32; r <<= 16; }
        if (xx >= 0x10000) { xx >>= 16; r <<= 8; }
        if (xx >= 0x100) { xx >>= 8; r <<= 4; }
        if (xx >= 0x10) { xx >>= 4; r <<= 2; }
        if (xx >= 0x8) { r <<= 1; }
        r = (r + x / r) >> 1;
        r = (r + x / r) >> 1;
        r = (r + x / r) >> 1;
        r = (r + x / r) >> 1;
        r = (r + x / r) >> 1;
        r = (r + x / r) >> 1;
        r = (r + x / r) >> 1; // Seven iterations should be enough
        uint256 r1 = x / r;
        return uint128 (r < r1 ? r : r1);
      }
    }
  }
}
          

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.17;

uint256 constant HELLP_RAMP_FREQ    = 1 days;
 int128 constant HELLP_EMIT_RATE    = 1690 * 10 ** 14;
 int128 constant HELLP_DEPOSIT_FEE  = 69 * 10 ** 14;
 int128 constant HELLP_WITHDRAW_FEE = 69 * 10 ** 14;
 int128 constant HELLP_REWARD       = 1 * 10 ** 14;
 string constant HELLP_NAME         = 'HELLP-Emissions';
 string constant HELLP_TOKEN        = 'HELLP';

uint256 constant HELGAS_RAMP_FREQ    = 1 days;
 int128 constant HELGAS_EMIT_RATE    = 669 * 10 ** 14;
 int128 constant HELGAS_DEPOSIT_FEE  = 69 * 10 ** 14;
 int128 constant HELGAS_WITHDRAW_FEE = 69 * 10 ** 14;
 int128 constant HELGAS_REWARD       = 1 * 10 ** 14;
 string constant HELGAS_NAME         = 'HELGO-Emissions';
 string constant HELGAS_TOKEN        = 'HELGAS';

 uint64 constant FOUNDERS_CLIFF   = 60 * 60 * 24 * 365; 
 uint64 constant FOUNDERS_VESTING = 60 * 60 * 24 * 5555;
 uint64 constant HELGO_LAUNCH_LENGTH = 33 days;

 int128 constant MEME_SMALL_PERC  = 69 * 10 ** 14;
 int128 constant MEME_LARGE_PERC  = 369 * 10 ** 14;

 uint64 constant VOTE_FREQUENCY     = 1 days;
 uint64 constant VOTE_MIN_FREQUENCY = 3 hours;
 uint64 constant VOTE_MAX_FREQUENCY = 4 weeks;

 uint64 constant VOTE_MIN_PRICE_DAYS                             = 3;
   uint constant VOTE_IDIOT_T_MAN                                = 1;
   uint constant VOTE_SHUT_UP_IDIOT_MAN                          = 2;
   uint constant VOTE_I_AM_HELGO                                 = 3;
   uint constant VOTE_PLEASE_EVERY_BODY_REMEMBER_TO_BUY_HEX      = 4;
   uint constant VOTE_DOUBLE_PERIOD                              = 5;
   uint constant VOTE_HALF_PERIOD                                = 6;
 string constant VOTE_DESC_IDIOT_T_MAN                           = 'Use 0.69% of HEX to buy HELGO';
 string constant VOTE_DESC_SHUT_UP_IDIOT_MAN                     = 'Use 0.69% of HELGO to buy HEX';
 string constant VOTE_DESC_I_AM_HELGO                            = 'Uses 3.69% of HEX to buy HELGO (votable when HEX near ATH)';
 string constant VOTE_DESC_PLEASE_EVERY_BODY_REMEMBER_TO_BUY_HEX = 'Uses 3.69% of HELGO to buy HEX (votable when HEX at 3 month low)';
 string constant VOTE_DESC_DOUBLE_PERIOD                         = 'Doubles the length of the vote period';
 string constant VOTE_DESC_HALF_PERIOD                           = 'Halves the length of the vote period';

// Uniswap V2 + PulseX router
address constant ROUTERV2 = 0x7a250d5630B4cF539739dF2C5dAcb4c659F2488D;
address constant WETH = 0xC02aaA39b223FE8D0A0e5C4F27eAD9083C756Cc2;

// LIVE, PulseX router V2
address constant ROUTERPULSEX = 0x165C3410fC91EF562C50559f7d2289fEbed552d9;
address constant WPLS = 0xA1077a294dDE1B09bB078844df40758a5D0f9a27;

contract Founders {
    // Founder addresses
    address[] public HELGO_FOUNDERS = [
        0x892097a6Bbf318e8B3b5d27044782975DcfBc47B,
        0xb7Da80B7db32f57281545d45ffD691914dc2252b,
        0x83559662dE19aaB3BECc817865061aF699421B9a,
        0x13E0A697a1dF2Fc28f6D8f4F98F417be51CA5232,
        0xF999e2E31cE9c70F697545a99dF20D4346B94e26,
        0x19Df3fC60AE23784cb2009C6a32E73999Dd7b4A4,
        0x10F0A702D1FF73d54404BA96A5E114B0A6574d05,
        0x0dC72F41FA93260c2A909408525dF37491d42999,
        0xE3AF5DB5947e4eFea79747C8A5C09DA728313BCC,
        0x728AacBcE90709d8Ee3DD7C42e56A5512CF742c2,
        0xDE0Fb3aF3B72AfD2e39c525E476d8Fbea1b6b006,
        0xA97cA893f62e845b929f65a8d128Cb71D03F3Be3,
        0x4d0e4012F8E0428E90FC36DFF351aF9788e0c60E,
        0x7e04D6194C2ECBf7Ee730B36E17d29726ea9c5FA,
        0x662F84b2f9507cfC02fb259C8c64455fAe8d01b6,
        0x48FcC86Bb079B97dDE0D10026B22069Df5c6630A,
        0x0De4aA116a9B536e9b7c17F2743925117Cdc57E0,
        0xDC6A8C0505EbC3954da4030A135fEe5e568F7d09,
        0xf027324b27Dff4243f13208F1a3aE34b6b514b3A,
        0x4555261e2d5A9A2b9b0FCF26f534a8fd8A8F2f9D,
        0x47C81C1D47742B41fF7d1c04e08d3036aE01F4a1,
        0x9C2f87D3ae338e4fE5f317a4219762dE7CE0eb24,
        0xE33b7F805c97A7f88963CE20629bbe88a9d08986,
        0x307F17350086232FEaa6E17808662A5AEF29841f,
        0x7CC483F2ba233F6F4b52f43b8b657D1071e5F5aB,
        0x2a25da22E94884f3b7B6841a98f21325E131C4b6,
        0x212ff16Ea41fc0394625c9e2D5D45532ea4Cf100,
        0xBeB348B205841be55bF4Fe1732c2a81b390c50d9,
        0x4D30801092100F9E0aA3bf31336B12cBa4dAb29b,
        0xE40569F208Ec96Adad9E0127b5724d50D15E039d,
        0x895A1feFf0ce1DFEB5C15f2c237223537Fc87FE2,
        0x7b156358C4a63a01088CB496212eA02412e34F75,
        0x717B8898860B1d45A621e41360f143DA2C8bc292,
        0x55f7B7286AE9a9Aeabc5cB79Cb8ede034665B20E,
        0x5bC36C7187aA603576CF95108B1107e087Aff64D,
        0x0a93F5Bc1a0aEbFa92180eEc1d4990827446188A,
        0x011df7c4D325290e5D07689E057c5527BdBBcEb0
    ];

    uint public immutable TOTAL_FOUNDERS;

    mapping(address => bool) public founder;

    constructor(){    
        for (uint i=0; i < HELGO_FOUNDERS.length; i++) {
            founder[HELGO_FOUNDERS[i]] = true;
        }
        TOTAL_FOUNDERS = HELGO_FOUNDERS.length;
    }
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

import "@openzeppelin/contracts/proxy/Clones.sol";
import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "contracts/Vault.sol";
import "interfaces/Helgo.sol";
import "interfaces/HEX.sol";
import "interfaces/IUniswapV2Router01.sol";
import "contracts/Votable.sol";
import "config/Settings.sol";

/**
 * @dev HELDAO
 *
 * Used to lock HELGO
 * Used for MEME votes
 * Creates Vault when necessary
 * Provides vote relative to time locked
 */

import { ABDKMath64x64 as Math } from "abdk-libraries-solidity/ABDKMath64x64.sol";

contract Heldao is Votable {

    IUniswapV2Router01 private ROUTER;
    IHEX immutable private HEX;
    IHELGO immutable private HELGO;
    Vault immutable private VAULT;

    uint64 private priceChecked;

    uint256[] public priceHistory;

    constructor(address _helgo, address _router, address _hex)
        Votable(VOTE_FREQUENCY)
    {
        ROUTER = IUniswapV2Router01(_router);
        HELGO = IHELGO(_helgo);
        HEX = IHEX(payable(_hex)); 
        VAULT = new Vault();

        // Add default proposals
        addProposal(VOTE_IDIOT_T_MAN, VOTE_DESC_IDIOT_T_MAN);
        addProposal(VOTE_SHUT_UP_IDIOT_MAN, VOTE_DESC_SHUT_UP_IDIOT_MAN);
        addProposal(VOTE_PLEASE_EVERY_BODY_REMEMBER_TO_BUY_HEX, VOTE_DESC_PLEASE_EVERY_BODY_REMEMBER_TO_BUY_HEX);
        addProposal(VOTE_I_AM_HELGO, VOTE_DESC_I_AM_HELGO);
        addProposal(VOTE_DOUBLE_PERIOD, VOTE_DESC_DOUBLE_PERIOD);
        addProposal(VOTE_HALF_PERIOD, VOTE_DESC_HALF_PERIOD);
        lockProposals();
    }

    mapping (address => Vault) public vaults;

    // @returns midnight unix utc
    function today() public view returns (uint64) {
        return uint64((block.timestamp / 1 days) * 1 days);
    }    

    /////////////////////
    // VAULT READ ONLY //
    /////////////////////

    // @returns HELGO balance in vault
    function balanceOf(address addr) public view returns(uint256) {
        Vault vault = vaults[addr];
        // zero when nothing locked
        if(address(vault) == address(0)) {
            return 0;
        }
        return HELGO.balanceOf(address(vault));
    }

    // @returns HELGO balance in vault, less vested amount
    function locked(address addr) public view returns(uint256) {
        Vault vault = vaults[addr];
        // zero when nothing locked
        if(address(vault) == address(0)) {
            return 0;
        }

        uint256 vest = vault.vestedAmount(address(HELGO), uint64(block.timestamp));
        uint256 balance = HELGO.balanceOf(address(vault));

        return balance - vest;
    }

    // @returns total HELGO that can be released
    function vested(address addr) public view returns(uint256) {
        Vault vault = vaults[addr];
        // zero when nothing locked
        if(address(vault) == address(0)) {
            return 0;
        }
        return vault.vestedAmount(address(HELGO), uint64(block.timestamp));
    }

    // @returns total HELGO released so far
    function released(address addr) public view returns(uint256) {
        Vault vault = vaults[addr];
        return vault.releasedToken(address(HELGO));
    }

    // @returns total votes (HELGO balance * duriation)
    function votes(address addr) public view returns(uint256) {
        Vault vault = vaults[addr];
        // No votes when nothing locked
        if(address(vault) == address(0)) {
            return 0;
        }
        // Multiply by duration of lock
        return HELGO.balanceOf(address(vault)) * vault.duration();
    }

    /////////////////
    // VAULT CALLS //
    /////////////////    

    // @notice creates or returns a vault for an address
    function initVault(address addr, uint64 start, uint64 duration) external returns(address) {
        Vault vault = vaults[addr];
        // Create vault when needed
        if(address(vault) == address(0)) {

            // Clone the vault
            address payable clone = payable(Clones.clone(address(VAULT)));

            vault = Vault(clone);

            // Initialise
            vault.initialise(addr, start, duration);

            // Changed to a clonable
            vaults[addr] = vault;
        }
        return address(vault);
    } 

    ////////////////////////
    // VOTABLE BEHAVIOURS //
    ////////////////////////  

    // @dev override votable getVotes
    // @returns votes for user
    function getVotes(address addr) override public view returns(uint256) {
        return votes(addr);
    }

    // @dev override votable castVote
    // @dev casts votes for a poposal
    function castVote(uint proposal, uint256 _votes) public override {

        // Update price history
        _updatePrice();

        // uses 3.69% of HELGO to buy HEX (votable when HEX at 3 month low)
        if(proposal == VOTE_PLEASE_EVERY_BODY_REMEMBER_TO_BUY_HEX) {
            require(alltimelowHEX(), 'HEX not at 90 day low');
        }

        // uses 3.69% of HEX to buy HELGO (votable when HEX near ATH)
        else if(proposal == VOTE_I_AM_HELGO) {
            require(alltimehighHEX(), 'HEX not at 90 day high');
        }        

        super.castVote(proposal, _votes);
    }

    // @dev overrides invokeVote — called on vote tally
    // @dev invokes votes
    function _invokeVote(uint proposal, uint256 _votes) override internal {

        // Update price history
        _updatePrice();

        // Do nothing when no votes
        if(_votes > 0) {
            if(proposal == VOTE_IDIOT_T_MAN) {
                idiot_t_man();
            }
            else if(proposal == VOTE_SHUT_UP_IDIOT_MAN) {
                shut_up_idiot_man();
            }
            else if(proposal == VOTE_I_AM_HELGO) {
                i_am_helgo();
            }
            else if(proposal == VOTE_PLEASE_EVERY_BODY_REMEMBER_TO_BUY_HEX) {
                please_every_body_remember_to_buy_hex();
            }
            else if(proposal == VOTE_DOUBLE_PERIOD) {
                double_vote_period();
            }
            else if(proposal == VOTE_HALF_PERIOD) {
                half_vote_period();
            }
        }
    }

    //////////////////////
    // HELGO MEME VOTES //
    //////////////////////

    // @notice uses small % of HEX to buy HELGO
    function idiot_t_man() internal {
        // Get HEX balance     
        uint256 amount = Math.mulu(Math.div(MEME_SMALL_PERC, 10 ** 18) + 1, HEX.balanceOf(address(this)));

        // Buy if balance
        if(amount > 0) {
            buyHELGO(amount);
        }
    }

    // @notice Use small % of HELGO to buy HEX
    function shut_up_idiot_man() internal {
        // Get HEX balance
        uint256 amount = Math.mulu(Math.div(MEME_SMALL_PERC, 10 ** 18) + 1, HELGO.balanceOf(address(this)));

        // Buy if balance
        if(amount > 0) {
            buyHEX(amount);
        }
    }

    // @notice uses large % of HEX to buy HELGO (votable when HEX near ATH)
    function i_am_helgo() internal {
        // Get HEX balance
        uint256 amount = Math.mulu(Math.div(MEME_LARGE_PERC, 10 ** 18) + 1, HEX.balanceOf(address(this)));

        // Buy if balance
        if(amount > 0) {
            buyHELGO(amount);
        }
    }

    // @notice uses large % of HEX to buy HELGO
    function please_every_body_remember_to_buy_hex() internal {
        // Get HEX balance
        uint256 amount = Math.mulu(Math.div(MEME_LARGE_PERC, 10 ** 18) + 1, HELGO.balanceOf(address(this)));

        // Buy if balance
        if(amount > 0) {
            buyHEX(amount);
        }
    }

    // @notice increases vote period
    function double_vote_period() internal {
        if(_voteFrequency < VOTE_MAX_FREQUENCY) {
            _voteFrequency = ((_voteFrequency * 2) / 1 hours) * 1 hours;
            _votePeriod = currentPeriod();
        }
    }

    // @notice decreases vote period
    function half_vote_period() internal {
        if(_voteFrequency > VOTE_MIN_FREQUENCY) {
            _voteFrequency = ((_voteFrequency / 2) / 1 hours) * 1 hours;
            _votePeriod = currentPeriod();
        }
    }

    ///////////////////
    // PRICE HISTORY //
    ///////////////////

    // @returns true if HEX at a < 90 day low
    function alltimelowHEX() public view returns(bool) {

        uint totaldays = priceHistory.length;

        if(totaldays > 90) {
            totaldays = 90;
        }

        if(totaldays == 0) {
            return false;
        }
        
        uint end = priceHistory.length - totaldays;
        uint256 low;

        // Tally and reset votes
        for (uint i = priceHistory.length - 1; i > end; i--) {
            if(priceHistory[i] < low || low == 0) {
                low = priceHistory[i];
            }
        }

        return priceHistory.length >= VOTE_MIN_PRICE_DAYS && low == priceHistory[priceHistory.length - 1];
    }

    // @returns true if HEX at a < 90 day high
    function alltimehighHEX() public view returns(bool) {

        uint totaldays = priceHistory.length;

        if(totaldays == 0) {
            return false;
        }

        if(totaldays > 90) {
            totaldays = 90;
        }

        uint end = priceHistory.length - totaldays;
        uint256 high;

        // Tally and reset votes
        for (uint i = priceHistory.length - 1; i > end; i--) {
            if(priceHistory[i] > high || high == 0) {
                high = priceHistory[i];
            }
        }

        return priceHistory.length >= VOTE_MIN_PRICE_DAYS && high == priceHistory[priceHistory.length - 1];
    }

    // @dev check if price should be recorded
    function _updatePrice() private {
        // update the price
        if( today() != priceChecked ) {
            priceHistory.push(
                priceHEX()
            );

            priceChecked = today();
        }        
    }

    //////////////////
    // ROUTER CALLS //
    //////////////////

    // @notice buys HELGO using HEX
    function buyHELGO(uint256 amountHex) private {
        swap(address(HEX), address(HELGO), amountHex, address(this));
    }

    // @notice buys HEX using HELGO
    function buyHEX(uint256 amountHelgo) private {
        swap(address(HELGO), address(HEX), amountHelgo, address(this));
    }

    // @notice swaps tokens using router
    function swap(address token0, address token1, uint256 amount, address to) private {

        address[] memory path;
        path = new address[](2);
        path[0] = token0;
        path[1] = token1;

        IERC20 erc = IERC20(token0);

        // check if ROUTER allowance, reset if required
        if(erc.allowance(address(this), address(ROUTER)) < amount){
            erc.approve(address(ROUTER), type(uint256).max);
        }                        
        ROUTER.swapExactTokensForTokens(
            amount, 0, path, to, block.timestamp + 10000
        );
    }

    // @returns price of token
    function price(address token0, address token1, uint decimals) private view returns(uint256 amount) {

        // Swap path
        address[] memory path;
        path = new address[](2);
        path[0] = token0;
        path[1] = token1;

        // Get amounts
        uint[] memory amounts = ROUTER.getAmountsOut(1 * 10 ** decimals, path);

        return amounts[1];
    }

    // @returns HEX price in ETH or PULSE
    function priceHEX() public view returns(uint256 amount) {
        return price(address(HEX), address(ROUTER) == ROUTERPULSEX ? WPLS : WETH, 10);
    }

    // @returns HELGO price in HEX
    function priceHELGO() public view returns(uint256 amount) {
        return price(address(HELGO), address(HEX), 18);
    }

}
          

// SPDX-License-Identifier: MIT
// Based on OpenZeppelin Contracts v4.4.1 (finance/VestingWallet.sol)
// Modified to support: cloning, increase start, increase duration, 
// only beneficiary can increase / release

import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/utils/Address.sol";
import "@openzeppelin/contracts/utils/Context.sol";
import "@openzeppelin/contracts/proxy/Clones.sol";

pragma solidity ^0.8.17;

contract Vault is Context {
    event Released(uint256 amount);
    event TokenReleased(address indexed token, uint256 amount);

    event IncreasedStart(uint64 timestamp);
    event IncreasedDuration(uint64 duration);

    uint256 private _released;
    mapping(address => uint256) private _erc20Released;

    address private _beneficiary;
    uint64 private  _start;
    uint64 private  _duration;
    bool private _intialised;

    // @dev Set the beneficiary, start timestamp and vesting duration of the vesting wallet.
    function initialise(
        address beneficiaryAddress,
        uint64 startTimestamp,
        uint64 durationSeconds
    ) public virtual {
        require(beneficiaryAddress != address(0), "Vault: beneficiary is zero address");
        require(_intialised != true, "Vault: already initialised");
        _beneficiary = beneficiaryAddress;
        _start = startTimestamp;
        _duration = durationSeconds;
        _intialised = true;
    }

    // @dev only allow beneficiary 
    modifier onlyBeneficiary() {
        require(beneficiary() == _msgSender(), "Vault: caller is not the beneficiary");
        _;
    }

    ///////////////
    // VIEW ONLY //
    ///////////////

    // @dev Getter for the beneficiary address.
    function beneficiary() public view virtual returns (address) {
        return _beneficiary;
    }

    // @dev Getter for the start timestamp.
    function start() public view virtual returns (uint256) {
        return _start;
    }

    // @dev Getter for the vesting duration.
    function duration() public view virtual returns (uint256) {
        return _duration;
    }

    // @dev Amount of eth already released
    function released() public view virtual returns (uint256) {
        return _released;
    }

    // @dev Amount of token already released
    function releasedToken(address token) public view virtual returns (uint256) {
        return _erc20Released[token];
    }

    // @dev Calculates the amount of ether that has already vested. Default implementation is a linear vesting curve.
    function vestedAmount(uint64 timestamp) public view virtual returns (uint256) {
        return _vestingSchedule(address(this).balance + released(), timestamp);
    }

    // @dev Calculates the amount of tokens that has already vested. Default implementation is a linear vesting curve.
    function vestedAmount(address token, uint64 timestamp) public view virtual returns (uint256) {
        return _vestingSchedule(IERC20(token).balanceOf(address(this)) + releasedToken(token), timestamp);
    }

    ////////////
    // PUBLIC //
    ////////////

    // @dev The contract should be able to receive Eth.
    receive() external payable virtual {}

    // @dev Release the native token (ether) that have already vested.
    function release() public virtual onlyBeneficiary {
        uint256 releasable = vestedAmount(uint64(block.timestamp)) - released();
        _released += releasable;
        emit Released(releasable);
        Address.sendValue(payable(beneficiary()), releasable);
    }

    // @dev Release the tokens that have already vested.
    function releaseToken(address token) public virtual onlyBeneficiary {
        uint256 releasable = vestedAmount(token, uint64(block.timestamp)) - releasedToken(token);
        _erc20Released[token] += releasable;
        emit TokenReleased(token, releasable);
        SafeERC20.safeTransfer(IERC20(token), beneficiary(), releasable);
    }

    // @dev allow vault owner to increase start 
    function increaseStart(uint64 newStart) public virtual onlyBeneficiary {
        require(newStart > _start, 'New start must be greater than previous');
        emit IncreasedStart(newStart);
        _start = newStart;
    }

    // @dev allow vault owner to increase duration 
    function increaseDuration(uint64 newDuration) public virtual onlyBeneficiary {
        require(newDuration > _duration, 'New duration must be greater than previous');
        emit IncreasedDuration(newDuration);
        _duration = newDuration;
    }

    //////////////
    // INTERNAL //
    //////////////

    // @dev Virtual implementation of the vesting formula. This returns the amout vested, as a function of time, for
    // an asset given its total historical allocation.
    function _vestingSchedule(uint256 totalAllocation, uint64 timestamp) internal view virtual returns (uint256) {
        if (timestamp < start()) {
            return 0;
        } else if (timestamp > start() + duration()) {
            return totalAllocation;
        } else {
            return (totalAllocation * (timestamp - start())) / duration();
        }
    }
}


          

// SPDX-License-Identifier: UNLICENSED

pragma solidity ^0.8.17;

/**
 * @dev Votable
 * 
 * 1x vote per voting votePeriod
 * vote count and eligibility handled by parent
 * override: getVotes, invokeVote, votePeriod, addProposal
 *
 */

contract Votable {

    event Proposed(uint id, string desc);
    event Voted(uint proposal, address addr, uint256 votes,  uint256 period);
    event Winner(uint proposal, uint256 votes, uint256 total);

    mapping(address => uint256) private voted;

    struct Proposal {
        uint id;
        string desc;
        uint256 votes;
    }

    struct Result {
        uint proposal;
        uint256 votes;
        uint256 total;
        uint64 timestamp;
    }

    Proposal[] public proposals;
    Result[] public results;

    bool private proposalsLocked;
    uint64 internal _votePeriod;
    uint64 internal _voteFrequency;

    constructor(uint64 frequency){
        // Start current vote votePeriod
        require(frequency >= 1 hours, 'initial voteFrequency less than 1 hour');
        _voteFrequency = frequency;
        _votePeriod = currentPeriod();
    }

    function currentPeriod() public virtual view returns(uint64) {
        return uint64(block.timestamp / _voteFrequency) * _voteFrequency;
    }

    function votePeriod() public virtual view returns(uint64) {
        return _votePeriod;
    }

    function voteFrequency() public virtual view returns(uint64) {
        return _voteFrequency;
    }

    function getProposals() public virtual view returns(Proposal[] memory){
        return proposals;
    }

    function totalProposals() public virtual view returns(uint256){
        return proposals.length;
    }

    function totalResults() public virtual view returns(uint256){
        return results.length;
    }

    function shouldTally() public view virtual returns(bool) {
        return _votePeriod != currentPeriod();
    }

    /**
     * @dev maximum votes for address
     * defaults to 1 per address
     * override for custom logic
     */     
    function getVotes(address addr) public virtual view returns(uint256) {
        if(addr != address(0)) {
            return 1;
        }
        else {
            return 0;
        }
    }

    function canVote(address addr) public view virtual returns(bool) {
        return _canVote(addr);
    }

    /**
     * @dev add a voting proposal
     * id must be unique and greater than zero
     */
    function addProposal(uint id, string memory desc) public virtual {
        require(!proposalsLocked, 'Proposals locked');
        _addProposal(id, desc);
    }

    function castVote(uint proposal, uint256 votes) public virtual {
        require(proposal > 0, 'Proposal required');
        require(votes > 0, 'Votes required');
        _castVote(msg.sender, proposal, votes);
    }

    function tallyVotes() public returns(uint256) {
        require(_votePeriod != currentPeriod(), 'Voting still underway');
        return _tallyVotes();
    }

    function lockProposals() internal {
        proposalsLocked = true;
    }

    /**
     * @dev invoke hook
     * called when vote is tallied 
     * override to handle result
     */
    function _invokeVote(uint proposal, uint256 votes) internal virtual {
    }

    function _addProposal(uint id, string memory desc) internal {
        // Check unique
        for (uint i = 0; i < proposals.length; i++) {
            require(proposals[i].id != id, 'Proposal id is not unique');
        }

        // Add proposal
        proposals.push(Proposal(id, desc, 0));

        // Emit event
        emit Proposed(
            id,
            desc
        );
    }

    function _canVote(address addr) internal virtual view returns(bool){
        return voted[addr] != currentPeriod() && getVotes(addr) > 0; 
    }

    function _castVote(address addr, uint proposal, uint256 votes) internal returns(uint256) {
        require( voted[addr] != currentPeriod(), 'Already voted');
        require( getVotes(addr) > 0, 'No votes');
        require( getVotes(addr) >= votes, 'Not enough votes');

        // Check if we should tally votes
        if(shouldTally()){
            _tallyVotes();
        }

        // One vote per votePeriod
        voted[addr] = currentPeriod();

        // Vote for option
        for (uint i = 0; i < proposals.length; i++) {
            if(proposals[i].id == proposal) {
                emit Voted(proposals[i].id, addr, votes, currentPeriod());
                return proposals[i].votes += votes;
            }
        }

        // No proposal matched
        revert('Not a valid proposal');
    }

    function _tallyVotes() private returns(uint256) {
  
        uint winner;
        uint256 max;
        uint256 total;
        uint256 draw;

        // Tally and reset votes
        for (uint i = 0; i < proposals.length; i++) {
            if(proposals[i].votes > max) {
                winner = proposals[i].id;
                max = proposals[i].votes;
                draw = 0;
            }
            else if(proposals[i].votes == max) {
                draw = 1;
            }

            total += proposals[i].votes;
            proposals[i].votes = 0;
        }

        // Disallow draws
        if(draw == 1) {
            winner = 0;
        }

        // Set new votePeriod
        _votePeriod = currentPeriod();

        // Emit result
        emit Winner(winner, max, total);

        // Record winndow
        results.push(Result(
            winner,
            max,
            total,
            uint64(block.timestamp)
        ));

        // Invoke winner (if any)
        _invokeVote(winner, max);

        return winner;
    }
}


          

// SPDX-License-Identifier: MIT
// !! THIS FILE WAS AUTOGENERATED BY abi-to-sol v0.5.2. SEE SOURCE BELOW. !!
// Launch claim events removed
pragma solidity >=0.7.0 <0.9.0;

interface IHEX {
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );
    event DailyDataUpdate(uint256 data0, address indexed updaterAddr);
    event ShareRateChange(uint256 data0, uint40 indexed stakeId);
    event StakeEnd(
        uint256 data0,
        uint256 data1,
        address indexed stakerAddr,
        uint40 indexed stakeId
    );
    event StakeGoodAccounting(
        uint256 data0,
        uint256 data1,
        address indexed stakerAddr,
        uint40 indexed stakeId,
        address indexed senderAddr
    );
    event StakeStart(
        uint256 data0,
        address indexed stakerAddr,
        uint40 indexed stakeId
    );
    event Transfer(address indexed from, address indexed to, uint256 value);

    function allocatedSupply() external view returns (uint256);

    function allowance(address owner, address spender)
        external
        view
        returns (uint256);

    function approve(address spender, uint256 amount) external returns (bool);

    function balanceOf(address account) external view returns (uint256);

    function currentDay() external view returns (uint256);

    function dailyData(uint256)
        external
        view
        returns (
            uint72 dayPayoutTotal,
            uint72 dayStakeSharesTotal,
            uint56 dayUnclaimedSatoshisTotal
        );

    function dailyDataRange(uint256 beginDay, uint256 endDay)
        external
        view
        returns (uint256[] memory list);

    function dailyDataUpdate(uint256 beforeDay) external;

    function decimals() external view returns (uint8);

    function decreaseAllowance(address spender, uint256 subtractedValue)
        external
        returns (bool);

    function globalInfo() external view returns (uint256[13] memory);

    function globals()
        external
        view
        returns (
            uint72 lockedHeartsTotal,
            uint72 nextStakeSharesTotal,
            uint40 shareRate,
            uint72 stakePenaltyTotal,
            uint16 dailyDataCount,
            uint72 stakeSharesTotal,
            uint40 latestStakeId,
            uint128 claimStats
        );

    function increaseAllowance(address spender, uint256 addedValue)
        external
        returns (bool);

    function name() external view returns (string memory);

    function stakeCount(address stakerAddr) external view returns (uint256);

    function stakeEnd(uint256 stakeIndex, uint40 stakeIdParam) external;

    function stakeGoodAccounting(
        address stakerAddr,
        uint256 stakeIndex,
        uint40 stakeIdParam
    ) external;

    function stakeLists(address, uint256)
        external
        view
        returns (
            uint40 stakeId,
            uint72 stakedHearts,
            uint72 stakeShares,
            uint16 lockedDay,
            uint16 stakedDays,
            uint16 unlockedDay,
            bool isAutoStake
        );

    function stakeStart(uint256 newStakedHearts, uint256 newStakedDays)
        external;

    function symbol() external view returns (string memory);

    function totalSupply() external view returns (uint256);

    function transfer(address recipient, uint256 amount)
        external
        returns (bool);

    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);
}
          

// SPDX-License-Identifier: UNLICENSED
// !! THIS FILE WAS AUTOGENERATED BY abi-to-sol v0.5.2. SEE SOURCE BELOW. !!
pragma solidity >=0.7.0 <0.9.0;
pragma experimental ABIEncoderV2;

interface IHELGO {
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );
    event Claimed(address indexed addr, uint256 amount, uint256 amountHELLP);
    event Deposited(address indexed addr, uint256 amount);
    event Launched(uint256 timestamp);
    event Locked(address indexed addr, uint256 amount);
    event Transfer(address indexed from, address indexed to, uint256 value);

    function DAYLAUNCH() external view returns (uint64);

    function DAYZERO() external view returns (uint64);

    function HELDAO() external view returns (address);

    function HELGAS() external view returns (address);

    function HELGO_FOUNDERS(uint256) external view returns (address);

    function HELLP() external view returns (address);

    function PAIR() external view returns (address);

    function TOTAL_FOUNDERS() external view returns (uint256);

    function _distribute(address addr) external returns (uint256, uint256);

    function allowance(address owner, address spender)
        external
        view
        returns (uint256);

    function approve(address spender, uint256 amount) external returns (bool);

    function balanceHEX() external view returns (uint256);

    function balanceOf(address account) external view returns (uint256);

    function burn(uint256 amount) external;

    function claim() external returns (uint256, uint256);

    function claimable() external view returns (uint256);

    function claimedHELGO() external view returns (uint256);

    function claimedHELLP() external view returns (uint256);

    function claimers(address) external view returns (bool);

    function day() external view returns (uint64);

    function decimals() external view returns (uint8);

    function decreaseAllowance(address spender, uint256 subtractedValue)
        external
        returns (bool);

    function deposit(uint256 amount) external;

    function deposited() external view returns (uint256);

    function deposits(address) external view returns (uint256);

    function distribute(address addr) external returns (uint256, uint256);

    function founder(address) external view returns (bool);

    function fundHELGAS(uint256 amount) external;

    function fundHELLP(uint256 amount) external;

    function getDeposit(address addr) external view returns (uint256);

    function getParticipant(uint256 i) external view returns (address);

    function globals() external view returns (IHELGO_STRUCTS.Globals memory);

    function increaseAllowance(address spender, uint256 addedValue)
        external
        returns (bool);

    function launch() external;

    function launched() external view returns (bool);

    function lock(
        uint256 amount,
        uint64 start,
        uint64 duration
    ) external returns (bool);

    function name() external view returns (string memory);

    function participants(uint256) external view returns (address);

    function symbol() external view returns (string memory);

    function today() external view returns (uint64);

    function totalDAO() external view returns (uint256);

    function totalEmissions() external view returns (uint256);

    function totalHEX() external view returns (uint256);

    function totalLiquid() external view returns (uint256);

    function totalLiquidity() external view returns (uint256);

    function totalLocked() external view returns (uint256);

    function totalParticipants() external view returns (uint256 count);

    function totalSupply() external view returns (uint256);

    function totals() external view returns (IHELGO_STRUCTS.Totals memory);

    function transfer(address to, uint256 amount) external returns (bool);

    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);

    function transform() external payable;
}

interface IHELGO_STRUCTS {
    struct Globals {
        uint64 dayzero;
        uint64 daylaunch;
        uint64 today;
        uint64 day;
        bool launched;
        uint256 balance;
        uint256 deposit;
        uint256 deposited;
        uint256 claimable;
        uint256 claimedHELGO;
        uint256 claimedHELLP;
        uint256 participants;
    }

    struct Totals {
        uint256 supply;
        uint256 emissions;
        uint256 locked;
        uint256 liquidity;
        uint256 liquid;
        uint256 DAO;
        uint256 HEX;
    }
}

// THIS FILE WAS AUTOGENERATED FROM THE FOLLOWING ABI JSON:
/*
[{"inputs":[{"internalType":"address payable","name":"hexAddr","type":"address"},{"internalType":"address","name":"routerAddr","type":"address"}],"stateMutability":"nonpayable","type":"constructor"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"owner","type":"address"},{"indexed":true,"internalType":"address","name":"spender","type":"address"},{"indexed":false,"internalType":"uint256","name":"value","type":"uint256"}],"name":"Approval","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"addr","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"amountHELLP","type":"uint256"}],"name":"Claimed","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"addr","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"Deposited","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint256","name":"timestamp","type":"uint256"}],"name":"Launched","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"addr","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"Locked","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"from","type":"address"},{"indexed":true,"internalType":"address","name":"to","type":"address"},{"indexed":false,"internalType":"uint256","name":"value","type":"uint256"}],"name":"Transfer","type":"event"},{"inputs":[],"name":"DAYLAUNCH","outputs":[{"internalType":"uint64","name":"","type":"uint64"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"DAYZERO","outputs":[{"internalType":"uint64","name":"","type":"uint64"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"HELDAO","outputs":[{"internalType":"contract Heldao","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"HELGAS","outputs":[{"internalType":"contract Helgas","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"","type":"uint256"}],"name":"HELGO_FOUNDERS","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"HELLP","outputs":[{"internalType":"contract Hellp","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"PAIR","outputs":[{"internalType":"contract IERC20","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"TOTAL_FOUNDERS","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"addr","type":"address"}],"name":"_distribute","outputs":[{"internalType":"uint256","name":"","type":"uint256"},{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"owner","type":"address"},{"internalType":"address","name":"spender","type":"address"}],"name":"allowance","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"spender","type":"address"},{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"approve","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"balanceHEX","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"account","type":"address"}],"name":"balanceOf","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"burn","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"claim","outputs":[{"internalType":"uint256","name":"","type":"uint256"},{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"claimable","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"claimedHELGO","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"claimedHELLP","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"","type":"address"}],"name":"claimers","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"day","outputs":[{"internalType":"uint64","name":"","type":"uint64"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"decimals","outputs":[{"internalType":"uint8","name":"","type":"uint8"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"spender","type":"address"},{"internalType":"uint256","name":"subtractedValue","type":"uint256"}],"name":"decreaseAllowance","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"deposit","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"deposited","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"","type":"address"}],"name":"deposits","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"addr","type":"address"}],"name":"distribute","outputs":[{"internalType":"uint256","name":"","type":"uint256"},{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"","type":"address"}],"name":"founder","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"fundHELGAS","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"fundHELLP","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"addr","type":"address"}],"name":"getDeposit","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"i","type":"uint256"}],"name":"getParticipant","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"globals","outputs":[{"components":[{"internalType":"uint64","name":"dayzero","type":"uint64"},{"internalType":"uint64","name":"daylaunch","type":"uint64"},{"internalType":"uint64","name":"today","type":"uint64"},{"internalType":"uint64","name":"day","type":"uint64"},{"internalType":"bool","name":"launched","type":"bool"},{"internalType":"uint256","name":"balance","type":"uint256"},{"internalType":"uint256","name":"deposit","type":"uint256"},{"internalType":"uint256","name":"deposited","type":"uint256"},{"internalType":"uint256","name":"claimable","type":"uint256"},{"internalType":"uint256","name":"claimedHELGO","type":"uint256"},{"internalType":"uint256","name":"claimedHELLP","type":"uint256"},{"internalType":"uint256","name":"participants","type":"uint256"}],"internalType":"struct Helgo.Globals","name":"","type":"tuple"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"spender","type":"address"},{"internalType":"uint256","name":"addedValue","type":"uint256"}],"name":"increaseAllowance","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"launch","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"launched","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"amount","type":"uint256"},{"internalType":"uint64","name":"start","type":"uint64"},{"internalType":"uint64","name":"duration","type":"uint64"}],"name":"lock","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"name","outputs":[{"internalType":"string","name":"","type":"string"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"","type":"uint256"}],"name":"participants","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"symbol","outputs":[{"internalType":"string","name":"","type":"string"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"today","outputs":[{"internalType":"uint64","name":"","type":"uint64"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totalDAO","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totalEmissions","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totalHEX","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totalLiquid","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totalLiquidity","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totalLocked","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totalParticipants","outputs":[{"internalType":"uint256","name":"count","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totalSupply","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totals","outputs":[{"components":[{"internalType":"uint256","name":"supply","type":"uint256"},{"internalType":"uint256","name":"emissions","type":"uint256"},{"internalType":"uint256","name":"locked","type":"uint256"},{"internalType":"uint256","name":"liquidity","type":"uint256"},{"internalType":"uint256","name":"liquid","type":"uint256"},{"internalType":"uint256","name":"DAO","type":"uint256"},{"internalType":"uint256","name":"HEX","type":"uint256"}],"internalType":"struct Helgo.Totals","name":"","type":"tuple"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"to","type":"address"},{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"transfer","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"from","type":"address"},{"internalType":"address","name":"to","type":"address"},{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"transferFrom","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"transform","outputs":[],"stateMutability":"payable","type":"function"}]
*/
          

// SPDX-License-Identifier: UNLICENSED
pragma solidity >=0.7.0 <0.9.0;
pragma experimental ABIEncoderV2;

interface IEmissions {
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );
    event Deposited(address indexed addr, uint256 amount, uint256 net);
    event Funded(address indexed addr, uint256 amount);
    event Ramped(uint256 timestamp, uint256 emission, int128 yield);
    event Reward(address indexed addr, uint256 amount);
    event Transfer(address indexed from, address indexed to, uint256 value);
    event Withdrawed(address indexed addr, uint256 amount, uint256 net);

    function DEPOSITFEE() external view returns (int128);

    function FREQUENCY() external view returns (uint256);

    function RATE() external view returns (int128);

    function REWARD() external view returns (int128);

    function TOKEN() external view returns (address);

    function WITHDRAWFEE() external view returns (int128);

    function allowance(address owner, address spender)
        external
        view
        returns (uint256);

    function approve(address spender, uint256 amount) external returns (bool);

    function balanceOf(address addr) external view returns (uint256);

    function basis() external view returns (int128);

    function decimals() external view returns (uint8);

    function decreaseAllowance(address spender, uint256 subtractedValue)
        external
        returns (bool);

    function deposit(uint256 amount) external;

    function deposited() external view returns (uint256);

    function deposits() external view returns (uint256);

    function emissions() external view returns (uint256);

    function emitting() external view returns (IEmissionsStructs.Emission memory);

    function fees() external view returns (uint256);

    function fund(uint256 amount) external;

    function globals() external view returns (IEmissionsStructs.Globals memory);

    function history(uint256)
        external
        view
        returns (
            uint256 timestamp,
            uint256 amount,
            int128 yield
        );

    function increaseAllowance(address spender, uint256 addedValue)
        external
        returns (bool);

    function lastramp() external view returns (uint256);

    function name() external view returns (string memory);

    function period() external view returns (uint256);

    function ramp() external returns (IEmissionsStructs.Emission memory);

    function reserves() external view returns (uint256);

    function should() external view returns (bool);

    function symbol() external view returns (string memory);

    function token() external view returns (address);

    function totalSupply() external view returns (uint256);

    function transfer(address recipient, uint256 amount)
        external
        returns (bool);

    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    function withdraw(uint256 amount) external;

    function withdrawAll() external;

    function withdrawn() external view returns (uint256);
}

interface IEmissionsStructs {
    struct Emission {
        uint256 timestamp;
        uint256 amount;
        int128 yield;
    }

    struct Globals {
        uint256 reserves;
        uint256 emissions;
        uint256 deposited;
        uint256 withdrawn;
        uint256 deposits;
        uint256 fees;
        uint256 lastramp;
        int128 basis;
        uint256 frequency;
        int128 rate;
        int128 depositfee;
        int128 withdrawfee;
    }
}


          

// SPDX-License-Identifier: UNLICENSED
// !! THIS FILE WAS AUTOGENERATED BY abi-to-sol v0.7.1. SEE SOURCE BELOW. !!
pragma solidity >=0.7.0 <0.9.0;

interface IHelfactory {
    function newHelgas(address helgo) external returns (address);

    function newHellp(
        address pair,
        address router,
        address token0,
        address token1
    ) external returns (address);
}
          

// SPDX-License-Identifier: UNLICENSED
pragma solidity >=0.5.0;

interface IUniswapV2Factory {
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);

    function feeTo() external view returns (address);
    function feeToSetter() external view returns (address);

    function getPair(address tokenA, address tokenB) external view returns (address pair);
    function allPairs(uint) external view returns (address pair);
    function allPairsLength() external view returns (uint);

    function createPair(address tokenA, address tokenB) external returns (address pair);

    function setFeeTo(address) external;
    function setFeeToSetter(address) external;
}
          

// SPDX-License-Identifier: UNLICENSED
pragma solidity >=0.6.2;

interface IUniswapV2Router01 {
    function factory() external pure returns (address);
    function WETH() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETH(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountToken, uint amountETH);
    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETHWithPermit(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountToken, uint amountETH);
    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapExactETHForTokens(uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);
    function swapTokensForExactETH(uint amountOut, uint amountInMax, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapExactTokensForETH(uint amountIn, uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapETHForExactTokens(uint amountOut, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);

    function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);
    function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);
    function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
}
          

// SPDX-License-Identifier: UNLICENSED
pragma solidity >=0.6.2;

import './IUniswapV2Router01.sol'; 

interface IUniswapV2Router02 is IUniswapV2Router01 {
    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountETH);
    function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountETH);

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable;
    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
}