Contract Address Details

// SPDX-License-Identifier: MIT


pragma solidity 0.8.24;


import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "./tokens/Token.sol";
import "./tokens/TaxToken.sol";
import "./tokens/SwitchEngineRefund.sol";

/*------------------------------------------------------------------
 *    :::: EXTERNAL_CONTRACT_INTERFACE ::::
 *-----------------------------------------------------------------*/


interface IHoldingPattern {
    function addToken(address token) external returns(bool);
}

interface ISupercharge {
    function addTaxToken(address token) external returns(bool);
    function getConfig(uint8 configType) external returns(uint256);
}

interface IIntarsiaConfigProvider {
    function setConfig(uint8 configType, address value) external returns(bool);
    function u_TaxStartTime() external view returns (uint32);
    function a_IntarsiaSafe() external view returns (address);
    function a_HoldingPattern() external view returns (address);
    function a_Supercharge() external view returns (address);
    function g_AddressArray(uint8 configType) external view returns (address[] memory returnedArray);
    function g_PowerRates() external view returns (uint64[] memory);
}

/*-------------------------------------------------------
 *    :::: CONTRACT_SWITCH_ENGINE ::::
 *------------------------------------------------------*/


/**
 * @title Switch Engine
 * @dev This contract provides an immutable and comprehensive token-switching mechanism.
 *
 * @notice The Switch Engine implements a robust system for switching tokens, ensuring strict validation 
 *         checks for balances, allowances, and transaction rules prior to executing token transfers. 
 *         Key features include:
 *         - Tax calculation logic for applicable tax tokens (standard ERC20 contracts).
 *         - Event logging for all significant actions.
 *         - Automatic refunds for tax tokens received during a switch, provided refund supplies are available.
 *
 *         Critical functions are restricted to the owner to mitigate centralization risks 
 *         and prevent manipulation of the protocol. The following functions have specific restrictions:
 *         - `createToken`: Disabled after contract ownership is renounced or when `b_isCreatingTokensActive` 
 *           is set to false. Token creation poses no additional risk as tokens are exclusively delivered 
 *           to this contract and/or the Holding Pattern.
 *         - `setCreateTokensFalse`: Can only be invoked to disable the creation of new tokens.
 *         - `modifyStartDate`: Includes a timelock that restricts its use after the switching process has begun.
 *         - `addHoldingPatterns`: Also includes a timelock to restrict its use after switching has commenced.
 *
 *         The contract utilizes the SAFE ERC20 library to ensure secure handling of bridged tokens.
 */

contract SwitchEngine is  
    Ownable, 
    ReentrancyGuard
{
    
   /*----------------------------
    *    :::: SAFE_ERC20 ::::
    *---------------------------*/

    using SafeERC20 for IERC20;
    
   /*----------------------------
    *    :::: ENUMERATION ::::
    *---------------------------*/

    enum ArrayType {
        StandardToken,
        PowerToken,
        MicroToken,
        TaxToken,
        AllTokens
    }
    
   /*----------------------------
    *    :::: STRUCTS ::::
    *---------------------------*/
    
	struct TokenInfo {
	    bool exists;
	    uint16 taxRate;
	    uint64 powerRate;
	}
	
    struct TokenCreationParams {
        string name;
        string symbol;
        uint16 taxRate;
	    uint64 powerRate;
        uint256 switchEngineSupply;
        uint256 holdingPatternSupply;
    }
    
   /*----------------------------
    *    :::: MAPPINGS ::::
    *---------------------------*/
    
    mapping(address => TokenInfo) private tokenInfo;
    mapping(address => bool) private m_isHoldingPattern;
    
   /*----------------------------
    *    :::: CONSTANTS ::::
    *---------------------------*/
    
    uint256 private constant MIN_AMOUNT = 1e6;
    uint256 private constant MAX_AMOUNT = 10e30;
    uint256 private constant MIN_POWER_RATE = 1;
    uint256 private constant MAX_POWER_RATE = 1e18;
    uint256 private constant MIN_TAX_RATE = 50;
    uint256 private constant MAX_TAX_RATE = 500;
    uint256 private constant MAX_SUPPLY = 1e33;
    
   /*----------------------------
    *    :::: IMMUTABLES ::::
    *---------------------------*/
    
    SwitchEngineRefund public immutable s_Refund_Token_Address;
    IIntarsiaConfigProvider public immutable i_configProvider;
    
    address public immutable a_Intarsia_Safe_Contract;
    address public immutable a_Supercharge_Contract;
    address public immutable a_Holding_Pattern;
    address public immutable a_Central_Token;
    uint32 public immutable u_Tax_Start_Time;
    
   /*----------------------------
    *    :::: ARRAYS ::::
    *---------------------------*/
    
    address[] public aa_listStandardTokens;
    address[] public aa_listMicroTokens;
    address[] public aa_listPowerTokens;
    address[] public aa_listTaxTokens;
    
   /*----------------------------
    *    :::: VARIABLES ::::
    *---------------------------*/
    
    bool public b_isCreatingTokensActive;
    uint256 public u_Switch_Start_Time;
    uint256 public u_Total_Token_Count;
    

/*-------------------------------------------------------
 *    :::: EVENTS_AND_ERRORS ::::
 *------------------------------------------------------*/


    event SwitchEngineInitialized(address indexed initializer,address switchEngineRefund, uint256 blockTimestamp);
    event AddHoldingPatternsEvent(address indexed sender, address holdingPattern);
    event ModifyStartDateEvent(address indexed sender, uint256 newStartDate);
    event ModifyCreateTokensEvent(address indexed sender, bool isCreateTokensActive);
    event SwitchTokensEvent(address indexed sender, uint256 taxReceiveRate, uint256 powerSendRate, uint256 powerReceiveRate, uint256 sendAmount, uint256 receiveAmount, uint256 refundAmount);
    event TokenCreated(address indexed tokenAddress, string name, string symbol, uint256 switchEngineSupply, uint256 holdingPatternSupply);
    
    
    error AddressZero_Error();
    error AllowanceLow_Error();
    error Amount_Error();
    error BalanceLow_Error();
    error CreateTokenAmount_Error();
    error CreatingTokensNotActive_Error();
    error FailedToAddToHP_Error();
    error FailedToAddToSC_Error();
    error InvalidHoldingPattern_Error();
    error InvalidToken_Error();
    error InvalidType_Error();
    error NameOrSymbol_Error();
    error PowerRate_Error();
    error RateOutOfBounds_Error();
    error ReceiveAmount_Error();
    error ReceiveAmountHigh_Error();
    error ReceiveAmountLow_Error();
    error RefundFailed_Error();
    error SendAmount_Error();
    error SetContract_Error();
    error SwitchingNotStarted_Error();
    error SwitchingStarted_Error();
    error Timestamp_Error();
    error TokenAmountCheck_Error();
    


/*-------------------------------------------------------
 *    :::: MODIFIERS ::::
 *------------------------------------------------------*/
 
    
   /** 
    * @notice Ensures the function is called before the switching period starts.
    */
    modifier switchingNotStarted() { 
        if (block.timestamp >= u_Switch_Start_Time) revert SwitchingStarted_Error();
        _;
        
    }

   /** 
    * @notice Ensures the function is called after the switching period has started.
    */
    modifier switchingStarted() {
        if (block.timestamp < u_Switch_Start_Time) revert SwitchingNotStarted_Error();
        _;
    }

    
/*-------------------------------------------------------
 *    :::: SWITCH_ENGINE_CONSTRUCTOR ::::
 *------------------------------------------------------*/
 
 
   /**
    * @dev Constructor for initializing the Switch Engine contract with specified parameters.
    *      Initializes the refund token contract and sets up the initial token configurations.
    */
    constructor(address _configProviderAddress) Ownable(_msgSender()) { 
    	
        i_configProvider = IIntarsiaConfigProvider(_configProviderAddress);
        
        address[] memory initialTokens_ = i_configProvider.g_AddressArray(11);
        uint64[] memory initialPowerRates_ = i_configProvider.g_PowerRates();
        
        if (initialTokens_.length != initialPowerRates_.length) revert Amount_Error();
        
        a_Holding_Pattern = i_configProvider.a_HoldingPattern();
        a_Supercharge_Contract = i_configProvider.a_Supercharge();
        a_Intarsia_Safe_Contract = i_configProvider.a_IntarsiaSafe();
        a_Central_Token = initialTokens_[0];
        u_Tax_Start_Time = i_configProvider.u_TaxStartTime();
        u_Switch_Start_Time = block.timestamp + 315360000; // DEFAULT
        
        SwitchEngineRefund.SerTokenConfig memory config = SwitchEngineRefund.SerTokenConfig({name: "Switch Engine Refund", symbol: "SER", switchEngineContract: address(this)});
        s_Refund_Token_Address = new SwitchEngineRefund(config);
        
        for (uint8 i; i < initialTokens_.length;) {
            address token = initialTokens_[i];
            uint64 powerRate = initialPowerRates_[i];
            tokenInfo[token] = TokenInfo(true, 0, powerRate);
            if (powerRate == 100) {aa_listStandardTokens.push(token);} 
            else if (powerRate > 100) {aa_listPowerTokens.push(token);} 
            else {aa_listMicroTokens.push(token);}
            unchecked { ++u_Total_Token_Count; }
            unchecked { ++i; }
        }
        
        m_isHoldingPattern[a_Holding_Pattern] = true;
        b_isCreatingTokensActive = true;
        
        // Set SwitchEngine within the Intarsia Config Contract
        if (!i_configProvider.setConfig(6, address(this))) revert SetContract_Error();
        if (!i_configProvider.setConfig(8, address(s_Refund_Token_Address))) revert SetContract_Error();
        
    }


/*-------------------------------------------------------
 *    :::: ONLY_OWNER_FUNCTION ::::
 *------------------------------------------------------*/


   /**
    * @dev Creates a new token with the specified parameters.
    * @notice This function can only be called by the contract owner. It checks that token creation is active,
    *         validates the provided parameters, and then creates either a standard token or a tax token based on
    *         the specified tax rate. The new token's address is stored, and it is added to the appropriate lists
    *         based on its characteristics.
    * @param params The parameters for creating the token, encapsulated in a `TokenCreationParams` struct.
    * Emits a {TokenCreated} event upon successful creation of the token.
    */
    function createToken(TokenCreationParams calldata params) external onlyOwner {
        
        if (!b_isCreatingTokensActive) revert CreatingTokensNotActive_Error();

        address holdingPattern_ = a_Holding_Pattern;

        if (bytes(params.name).length == 0 || bytes(params.name).length > 32 || bytes(params.symbol).length == 0 || bytes(params.symbol).length > 10) revert NameOrSymbol_Error();
        if (holdingPattern_ == address(0) || !m_isHoldingPattern[holdingPattern_]) revert InvalidHoldingPattern_Error();
        if (params.switchEngineSupply > MAX_SUPPLY || params.holdingPatternSupply > MAX_SUPPLY) revert CreateTokenAmount_Error();
        unchecked {if (params.switchEngineSupply + params.holdingPatternSupply == 0) revert CreateTokenAmount_Error();}
        
        bool isNonTaxToken = params.taxRate == 0 ? true : false;
        address tokenAddress;
        
        if (isNonTaxToken) { 
            if (params.powerRate > MAX_POWER_RATE || params.powerRate < MIN_POWER_RATE) revert RateOutOfBounds_Error();
            Token.TokenConfig memory config = Token.TokenConfig({
                name: params.name,
                symbol: params.symbol,
                holdingPatternSupply: params.holdingPatternSupply,
                switchEngineSupply: params.switchEngineSupply,
                creatorAddress: _msgSender(),
                holdingPatternContract: holdingPattern_,
                switchEngineContract: address(this)
            });
            tokenAddress = address(new Token(config));
        } else { 
            if (params.taxRate > MAX_TAX_RATE || params.taxRate < MIN_TAX_RATE || params.powerRate != 100) revert RateOutOfBounds_Error();
            TaxToken.TaxTokenConfig memory config = TaxToken.TaxTokenConfig({
                name: params.name,
                symbol: params.symbol,
                holdingPatternSupply: params.holdingPatternSupply,
                switchEngineSupply: params.switchEngineSupply,
                creatorAddress: _msgSender(),
                holdingPatternContract: holdingPattern_,
                switchEngineContract: address(this),
                superchargeContract: a_Supercharge_Contract,
                taxStartTime: u_Tax_Start_Time,
                taxRate: params.taxRate
            });
            tokenAddress = address(new TaxToken(config));
        }

        tokenInfo[tokenAddress] = TokenInfo(true, params.taxRate, params.powerRate);
        
        if (!isNonTaxToken) {
        	if (!ISupercharge(a_Supercharge_Contract).addTaxToken(tokenAddress)) revert FailedToAddToSC_Error();
            aa_listTaxTokens.push(tokenAddress);
        } else if (params.powerRate == 100) {
            aa_listStandardTokens.push(tokenAddress);
        } else if (params.powerRate > 100) {
            aa_listPowerTokens.push(tokenAddress);
        } else if (params.powerRate < 100) {
            aa_listMicroTokens.push(tokenAddress);
        } else {
            revert RateOutOfBounds_Error();
        }
        
        if (!IHoldingPattern(holdingPattern_).addToken(tokenAddress)) revert FailedToAddToHP_Error();
        
        unchecked { ++u_Total_Token_Count; }

        emit TokenCreated(
            tokenAddress,
            params.name,
            params.symbol,
            params.switchEngineSupply,
            params.holdingPatternSupply
        );
    }

 
   /**
    * @notice Disables the ability to create new tokens.
    * @dev Sets the b_isCreatingTokensActive flag to false. Can only be called by the contract owner and deployer.
    */
    function setCreateTokensFalse() external onlyOwner {
        b_isCreatingTokensActive = false;
        emit ModifyCreateTokensEvent(_msgSender(), b_isCreatingTokensActive);
    }
    

/*-------------------------------------------------------
 *    :::: ONLY_OWNER_DISABLED_AFTER_SWITCHING_STARTS ::::
 *------------------------------------------------------*/
 
    
   /** 
    * @notice Callable only before switching initiates.
    * @dev Modifies the start date of the switching process.
    * @param newStartDate The new timestamp to set as the start date.
    */
    function modifyStartDate(uint256 newStartDate) external onlyOwner switchingNotStarted {
        if (newStartDate <= block.timestamp) revert Timestamp_Error();
        u_Switch_Start_Time = newStartDate;
        emit ModifyStartDateEvent(_msgSender(),newStartDate);
    }

    
/*-------------------------------------------------------
 *    :::: EXTERNAL_GETTER_FUNCTIONS ::::
 *------------------------------------------------------*/
 
 
   /**
    * @dev Returns the array count for the specific type.
    */
    function getArrayCount(ArrayType arrayType) external view returns (uint256) {
        if (arrayType == ArrayType.StandardToken) return aa_listStandardTokens.length;
        if (arrayType == ArrayType.PowerToken) return aa_listPowerTokens.length;
        if (arrayType == ArrayType.MicroToken) return aa_listMicroTokens.length;
        if (arrayType == ArrayType.TaxToken) return aa_listTaxTokens.length;
        if (arrayType == ArrayType.AllTokens) return u_Total_Token_Count;
        revert InvalidType_Error();
    }


   /**
    * @dev Calculates the amounts to be received and the tax amount based on 
    *      the specified send amount and power rates.
    */
    function getSwitchAmounts(uint16 taxReceiveRate, uint64 powerSendRate, uint64 powerReceiveRate, uint256 sendAmount) external pure returns (uint256, uint256, uint256) { 
        uint256 amountReceived = _calcReceiveAmount(sendAmount, powerSendRate, powerReceiveRate);
        return(
            (powerSendRate < powerReceiveRate) ? ((MIN_AMOUNT * powerReceiveRate) / powerSendRate) : MIN_AMOUNT,
            amountReceived,
            taxReceiveRate != 0 ? _calcTax(amountReceived, taxReceiveRate) : 0
        );
    }
    

   /**
    * @dev Retrieves information about a specific token.
    */
    function getTokenInfo(address token) external view returns (uint16, uint64, bool) {
        TokenInfo memory tokenInfo_ = tokenInfo[token];
        if (!tokenInfo_.exists) revert InvalidToken_Error();
        return (tokenInfo_.taxRate, tokenInfo_.powerRate, tokenInfo_.exists);
    }


/*-------------------------------------------------------
 *    :::: EXTERNAL_WRITE_FUNCTION ::::
 *------------------------------------------------------*/
 

   /**
    * @notice Allows users to switch tokens by sending a specified amount of one token 
    *         and receiving another token in return.
    * @dev This function calculates the rates for sending and receiving tokens, checks 
    *      the token amounts, and processes the transfers. It also handles any applicable 
    *      tax refunds and emits a SwitchTokensEvent upon successful execution.
    *
    * @param sendToken The ERC20 token that the user is sending.
    * @param receiveToken The ERC20 token that the user will receive.
    * @param sendAmount The amount of the sendToken that the user wants to send.
    * 
    * Requirements:
    * - Switching must have started and the function must not be reentrant.
    * - The sender must have a valid amount of sendToken to switch.
    * - The calculated receive amount must be valid based on the rates.
    *
    */
    function switchTokens(
        IERC20 sendToken, 
        IERC20 receiveToken, 
        uint256 sendAmount
    ) external 
        switchingStarted 
        nonReentrant 
    { 
    	
        address sender_ = _msgSender();
        address sendTokenAddress_ = address(sendToken);
        address receiveTokenAddress_ = address(receiveToken);
        
        (uint64 powerSendRate, uint16 taxReceiveRate, uint64 powerReceiveRate) = _getRates(sender_, sendTokenAddress_, receiveTokenAddress_);
        (uint256 receiveAmount) = _calcReceiveAmount(sendAmount, powerSendRate, powerReceiveRate);
        
        if (!_checkTokenAmount(sender_, sendToken, receiveToken, sendAmount, receiveAmount)) revert TokenAmountCheck_Error();
        
        sendToken.safeTransferFrom(sender_, address(this), sendAmount);
        receiveToken.safeTransfer(sender_, receiveAmount);
        
        uint256 refundAmount_;
        
        if (taxReceiveRate != 0 && block.timestamp >= u_Tax_Start_Time) { 
            refundAmount_ = _calcTax(receiveAmount, taxReceiveRate);
            if (!s_Refund_Token_Address.refundTokens(sender_, refundAmount_)) revert RefundFailed_Error();
        }
        
        emit SwitchTokensEvent(sender_, taxReceiveRate, powerSendRate, powerReceiveRate, sendAmount, receiveAmount - refundAmount_, refundAmount_);
    }
    
    
/*-------------------------------------------------------
 *    :::: PRIVATE_FUNCTIONS ::::
 *------------------------------------------------------*/
 
    
   /**
    * @notice Retrieves the rates for sending and receiving tokens.
    * @dev Reverts with AddressZero_Error if any address is zero.
    *      Reverts with InvalidToken_Error if the tokens do not exist or are the same.
    * @param _sender The address of the sender.
    * @param _sendAddress The address of the token being sent.
    * @param _receiveAddress The address of the token being received.
    * @return powerRate The power rate of the token being sent.
    * @return taxRate The tax rate of the token being received.
    * @return receivePowerRate The power rate of the token being received.
    */
    function _getRates(address _sender, address _sendAddress, address _receiveAddress) private view returns (uint64, uint16, uint64) {
        if (_sender == address(0) || _sendAddress == address(0) || _receiveAddress == address(0)) revert AddressZero_Error();
        TokenInfo memory sendInfo_ = tokenInfo[_sendAddress];
        TokenInfo memory receiveInfo_ = tokenInfo[_receiveAddress];
        if (!sendInfo_.exists || !receiveInfo_.exists || _sendAddress == _receiveAddress) revert InvalidToken_Error();
        return (sendInfo_.powerRate, receiveInfo_.taxRate, receiveInfo_.powerRate);
    }
    
    
   /**
    * @notice Calculates the amount received after applying the power rates using integer arithmetic, truncating remainders to maintain whole token units, with a minimum amount check to ensure meaningful outputs.
    * @dev Reverts with Amount_Error if the minimum amount check fails. (e.g., "3e6 * 1e18 / 2e18 = 1e6, truncating 1.5e6")
    * @param _sendAmount The amount of tokens being sent.
    * @param _powerSendRate The power rate of the token being sent.
    * @param _powerReceiveRate The power rate of the token being received.
    * @return The amount of tokens received after applying the rates.
    */ 
    function _calcReceiveAmount(uint256 _sendAmount, uint256 _powerSendRate, uint256 _powerReceiveRate) private pure returns(uint256) {
        if (!_checkMinAmount(_sendAmount, _powerSendRate, _powerReceiveRate)) revert ReceiveAmount_Error();
        return ((_sendAmount * _powerSendRate) / _powerReceiveRate);
    }
    
    
   /** 
    * @notice Taxes only apply to tax tokens that are approved addresses for this protocol. 
    *         Taxes are refunded to the user in `Switch Engine Refund` SER tokens.
    * @dev Private function to check if token received has a tax and calculate the tax for refund
    * @param _receiveAmount amount of tokens.
    * @param _taxReceiveRate tax rate.
    */
    function _calcTax(uint256 _receiveAmount, uint256 _taxReceiveRate) private pure returns(uint256) {
        return ((_receiveAmount * _taxReceiveRate * 1e26) / 1e30);
    }
    
    
   /**
    * @notice Checks if the send amount meets the minimum requirements based on power send and receive rates.
    * @param _sendAmount The amount of tokens being sent.
    * @param _powerSendRate The rate at which tokens are sent, expressed in a fixed-point format.
    * @param _powerReceiveRate The rate at which tokens are received, expressed in a fixed-point format.
    * @return bool True if the send amount is valid, false otherwise.
    */
    function _checkMinAmount(uint256 _sendAmount, uint256 _powerSendRate, uint256 _powerReceiveRate) private pure returns(bool) {
        uint256 minAmountRequired_ = MIN_AMOUNT;
        uint256 maxAmountRequired_ = MAX_AMOUNT;
        uint256 maxPowerRateRequired_ = MAX_POWER_RATE;
        if (_sendAmount < minAmountRequired_ || _sendAmount > maxAmountRequired_) revert SendAmount_Error();
        if (_powerSendRate == 0 || _powerSendRate > maxPowerRateRequired_ || _powerReceiveRate == 0 || _powerReceiveRate > maxPowerRateRequired_) revert PowerRate_Error();
        uint256 minAmount = (_powerSendRate < _powerReceiveRate) ? ((minAmountRequired_ * _powerReceiveRate) / _powerSendRate) : minAmountRequired_;
        return (minAmount >= minAmountRequired_ && _sendAmount >= minAmount);
    }
    

   /**
    * @notice Validates the token amounts for the transaction.
    * @param _sender The address of the sender.
    * @param _sendToken The token being sent.
    * @param _receiveToken The token being received.
    * @param _sendAmount The amount of tokens being sent.
    * @param _receiveAmount The amount of tokens expected to be received.
    * @return bool True if the token amounts are valid, false otherwise.
    */
    function _checkTokenAmount(address _sender, IERC20 _sendToken, IERC20 _receiveToken, uint256 _sendAmount, uint256 _receiveAmount) private view returns (bool) {
        if (_receiveAmount < MIN_AMOUNT) revert ReceiveAmountLow_Error();
        if (_receiveAmount > MAX_AMOUNT) revert ReceiveAmountHigh_Error();
        if (_sendToken.balanceOf(_sender) < _sendAmount) revert BalanceLow_Error();
        if (_sendToken.allowance(_sender, address(this)) < _sendAmount) revert AllowanceLow_Error();
        if (_receiveToken.balanceOf(address(this)) < _receiveAmount) revert BalanceLow_Error();
        return true;
    }
    


}

        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../utils/introspection/IERC165.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../token/ERC20/IERC20.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC-1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * Both values are immutable: they can only be set once during construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner`'s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner`'s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance < type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.20;

import {ERC20} from "../ERC20.sol";
import {Context} from "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys a `value` amount of tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 value) public virtual {
        _burn(_msgSender(), value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, deducting from
     * the caller's allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `value`.
     */
    function burnFrom(address account, uint256 value) public virtual {
        _spendAllowance(account, _msgSender(), value);
        _burn(account, value);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
          

// SPDX-License-Identifier: MIT

pragma solidity 0.8.24;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";


/**
 * @title SwitchEngineRefund Token for the Intarsia Switch Engine Tax Refunds
 * @dev This contract is an ERC20 token that can be minted by the Switch Engine.
 * @notice The owner of the contract is set to the address of the switch engine contract upon deployment.
 */
contract SwitchEngineRefund is 
    ERC20, 
    Ownable 
{
	
    struct SerTokenConfig {
        address switchEngineContract;
        string name;
        string symbol;
    }
    
    address public immutable switchEngineContract;
    
    event TokensRefunded(address indexed recipient, uint256 amount);
    
    error OwnerTransferDisabled();
    error OwnerRenounceDisabled();
    
    constructor(
        SerTokenConfig memory config
    ) Ownable(config.switchEngineContract) ERC20(config.name, config.symbol) {
        switchEngineContract = config.switchEngineContract;
    }
    
    function refundTokens(address recipient, uint256 amount) external onlyOwner returns (bool) {
        _mint(recipient, amount);
        emit TokensRefunded(recipient, amount);
        return true;
    }

    // Override to make ownership immutable
    function transferOwnership(address) public onlyOwner override view {
        revert OwnerTransferDisabled();
    }

    // Override renounceOwnership
    function renounceOwnership() public onlyOwner override view {
        revert OwnerRenounceDisabled();
    }
    
}
          

// SPDX-License-Identifier: MIT

pragma solidity 0.8.24;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";


/**
 * @title Taxed Token for the Intarsia Switch Engine
 * @notice This contract implements a standard ERC20 token with a fee on transfers and burnable functionality, created by the SwitchEngine contract.
 *         Transfers of amounts less than 1e-15 will incur a specified tax amount:
 *         - If the amount sent is between 1e-16 and 9.99e-16, the tax is 5e-17.
 *         - If the amount sent is between 1e-17 and 9.9e-17, the tax is 5e-18.
 *         - If the amount sent is between 1e-18 and 9e-18, the tax is 1e-18.
 * @dev This contract represents a `tax` token that is minted to the SwitchEngine and a designated Holding Pattern contract upon deployment.
 *      It includes immutable metadata for the creator, SwitchEngine, and Holding Pattern addresses, as well as the total initial supply.
 */
contract TaxToken is 
    ERC20, 
    ERC20Burnable 
{
    struct TaxTokenConfig {
        string name;
        string symbol;
        uint256 holdingPatternSupply;
        uint256 switchEngineSupply;
        address creatorAddress;
        address holdingPatternContract;
        address switchEngineContract;
        address superchargeContract;
        uint32 taxStartTime;
        uint16 taxRate;
    }
    
	mapping(address => bool) private excludeSenderFromFee;
	mapping(address => bool) private excludeRecipientFromFee;

    uint16 public immutable TAX_RATE;
    uint32 public immutable TAX_START_TIME;
    uint256 public immutable totalInitialSupply;
    address public immutable superchargeContract;
    address public immutable creatorAddress;
    address public immutable switchEngineContract;
    address public immutable holdingPatternContract;
    
    event TaxTokenInitialized(address indexed creator, address holdingPattern, address switchEngine, uint256 totalSupply);
    event TransferWithTax(address indexed from, address to, uint16 taxRate, uint256 sentAmount, uint256 taxPaid, uint256 remainder);
    
    constructor(
        TaxTokenConfig memory config
    ) ERC20(config.name, config.symbol) { 
    	
        creatorAddress = config.creatorAddress;
        switchEngineContract = config.switchEngineContract;
        holdingPatternContract = config.holdingPatternContract;
        superchargeContract = config.superchargeContract;
        unchecked { totalInitialSupply = config.holdingPatternSupply + config.switchEngineSupply; }
        
        TAX_START_TIME = config.taxStartTime;
        TAX_RATE = config.taxRate;
        
        // EXCLUDE_TAX_FROM
        excludeSenderFromFee[config.holdingPatternContract] = true;
        excludeSenderFromFee[config.superchargeContract] = true;
        excludeRecipientFromFee[config.holdingPatternContract] = true;
        excludeRecipientFromFee[config.switchEngineContract] = true;
        
        if (config.holdingPatternSupply != 0) _mint(config.holdingPatternContract, config.holdingPatternSupply);
        if (config.switchEngineSupply != 0) _mint(config.switchEngineContract, config.switchEngineSupply);
        
        emit TaxTokenInitialized(creatorAddress,holdingPatternContract,switchEngineContract,totalInitialSupply);
    }
    
    function _update(address sender, address recipient, uint256 amount) internal override {
        uint16 taxRate = TAX_RATE;
        if (
            amount != 0 && 
            block.timestamp >= TAX_START_TIME && 
            !excludeSenderFromFee[sender] && 
            !excludeRecipientFromFee[recipient]
        ) {
            uint256 remainder = _taxRemainder(amount, taxRate);
            uint256 tax = amount - remainder;
            super._update(sender, recipient, remainder);
            super._update(sender, superchargeContract, tax);
            emit TransferWithTax(sender, recipient, taxRate, amount, tax, remainder);
            return;
        }
        super._update(sender, recipient, amount);
    }
    
    function _taxRemainder(uint256 _amount, uint256 _taxRate) private pure returns (uint256) {
        if (_amount > 1000) return (_amount - ((_amount * _taxRate * 1e26) / 1e30));
        if (_amount > 100) return _amount - 50;
        if (_amount > 10) return _amount - 5;
        if (_amount > 0) return _amount - 1;
        return 0;
    }
    
}
          

// SPDX-License-Identifier: MIT

pragma solidity 0.8.24;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";


/**
 * @title Token For The Intarsia Switch Engine
 * @notice A standard ERC20 token with burnable functionality, created by the SwitchEngine contract.
 * @dev This contract represents a token that is minted to the SwitchEngine and a designated Holding Pattern contract upon deployment.
 *      It includes immutable metadata for the creator, SwitchEngine, and Holding Pattern addresses, as well as the total initial supply.
 */
contract Token is 
    ERC20, 
    ERC20Burnable 
{
    struct TokenConfig {
        string name;
        string symbol;
        uint256 holdingPatternSupply;
        uint256 switchEngineSupply;
        address creatorAddress;
        address holdingPatternContract;
        address switchEngineContract;
    }

    address public immutable creatorAddress;
    address public immutable switchEngineContract;
    address public immutable holdingPatternContract;
    uint256 public immutable totalInitialSupply;
    
    event TokenInitialized(address indexed creator, address holdingPattern, address switchEngine, uint256 totalSupply);
    
    constructor(
        TokenConfig memory config
    ) ERC20(config.name, config.symbol) { 
        creatorAddress = config.creatorAddress;
        switchEngineContract = config.switchEngineContract;
        holdingPatternContract = config.holdingPatternContract;
        unchecked { totalInitialSupply = config.holdingPatternSupply + config.switchEngineSupply; }
        if (config.holdingPatternSupply != 0) _mint(config.holdingPatternContract, config.holdingPatternSupply);
        if (config.switchEngineSupply != 0) _mint(config.switchEngineContract, config.switchEngineSupply);
        emit TokenInitialized(creatorAddress,holdingPatternContract,switchEngineContract,totalInitialSupply);
    }
}