Contract Address Details

// SPDX-License-Identifier: MIT

pragma solidity 0.7.6;
pragma experimental ABIEncoderV2;

import "../../dependencies/openzeppelin/contracts/SafeMath.sol";
import "../../dependencies/openzeppelin/contracts/ReentrancyGuard.sol";
import "../../dependencies/openzeppelin/contracts/IERC20.sol";
import "../../dependencies/openzeppelin/contracts/SafeERC20.sol";
import "../../interfaces/IUSDPH.sol";
import "../../interfaces/IVault.sol";
import "../../interfaces/IVaultConfigurator.sol";
import "../../interfaces/IPhamePriceOracle.sol";
import "../libraries/helpers/VaultErrors.sol";
import "../libraries/logic/TokenConfigsLogic.sol";
import "../libraries/utils/VaultUtils.sol";
import "../libraries/utils/GeneralUtils.sol";
import "../libraries/types/DataTypes.sol";

contract Vault is IVault, ReentrancyGuard {
    using SafeMath for uint256;
    using SafeERC20 for IERC20;
    using TokenConfigsLogic for DataTypes.TokenConfigs;

    uint256 public constant BASIS_POINTS_DIVISOR = 10000;
    uint256 public constant PRICE_PRECISION = 10 ** 30;
    uint256 public constant USDPH_DECIMALS = 18;
    uint256 public constant FUNDING_RATE_PRECISION = 1000000;

    IAddressesProvider public immutable override addressesProvider;

    DataTypes.VaultConfig private _vaultConfig;
    DataTypes.TokenConfigs private _tokenConfigs;
    mapping(address => mapping(address => DataTypes.AccountTokenConfig))
        private _accountTokenConfigs;

    // tokenBalances is used only to determine _transferIn values
    mapping(address => uint256) public override tokenBalances;

    // usdphAmounts tracks the amount of USDPH debt for each whitelisted token
    mapping(address => uint256) public override usdphAmounts;

    // poolAmounts tracks the number of received tokens that can be used for leverage
    // this is tracked separately from tokenBalances to exclude funds that are deposited as margin collateral
    mapping(address => uint256) public override poolAmounts;

    // reservedAmounts tracks the number of tokens reserved for open leverage positions
    mapping(address => uint256) public override reservedAmounts;

    // guaranteedUsd tracks the amount of USD that is "guaranteed" by opened leverage positions
    // this value is used to calculate the redemption values for selling of USDPH
    // this is an estimated amount, it is possible for the actual guaranteed value to be lower
    // in the case of sudden price decreases, the guaranteed value should be corrected
    // after liquidations are carried out
    mapping(address => uint256) public override guaranteedUsd;

    // cumulativeFundingRates tracks the funding rates based on utilization
    mapping(address => uint256) public override cumulativeFundingRates;
    // lastFundingTimes tracks the last time funding was updated for a token
    mapping(address => uint256) public override lastFundingTimes;

    // positions tracks all open positions
    mapping(bytes32 => Position) public positions;

    // feeReserves tracks the amount of fees per token
    mapping(address => uint256) public override feeReserves;

    mapping(address => uint256) public override globalShortSizes;

    constructor(IAddressesProvider addressesProvider_) {
        addressesProvider = addressesProvider_;
    }

    function setVaultConfig(
        DataTypes.VaultConfig calldata vaultConfig
    ) external override {
        _validateConfigurator();

        _vaultConfig = vaultConfig;
    }

    function getVaultConfig()
        external
        view
        override
        returns (DataTypes.VaultConfig memory)
    {
        return _vaultConfig;
    }

    function allWhitelistedTokensLength()
        external
        view
        override
        returns (uint256)
    {
        return _tokenConfigs.allWhitelistedTokens.length;
    }

    function totalTokenWeights() external view override returns (uint256) {
        return _tokenConfigs.totalTokenWeights;
    }

    function allWhitelistedTokens(
        uint256 i
    ) external view override returns (address) {
        return _tokenConfigs.allWhitelistedTokens[i];
    }

    function setTokenConfig(
        address _token,
        DataTypes.TokenConfig calldata tokenConfig
    ) external override {
        _validateConfigurator();
        _tokenConfigs.setTokenConfig(_token, tokenConfig);
    }

    function clearTokenConfig(address _token) external override {
        _validateConfigurator();
        _tokenConfigs.clearTokenConfig(_token);
    }

    function getTokenConfig(
        address _token
    ) external view override returns (DataTypes.TokenConfig memory) {
        return _tokenConfigs.tokenConfigs[_token];
    }

    function setAccountTokenConfig(
        address _account,
        address _token,
        DataTypes.AccountTokenConfig calldata accountTokenConfig
    ) external override {
        _validateConfigurator();
        _accountTokenConfigs[_account][_token] = accountTokenConfig;
    }

    function getAccountTokenConfig(
        address _account,
        address _token
    ) external view override returns (DataTypes.AccountTokenConfig memory) {
        return _accountTokenConfigs[_account][_token];
    }

    function setUsdphAmount(address _token, uint256 _amount) external override {
        _validateConfigurator();

        uint256 usdphAmount = usdphAmounts[_token];
        if (_amount > usdphAmount) {
            _increaseUsdphAmount(_token, _amount.sub(usdphAmount));
            return;
        }

        _decreaseUsdphAmount(_token, usdphAmount.sub(_amount));
    }

    function withdrawFees(
        address _token,
        address _receiver
    ) external override returns (uint256) {
        _validateManager();
        uint256 amount = feeReserves[_token];
        if (amount == 0) {
            return 0;
        }
        feeReserves[_token] = 0;
        _transferOut(_token, amount, _receiver);
        return amount;
    }

    // deposit into the pool without minting USDPH tokens
    // useful in allowing the pool to become over-collaterised
    function directPoolDeposit(address _token) external override nonReentrant {
        _validate(
            _tokenConfigs.tokenConfigs[_token].isWhitelisted,
            VaultErrors.V_TOKEN_NOT_WHITELISTED
        );
        uint256 tokenAmount = _transferIn(_token);
        _validate(tokenAmount > 0, VaultErrors.V_INVALID_TOKEN_AMOUNT);
        _increasePoolAmount(_token, tokenAmount);
        emit DirectPoolDeposit(_token, tokenAmount);
    }

    function buyUSDPH(
        address _token,
        address _receiver
    ) external override nonReentrant returns (uint256) {
        _validateManager();
        _validate(
            _tokenConfigs.tokenConfigs[_token].isWhitelisted,
            VaultErrors.V_TOKEN_NOT_WHITELISTED
        );

        address usdph = addressesProvider.getUsdph();

        uint256 tokenAmount = _transferIn(_token);
        _validate(tokenAmount > 0, VaultErrors.V_INVALID_TOKEN_AMOUNT);

        updateCumulativeFundingRate(_token);

        uint256 price = IPhamePriceOracle(addressesProvider.getPriceOracle())
            .getPrice(_token, false);

        uint256 usdphAmount = tokenAmount.mul(price).div(PRICE_PRECISION);
        usdphAmount = _adjustForDecimals(usdphAmount, _token, usdph);
        _validate(usdphAmount > 0, VaultErrors.V_INVALID_USDPH_AMOUNT);

        uint256 feeBps = VaultUtils.getBuyUsdphFeeBps(
            addressesProvider,
            _token,
            usdphAmount
        );
        (uint256 amountAfterFees, uint256 feeAmount) = _collectSwapFees(
            _token,
            tokenAmount,
            feeBps
        );
        uint256 mintAmount = amountAfterFees.mul(price).div(PRICE_PRECISION);
        mintAmount = _adjustForDecimals(mintAmount, _token, usdph);

        _increaseUsdphAmount(_token, mintAmount);
        _increasePoolAmount(_token, amountAfterFees);

        IUSDPH(usdph).mint(_receiver, mintAmount);

        emit BuyUSDPH(_receiver, _token, tokenAmount, mintAmount, feeBps);

        _payLpFees(_token, feeAmount);
        return mintAmount;
    }

    function buyUSDPHwithoutFee(
        address _token
    ) external override nonReentrant returns (uint256) {
        _validateManager();
        _validate(
            _tokenConfigs.tokenConfigs[_token].isWhitelisted,
            VaultErrors.V_TOKEN_NOT_WHITELISTED
        );

        address usdph = addressesProvider.getUsdph();

        uint256 tokenAmount = _transferIn(_token);
        _validate(tokenAmount > 0, VaultErrors.V_INVALID_TOKEN_AMOUNT);

        updateCumulativeFundingRate(_token);

        uint256 price = IPhamePriceOracle(addressesProvider.getPriceOracle())
            .getPrice(_token, false);

        uint256 usdphAmount = tokenAmount.mul(price).div(PRICE_PRECISION);
        usdphAmount = _adjustForDecimals(usdphAmount, _token, usdph);
        _validate(usdphAmount > 0, VaultErrors.V_INVALID_USDPH_AMOUNT);

        uint256 mintAmount = tokenAmount.mul(price).div(PRICE_PRECISION);
        mintAmount = _adjustForDecimals(mintAmount, _token, usdph);

        usdphAmounts[_token] = usdphAmounts[_token].add(mintAmount);
        emit IncreaseUsdphAmount(_token, mintAmount);
        _increasePoolAmount(_token, tokenAmount);

        IUSDPH(usdph).mint(msg.sender, mintAmount);

        emit BuyUSDPH(msg.sender, _token, tokenAmount, mintAmount, 0);

        return mintAmount;
    }

    function sellUSDPH(
        address _token,
        address _receiver
    ) external override nonReentrant returns (uint256) {
        _validateManager();
        _validate(
            _tokenConfigs.tokenConfigs[_token].isWhitelisted,
            VaultErrors.V_TOKEN_NOT_WHITELISTED
        );

        address usdph = addressesProvider.getUsdph();

        uint256 usdphAmount = _transferIn(usdph);
        _validate(usdphAmount > 0, VaultErrors.V_INVALID_USDPH_AMOUNT);

        updateCumulativeFundingRate(_token);

        uint256 redemptionAmount = getRedemptionAmount(_token, usdphAmount);
        _validate(
            redemptionAmount > 0,
            VaultErrors.V_INVALID_REDEMPTION_AMOUNT
        );

        _decreaseUsdphAmount(_token, usdphAmount);
        _decreasePoolAmount(_token, redemptionAmount);

        IUSDPH(usdph).burn(address(this), usdphAmount);

        // the _transferIn call increased the value of tokenBalances[usdph]
        // usually decreases in token balances are synced by calling _transferOut
        // however, for usdph, the tokens are burnt, so tokenBalances should
        // be manually updated record the decrease in tokens
        tokenBalances[usdph] = IERC20(usdph).balanceOf(address(this));

        uint256 feeBps = VaultUtils.getSellUsdphFeeBps(
            addressesProvider,
            _token,
            usdphAmount
        );
        (uint256 amountOut, uint256 feeAmount) = _collectSwapFees(
            _token,
            redemptionAmount,
            feeBps
        );
        _validate(amountOut > 0, VaultErrors.V_INVALID_AMOUNT_OUT);

        _transferOut(_token, amountOut, _receiver);

        emit SellUSDPH(_receiver, _token, usdphAmount, amountOut, feeBps);

        _payLpFees(_token, feeAmount);
        return amountOut;
    }

    function swap(
        address _tokenIn,
        address _tokenOut,
        address _receiver
    ) external override nonReentrant returns (uint256) {
        _validate(_vaultConfig.isSwapEnabled, VaultErrors.V_SWAPS_NOT_ENABLED);
        _validate(
            _tokenConfigs.tokenConfigs[_tokenIn].isWhitelisted,
            VaultErrors.V_TOKEN_NOT_WHITELISTED
        );
        _validate(
            _tokenConfigs.tokenConfigs[_tokenOut].isWhitelisted,
            VaultErrors.V_TOKEN_NOT_WHITELISTED
        );
        _validate(_tokenIn != _tokenOut, VaultErrors.V_SAME_TOKEN);

        updateCumulativeFundingRate(_tokenIn);
        updateCumulativeFundingRate(_tokenOut);

        uint256 amountIn = _transferIn(_tokenIn);
        _validate(amountIn > 0, VaultErrors.V_INVALID_AMOUNT_IN);

        IPhamePriceOracle priceOracle = IPhamePriceOracle(
            addressesProvider.getPriceOracle()
        );
        uint256 priceIn = priceOracle.getPrice(_tokenIn, false);
        uint256 priceOut = priceOracle.getPrice(_tokenOut, true);

        uint256 amountOut = amountIn.mul(priceIn).div(priceOut);
        amountOut = _adjustForDecimals(amountOut, _tokenIn, _tokenOut);

        // adjust usdphAmounts by the same usdphAmount as debt is shifted between the assets
        uint256 usdphAmount = amountIn.mul(priceIn).div(PRICE_PRECISION);
        usdphAmount = _adjustForDecimals(
            usdphAmount,
            _tokenIn,
            addressesProvider.getUsdph()
        );

        uint256 feeBps = VaultUtils.getSwapFeeBps(
            addressesProvider,
            _tokenIn,
            _tokenOut,
            usdphAmount
        );
        (uint256 amountOutAfterFees, uint256 feeAmount) = _collectSwapFees(
            _tokenOut,
            amountOut,
            feeBps
        );

        _increaseUsdphAmount(_tokenIn, usdphAmount);
        _decreaseUsdphAmount(_tokenOut, usdphAmount);

        _increasePoolAmount(_tokenIn, amountIn);
        _decreasePoolAmount(_tokenOut, amountOut);

        _validate(
            poolAmounts[_tokenOut] >=
                _tokenConfigs.tokenConfigs[_tokenOut].bufferAmount,
            VaultErrors.V_POOL_LESS_THAN_BUFFER
        );

        _transferOut(_tokenOut, amountOutAfterFees, _receiver);

        emit Swap(
            _receiver,
            _tokenIn,
            _tokenOut,
            amountIn,
            amountOut,
            amountOutAfterFees,
            feeBps
        );

        _payLpFees(_tokenOut, feeAmount);

        return amountOutAfterFees;
    }

    function increasePosition(
        address _account,
        address _collateralToken,
        address _indexToken,
        uint256 _sizeDelta,
        bool _isLong
    ) external override nonReentrant {
        _validateRouter();
        _tokenConfigs.validateTokens(_collateralToken, _indexToken, _isLong);
        _validate(
            _vaultConfig.isLeverageEnabled,
            VaultErrors.V_LEVERAGE_NOT_ENABLED
        );

        updateCumulativeFundingRate(_collateralToken);

        bytes32 key = _getPositionKey(
            _account,
            _collateralToken,
            _indexToken,
            _isLong
        );
        Position storage position = positions[key];

        uint256 price = IPhamePriceOracle(addressesProvider.getPriceOracle())
            .getPrice(_indexToken, _isLong);

        if (_sizeDelta > 0) {
            _validate(
                position.size.add(_sizeDelta) <=
                    getAccountTokenPositionSizeLimit(
                        _account,
                        _indexToken,
                        _isLong
                    ),
                VaultErrors.V_MAX_POSITION_SIZE_EXCEEDED
            );
        }

        if (position.size == 0) {
            position.averagePrice = price;
        }

        if (position.size > 0 && _sizeDelta > 0) {
            position.averagePrice = _getNextAveragePrice(
                _indexToken,
                position.size,
                position.averagePrice,
                _isLong,
                price,
                _sizeDelta,
                position.lastIncreasedTime
            );
        }

        (uint256 fee, uint256 feeAmount) = _collectMarginFees(
            _account,
            _collateralToken,
            _indexToken,
            _isLong,
            _sizeDelta,
            position.size,
            position.entryFundingRate
        );
        uint256 collateralDelta = _transferIn(_collateralToken);
        uint256 collateralDeltaUsd = tokenToUsdMin(
            _collateralToken,
            collateralDelta
        );

        position.collateral = position.collateral.add(collateralDeltaUsd);
        _validate(
            position.collateral >= fee,
            VaultErrors.V_INSUFFICIENT_COLLATERAL_FOR_FEES
        );

        position.collateral = position.collateral.sub(fee);
        position.entryFundingRate = cumulativeFundingRates[_collateralToken];
        position.size = position.size.add(_sizeDelta);
        position.lastIncreasedTime = block.timestamp;

        _validate(position.size > 0, VaultErrors.V_INVALID_POSITION_SIZE);
        _validatePosition(position.size, position.collateral);
        validateLiquidation(
            _account,
            _collateralToken,
            _indexToken,
            _isLong,
            true
        );

        // reserve tokens to pay profits on the position
        uint256 reserveDelta = usdToToken(_collateralToken, _sizeDelta, true);
        position.reserveAmount = position.reserveAmount.add(reserveDelta);
        _increaseReservedAmount(_collateralToken, reserveDelta);

        if (_isLong) {
            // guaranteedUsd stores the sum of (position.size - position.collateral) for all positions
            // if a fee is charged on the collateral then guaranteedUsd should be increased by that fee amount
            // since (position.size - position.collateral) would have increased by `fee`
            _adjustGuaranteedUsd(
                _collateralToken,
                _sizeDelta.add(fee),
                collateralDeltaUsd,
                _sizeDelta > 0 // don't check max size if only adding collateral
            );
            // treat the deposited collateral as part of the pool
            _increasePoolAmount(_collateralToken, collateralDelta);
            // fees need to be deducted from the pool since fees are deducted from position.collateral
            // and collateral is treated as part of the pool
            _decreasePoolAmount(
                _collateralToken,
                usdToToken(_collateralToken, fee, false)
            );
        } else {
            _increaseGlobalShortSize(_indexToken, _sizeDelta);
        }

        emit IncreasePosition(
            key,
            _account,
            _collateralToken,
            _indexToken,
            collateralDeltaUsd,
            _sizeDelta,
            _isLong,
            price,
            fee
        );
        emit UpdatePosition(
            key,
            position.size,
            position.collateral,
            position.averagePrice,
            position.entryFundingRate,
            position.reserveAmount,
            position.realisedPnl,
            price
        );

        _payLpFees(_collateralToken, feeAmount);
    }

    function decreasePosition(
        address _account,
        address _collateralToken,
        address _indexToken,
        uint256 _collateralDelta,
        uint256 _sizeDelta,
        bool _isLong,
        address _receiver
    ) external override nonReentrant returns (uint256) {
        _validateRouter();
        return
            _decreasePosition(
                _account,
                _collateralToken,
                _indexToken,
                _collateralDelta,
                _sizeDelta,
                _isLong,
                _receiver
            );
    }

    function _decreasePosition(
        address _account,
        address _collateralToken,
        address _indexToken,
        uint256 _collateralDelta,
        uint256 _sizeDelta,
        bool _isLong,
        address _receiver
    ) private returns (uint256) {
        updateCumulativeFundingRate(_collateralToken);

        bytes32 key = _getPositionKey(
            _account,
            _collateralToken,
            _indexToken,
            _isLong
        );
        Position storage position = positions[key];
        _validate(position.size > 0, VaultErrors.V_EMPTY_POSITION);
        _validate(
            position.size >= _sizeDelta,
            VaultErrors.V_POSITION_SIZE_EXCEEDED
        );
        _validate(
            position.collateral >= _collateralDelta,
            VaultErrors.V_POSITION_COLLATERAL_EXCEEDED
        );

        uint256 collateral = position.collateral;
        // scrop variables to avoid stack too deep VaultErrors
        {
            uint256 reserveDelta = position.reserveAmount.mul(_sizeDelta).div(
                position.size
            );
            position.reserveAmount = position.reserveAmount.sub(reserveDelta);
            _decreaseReservedAmount(_collateralToken, reserveDelta);
        }

        (uint256 usdOut, uint256 usdOutAfterFee) = _reduceCollateral(
            _account,
            _collateralToken,
            _indexToken,
            _collateralDelta,
            _sizeDelta,
            _isLong
        );

        if (position.size != _sizeDelta) {
            position.entryFundingRate = cumulativeFundingRates[
                _collateralToken
            ];
            position.size = position.size.sub(_sizeDelta);

            _validatePosition(position.size, position.collateral);
            validateLiquidation(
                _account,
                _collateralToken,
                _indexToken,
                _isLong,
                true
            );

            if (_isLong) {
                _adjustGuaranteedUsd(
                    _collateralToken,
                    collateral.sub(position.collateral),
                    _sizeDelta,
                    true
                );
            }

            uint256 price = IPhamePriceOracle(
                addressesProvider.getPriceOracle()
            ).getPrice(_indexToken, !_isLong);
            emit DecreasePosition(
                key,
                _account,
                _collateralToken,
                _indexToken,
                _collateralDelta,
                _sizeDelta,
                _isLong,
                price,
                usdOut.sub(usdOutAfterFee)
            );
            emit UpdatePosition(
                key,
                position.size,
                position.collateral,
                position.averagePrice,
                position.entryFundingRate,
                position.reserveAmount,
                position.realisedPnl,
                price
            );
        } else {
            if (_isLong) {
                _adjustGuaranteedUsd(
                    _collateralToken,
                    collateral,
                    _sizeDelta,
                    true
                );
            }

            uint256 price = IPhamePriceOracle(
                addressesProvider.getPriceOracle()
            ).getPrice(_indexToken, !_isLong);
            emit DecreasePosition(
                key,
                _account,
                _collateralToken,
                _indexToken,
                _collateralDelta,
                _sizeDelta,
                _isLong,
                price,
                usdOut.sub(usdOutAfterFee)
            );
            emit ClosePosition(
                key,
                position.size,
                position.collateral,
                position.averagePrice,
                position.entryFundingRate,
                position.reserveAmount,
                position.realisedPnl
            );

            delete positions[key];
        }

        if (!_isLong) {
            _decreaseGlobalShortSize(_indexToken, _sizeDelta);
        }

        if (usdOut > 0) {
            if (_isLong) {
                _decreasePoolAmount(
                    _collateralToken,
                    usdToToken(_collateralToken, usdOut, false)
                );
            }
            uint256 amountOutAfterFees = usdToToken(
                _collateralToken,
                usdOutAfterFee,
                false
            );
            _transferOut(_collateralToken, amountOutAfterFees, _receiver);
            return amountOutAfterFees;
        }

        return 0;
    }

    function liquidatePosition(
        address _account,
        address _collateralToken,
        address _indexToken,
        bool _isLong,
        address _feeReceiver
    ) external override nonReentrant {
        // only position manager can liquidate
        _validate(
            addressesProvider.getPositionManager() == msg.sender,
            VaultErrors.V_INVALID_LIQUIDATOR
        );

        updateCumulativeFundingRate(_collateralToken);

        bytes32 key = _getPositionKey(
            _account,
            _collateralToken,
            _indexToken,
            _isLong
        );
        Position memory position = positions[key];
        _validate(position.size > 0, VaultErrors.V_EMPTY_POSITION);

        (uint256 liquidationState, uint256 marginFees) = validateLiquidation(
            _account,
            _collateralToken,
            _indexToken,
            _isLong,
            false
        );
        _validate(
            liquidationState != 0,
            VaultErrors.V_POSITION_CANNOT_BE_LIQUIDATED
        );
        if (liquidationState == 2) {
            // max leverage exceeded but there is collateral remaining after deducting losses so decreasePosition instead
            _decreasePosition(
                _account,
                _collateralToken,
                _indexToken,
                0,
                position.size,
                _isLong,
                _account
            );
            return;
        }

        uint256 feeTokens = usdToToken(_collateralToken, marginFees, false);
        feeReserves[_collateralToken] = feeReserves[_collateralToken].add(
            feeTokens
        );
        emit CollectMarginFees(_collateralToken, marginFees, feeTokens);

        _decreaseReservedAmount(_collateralToken, position.reserveAmount);
        if (_isLong) {
            _adjustGuaranteedUsd(
                _collateralToken,
                0,
                position.size.sub(position.collateral),
                false
            );
            _decreasePoolAmount(
                _collateralToken,
                usdToToken(_collateralToken, marginFees, false)
            );
        }

        uint256 markPrice = IPhamePriceOracle(
            addressesProvider.getPriceOracle()
        ).getPrice(_indexToken, !_isLong);
        emit LiquidatePosition(
            key,
            _account,
            _collateralToken,
            _indexToken,
            _isLong,
            position.size,
            position.collateral,
            position.reserveAmount,
            position.realisedPnl,
            markPrice
        );

        if (!_isLong && marginFees < position.collateral) {
            uint256 remainingCollateral = position.collateral.sub(marginFees);
            _increasePoolAmount(
                _collateralToken,
                usdToToken(_collateralToken, remainingCollateral, false)
            );
        }

        if (!_isLong) {
            _decreaseGlobalShortSize(_indexToken, position.size);
        }

        delete positions[key];

        // pay the fee receiver using the pool, we assume that in general the liquidated amount should be sufficient to cover
        // the liquidation fees
        uint256 liquidationFeeUsd = _vaultConfig.liquidationFeeUsd;
        _decreasePoolAmount(
            _collateralToken,
            usdToToken(_collateralToken, liquidationFeeUsd, false)
        );
        _transferOut(
            _collateralToken,
            usdToToken(_collateralToken, liquidationFeeUsd, false),
            _feeReceiver
        );

        _payLpFees(_collateralToken, feeTokens);
    }

    // validateLiquidation returns (state, fees)
    function validateLiquidation(
        address _account,
        address _collateralToken,
        address _indexToken,
        bool _isLong,
        bool _raise
    ) public view override returns (uint256, uint256) {
        return
            VaultUtils.validateLiquidation(
                addressesProvider,
                _account,
                _collateralToken,
                _indexToken,
                _isLong,
                _raise
            );
    }

    function getRedemptionAmount(
        address _token,
        uint256 _usdphAmount
    ) public view override returns (uint256) {
        uint256 price = IPhamePriceOracle(addressesProvider.getPriceOracle())
            .getPrice(_token, true);
        uint256 redemptionAmount = _usdphAmount.mul(PRICE_PRECISION).div(price);
        return
            _adjustForDecimals(
                redemptionAmount,
                addressesProvider.getUsdph(),
                _token
            );
    }

    function _adjustForDecimals(
        uint256 _amount,
        address _tokenDiv,
        address _tokenMul
    ) private view returns (uint256) {
        address usdph = addressesProvider.getUsdph();
        uint256 decimalsDiv = _tokenDiv == usdph
            ? USDPH_DECIMALS
            : _tokenConfigs.tokenConfigs[_tokenDiv].decimals;
        uint256 decimalsMul = _tokenMul == usdph
            ? USDPH_DECIMALS
            : _tokenConfigs.tokenConfigs[_tokenMul].decimals;
        return _amount.mul(10 ** decimalsMul).div(10 ** decimalsDiv);
    }

    function tokenToUsdMin(
        address _token,
        uint256 _tokenAmount
    ) public view override returns (uint256) {
        if (_tokenAmount == 0) {
            return 0;
        }
        return
            _tokenAmount
                .mul(
                    IPhamePriceOracle(addressesProvider.getPriceOracle())
                        .getPrice(_token, false)
                )
                .div(10 ** _tokenConfigs.tokenConfigs[_token].decimals);
    }

    function usdToToken(
        address _token,
        uint256 _usdAmount,
        bool _maximise
    ) private view returns (uint256) {
        if (_usdAmount == 0) {
            return 0;
        }
        return
            _usdAmount
                .mul(10 ** _tokenConfigs.tokenConfigs[_token].decimals)
                .div(
                    IPhamePriceOracle(addressesProvider.getPriceOracle())
                        .getPrice(_token, !_maximise)
                );
    }

    function getPosition(
        address _account,
        address _collateralToken,
        address _indexToken,
        bool _isLong
    )
        public
        view
        override
        returns (
            uint256,
            uint256,
            uint256,
            uint256,
            uint256,
            uint256,
            bool,
            uint256
        )
    {
        Position memory position = positions[
            _getPositionKey(_account, _collateralToken, _indexToken, _isLong)
        ];
        uint256 realisedPnl = position.realisedPnl > 0
            ? uint256(position.realisedPnl)
            : uint256(-position.realisedPnl);
        return (
            position.size, // 0
            position.collateral, // 1
            position.averagePrice, // 2
            position.entryFundingRate, // 3
            position.reserveAmount, // 4
            realisedPnl, // 5
            position.realisedPnl >= 0, // 6
            position.lastIncreasedTime // 7
        );
    }

    function updateCumulativeFundingRate(address _collateralToken) public {
        uint256 fundingInterval = _tokenConfigs
            .tokenConfigs[_collateralToken]
            .fundingInterval;

        if (lastFundingTimes[_collateralToken] == 0) {
            lastFundingTimes[_collateralToken] = block
                .timestamp
                .div(fundingInterval)
                .mul(fundingInterval);
            return;
        }

        if (
            lastFundingTimes[_collateralToken].add(fundingInterval) >
            block.timestamp
        ) {
            return;
        }

        uint256 fundingRate = getNextFundingRate(_collateralToken);
        cumulativeFundingRates[_collateralToken] = cumulativeFundingRates[
            _collateralToken
        ].add(fundingRate);
        lastFundingTimes[_collateralToken] = block
            .timestamp
            .div(fundingInterval)
            .mul(fundingInterval);

        emit UpdateFundingRate(
            _collateralToken,
            cumulativeFundingRates[_collateralToken]
        );
    }

    function getNextFundingRate(
        address _token
    ) public view override returns (uint256) {
        return VaultUtils.getNextFundingRate(addressesProvider, _token);
    }

    // for longs: nextAveragePrice = (nextPrice * nextSize)/ (nextSize + delta)
    // for shorts: nextAveragePrice = (nextPrice * nextSize) / (nextSize - delta)
    function _getNextAveragePrice(
        address _indexToken,
        uint256 _size,
        uint256 _averagePrice,
        bool _isLong,
        uint256 _nextPrice,
        uint256 _sizeDelta,
        uint256 _lastIncreasedTime
    ) private view returns (uint256) {
        (bool hasProfit, uint256 delta) = getDelta(
            _indexToken,
            _size,
            _averagePrice,
            _isLong,
            _lastIncreasedTime
        );
        uint256 nextSize = _size.add(_sizeDelta);
        uint256 divisor;
        if (_isLong) {
            divisor = hasProfit ? nextSize.add(delta) : nextSize.sub(delta);
        } else {
            divisor = hasProfit ? nextSize.sub(delta) : nextSize.add(delta);
        }
        return _nextPrice.mul(nextSize).div(divisor);
    }

    function getMinProfitTime(
        address _indexToken,
        uint256 _size,
        bool _isLong
    ) public view override returns (uint256) {
        return
            VaultUtils.getMinProfitTime(
                addressesProvider,
                _indexToken,
                _size,
                _isLong
            );
    }

    function getDelta(
        address _indexToken,
        uint256 _size,
        uint256 _averagePrice,
        bool _isLong,
        uint256 _lastIncreasedTime
    ) public view override returns (bool, uint256) {
        return
            VaultUtils.getDelta(
                addressesProvider,
                _indexToken,
                _size,
                _averagePrice,
                _isLong,
                _lastIncreasedTime
            );
    }

    function getFundingFee(
        address _account,
        address _collateralToken,
        address _indexToken,
        bool _isLong,
        uint256 _size,
        uint256 _entryFundingRate
    ) public view returns (uint256) {
        return
            VaultUtils.getFundingFee(
                this,
                _account,
                _collateralToken,
                _indexToken,
                _isLong,
                _size,
                _entryFundingRate
            );
    }

    // cases to consider
    // 1. initialAmount is far from targetAmount, action increases balance slightly => high rebate
    // 2. initialAmount is far from targetAmount, action increases balance largely => high rebate
    // 3. initialAmount is close to targetAmount, action increases balance slightly => low rebate
    // 4. initialAmount is far from targetAmount, action reduces balance slightly => high tax
    // 5. initialAmount is far from targetAmount, action reduces balance largely => high tax
    // 6. initialAmount is close to targetAmount, action reduces balance largely => low tax
    // 7. initialAmount is above targetAmount, nextAmount is below targetAmount and vice versa
    // 8. a large swap should have similar fees as the same trade split into multiple smaller swaps
    function getFeeBps(
        address _token,
        uint256 _usdphDelta,
        uint256 _feeBps,
        uint256 _taxBps,
        bool _increment
    ) public view override returns (uint256) {
        return
            VaultUtils.getFeeBps(
                addressesProvider,
                _token,
                _usdphDelta,
                _feeBps,
                _taxBps,
                _increment
            );
    }

    function getAccountTokenPositionSizeLimit(
        address _account,
        address _token,
        bool _isLong
    ) public view override returns (uint256) {
        DataTypes.AccountTokenConfig
            memory accountTokenConfig = _accountTokenConfigs[_account][_token];
        DataTypes.TokenConfig memory tokenConfig = _tokenConfigs.tokenConfigs[
            _token
        ];
        if (_isLong) {
            if (accountTokenConfig.isLongBlacklisted) {
                return 0;
            } else if (accountTokenConfig.maxPositionLongSizeOverride == 0) {
                return tokenConfig.maxPositionLongSize;
            } else {
                return accountTokenConfig.maxPositionLongSizeOverride;
            }
        } else {
            if (accountTokenConfig.isShortBlacklisted) {
                return 0;
            } else if (accountTokenConfig.maxPositionShortSizeOverride == 0) {
                return tokenConfig.maxPositionShortSize;
            } else {
                return accountTokenConfig.maxPositionShortSizeOverride;
            }
        }
    }

    function _getPositionKey(
        address _account,
        address _collateralToken,
        address _indexToken,
        bool _isLong
    ) private pure returns (bytes32) {
        return
            keccak256(
                abi.encodePacked(
                    _account,
                    _collateralToken,
                    _indexToken,
                    _isLong
                )
            );
    }

    function _reduceCollateral(
        address _account,
        address _collateralToken,
        address _indexToken,
        uint256 _collateralDelta,
        uint256 _sizeDelta,
        bool _isLong
    ) private returns (uint256, uint256) {
        Position storage position;
        bool hasProfit;
        uint256 adjustedDelta;
        // scope variables to avoid stack too deep VaultErrors
        {
            bytes32 key = _getPositionKey(
                _account,
                _collateralToken,
                _indexToken,
                _isLong
            );
            position = positions[key];
            (bool _hasProfit, uint256 delta) = getDelta(
                _indexToken,
                position.size,
                position.averagePrice,
                _isLong,
                position.lastIncreasedTime
            );
            hasProfit = _hasProfit;
            // get the proportional change in pnl
            adjustedDelta = _sizeDelta.mul(delta).div(position.size);
            emit UpdatePnl(key, hasProfit, adjustedDelta);
        }

        (uint256 fee, uint256 feeAmount) = _collectMarginFees(
            _account,
            _collateralToken,
            _indexToken,
            _isLong,
            _sizeDelta,
            position.size,
            position.entryFundingRate
        );

        uint256 usdOut;
        // transfer profits out
        if (hasProfit && adjustedDelta > 0) {
            usdOut = adjustedDelta;
            position.realisedPnl = position.realisedPnl + int256(adjustedDelta);

            // pay out realised profits from the pool amount for short positions
            if (!_isLong) {
                uint256 tokenAmount = usdToToken(
                    _collateralToken,
                    adjustedDelta,
                    false
                );
                _decreasePoolAmount(_collateralToken, tokenAmount);
            }
        }

        if (!hasProfit && adjustedDelta > 0) {
            position.collateral = position.collateral.sub(adjustedDelta);

            // transfer realised losses to the pool for short positions
            // realised losses for long positions are not transferred here as
            // _increasePoolAmount was already called in increasePosition for longs
            if (!_isLong) {
                uint256 tokenAmount = usdToToken(
                    _collateralToken,
                    adjustedDelta,
                    false
                );
                _increasePoolAmount(_collateralToken, tokenAmount);
            }

            position.realisedPnl = position.realisedPnl - int256(adjustedDelta);
        }

        // reduce the position's collateral by _collateralDelta
        // transfer _collateralDelta out
        if (_collateralDelta > 0) {
            usdOut = usdOut.add(_collateralDelta);
            position.collateral = position.collateral.sub(_collateralDelta);
        }

        // if the position will be closed, then transfer the remaining collateral out
        if (position.size == _sizeDelta) {
            usdOut = usdOut.add(position.collateral);
            position.collateral = 0;
        }

        // if the usdOut is more than the fee then deduct the fee from the usdOut directly
        // else deduct the fee from the position's collateral
        uint256 usdOutAfterFee = usdOut;
        if (usdOut > fee) {
            usdOutAfterFee = usdOut.sub(fee);
        } else {
            position.collateral = position.collateral.sub(fee);
            if (_isLong) {
                uint256 feeTokens = usdToToken(_collateralToken, fee, false);
                _decreasePoolAmount(_collateralToken, feeTokens);
            }
        }

        _payLpFees(_collateralToken, feeAmount);

        return (usdOut, usdOutAfterFee);
    }

    function _validatePosition(
        uint256 _size,
        uint256 _collateral
    ) private pure {
        if (_size == 0) {
            _validate(
                _collateral == 0,
                VaultErrors.V_COLLATERAL_SHOULD_BE_WITHDRAWN
            );
            return;
        }
        _validate(
            _size >= _collateral,
            VaultErrors.V_SIZE_MUST_BE_MORE_THAN_COLLATERAL
        );
    }

    function _collectSwapFees(
        address _token,
        uint256 _amount,
        uint256 _feeBps
    ) private returns (uint256, uint256) {
        uint256 afterFeeAmount = _amount
            .mul(BASIS_POINTS_DIVISOR.sub(_feeBps))
            .div(BASIS_POINTS_DIVISOR);
        uint256 feeAmount = _amount.sub(afterFeeAmount);
        feeReserves[_token] = feeReserves[_token].add(feeAmount);
        emit CollectSwapFees(
            _token,
            tokenToUsdMin(_token, feeAmount),
            feeAmount
        );
        return (afterFeeAmount, feeAmount);
    }

    function _payLpFees(address token, uint256 feeAmount) private {
        uint256 lpFee = feeAmount
            .mul(BASIS_POINTS_DIVISOR.sub(_vaultConfig.stakingBps))
            .div(BASIS_POINTS_DIVISOR);
        if (lpFee > 0) {
            feeReserves[token] = feeReserves[token].sub(lpFee);
            poolAmounts[token] = poolAmounts[token].add(lpFee);
            emit PayLpFees(token, lpFee);
        }
    }

    function _collectMarginFees(
        address _account,
        address _collateralToken,
        address _indexToken,
        bool _isLong,
        uint256 _sizeDelta,
        uint256 _size,
        uint256 _entryFundingRate
    ) private returns (uint256, uint256) {
        uint256 feeUsd = VaultUtils
            .getPositionFee(
                addressesProvider,
                _account,
                _collateralToken,
                _indexToken,
                _isLong,
                _sizeDelta
            )
            .add(
                getFundingFee(
                    _account,
                    _collateralToken,
                    _indexToken,
                    _isLong,
                    _size,
                    _entryFundingRate
                )
            );

        uint256 feeTokens = usdToToken(_collateralToken, feeUsd, false);
        feeReserves[_collateralToken] = feeReserves[_collateralToken].add(
            feeTokens
        );
        emit CollectMarginFees(_collateralToken, feeUsd, feeTokens);

        return (feeUsd, feeTokens);
    }

    function _transferIn(address _token) private returns (uint256) {
        uint256 prevBalance = tokenBalances[_token];
        uint256 nextBalance = IERC20(_token).balanceOf(address(this));
        tokenBalances[_token] = nextBalance;

        return nextBalance.sub(prevBalance);
    }

    function _transferOut(
        address _token,
        uint256 _amount,
        address _receiver
    ) private {
        IERC20(_token).safeTransfer(_receiver, _amount);
        tokenBalances[_token] = IERC20(_token).balanceOf(address(this));
    }

    function _increasePoolAmount(address _token, uint256 _amount) private {
        poolAmounts[_token] = poolAmounts[_token].add(_amount);
        uint256 balance = IERC20(_token).balanceOf(address(this));
        if (poolAmounts[_token] > balance) {
            poolAmounts[_token] = balance;
        }
        emit IncreasePoolAmount(_token, _amount);
    }

    function _decreasePoolAmount(address _token, uint256 _amount) private {
        poolAmounts[_token] = poolAmounts[_token].sub(_amount);
        _validate(
            reservedAmounts[_token] <= poolAmounts[_token],
            VaultErrors.V_RESERVE_EXCEEDS_POOL
        );
        emit DecreasePoolAmount(_token, _amount);
    }

    function _increaseUsdphAmount(address _token, uint256 _amount) private {
        usdphAmounts[_token] = usdphAmounts[_token].add(_amount);
        uint256 maxUsdphAmount = _tokenConfigs
            .tokenConfigs[_token]
            .maxUsdphAmount;
        if (maxUsdphAmount != 0) {
            _validate(
                usdphAmounts[_token] <= maxUsdphAmount,
                VaultErrors.V_MAX_USDPH_EXCEEDED
            );
        }
        emit IncreaseUsdphAmount(_token, _amount);
    }

    function _decreaseUsdphAmount(address _token, uint256 _amount) private {
        uint256 value = usdphAmounts[_token];
        // since USDPH can be minted using multiple assets
        // it is possible for the USDPH debt for a single asset to be less than zero
        // the USDPH debt is capped to zero for this case
        if (value <= _amount) {
            usdphAmounts[_token] = 0;
            emit DecreaseUsdphAmount(_token, value);
            return;
        }
        usdphAmounts[_token] = value.sub(_amount);
        emit DecreaseUsdphAmount(_token, _amount);
    }

    function _increaseReservedAmount(address _token, uint256 _amount) private {
        reservedAmounts[_token] = reservedAmounts[_token].add(_amount);
        _validate(
            reservedAmounts[_token] <= poolAmounts[_token],
            VaultErrors.V_RESERVE_EXCEEDS_POOL
        );
        emit IncreaseReservedAmount(_token, _amount);
    }

    function _decreaseReservedAmount(address _token, uint256 _amount) private {
        reservedAmounts[_token] = reservedAmounts[_token].sub(
            _amount,
            "Vault: insufficient reserve"
        );
        emit DecreaseReservedAmount(_token, _amount);
    }

    function _adjustGuaranteedUsd(
        address _token,
        uint256 _increasedUsdAmount,
        uint256 _decreasedUsdAmount,
        bool _checkMaxSize
    ) private {
        guaranteedUsd[_token] = guaranteedUsd[_token]
            .add(_increasedUsdAmount)
            .sub(_decreasedUsdAmount);

        if (_checkMaxSize && _increasedUsdAmount > _decreasedUsdAmount) {
            uint256 maxSize = _tokenConfigs
                .tokenConfigs[_token]
                .maxGlobalLongSize;
            if (maxSize != 0) {
                _validate(
                    guaranteedUsd[_token] <= maxSize,
                    VaultErrors.V_MAX_GLOBAL_LONG_EXCEEDED
                );
            }
        }

        if (_increasedUsdAmount > 0) {
            emit IncreaseGuaranteedUsd(_token, _increasedUsdAmount);
        }
        if (_decreasedUsdAmount > 0) {
            emit DecreaseGuaranteedUsd(_token, _decreasedUsdAmount);
        }
    }

    function _increaseGlobalShortSize(address _token, uint256 _amount) private {
        if (_amount == 0) {
            return;
        }

        globalShortSizes[_token] = globalShortSizes[_token].add(_amount);

        uint256 maxSize = _tokenConfigs.tokenConfigs[_token].maxGlobalShortSize;
        if (maxSize != 0) {
            _validate(
                globalShortSizes[_token] <= maxSize,
                VaultErrors.V_MAX_GLOBAL_SHORT_EXCEEDED
            );
        }
    }

    function _decreaseGlobalShortSize(address _token, uint256 _amount) private {
        uint256 size = globalShortSizes[_token];
        if (_amount > size) {
            globalShortSizes[_token] = 0;
            return;
        }

        globalShortSizes[_token] = size.sub(_amount);
    }

    // we have this validation as a function instead of a modifier to reduce contract size
    function _validateManager() private view {
        _validate(
            msg.sender == addressesProvider.getPhlpManager(),
            VaultErrors.V_NOT_PHLP_MANAGER
        );
    }

    function _validateConfigurator() private view {
        _validate(
            msg.sender == addressesProvider.getVaultConfigurator(),
            VaultErrors.V_NOT_CONFIGURATOR
        );
    }

    function _validateRouter() private view {
        _validate(
            msg.sender == addressesProvider.getRouter(),
            VaultErrors.V_NOT_ROUTER
        );
    }

    function _validate(bool _condition, uint256 _errorCode) private pure {
        GeneralUtils.validate(_condition, _errorCode);
    }
}
        

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.2 <0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(
            address(this).balance >= amount,
            "Address: insufficient balance"
        );

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{value: amount}("");
        require(
            success,
            "Address: unable to send value, recipient may have reverted"
        );
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data)
        internal
        returns (bytes memory)
    {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return
            functionCallWithValue(
                target,
                data,
                value,
                "Address: low-level call with value failed"
            );
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(
            address(this).balance >= value,
            "Address: insufficient balance for call"
        );
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{value: value}(
            data
        );
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data)
        internal
        view
        returns (bytes memory)
    {
        return
            functionStaticCall(
                target,
                data,
                "Address: low-level static call failed"
            );
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data)
        internal
        returns (bytes memory)
    {
        return
            functionDelegateCall(
                target,
                data,
                "Address: low-level delegate call failed"
            );
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    function _verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) private pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}
          

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount)
        external
        returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender)
        external
        view
        returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );
}
          

// SPDX-License-Identifier: MIT

pragma solidity 0.7.6;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and make it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}
          

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

import "./IERC20.sol";
import "./SafeMath.sol";
import "./Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using SafeMath for uint256;
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(
            token,
            abi.encodeWithSelector(token.transfer.selector, to, value)
        );
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(
            token,
            abi.encodeWithSelector(token.transferFrom.selector, from, to, value)
        );
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(
            token,
            abi.encodeWithSelector(token.approve.selector, spender, value)
        );
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender).add(
            value
        );
        _callOptionalReturn(
            token,
            abi.encodeWithSelector(
                token.approve.selector,
                spender,
                newAllowance
            )
        );
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender).sub(
            value,
            "SafeERC20: decreased allowance below zero"
        );
        _callOptionalReturn(
            token,
            abi.encodeWithSelector(
                token.approve.selector,
                spender,
                newAllowance
            )
        );
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(
            data,
            "SafeERC20: low-level call failed"
        );
        if (returndata.length > 0) {
            // Return data is optional
            // solhint-disable-next-line max-line-length
            require(
                abi.decode(returndata, (bool)),
                "SafeERC20: ERC20 operation did not succeed"
            );
        }
    }
}
          

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b)
        internal
        pure
        returns (bool, uint256)
    {
        uint256 c = a + b;
        if (c < a) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b)
        internal
        pure
        returns (bool, uint256)
    {
        if (b > a) return (false, 0);
        return (true, a - b);
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b)
        internal
        pure
        returns (bool, uint256)
    {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) return (true, 0);
        uint256 c = a * b;
        if (c / a != b) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b)
        internal
        pure
        returns (bool, uint256)
    {
        if (b == 0) return (false, 0);
        return (true, a / b);
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b)
        internal
        pure
        returns (bool, uint256)
    {
        if (b == 0) return (false, 0);
        return (true, a % b);
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");
        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b <= a, "SafeMath: subtraction overflow");
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        if (a == 0) return 0;
        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");
        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: division by zero");
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: modulo by zero");
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        return a - b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryDiv}.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a % b;
    }
}
          

// SPDX-License-Identifier: agpl-3.0
pragma solidity 0.7.6;

interface IAddressesProvider {
    function getUsdph() external view returns (address);

    function getPhlp() external view returns (address);

    function getPhlpManager() external view returns (address);

    function getVault() external view returns (address);

    function getVaultConfigurator() external view returns (address);

    function getRouter() external view returns (address);

    function getOrderBook() external view returns (address);

    function getPositionManager() external view returns (address);

    function getPositionRouter() external view returns (address);

    function getPriceOracle() external view returns (address);

    function getShortsTracker() external view returns (address);

    function getTreasury() external view returns (address payable);

    function getFeeDistribution() external view returns (address);
}
          

// SPDX-License-Identifier: MIT

pragma solidity 0.7.6;

interface IPhamePriceOracle {
    function backupPriceOracle() external view returns (address);

    function adjustmentBps(address _token) external view returns (uint256);

    function isAdjustmentAdditive(address _token) external view returns (bool);

    function setAdjustment(
        address _token,
        bool _isAdditive,
        uint256 _adjustmentBps
    ) external;

    function setSpreadBps(address _token, uint256 _spreadBps) external;

    function setSpreadThresholdBps(uint256 _spreadThresholdBps) external;

    function setPriceSampleSpace(uint256 _priceSampleSpace) external;

    function setMaxStrictPriceDeviation(
        uint256 _maxStrictPriceDeviation
    ) external;

    function getPrice(
        address _token,
        bool _maximise
    ) external view returns (uint256);

    function setTokenConfig(
        address _token,
        address _priceFeed,
        uint256 _priceDecimals,
        bool _isStrictStable
    ) external;
}
          

// SPDX-License-Identifier: MIT

pragma solidity 0.7.6;

interface IUSDPH {
    function mint(address _account, uint256 _amount) external;

    function burn(address _account, uint256 _amount) external;
}
          

// SPDX-License-Identifier: MIT

pragma solidity 0.7.6;
pragma experimental ABIEncoderV2;

import "../protocol/libraries/types/DataTypes.sol";
import "./IAddressesProvider.sol";

interface IVault {
    struct Position {
        uint256 size;
        uint256 collateral;
        uint256 averagePrice;
        uint256 entryFundingRate;
        uint256 reserveAmount;
        int256 realisedPnl;
        uint256 lastIncreasedTime;
    }

    event BuyUSDPH(
        address account,
        address token,
        uint256 tokenAmount,
        uint256 usdphAmount,
        uint256 feeBps
    );
    event SellUSDPH(
        address account,
        address token,
        uint256 usdphAmount,
        uint256 tokenAmount,
        uint256 feeBps
    );
    event Swap(
        address account,
        address tokenIn,
        address tokenOut,
        uint256 amountIn,
        uint256 amountOut,
        uint256 amountOutAfterFees,
        uint256 feeBps
    );
    event IncreasePosition(
        bytes32 key,
        address account,
        address collateralToken,
        address indexToken,
        uint256 collateralDelta,
        uint256 sizeDelta,
        bool isLong,
        uint256 price,
        uint256 fee
    );
    event DecreasePosition(
        bytes32 key,
        address account,
        address collateralToken,
        address indexToken,
        uint256 collateralDelta,
        uint256 sizeDelta,
        bool isLong,
        uint256 price,
        uint256 fee
    );
    event LiquidatePosition(
        bytes32 key,
        address account,
        address collateralToken,
        address indexToken,
        bool isLong,
        uint256 size,
        uint256 collateral,
        uint256 reserveAmount,
        int256 realisedPnl,
        uint256 markPrice
    );
    event UpdatePosition(
        bytes32 key,
        uint256 size,
        uint256 collateral,
        uint256 averagePrice,
        uint256 entryFundingRate,
        uint256 reserveAmount,
        int256 realisedPnl,
        uint256 markPrice
    );
    event ClosePosition(
        bytes32 key,
        uint256 size,
        uint256 collateral,
        uint256 averagePrice,
        uint256 entryFundingRate,
        uint256 reserveAmount,
        int256 realisedPnl
    );

    event UpdateFundingRate(address token, uint256 fundingRate);
    event UpdatePnl(bytes32 key, bool hasProfit, uint256 delta);

    event CollectSwapFees(address token, uint256 feeUsd, uint256 feeTokens);
    event CollectMarginFees(address token, uint256 feeUsd, uint256 feeTokens);
    event PayLpFees(address token, uint256 feeTokens);

    event DirectPoolDeposit(address token, uint256 amount);
    event IncreasePoolAmount(address token, uint256 amount);
    event DecreasePoolAmount(address token, uint256 amount);
    event IncreaseUsdphAmount(address token, uint256 amount);
    event DecreaseUsdphAmount(address token, uint256 amount);
    event IncreaseReservedAmount(address token, uint256 amount);
    event DecreaseReservedAmount(address token, uint256 amount);
    event IncreaseGuaranteedUsd(address token, uint256 amount);
    event DecreaseGuaranteedUsd(address token, uint256 amount);

    function addressesProvider() external view returns (IAddressesProvider);

    function getVaultConfig()
        external
        view
        returns (DataTypes.VaultConfig memory);

    function setVaultConfig(
        DataTypes.VaultConfig calldata vaultConfig
    ) external;

    function allWhitelistedTokensLength() external view returns (uint256);

    function totalTokenWeights() external view returns (uint256);

    function allWhitelistedTokens(uint256) external view returns (address);

    function getTokenConfig(
        address _token
    ) external view returns (DataTypes.TokenConfig memory);

    function setTokenConfig(
        address _token,
        DataTypes.TokenConfig calldata tokenConfig
    ) external;

    function clearTokenConfig(address _token) external;

    function getAccountTokenConfig(
        address _account,
        address _token
    ) external view returns (DataTypes.AccountTokenConfig memory);

    function setAccountTokenConfig(
        address _account,
        address _token,
        DataTypes.AccountTokenConfig calldata accountTokenConfig
    ) external;

    function getAccountTokenPositionSizeLimit(
        address _account,
        address _token,
        bool _isLong
    ) external view returns (uint256);

    function setUsdphAmount(address _token, uint256 _amount) external;

    function tokenBalances(address _token) external view returns (uint256);

    function lastFundingTimes(address _token) external view returns (uint256);

    function withdrawFees(
        address _token,
        address _receiver
    ) external returns (uint256);

    function directPoolDeposit(address _token) external;

    function buyUSDPH(
        address _token,
        address _receiver
    ) external returns (uint256);

    function buyUSDPHwithoutFee(address _token) external returns (uint256);

    function sellUSDPH(
        address _token,
        address _receiver
    ) external returns (uint256);

    function swap(
        address _tokenIn,
        address _tokenOut,
        address _receiver
    ) external returns (uint256);

    function increasePosition(
        address _account,
        address _collateralToken,
        address _indexToken,
        uint256 _sizeDelta,
        bool _isLong
    ) external;

    function decreasePosition(
        address _account,
        address _collateralToken,
        address _indexToken,
        uint256 _collateralDelta,
        uint256 _sizeDelta,
        bool _isLong,
        address _receiver
    ) external returns (uint256);

    function validateLiquidation(
        address _account,
        address _collateralToken,
        address _indexToken,
        bool _isLong,
        bool _raise
    ) external view returns (uint256, uint256);

    function liquidatePosition(
        address _account,
        address _collateralToken,
        address _indexToken,
        bool _isLong,
        address _feeReceiver
    ) external;

    function tokenToUsdMin(
        address _token,
        uint256 _tokenAmount
    ) external view returns (uint256);

    function cumulativeFundingRates(
        address _token
    ) external view returns (uint256);

    function getNextFundingRate(address _token) external view returns (uint256);

    function getFeeBps(
        address _token,
        uint256 _usdphDelta,
        uint256 _feeBps,
        uint256 _taxBps,
        bool _increment
    ) external view returns (uint256);

    function feeReserves(address _token) external view returns (uint256);

    function globalShortSizes(address _token) external view returns (uint256);

    function guaranteedUsd(address _token) external view returns (uint256);

    function poolAmounts(address _token) external view returns (uint256);

    function reservedAmounts(address _token) external view returns (uint256);

    function usdphAmounts(address _token) external view returns (uint256);

    function getRedemptionAmount(
        address _token,
        uint256 _usdphAmount
    ) external view returns (uint256);

    function getMinProfitTime(
        address _indexToken,
        uint256 _size,
        bool _isLong
    ) external view returns (uint256);

    function getDelta(
        address _indexToken,
        uint256 _size,
        uint256 _averagePrice,
        bool _isLong,
        uint256 _lastIncreasedTime
    ) external view returns (bool, uint256);

    function getPosition(
        address _account,
        address _collateralToken,
        address _indexToken,
        bool _isLong
    )
        external
        view
        returns (
            uint256,
            uint256,
            uint256,
            uint256,
            uint256,
            uint256,
            bool,
            uint256
        );
}
          

// SPDX-License-Identifier: MIT

pragma solidity 0.7.6;
pragma experimental ABIEncoderV2;

interface IVaultConfigurator {
    function setIsLeverageEnabled(bool _isLeverageEnabled) external;

    function setStakingBps(uint256 _stakingBps) external;

    function setUsdphAmount(address _token, uint256 _amount) external;

    function setTokenConfig(
        address _token,
        uint256 _tokenDecimals,
        uint256 _tokenWeight,
        uint256 _maxUsdphAmount,
        bool _isStable,
        bool _isShortable
    ) external;

    function setTokenMinProfit(
        address _token,
        uint256 _minProfitBps,
        uint256 _minProfitTime,
        bool _hasMinProfitTimeFloor,
        uint256 _minProfitTimeCoefBps
    ) external;

    function setTokenMaxSizes(
        address _token,
        uint256 maxGlobalLongSize,
        uint256 maxGlobalShortSize,
        uint256 maxPositionLongSize,
        uint256 maxPositionShortSize
    ) external;

    function setAccountTokenConfig(
        address _account,
        address _token,
        bool _isLongBlacklisted,
        bool _isShortBlacklisted,
        uint256 _maxPositionLongSizeOverride,
        uint256 _maxPositionShortSizeOverride
    ) external;

    function getSwapFeeAndTaxBps(
        bool isStableSwap
    ) external view returns (uint256, uint256);
}
          

// SPDX-License-Identifier: agpl-3.0
pragma solidity 0.7.6;

library Errors {
    string public constant VC_INVALID_STAKING_BPS = "1"; // VaultConfigurator: invalid stakingBps
    string public constant VC_INVALID_MAX_LEVERAGE = "2"; // VaultConfigurator: invalid maxLeverage
    string public constant VC_INVALID_TAX_BPS = "3"; // VaultConfigurator: invalid taxBps
    string public constant VC_INVALID_STABLE_TAX_BPS = "4"; // VaultConfigurator: invalid stableTaxBps
    string public constant VC_INVALID_MINT_BURN_FEE_BPS = "5"; // VaultConfigurator: invalid mintBurnFeeBps
    string public constant VC_INVALID_SWAP_FEE_BPS = "6"; // VaultConfigurator: invalid swapFeeBps
    string public constant VC_INVALID_STABLE_SWAP_FEE_BPS = "7"; // VaultConfigurator: invalid stableSwapFeeBps
    string public constant VC_INVALID_MARGIN_FEE_BPS = "8"; // VaultConfigurator: invalid marginFeeBps
    string public constant VC_INVALID_LIQUIDATION_FEE_USD = "9"; // VaultConfigurator: invalid _liquidationFeeUsd
    string public constant VC_INVALID_FUNDING_INTERVAL = "10"; // VaultConfigurator: invalid fundingInterval
    string public constant VC_INVALID_FUNDING_RATE_FACTOR = "11"; // VaultConfigurator: invalid fundingRateFactor
    string public constant VC_TOKEN_NOT_WHITELISTED = "13"; // VaultConfigurator: token not whitelisted
    string public constant VC_INVALID_MIN_PROFIT_TIME_COEF_BPS = "16"; // VaultConfigurator: invalid minProfitTimeCoefBps

    string public constant VU_INVALID_AVERAGE_PRICE = "38"; // VaultUtil: invalid averagePrice
    string public constant VU_INVALID_MSG_SENDER = "41"; // VaultUtil: invalid msg.sender

    string public constant TCL_MISMATCHED_TOKENS = "42"; // TokenConfigsLogic: mismatched tokens
    string public constant TCL_COLLATERAL_TOKEN_NOT_WHITELISTED = "43"; // TokenConfigsLogic: collateralToken not whitelisted
    string public constant TCL_COLLATERAL_TOKEN_MUST_NOT_BE_STABLE = "44"; // TokenConfigsLogic: collateralToken must not be a stableToken
    string public constant TCL_COLLATERAL_TOKEN_MUST_BE_STABLE = "46"; // TokenConfigsLogic: collateralToken must be a stableToken
    string public constant TCL_INDEX_TOKEN_MUST_NOT_BE_STABLE = "47"; // TokenConfigsLogic: indexToken must not be a stableToken
    string public constant TCL_INDEX_TOKEN_NOT_SHORTABLE = "48"; // TokenConfigsLogic: indexToken not shortable
    string public constant TCL_TOKEN_NOT_WHITELISTED = "200"; // TokenConfigsLogic: token not whitelisted
    string public constant TCL_INVALID_TOKEN_WEIGHT = "201"; // TokenConfigsLogic: invalid token weight
}
          

// SPDX-License-Identifier: agpl-3.0
pragma solidity 0.7.6;

library VaultErrors {
    uint256 public constant V_TOKEN_NOT_WHITELISTED = 14; // Vault: token not whitelisted
    uint256 public constant V_INVALID_TOKEN_AMOUNT = 15; // Vault: invalid tokenAmount
    uint256 public constant V_INVALID_USDPH_AMOUNT = 18; // Vault: invalid usdphAmount
    uint256 public constant V_INVALID_REDEMPTION_AMOUNT = 21; // Vault: invalid redemptionAmount
    uint256 public constant V_INVALID_AMOUNT_OUT = 22; // Vault: invalid amountOut
    uint256 public constant V_SWAPS_NOT_ENABLED = 23; // Vault: swaps not enabled
    uint256 public constant V_SAME_TOKEN = 26; // Vault: same token in and out
    uint256 public constant V_INVALID_AMOUNT_IN = 27; // Vault: invalid amountIn
    uint256 public constant V_LEVERAGE_NOT_ENABLED = 28; // Vault: leverage not enabled
    uint256 public constant V_INSUFFICIENT_COLLATERAL_FOR_FEES = 29; // Vault: insufficient collateral for fees
    uint256 public constant V_INVALID_POSITION_SIZE = 30; // Vault: invalid position.size
    uint256 public constant V_EMPTY_POSITION = 31; // Vault: empty position
    uint256 public constant V_POSITION_SIZE_EXCEEDED = 32; // Vault: position size exceeded
    uint256 public constant V_POSITION_COLLATERAL_EXCEEDED = 33; // Vault: position collateral exceeded
    uint256 public constant V_INVALID_LIQUIDATOR = 34; // Vault: invalid liquidator
    uint256 public constant V_POSITION_CANNOT_BE_LIQUIDATED = 36; // Vault: position cannot be liquidated
    uint256 public constant V_COLLATERAL_SHOULD_BE_WITHDRAWN = 39; // Vault: collateral should be withdrawn
    uint256 public constant V_SIZE_MUST_BE_MORE_THAN_COLLATERAL = 40; // Vault: size must be more than collateral
    uint256 public constant V_RESERVE_EXCEEDS_POOL = 50; // Vault: reserve exceeds pool
    uint256 public constant V_MAX_USDPH_EXCEEDED = 51; // Vault: max USDPH exceeded
    uint256 public constant V_NOT_PHLP_MANAGER = 54; // Vault: caller is not PHLP Manager
    uint256 public constant V_POOL_LESS_THAN_BUFFER = 100; // Vault: poolAmount < bufferAmount
    uint256 public constant V_MAX_GLOBAL_LONG_EXCEEDED = 104; // Vault: max global long exceeded
    uint256 public constant V_MAX_GLOBAL_SHORT_EXCEEDED = 101; // Vault: max global short exceeded
    uint256 public constant V_MAX_POSITION_SIZE_EXCEEDED = 105; // Vault: max position long exceeded
    uint256 public constant V_NOT_CONFIGURATOR = 102; // Vault: caller is not the vault configurator
    uint256 public constant V_NOT_ROUTER = 103; // Vault: caller is not the router
}
          

// SPDX-License-Identifier: agpl-3.0

pragma solidity 0.7.6;
pragma experimental ABIEncoderV2;

import "../../../dependencies/openzeppelin/contracts/SafeMath.sol";
import "../helpers/Errors.sol";
import "../types/DataTypes.sol";

library TokenConfigsLogic {
    using SafeMath for uint256;
    using TokenConfigsLogic for DataTypes.TokenConfigs;

    function version() public pure returns (uint256) {
        return 1;
    }

    function setTokenConfig(
        DataTypes.TokenConfigs storage tokenConfigs,
        address _token,
        DataTypes.TokenConfig calldata tokenConfig
    ) public {
        require(tokenConfig.isWhitelisted, Errors.TCL_TOKEN_NOT_WHITELISTED);
        require(tokenConfig.weight > 0, Errors.TCL_INVALID_TOKEN_WEIGHT);

        // increment token count for the first time
        if (!tokenConfigs.tokenConfigs[_token].isWhitelisted) {
            tokenConfigs.allWhitelistedTokens.push(_token);
        }

        uint256 _totalTokenWeights = tokenConfigs.totalTokenWeights.sub(
            tokenConfigs.tokenConfigs[_token].weight
        );

        tokenConfigs.tokenConfigs[_token] = tokenConfig;

        tokenConfigs.totalTokenWeights = _totalTokenWeights.add(
            tokenConfig.weight
        );
    }

    function clearTokenConfig(
        DataTypes.TokenConfigs storage tokenConfigs,
        address _token
    ) public {
        require(
            tokenConfigs.tokenConfigs[_token].isWhitelisted,
            Errors.TCL_TOKEN_NOT_WHITELISTED
        );
        tokenConfigs.totalTokenWeights = tokenConfigs.totalTokenWeights.sub(
            tokenConfigs.tokenConfigs[_token].weight
        );
        delete tokenConfigs.tokenConfigs[_token];
        uint256 lengthMinus1 = tokenConfigs.allWhitelistedTokens.length - 1;
        for (uint256 i = 0; i < lengthMinus1; i++) {
            // no need to compare last element
            // if no match, it's the target to be removed
            // otherwise, its value will be saved in target's slot
            if (tokenConfigs.allWhitelistedTokens[i] == _token) {
                tokenConfigs.allWhitelistedTokens[i] = tokenConfigs
                    .allWhitelistedTokens[lengthMinus1];
                break;
            }
        }
        tokenConfigs.allWhitelistedTokens.pop();
    }

    function validateTokens(
        DataTypes.TokenConfigs storage tokenConfigs,
        address _collateralToken,
        address _indexToken,
        bool _isLong
    ) public view {
        if (_isLong) {
            require(
                _collateralToken == _indexToken,
                Errors.TCL_MISMATCHED_TOKENS
            );
            require(
                tokenConfigs.tokenConfigs[_collateralToken].isWhitelisted,
                Errors.TCL_COLLATERAL_TOKEN_NOT_WHITELISTED
            );
            require(
                !tokenConfigs.tokenConfigs[_collateralToken].isStable,
                Errors.TCL_COLLATERAL_TOKEN_MUST_NOT_BE_STABLE
            );
            return;
        }

        require(
            tokenConfigs.tokenConfigs[_collateralToken].isWhitelisted,
            Errors.TCL_COLLATERAL_TOKEN_NOT_WHITELISTED
        );
        require(
            tokenConfigs.tokenConfigs[_collateralToken].isStable,
            Errors.TCL_COLLATERAL_TOKEN_MUST_BE_STABLE
        );
        require(
            !tokenConfigs.tokenConfigs[_indexToken].isStable,
            Errors.TCL_INDEX_TOKEN_MUST_NOT_BE_STABLE
        );
        require(
            tokenConfigs.tokenConfigs[_indexToken].isShortable,
            Errors.TCL_INDEX_TOKEN_NOT_SHORTABLE
        );
    }
}
          

// SPDX-License-Identifier: agpl-3.0
pragma solidity 0.7.6;

library DataTypes {
    struct VaultConfig {
        bool isSwapEnabled;
        bool isLeverageEnabled;
        uint256 maxLeverage;
        // fees
        uint256 taxBps;
        uint256 stableTaxBps;
        uint256 mintBurnFeeBps;
        uint256 swapFeeBps;
        uint256 stableSwapFeeBps;
        uint256 liquidationFeeUsd;
        bool hasDynamicFees;
        // staking
        uint256 stakingBps;
    }

    struct TokenConfig {
        // should always be true if token exists
        bool isWhitelisted;
        // basic parameters
        uint256 decimals;
        uint256 weight; // customisation of index composition
        uint256 minProfitBps;
        uint256 minProfitTime;
        bool hasMinProfitTimeFloor;
        uint256 minProfitTimeCoefBps; // coefficient for minProfitTime
        uint256 maxUsdphAmount; // a max amount of USDPH debt for a token
        bool isStable;
        bool isShortable;
        // risk parameters
        // bufferAmount allows specification of an amount to exclude from swaps
        // this can be used to ensure a certain amount of liquidity is available for leverage positions
        uint256 bufferAmount;
        uint256 maxGlobalLongSize;
        uint256 maxGlobalShortSize;
        uint256 maxPositionLongSize;
        uint256 maxPositionShortSize;
        // fees
        uint256 longMarginFeeBps;
        uint256 shortMarginFeeBps;
        // funding rate
        uint256 fundingInterval;
        uint256 fundingRateFactor;
    }

    struct TokenConfigs {
        uint256 totalTokenWeights;
        address[] allWhitelistedTokens;
        mapping(address => TokenConfig) tokenConfigs;
    }

    struct AccountTokenConfig {
        bool isLongBlacklisted;
        bool isShortBlacklisted;
        uint256 maxPositionLongSizeOverride;
        uint256 maxPositionShortSizeOverride;
    }
}
          

// SPDX-License-Identifier: MIT

pragma solidity 0.7.6;
pragma experimental ABIEncoderV2;

import "../../../dependencies/openzeppelin/contracts/IERC20.sol";
import "../../../dependencies/openzeppelin/contracts/SafeMath.sol";
import "../../../interfaces/IAddressesProvider.sol";
import "../../../interfaces/IVault.sol";
import "../../../interfaces/IVaultConfigurator.sol";
import "../../../interfaces/IPhamePriceOracle.sol";

library GeneralUtils {
    function validate(bool condition, uint256 errorCode) public pure {
        require(condition, _uint2str(errorCode));
    }

    function _uint2str(uint256 _i) private pure returns (string memory str) {
        if (_i == 0) {
            return "0";
        }
        uint256 j = _i;
        uint256 length;
        while (j != 0) {
            length++;
            j /= 10;
        }
        bytes memory bstr = new bytes(length);
        uint256 k = length;
        j = _i;
        while (j != 0) {
            bstr[--k] = bytes1(uint8(48 + (j % 10)));
            j /= 10;
        }
        str = string(bstr);
    }
}
          

// SPDX-License-Identifier: MIT

pragma solidity 0.7.6;
pragma experimental ABIEncoderV2;

import "../../../dependencies/openzeppelin/contracts/IERC20.sol";
import "../../../dependencies/openzeppelin/contracts/SafeMath.sol";
import "../../../interfaces/IAddressesProvider.sol";
import "../../../interfaces/IVault.sol";
import "../../../interfaces/IVaultConfigurator.sol";
import "../../../interfaces/IPhamePriceOracle.sol";
import "../helpers/Errors.sol";

library VaultUtils {
    using SafeMath for uint256;

    struct Position {
        uint256 size;
        uint256 collateral;
        uint256 averagePrice;
        uint256 entryFundingRate;
        uint256 reserveAmount;
        int256 realisedPnl;
        uint256 lastIncreasedTime;
    }

    uint256 public constant BASIS_POINTS_DIVISOR = 10000;
    uint256 public constant FUNDING_RATE_PRECISION = 1000000;

    function validateLiquidation(
        IAddressesProvider addressesProvider,
        address _account,
        address _collateralToken,
        address _indexToken,
        bool _isLong,
        bool _raise
    ) public view returns (uint256, uint256) {
        IVault vault = IVault(addressesProvider.getVault());

        Position memory position = _getPosition(
            vault,
            _account,
            _collateralToken,
            _indexToken,
            _isLong
        );

        (bool hasProfit, uint256 delta) = vault.getDelta(
            _indexToken,
            position.size,
            position.averagePrice,
            _isLong,
            position.lastIncreasedTime
        );
        uint256 marginFees = getFundingFee(
            vault,
            _account,
            _collateralToken,
            _indexToken,
            _isLong,
            position.size,
            position.entryFundingRate
        ).add(
                getPositionFee(
                    addressesProvider,
                    _account,
                    _collateralToken,
                    _indexToken,
                    _isLong,
                    position.size
                )
            );

        if (!hasProfit && position.collateral < delta) {
            if (_raise) {
                revert("VaultUtils: losses exceed collateral");
            }
            return (1, marginFees);
        }

        uint256 remainingCollateral = position.collateral;
        if (!hasProfit) {
            remainingCollateral = position.collateral.sub(delta);
        }

        if (remainingCollateral < marginFees) {
            if (_raise) {
                revert("VaultUtils: fees exceed collateral");
            }
            // cap the fees to the remainingCollateral
            return (1, remainingCollateral);
        }

        DataTypes.VaultConfig memory vaultConfig = IVault(
            addressesProvider.getVault()
        ).getVaultConfig();
        if (
            remainingCollateral < marginFees.add(vaultConfig.liquidationFeeUsd)
        ) {
            if (_raise) {
                revert("VaultUtils: liquidation fees exceed collateral");
            }
            return (1, marginFees);
        }

        if (
            remainingCollateral.mul(vaultConfig.maxLeverage) <
            position.size.mul(BASIS_POINTS_DIVISOR)
        ) {
            if (_raise) {
                revert("VaultUtils: maxLeverage exceeded");
            }
            return (2, marginFees);
        }

        return (0, marginFees);
    }

    function getNextFundingRate(
        IAddressesProvider addressesProvider,
        address _token
    ) public view returns (uint256) {
        IVault vault = IVault(addressesProvider.getVault());
        DataTypes.TokenConfig memory tokenConfig = vault.getTokenConfig(_token);

        uint256 fundingInterval = tokenConfig.fundingInterval;

        if (
            vault.lastFundingTimes(_token).add(fundingInterval) >
            block.timestamp
        ) {
            return 0;
        }

        uint256 intervals = block
            .timestamp
            .sub(vault.lastFundingTimes(_token))
            .div(fundingInterval);
        uint256 poolAmount = vault.poolAmounts(_token);
        if (poolAmount == 0) {
            return 0;
        }

        return
            tokenConfig
                .fundingRateFactor
                .mul(vault.reservedAmounts(_token))
                .mul(intervals)
                .div(poolAmount);
    }

    function getPositionFee(
        IAddressesProvider addressesProvider,
        address /* _account */,
        address /* _collateralToken */,
        address _indexToken,
        bool _isLong,
        uint256 _sizeDelta
    ) public view returns (uint256) {
        if (_sizeDelta == 0) {
            return 0;
        }

        DataTypes.TokenConfig memory tokenConfig = IVault(
            addressesProvider.getVault()
        ).getTokenConfig(_indexToken);
        uint256 afterFeeUsd = _sizeDelta
            .mul(
                BASIS_POINTS_DIVISOR.sub(
                    _isLong
                        ? tokenConfig.longMarginFeeBps
                        : tokenConfig.shortMarginFeeBps
                )
            )
            .div(BASIS_POINTS_DIVISOR);
        return _sizeDelta.sub(afterFeeUsd);
    }

    function getFundingFee(
        IVault vault,
        address /* _account */,
        address _collateralToken,
        address /* _indexToken */,
        bool /* _isLong */,
        uint256 _size,
        uint256 _entryFundingRate
    ) public view returns (uint256) {
        if (_size == 0) {
            return 0;
        }

        uint256 fundingRate = vault
            .cumulativeFundingRates(_collateralToken)
            .sub(_entryFundingRate);
        if (fundingRate == 0) {
            return 0;
        }

        return _size.mul(fundingRate).div(FUNDING_RATE_PRECISION);
    }

    function getBuyUsdphFeeBps(
        IAddressesProvider addressesProvider,
        address _token,
        uint256 _usdphAmount
    ) public view returns (uint256) {
        DataTypes.VaultConfig memory vaultConfig = IVault(
            addressesProvider.getVault()
        ).getVaultConfig();
        return
            getFeeBps(
                addressesProvider,
                _token,
                _usdphAmount,
                vaultConfig.mintBurnFeeBps,
                vaultConfig.taxBps,
                true
            );
    }

    function getSellUsdphFeeBps(
        IAddressesProvider addressesProvider,
        address _token,
        uint256 _usdphAmount
    ) public view returns (uint256) {
        DataTypes.VaultConfig memory vaultConfig = IVault(
            addressesProvider.getVault()
        ).getVaultConfig();
        return
            getFeeBps(
                addressesProvider,
                _token,
                _usdphAmount,
                vaultConfig.mintBurnFeeBps,
                vaultConfig.taxBps,
                false
            );
    }

    function getSwapFeeBps(
        IAddressesProvider addressesProvider,
        address _tokenIn,
        address _tokenOut,
        uint256 _usdphAmount
    ) public view returns (uint256) {
        IVault vault = IVault(addressesProvider.getVault());
        (uint256 baseBps, uint256 taxBps) = IVaultConfigurator(
            addressesProvider.getVaultConfigurator()
        ).getSwapFeeAndTaxBps(
                vault.getTokenConfig(_tokenIn).isStable &&
                    vault.getTokenConfig(_tokenOut).isStable
            );
        uint256 feesBps0 = getFeeBps(
            addressesProvider,
            _tokenIn,
            _usdphAmount,
            baseBps,
            taxBps,
            true
        );
        uint256 feesBps1 = getFeeBps(
            addressesProvider,
            _tokenOut,
            _usdphAmount,
            baseBps,
            taxBps,
            false
        );
        // use the higher of the two fee basis points
        return feesBps0 > feesBps1 ? feesBps0 : feesBps1;
    }

    // cases to consider
    // 1. initialAmount is far from targetAmount, action increases balance slightly => high rebate
    // 2. initialAmount is far from targetAmount, action increases balance largely => high rebate
    // 3. initialAmount is close to targetAmount, action increases balance slightly => low rebate
    // 4. initialAmount is far from targetAmount, action reduces balance slightly => high tax
    // 5. initialAmount is far from targetAmount, action reduces balance largely => high tax
    // 6. initialAmount is close to targetAmount, action reduces balance largely => low tax
    // 7. initialAmount is above targetAmount, nextAmount is below targetAmount and vice versa
    // 8. a large swap should have similar fees as the same trade split into multiple smaller swaps
    function getFeeBps(
        IAddressesProvider addressesProvider,
        address _token,
        uint256 _usdphDelta,
        uint256 _feeBps,
        uint256 _taxBps,
        bool _increment
    ) public view returns (uint256) {
        if (
            !IVault(addressesProvider.getVault())
                .getVaultConfig()
                .hasDynamicFees
        ) {
            return _feeBps;
        }

        uint256 initialAmount = IVault(addressesProvider.getVault())
            .usdphAmounts(_token);
        uint256 nextAmount = initialAmount.add(_usdphDelta);
        if (!_increment) {
            nextAmount = _usdphDelta > initialAmount
                ? 0
                : initialAmount.sub(_usdphDelta);
        }

        uint256 targetAmount = _getTargetUsdphAmount(addressesProvider, _token);
        if (targetAmount == 0) {
            return _feeBps;
        }

        uint256 initialDiff = initialAmount > targetAmount
            ? initialAmount.sub(targetAmount)
            : targetAmount.sub(initialAmount);
        uint256 nextDiff = nextAmount > targetAmount
            ? nextAmount.sub(targetAmount)
            : targetAmount.sub(nextAmount);

        // action improves relative asset balance
        if (nextDiff < initialDiff) {
            uint256 rebateBps = _taxBps.mul(initialDiff).div(targetAmount);
            return rebateBps > _feeBps ? 0 : _feeBps.sub(rebateBps);
        }

        uint256 averageDiff = initialDiff.add(nextDiff).div(2);
        if (averageDiff > targetAmount) {
            averageDiff = targetAmount;
        }
        uint256 taxBps = _taxBps.mul(averageDiff).div(targetAmount);
        return _feeBps.add(taxBps);
    }

    function _getMinProfitTime(
        DataTypes.TokenConfig memory tokenConfig,
        uint256 _size,
        bool _isLong
    ) private pure returns (uint256) {
        if (_size == 0 || tokenConfig.minProfitTime == 0) {
            return 0;
        }
        uint256 baseSize = _isLong
            ? tokenConfig.maxPositionLongSize
            : tokenConfig.maxPositionShortSize;
        if (baseSize == 0) {
            return tokenConfig.minProfitTime;
        }
        if (
            (tokenConfig.hasMinProfitTimeFloor && _size < baseSize) ||
            (_size == baseSize)
        ) {
            return tokenConfig.minProfitTime;
        }

        if (_size < baseSize) {
            return tokenConfig.minProfitTime.mul(_size).div(baseSize);
        } else {
            return
                tokenConfig
                    .minProfitTime
                    .mul(
                        baseSize.mul(10000).add(
                            _size.sub(baseSize).mul(
                                tokenConfig.minProfitTimeCoefBps
                            )
                        )
                    )
                    .div(baseSize)
                    .div(10000);
        }
    }

    function getMinProfitTime(
        IAddressesProvider addressesProvider,
        address _indexToken,
        uint256 _size,
        bool _isLong
    ) public view returns (uint256) {
        DataTypes.TokenConfig memory tokenConfig = IVault(
            addressesProvider.getVault()
        ).getTokenConfig(_indexToken);
        return _getMinProfitTime(tokenConfig, _size, _isLong);
    }

    function getDelta(
        IAddressesProvider addressesProvider,
        address _indexToken,
        uint256 _size,
        uint256 _averagePrice,
        bool _isLong,
        uint256 _lastIncreasedTime
    ) public view returns (bool, uint256) {
        require(_averagePrice > 0, Errors.VU_INVALID_AVERAGE_PRICE);
        uint256 price = IPhamePriceOracle(addressesProvider.getPriceOracle())
            .getPrice(_indexToken, !_isLong);
        uint256 priceDelta = _averagePrice > price
            ? _averagePrice.sub(price)
            : price.sub(_averagePrice);
        uint256 delta = _size.mul(priceDelta).div(_averagePrice);

        bool hasProfit;

        if (_isLong) {
            hasProfit = price > _averagePrice;
        } else {
            hasProfit = _averagePrice > price;
        }

        // if the minProfitTime has passed then there will be no min profit threshold
        // the min profit threshold helps to prevent front-running issues
        DataTypes.TokenConfig memory tokenConfig = IVault(
            addressesProvider.getVault()
        ).getTokenConfig(_indexToken);
        uint256 minBps = block.timestamp >
            _lastIncreasedTime.add(
                _getMinProfitTime(tokenConfig, _size, _isLong)
            )
            ? 0
            : tokenConfig.minProfitBps;
        if (hasProfit && delta.mul(BASIS_POINTS_DIVISOR) <= _size.mul(minBps)) {
            delta = 0;
        }

        return (hasProfit, delta);
    }

    function _getPosition(
        IVault vault,
        address _account,
        address _collateralToken,
        address _indexToken,
        bool _isLong
    ) private view returns (Position memory) {
        Position memory position;
        {
            (
                uint256 size,
                uint256 collateral,
                uint256 averagePrice,
                uint256 entryFundingRate /* reserveAmount */ /* realisedPnl */ /* hasProfit */,
                ,
                ,
                ,
                uint256 lastIncreasedTime
            ) = vault.getPosition(
                    _account,
                    _collateralToken,
                    _indexToken,
                    _isLong
                );
            position.size = size;
            position.collateral = collateral;
            position.averagePrice = averagePrice;
            position.entryFundingRate = entryFundingRate;
            position.lastIncreasedTime = lastIncreasedTime;
        }
        return position;
    }

    function _getTargetUsdphAmount(
        IAddressesProvider addressesProvider,
        address _token
    ) private view returns (uint256) {
        uint256 supply = IERC20(addressesProvider.getUsdph()).totalSupply();
        if (supply == 0) {
            return 0;
        }
        IVault vault = IVault(addressesProvider.getVault());
        uint256 weight = vault.getTokenConfig(_token).weight;
        return weight.mul(supply).div(vault.totalTokenWeights());
    }
}