Contract Address Details

// SPDX-License-Identifier: Unlicensed
pragma solidity 0.8.2;

import "./Ownable.sol";
import "./ERC20.sol";
import "./SafeMath.sol";
import "./IPulseX.sol";

contract SkyRocket is Ownable, ERC20 {
	using SafeMath for uint256;
	
    uint256 private constant MAX = ~uint256(0);
    uint256 private _tTotal = 1000000000001 * (10**18);
	
    uint256 private _rTotal = (MAX - (MAX % _tTotal));
    uint256 private _tFeeTotal;
	
	uint256 public reflectionFee;
	uint256 public buyBurnFee;
	uint256 public SingleStakeFee;
	uint256 public LPProviderFee;
	
	uint256 private _reflectionFee;
	uint256 private _buyBurnFee;
	uint256 private _SingleStakeFee;
	uint256 private _LPProviderFee;
	
	uint256 public swapThreshold;
	bool public feesEnabled = true;
    uint256 public totalBuyBurnTax;
    uint256 public totalSingleStakeTax;
    uint256 public totalLPStakeTax;
	
	IPulseXRouter public pulseXRouter;

    bool public takeFeeOnBuy = true;
    bool public takeFeeOnSell = true;
    bool public takeFeeOnP2P = true;

    address public singleStake;
    address public lpStake;
    address public skrBurner;
	address public burnWallet = address(0x0000000000000000000000000000000000000369);

	address[] public pairs;
	
	bool private swapping;

	address[] private _excluded;
	
	mapping(address => uint256) public rOwned;
    mapping(address => uint256) public tOwned;

    mapping(address => bool) public isExcludedFromFee;
    mapping(address => bool) public isExcludedFromReflection;

	mapping(address => bool) public isliquidityPair;
    mapping(address => bool) public minterAddress;

	event SwapThresholdUpdated(uint256 amount);
	event AccountExcludeFromFee(address account, bool status);
    event AccountIncludeInReflection(address account);
    event AccountExcludeFromReflection(address account);
	event LPStakingAddressAdded(address newAddress);
    event FeesEnabledUpdated(bool enabled);
	event PLSDistributed(address indexed to, uint256 amount);
    event MinterAdded(address indexed account, bool status);

	constructor(address owner, address _singleStake, address _lpStake, address _skrBurner) ERC20("SkyRocket", "SKR") {
	    require(address(owner) != address(0), "Zero address");

        singleStake = _singleStake;
        lpStake = _lpStake;
        skrBurner = _skrBurner;
		rOwned[address(owner)] = _rTotal;
		pulseXRouter = IPulseXRouter(0x165C3410fC91EF562C50559f7d2289fEbed552d9);

		pairs.push(IPulseXFactory(pulseXRouter.factory()).createPair(address(this), address(0xA1077a294dDE1B09bB078844df40758a5D0f9a27))); //WPLS
		pairs.push(IPulseXFactory(pulseXRouter.factory()).createPair(address(this), address(0x2fa878Ab3F87CC1C9737Fc071108F904c0B0C95d))); //INC
		pairs.push(IPulseXFactory(pulseXRouter.factory()).createPair(address(this), address(0x95B303987A60C71504D99Aa1b13B4DA07b0790ab))); //PLSX
		pairs.push(IPulseXFactory(pulseXRouter.factory()).createPair(address(this), address(0x2b591e99afE9f32eAA6214f7B7629768c40Eeb39))); //HEX
		pairs.push(IPulseXFactory(pulseXRouter.factory()).createPair(address(this), address(0x57fde0a71132198BBeC939B98976993d8D89D225))); //eHEX
		pairs.push(IPulseXFactory(pulseXRouter.factory()).createPair(address(this), address(0xefD766cCb38EaF1dfd701853BFCe31359239F305))); //eDAI
		
		_setLiquidityPair(pairs[0]);
		_setLiquidityPair(pairs[1]);
		_setLiquidityPair(pairs[2]);
		_setLiquidityPair(pairs[3]);
		_setLiquidityPair(pairs[4]);
		_setLiquidityPair(pairs[5]);

		_excludeFromReflection(address(this));
		_excludeFromReflection(address(owner));
        _excludeFromReflection(address(burnWallet));
        _excludeFromReflection(address(_singleStake));
        _excludeFromReflection(address(_lpStake));
        _excludeFromReflection(address(_skrBurner));
		
		_excludeFromFee(address(this), true);
        _excludeFromFee(address(owner), true);
        _excludeFromFee(address(burnWallet), true);
        _excludeFromFee(address(_singleStake),true);
        _excludeFromFee(address(_lpStake),true);
		_excludeFromFee(address(_skrBurner),true);

		swapThreshold = 100000 * (10**18);
		
		reflectionFee = 100;
		buyBurnFee = 300;
		SingleStakeFee = 100;
		LPProviderFee = 100;

		restoreAllFee();

		emit Transfer(address(0), address(owner), _tTotal);
    }
	
	receive() external payable {}

    function setFeeTriggers(bool _onBuy, bool _onSell, bool _onP2P) external onlyOwner {
        takeFeeOnBuy = _onBuy;
        takeFeeOnSell = _onSell;
        takeFeeOnP2P = _onP2P;
    }

    function setSkrBurner(address _newskrBurner) external onlyOwner {
        require(_newskrBurner != address(0), "Invalid address");
        skrBurner = _newskrBurner;
        _excludeFromReflection(_newskrBurner);
        _excludeFromFee(_newskrBurner,true);
    }

    function addMinter(address account, bool status) external onlyOwner {
        minterAddress[account] = status;
        emit MinterAdded(account, status);
    }
    function mint(address account, uint256 tAmount) external {
        require(account != address(0), "mint to zero");
        require(minterAddress[msg.sender] || owner() == msg.sender, "Not authorized to mint");

        uint256 currentRate = _getRate();
        uint256 rAmount = tAmount * currentRate;

        _tTotal += tAmount;
        _rTotal += rAmount;

        rOwned[account] += rAmount;
        if (isExcludedFromReflection[account]) {
            tOwned[account] += tAmount;
        }

        emit Transfer(address(0), account, tAmount);
    }
    function burn(uint256 tAmount) public {
        require(balanceOf(msg.sender) >= tAmount, "Not enough tokens");

        uint256 currentRate = _getRate();
        uint256 rAmount = tAmount * currentRate;

        _tTotal -= tAmount;
        _rTotal -= rAmount;

        if (isExcludedFromReflection[msg.sender]) {
            tOwned[msg.sender] -= tAmount;
        }
        rOwned[msg.sender] -= rAmount;

        emit Transfer(msg.sender, address(0), tAmount);
    }

    function setFeesEnabled(bool enabled) external onlyOwner {
        feesEnabled = enabled;
        emit FeesEnabledUpdated(enabled);
    }

    function setAllFees(
        uint256 _newreflectionFee,
        uint256 _newbuyBurnFee,
        uint256 _newsingleStakeFee,
        uint256 _newlpProviderFee
    ) external onlyOwner {
        require(_newreflectionFee >= 0, "Reflection fee invalid");
        require(_newbuyBurnFee >= 0, "BuyBurn fee invalid");
        require(_newsingleStakeFee >= 0, "SingleStake fee invalid");
        require(_newlpProviderFee >= 0, "LPProvider fee invalid");

        reflectionFee = _newreflectionFee;
        buyBurnFee = _newbuyBurnFee;
        SingleStakeFee = _newsingleStakeFee;
        LPProviderFee = _newlpProviderFee;

        restoreAllFee();
    }
    function totalSupply() public override view returns (uint256) {
        return _tTotal;
    }
	
    function balanceOf(address account) public override view returns (uint256) {
        if (isExcludedFromReflection[account]) return tOwned[account];
        return tokenFromReflection(rOwned[account]);
    }
	
    function tokenFromReflection(uint256 rAmount) public view returns(uint256) {
        require(rAmount <= _rTotal, "Amount must be less than total reflections");
        uint256 currentRate =  _getRate();
        return rAmount.div(currentRate);
    }
	
	function _excludeFromReflection(address account) internal {
    if (isExcludedFromReflection[account]) return;
        if (rOwned[account] > 0) {
            tOwned[account] = tokenFromReflection(rOwned[account]);
        }
        isExcludedFromReflection[account] = true;
        _excluded.push(account);
    }
	
    function _setLiquidityPair(address pair) internal {
        isliquidityPair[address(pair)] = true;
		_excludeFromReflection(address(pair));
    }
	function addLiquidityPair(address newPair) external onlyOwner {
        require(newPair != address(0), "Invalid pair address");
        require(!isliquidityPair[newPair], "Already registered as pair");

        pairs.push(newPair);
        _setLiquidityPair(newPair);

        emit LPStakingAddressAdded(newPair);
    }
    function removeLiquidityPair(address pair) external onlyOwner {
        require(isliquidityPair[pair], "Address is not a registered liquidity pair");

  
        isliquidityPair[pair] = false;

    
        for (uint256 i = 0; i < pairs.length; i++) {
            if (pairs[i] == pair) {
                pairs[i] = pairs[pairs.length - 1];
                pairs.pop();
                break;
            }
        }

        emit LPStakingAddressAdded(pair);
    }

	function _excludeFromFee(address account, bool value) internal {
        isExcludedFromFee[account] = value;
    }
	
    function _reflectFee(uint256 rFee, uint256 tFee) internal {
        _rTotal = _rTotal.sub(rFee);
        _tFeeTotal = _tFeeTotal.add(tFee);
    }
	
	function _contractFee(uint256 tContract) internal {
        uint256 currentRate =  _getRate();
        uint256 rContract = tContract.mul(currentRate);
        rOwned[address(this)] = rOwned[address(this)].add(rContract);
        if(isExcludedFromReflection[address(this)])
            tOwned[address(this)] = tOwned[address(this)].add(tContract);
    }
	
    function _getValues(uint256 tAmount) internal view returns (uint256, uint256, uint256, uint256, uint256, uint256) {
        (uint256 tTransferAmount, uint256 tFee, uint256 tContract) = _getTValues(tAmount);
        (uint256 rAmount, uint256 rTransferAmount, uint256 rFee) = _getRValues(tAmount, tFee, tContract, _getRate());
        return (rAmount, rTransferAmount, rFee, tTransferAmount, tFee, tContract);
    }
	
    function _getTValues(uint256 tAmount) internal view returns (uint256, uint256, uint256) {
		uint256 tFee = calculateReflectionFee(tAmount);
        uint256 tContract = calculateContractFee(tAmount);
		
		uint256 tTransferAmount = tAmount.sub(tFee).sub(tContract);
        return (tTransferAmount, tFee, tContract);
    }
	
    function _getRValues(uint256 tAmount, uint256 tFee, uint256 tContract, uint256 currentRate) internal pure returns (uint256, uint256, uint256) {
        uint256 rAmount = tAmount.mul(currentRate);
        uint256 rFee = tFee.mul(currentRate);
        uint256 rContract = tContract.mul(currentRate);
		
		uint256 rTransferAmount = rAmount.sub(rFee).sub(rContract);
        return (rAmount, rTransferAmount, rFee);
    }

    function _getRate() internal view returns(uint256) {
        (uint256 rSupply, uint256 tSupply) = _getCurrentSupply();
        return tSupply == 0 ? 1 : rSupply.div(tSupply);
    }
	
    function _getCurrentSupply() internal view returns(uint256, uint256) {
        uint256 rSupply = _rTotal;
        uint256 tSupply = _tTotal;      
        for (uint256 i = 0; i < _excluded.length; i++) {
            if (rOwned[_excluded[i]] > rSupply || tOwned[_excluded[i]] > tSupply) return (_rTotal, _tTotal);
            rSupply = rSupply.sub(rOwned[_excluded[i]]);
            tSupply = tSupply.sub(tOwned[_excluded[i]]);
        }
        if (rSupply < _rTotal.div(_tTotal)) return (_rTotal, _tTotal);
        return (rSupply, tSupply);
    }
    
    function calculateReflectionFee(uint256 _amount) internal view returns (uint256) {
        return _amount.mul(_reflectionFee).div(10000);
    }
	
    function calculateContractFee(uint256 _amount) internal view returns (uint256) {
        return _amount.mul((_buyBurnFee + _SingleStakeFee + _LPProviderFee)).div(10000);
    }
	
    function removeAllFee() internal {
	   _reflectionFee = 0;
	   _buyBurnFee = 0;
	   _SingleStakeFee = 0;
	   _LPProviderFee = 0;
    }
	
    function restoreAllFee() internal {
	   _reflectionFee = reflectionFee;
	   _buyBurnFee = buyBurnFee;
	   _SingleStakeFee = SingleStakeFee;
	   _LPProviderFee = LPProviderFee;
    }

    function transfer(address recipient, uint256 amount) public override returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    function transferFrom(address sender, address recipient, uint256 amount) public override returns (bool) {
        uint256 currentAllowance = allowance(sender, _msgSender());
        require(currentAllowance >= amount, "ERC20: transfer amount exceeds allowance");

        _transfer(sender, recipient, amount);

        _approve(sender, _msgSender(), currentAllowance - amount);

        return true;
        }


    function _transfer(address from, address to, uint256 amount) internal override {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");
        require(balanceOf(from) >= amount, "Transfer amount exceeds balance");

        uint256 contractTokenBalance = balanceOf(address(this));
        bool canSwap = contractTokenBalance >= swapThreshold;

        if (canSwap && !swapping && isliquidityPair[to] && from != address(this)) {

                swapping = true;

                swapTokensForPLS(swapThreshold); 

                uint256 PLSBalance = address(this).balance;
                uint256 allFee = buyBurnFee.add(SingleStakeFee).add(LPProviderFee);

                if (allFee > 0 && PLSBalance > 0) {
                    uint256 remainingBalance = PLSBalance;

                    uint256 buyBurnPart = remainingBalance.mul(buyBurnFee).div(allFee);
                    remainingBalance = remainingBalance.sub(buyBurnPart);

                    uint256 SingleStakePart = remainingBalance.mul(SingleStakeFee).div(allFee);
                    remainingBalance = remainingBalance.sub(SingleStakePart);

                    uint256 LPProviderPart = remainingBalance;

                    if (buyBurnPart > 0) {
                        (bool sent1, ) = payable(skrBurner).call{value: buyBurnPart}("");
                        if (sent1) {
                            totalBuyBurnTax += buyBurnPart;
                            emit PLSDistributed(skrBurner, buyBurnPart);
                        }
                    }
                    if (SingleStakePart > 0) {
                        (bool sent2, ) = payable(singleStake).call{value: SingleStakePart}("");
                        if (sent2) {
                            totalSingleStakeTax += SingleStakePart;
                            emit PLSDistributed(singleStake, SingleStakePart);
                        }
                    }

                    if (LPProviderPart > 0) {
                        (bool sent3, ) = payable(lpStake).call{value: LPProviderPart}("");
                        if (sent3) {
                            totalLPStakeTax += LPProviderPart;
                            emit PLSDistributed(lpStake, LPProviderPart);
                        }
                    }

                }

                swapping = false;
            }

        bool isBuy = isliquidityPair[from];
        bool isSell = isliquidityPair[to];
        bool isP2P = !isBuy && !isSell;

        bool applyBuy = isBuy && takeFeeOnBuy;
        bool applySell = isSell && takeFeeOnSell;
        bool applyP2P = isP2P && takeFeeOnP2P;

        bool takeFee = feesEnabled && (applyBuy || applySell || applyP2P) && !(isExcludedFromFee[from] || isExcludedFromFee[to]);

        _tokenTransfer(from, to, amount, takeFee);

    }

    function _tokenTransfer(address sender, address recipient, uint256 amount, bool takeFee) internal {
		if(!takeFee){
		   removeAllFee();
		}
        if (isExcludedFromReflection[sender] && !isExcludedFromReflection[recipient]){
            _transferFromExcluded(sender, recipient, amount);
        } else if (!isExcludedFromReflection[sender] && isExcludedFromReflection[recipient]){
            _transferToExcluded(sender, recipient, amount);
        } else if (!isExcludedFromReflection[sender] && !isExcludedFromReflection[recipient]){
            _transferStandard(sender, recipient, amount);
        } else if (isExcludedFromReflection[sender] && isExcludedFromReflection[recipient]){
            _transferBothExcluded(sender, recipient, amount);
        }else{
            _transferStandard(sender, recipient, amount);
        }
		if(!takeFee){
		   restoreAllFee();
		}
    }
	
    function _transferStandard(address sender, address recipient, uint256 tAmount) internal {
        (uint256 rAmount, uint256 rTransferAmount, uint256 rFee, uint256 tTransferAmount, uint256 tFee, uint256 tContract) = _getValues(tAmount);
        
		rOwned[sender] = rOwned[sender].sub(rAmount);
        rOwned[recipient] = rOwned[recipient].add(rTransferAmount);
		
        _contractFee(tContract);
        _reflectFee(rFee, tFee);
		
		if(tContract > 0)
		{
		   emit Transfer(sender, address(this), tContract);
		}
        emit Transfer(sender, recipient, tTransferAmount);
    }
	
    function _transferToExcluded(address sender, address recipient, uint256 tAmount) internal {
        (uint256 rAmount, uint256 rTransferAmount, uint256 rFee, uint256 tTransferAmount, uint256 tFee, uint256 tContract) = _getValues(tAmount);
        
		rOwned[sender] = rOwned[sender].sub(rAmount);
        tOwned[recipient] = tOwned[recipient].add(tTransferAmount);
        rOwned[recipient] = rOwned[recipient].add(rTransferAmount);  
		
        _contractFee(tContract);
        _reflectFee(rFee, tFee);
		
		if(tContract > 0)
		{
		   emit Transfer(sender, address(this), tContract);
		}
        emit Transfer(sender, recipient, tTransferAmount);
    }

    function _transferFromExcluded(address sender, address recipient, uint256 tAmount) internal {
        (uint256 rAmount, uint256 rTransferAmount, uint256 rFee, uint256 tTransferAmount, uint256 tFee, uint256 tContract) = _getValues(tAmount);
        
		tOwned[sender] = tOwned[sender].sub(tAmount);
        rOwned[sender] = rOwned[sender].sub(rAmount);
        rOwned[recipient] = rOwned[recipient].add(rTransferAmount); 
		
        _contractFee(tContract);
        _reflectFee(rFee, tFee);
		
		if(tContract > 0)
		{
		   emit Transfer(sender, address(this), tContract);
		}
        emit Transfer(sender, recipient, tTransferAmount);
    }
	
	function _transferBothExcluded(address sender, address recipient, uint256 tAmount) internal {
        (uint256 rAmount, uint256 rTransferAmount, uint256 rFee, uint256 tTransferAmount, uint256 tFee, uint256 tContract) = _getValues(tAmount);
		
		tOwned[sender] = tOwned[sender].sub(tAmount);
        rOwned[sender] = rOwned[sender].sub(rAmount);
        tOwned[recipient] = tOwned[recipient].add(tTransferAmount);
        rOwned[recipient] = rOwned[recipient].add(rTransferAmount);   
		
        _contractFee(tContract);
        _reflectFee(rFee, tFee);
		
		if(tContract > 0)
		{
		   emit Transfer(sender, address(this), tContract);
		}
        emit Transfer(sender, recipient, tTransferAmount);
    }
	
	function swapTokensForPLS(uint256 tokenAmount) internal {
        address[] memory path = new address[](2);
        path[0] = address(this);
        path[1] = pulseXRouter.WPLS();
		
        _approve(address(this), address(pulseXRouter), tokenAmount);
        pulseXRouter.swapExactTokensForETHSupportingFeeOnTransferTokens(
            tokenAmount,
            0,
            path,
            address(this),
            block.timestamp
        );
    }

	function buybackBurnSkyRocket(uint256 PLSAmount) internal {
        address[] memory path = new address[](2);
        path[0] = pulseXRouter.WPLS();
        path[1] = address(this);

        pulseXRouter.swapExactETHForTokensSupportingFeeOnTransferTokens{value: PLSAmount}(
            0,
            path,
            burnWallet,
            block.timestamp
        );
    }

	function updatedSwapThreshold(uint256 amount) external onlyOwner {
  	    require(amount <= totalSupply(), "Amount cannot be over the total supply.");
		require(amount >= 1 * (10 ** 18), "Minimum 1 token per swap required");
		
		swapThreshold = amount;
		emit SwapThresholdUpdated(amount);
  	}
	
	function excludeFromReflection(address account) public onlyOwner() {
       require(!isExcludedFromReflection[account], "Account is already excluded");
	   
	   _excludeFromReflection(account);
	   emit AccountExcludeFromReflection(account);
    }
	
    function includeInReflection(address account) external onlyOwner() {
        require(isExcludedFromReflection[account], "Account is already included");
        for (uint256 i = 0; i < _excluded.length; i++) {
            if (_excluded[i] == account) {
                _excluded[i] = _excluded[_excluded.length - 1];
                tOwned[account] = 0;
                isExcludedFromReflection[account] = false;
                _excluded.pop();
                break;
            }
        }
		emit AccountIncludeInReflection(account);
    }
	
	function excludeFromFee(address account, bool status) external onlyOwner {
        require(account != address(0), "Wallet address is not correct");
		
		_excludeFromFee(account, status);
		emit AccountExcludeFromFee(account, status);
    }

    function setStakingAddresses(address _singleStake, address _lpStake) external onlyOwner {
        if (_singleStake != address(0)) {
            singleStake = _singleStake;

            _excludeFromReflection(_singleStake);
            _excludeFromFee(_singleStake, true);

            emit AccountExcludeFromReflection(_singleStake);
            emit AccountExcludeFromFee(_singleStake, true);
        }

        if (_lpStake != address(0)) {
            lpStake = _lpStake;

            _excludeFromReflection(_lpStake);
            _excludeFromFee(_lpStake, true);

            emit AccountExcludeFromReflection(_lpStake);
            emit AccountExcludeFromFee(_lpStake, true);
        }

    }
    function totalReflectionDistributed() external view returns (uint256) {
        return _tFeeTotal;
    }

}
        

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.

/**
 * @dev Wrappers over Solidity's arithmetic operations.
 *
 * NOTE: `SafeMath` is generally not needed starting with Solidity 0.8, since the compiler
 * now has built in overflow checking.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator.
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b <= a, errorMessage);
            return a - b;
        }
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a / b;
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a % b;
        }
    }
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

interface IPulseXFactory {
   function createPair(address tokenA, address tokenB) external returns (address pair);
}

interface IPulseXRouter {
   function factory() external pure returns (address);
   function WPLS() external pure returns (address);
   function addLiquidityETH(address token, uint amountTokenDesired, uint amountTokenMin, uint amountETHMin, address to, uint deadline) external payable returns (uint amountToken, uint amountETH, uint liquidity);
   function addLiquidity(address tokenA, address tokenB, uint amountADesired, uint amountBDesired, uint amountAMin, uint amountBMin, address to, uint deadline) external returns (uint amountA, uint amountB, uint liquidity);
   function removeLiquidityETHSupportingFeeOnTransferTokens(address token, uint liquidity, uint amountTokenMin, uint amountETHMin, address to,uint deadline) external returns (uint amountETH);
   function removeLiquidity(address tokenA, address tokenB, uint liquidity, uint amountAMin, uint amountBMin, address to, uint deadline) external returns (uint amountA, uint amountB);
   function swapExactTokensForETHSupportingFeeOnTransferTokens(uint amountIn, uint amountOutMin, address[] calldata path, address to, uint deadline) external;
   function swapExactETHForTokensSupportingFeeOnTransferTokens(uint amountOutMin, address[] calldata path, address to, uint deadline) external payable;
}

interface PulseXPair {
   function token0() external pure returns (address);
   function token1() external pure returns (address);
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./IERC20Metadata.sol";
import "./Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * The default value of {decimals} is 18. To select a different value for
     * {decimals} you should overload it.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless this function is
     * overridden;
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
        }
        _balances[to] += amount;

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        _balances[account] += amount;
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
        }
        _totalSupply -= amount;

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }
	
    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}