Contract Address Details

//SPDX-License-Identifier: MIT

pragma solidity 0.8.26;

/* === OZ === */
import {ReentrancyGuard} from "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";

/* === UNISWAP V2 === */
import {IUniswapV2Router01, IUniswapV2Router02} from "@uniswap/v2-periphery/contracts/interfaces/IUniswapV2Router02.sol";
import {IUniswapV2Factory} from "@uniswap/v2-core/contracts/interfaces/IUniswapV2Factory.sol";
import {IUniswapV2Pair} from "@uniswap/v2-core/contracts/interfaces/IUniswapV2Pair.sol";

/* === SYSTEM === */
import {RhinoCharging} from "./RhinoCharging.sol";

/**
 * Standard SafeMath, stripped down to just add/sub/mul/div
 */
library SafeMath {
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    function sub(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    function div(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        // Solidity only automatically asserts when dividing by 0
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }
}

/**
 * ERC20 standard interface.
 */
interface IERC20 {
    function totalSupply() external view returns (uint256);

    function decimals() external view returns (uint8);

    function symbol() external view returns (string memory);

    function name() external view returns (string memory);

    function balanceOf(address account) external view returns (uint256);

    function transfer(
        address recipient,
        uint256 amount
    ) external returns (bool);

    function allowance(
        address _owner,
        address spender
    ) external view returns (uint256);

    function approve(address spender, uint256 amount) external returns (bool);

    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    event Transfer(address indexed from, address indexed to, uint256 value);
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );
}

interface IWPLS {
    function withdraw(uint256 wad) external;
}

interface ISOLIDX {
    function burn(uint256 amount) external;
}

interface IDividendDistributor {
    function setDistributionCriteria(
        address token,
        uint256 minPeriod,
        uint256 minDistribution
    ) external;

    function setShare(address shareholder, uint256 amount) external;

    function setLpShare(address shareholder, uint256 amount) external;

    function depositForReflection(address reflectedToken) external payable;

    function depositForPlsReflection() external payable;

    function depositForRhinoReflection(uint256 amount) external;

    function depositForSolidXBurn() external payable;

    function depositForGelatoBurn() external payable;

    function processDividend(address token, uint256 gas) external;

    function claimDividend(address user) external;

    function claimLpDividend(address user) external;
}

interface IRhino {
    function getLpTokenValueInRhino(
        address user
    ) external view returns (uint256);
    function feeDenominator() external view returns (uint256);
    function lpReflectionPercent() external view returns (uint256);
}

contract DividendDistributor is IDividendDistributor {
    using SafeMath for uint256;

    address public rhino;

    // Dividend Trackers
    struct DividendInfo {
        uint256 currentIndex;
        uint256 totalDividends;
        uint256 totalDistributed;
        uint256 dividendsPerShare;
        uint256 minPeriod;
        uint256 minDistribution;
    }

    struct LpDividendInfo {
        uint256 currentIndex;
        uint256 totalDividends;
        uint256 totalDistributed;
        uint256 dividendsPerShare;
        uint256 minPeriod;
        uint256 minDistribution;
    }

    // Shares & Reward Trackers
    struct Share {
        uint256 amount;
        uint256 totalExcluded;
        uint256 totalRealised;
    }

    struct LpShare {
        uint256 amount;
        uint256 totalExcluded;
        uint256 totalRealised;
    }

    mapping(address token => address[] lpShareholder) public lpShareholders;
    mapping(address => mapping(address => uint256)) public lpShareholderIndexes;
    mapping(address => mapping(address => uint256)) public lpShareholderClaims;
    mapping(address token => mapping(address shareholder => Share))
        public lpShares;
    mapping(address => LpDividendInfo) public lpDividends;
    uint256 public lpTotalShares;

    mapping(address token => address[] shareholder) public shareholders;
    mapping(address => mapping(address => uint256)) public shareholderIndexes;
    mapping(address => mapping(address => uint256)) public shareholderClaims;
    mapping(address token => mapping(address shareholder => Share))
        public shares;
    mapping(address => DividendInfo) public dividends;
    uint256 public totalShares;

    uint256 public dividendsPerShareAccuracyFactor = 10 ** 36;

    IERC20 immutable SOLIDX =
        IERC20(0x8Da17Db850315A34532108f0f5458fc0401525f6);
    IERC20 immutable EHEX = IERC20(0x57fde0a71132198BBeC939B98976993d8D89D225);
    IERC20 immutable PHEX = IERC20(0x2b591e99afE9f32eAA6214f7B7629768c40Eeb39);
    IERC20 immutable GELATO =
        IERC20(0x616cb6a245Ed4c11216Ec58D10B6A2E87271845d);
    IERC20 immutable PLSX = IERC20(0x95B303987A60C71504D99Aa1b13B4DA07b0790ab);
    IERC20 immutable INC = IERC20(0x2fa878Ab3F87CC1C9737Fc071108F904c0B0C95d);
    IERC20 immutable WPLS = IERC20(0xA1077a294dDE1B09bB078844df40758a5D0f9a27);
    address immutable ZERO = 0x0000000000000000000000000000000000000000;
    address immutable DEAD = 0x000000000000000000000000000000000000dEaD;
    IUniswapV2Router02 public immutable pulseRouterV1 =
        IUniswapV2Router02(0x98bf93ebf5c380C0e6Ae8e192A7e2AE08edAcc02);
    IUniswapV2Router02 public immutable pulseRouterV2 =
        IUniswapV2Router02(0x165C3410fC91EF562C50559f7d2289fEbed552d9);
    IUniswapV2Router02 public immutable nineinchRouter =
        IUniswapV2Router02(0xeB45a3c4aedd0F47F345fB4c8A1802BB5740d725);

    uint256 public totalSolidXBurned;
    uint256 public totalGelatoBurned;

    modifier onlyToken() {
        require(msg.sender == rhino);
        _;
    }

    bool public distributing;

    modifier inDistribution() {
        distributing = true;
        _;
        distributing = false;
    }

    constructor() {
        rhino = msg.sender;
        dividends[address(WPLS)].minPeriod = 1 hours;
        dividends[address(WPLS)].minDistribution = 30000 * (10 ** 18);
        dividends[msg.sender].minPeriod = 1 hours;
        dividends[msg.sender].minDistribution = 10000 * (10 ** 18);
        dividends[address(SOLIDX)].minPeriod = 1 hours;
        dividends[address(SOLIDX)].minDistribution = (1 * (10 ** 18)) / 10;
        dividends[address(EHEX)].minPeriod = 1 hours;
        dividends[address(EHEX)].minDistribution = 500 * (10 ** 8);
        dividends[address(PHEX)].minPeriod = 1 hours;
        dividends[address(PHEX)].minDistribution = 100 * (10 ** 8);
        dividends[address(GELATO)].minPeriod = 1 hours;
        dividends[address(GELATO)].minDistribution = 10000 * (10 ** 18);
        dividends[address(PLSX)].minPeriod = 1 hours;
        dividends[address(PLSX)].minDistribution = 30000 * (10 ** 18);
        dividends[address(INC)].minPeriod = 1 hours;
        dividends[address(INC)].minDistribution = 1 * (10 ** 18);
    }

    function setDistributionCriteria(
        address token,
        uint256 minPeriod,
        uint256 minDistribution
    ) external override onlyToken {
        dividends[token].minPeriod = minPeriod;
        dividends[token].minDistribution = minDistribution;
    }

    function setShare(address shareholder, uint256 amount) external onlyToken {
        address[] memory tokens = new address[](8);
        tokens[0] = rhino;
        tokens[1] = address(WPLS);
        tokens[2] = address(SOLIDX);
        tokens[3] = address(EHEX);
        tokens[4] = address(PHEX);
        tokens[5] = address(GELATO);
        tokens[6] = address(PLSX);
        tokens[7] = address(INC);

        if (shares[rhino][shareholder].amount > 0) {
            for (uint256 i = 0; i < tokens.length; i++) {
                _distributeDividend(tokens[i], shareholder);
            }
        }

        bool isNewShareholder = (amount > 0 &&
            shares[rhino][shareholder].amount == 0);
        bool isRemovedShareholder = (amount == 0 &&
            shares[rhino][shareholder].amount > 0);

        if (isNewShareholder) {
            _addShareholder(shareholder);
        } else if (isRemovedShareholder) {
            _removeShareholder(shareholder);
        }

        totalShares = totalShares.sub(shares[rhino][shareholder].amount).add(
            amount
        );

        for (uint256 i = 0; i < tokens.length; i++) {
            shares[tokens[i]][shareholder].amount = amount;
            shares[tokens[i]][shareholder]
                .totalExcluded = getCumulativeDividends(tokens[i], amount);
        }
    }

    function setLpShare(
        address shareholder,
        uint256 amount
    ) external onlyToken {
        address[] memory tokens = new address[](8);
        tokens[0] = rhino;
        tokens[1] = address(WPLS);
        tokens[2] = address(SOLIDX);
        tokens[3] = address(EHEX);
        tokens[4] = address(PHEX);
        tokens[5] = address(GELATO);
        tokens[6] = address(PLSX);
        tokens[7] = address(INC);

        if (lpShares[rhino][shareholder].amount > 0) {
            for (uint256 i = 0; i < tokens.length; i++) {
                _distributeLpDividend(tokens[i], shareholder);
            }
        }

        bool isNewShareholder = (amount > 0 &&
            lpShares[rhino][shareholder].amount == 0);
        bool isRemovedShareholder = (amount == 0 &&
            lpShares[rhino][shareholder].amount > 0);

        if (isNewShareholder) {
            _addLpShareholder(shareholder);
        } else if (isRemovedShareholder) {
            _removeLpShareholder(shareholder);
        }

        lpTotalShares = lpTotalShares
            .sub(lpShares[rhino][shareholder].amount)
            .add(amount);

        for (uint256 i = 0; i < tokens.length; i++) {
            lpShares[tokens[i]][shareholder].amount = amount;
            lpShares[tokens[i]][shareholder]
                .totalExcluded = getLpCumulativeDividends(tokens[i], amount);
        }
    }

    function depositForReflection(
        address reflectedToken
    ) external payable override onlyToken {
        uint256 balanceBefore = IERC20(reflectedToken).balanceOf(address(this));

        address[] memory path = new address[](2);
        path[0] = address(WPLS);
        path[1] = reflectedToken;

        IUniswapV2Router02 router = IUniswapV2Router02(
            getBestRouter(msg.value, path)
        );

        router.swapExactETHForTokensSupportingFeeOnTransferTokens{
            value: msg.value
        }(0, path, address(this), block.timestamp);

        uint256 balanceAfter = IERC20(reflectedToken).balanceOf(address(this));

        uint256 tokenReceived = balanceAfter.sub(balanceBefore);

        uint256 feeDenom = IRhino(rhino).feeDenominator();
        uint256 lpReflectionPercent = IRhino(rhino).lpReflectionPercent();

        if (lpTotalShares > 0 && lpReflectionPercent > 0) {
            uint256 amountReflection = tokenReceived
                .mul(feeDenom.sub(lpReflectionPercent))
                .div(feeDenom);

            dividends[reflectedToken].totalDividends = dividends[reflectedToken]
                .totalDividends
                .add(amountReflection);
            dividends[reflectedToken].dividendsPerShare = dividends[
                reflectedToken
            ].dividendsPerShare.add(
                    dividendsPerShareAccuracyFactor.mul(amountReflection).div(
                        totalShares
                    )
                );

            uint256 amountLpReflection = (
                tokenReceived.mul(lpReflectionPercent)
            ).div(feeDenom);

            lpDividends[reflectedToken].totalDividends = lpDividends[
                reflectedToken
            ].totalDividends.add(amountLpReflection);
            lpDividends[reflectedToken].dividendsPerShare = lpDividends[
                reflectedToken
            ].dividendsPerShare.add(
                    dividendsPerShareAccuracyFactor.mul(amountLpReflection).div(
                        lpTotalShares
                    )
                );
        } else {
            uint256 amountReflection = tokenReceived;

            dividends[reflectedToken].totalDividends = dividends[reflectedToken]
                .totalDividends
                .add(amountReflection);
            dividends[reflectedToken].dividendsPerShare = dividends[
                reflectedToken
            ].dividendsPerShare.add(
                    dividendsPerShareAccuracyFactor.mul(amountReflection).div(
                        totalShares
                    )
                );
        }
    }

    function depositForPlsReflection() external payable override onlyToken {
        uint256 feeDenom = IRhino(rhino).feeDenominator();
        uint256 lpReflectionPercent = IRhino(rhino).lpReflectionPercent();

        if (lpTotalShares > 0 && lpReflectionPercent > 0) {
            uint256 amountReflection = msg
                .value
                .mul((feeDenom).sub(lpReflectionPercent))
                .div(feeDenom);

            dividends[address(WPLS)].totalDividends = dividends[address(WPLS)]
                .totalDividends
                .add(amountReflection);
            dividends[address(WPLS)].dividendsPerShare = dividends[
                address(WPLS)
            ].dividendsPerShare.add(
                    dividendsPerShareAccuracyFactor.mul(amountReflection).div(
                        totalShares
                    )
                );

            uint256 amountLpReflection = (msg.value.mul(lpReflectionPercent))
                .div(feeDenom);

            lpDividends[address(WPLS)].totalDividends = lpDividends[
                address(WPLS)
            ].totalDividends.add(amountLpReflection);
            lpDividends[address(WPLS)].dividendsPerShare = lpDividends[
                address(WPLS)
            ].dividendsPerShare.add(
                    dividendsPerShareAccuracyFactor.mul(amountLpReflection).div(
                        lpTotalShares
                    )
                );
        } else {
            uint256 amountReflection = msg.value;

            dividends[address(WPLS)].totalDividends = dividends[address(WPLS)]
                .totalDividends
                .add(amountReflection);
            dividends[address(WPLS)].dividendsPerShare = dividends[
                address(WPLS)
            ].dividendsPerShare.add(
                    dividendsPerShareAccuracyFactor.mul(amountReflection).div(
                        totalShares
                    )
                );
        }
    }

    function depositForRhinoReflection(
        uint256 amount
    ) external override onlyToken {
        IERC20(rhino).transferFrom(address(rhino), address(this), amount);

        uint256 feeDenom = IRhino(rhino).feeDenominator();
        uint256 lpReflectionPercent = IRhino(rhino).lpReflectionPercent();

        if (lpTotalShares > 0 && lpReflectionPercent > 0) {
            uint256 reflectionAmount = amount
                .mul((feeDenom).sub(lpReflectionPercent))
                .div(feeDenom);

            dividends[address(rhino)].totalDividends = dividends[address(rhino)]
                .totalDividends
                .add(reflectionAmount);
            dividends[address(rhino)].dividendsPerShare = dividends[
                address(rhino)
            ].dividendsPerShare.add(
                    dividendsPerShareAccuracyFactor.mul(reflectionAmount).div(
                        totalShares
                    )
                );

            uint256 amountLpReflection = (amount.mul(lpReflectionPercent)).div(
                feeDenom
            );

            lpDividends[address(rhino)].totalDividends = lpDividends[
                address(rhino)
            ].totalDividends.add(amountLpReflection);
            lpDividends[address(rhino)].dividendsPerShare = lpDividends[
                address(rhino)
            ].dividendsPerShare.add(
                    dividendsPerShareAccuracyFactor.mul(amountLpReflection).div(
                        lpTotalShares
                    )
                );
        } else {
            uint256 reflectionAmount = amount;

            dividends[address(rhino)].totalDividends = dividends[address(rhino)]
                .totalDividends
                .add(reflectionAmount);
            dividends[address(rhino)].dividendsPerShare = dividends[
                address(rhino)
            ].dividendsPerShare.add(
                    dividendsPerShareAccuracyFactor.mul(reflectionAmount).div(
                        totalShares
                    )
                );
        }
    }

    function depositForSolidXBurn() external payable override onlyToken {
        uint256 solidXBefore = SOLIDX.balanceOf(address(this));

        address[] memory path = new address[](2);
        path[0] = address(WPLS);
        path[1] = address(SOLIDX);

        IUniswapV2Router01 router = IUniswapV2Router01(
            getBestRouter(msg.value, path)
        );

        router.swapExactETHForTokens{value: msg.value}(
            0,
            path,
            address(this),
            block.timestamp
        );

        uint256 solidXGained = SOLIDX.balanceOf(address(this)).sub(
            solidXBefore
        );

        ISOLIDX(address(SOLIDX)).burn(solidXGained);
        totalSolidXBurned = totalSolidXBurned.add(solidXGained);
    }

    function depositForGelatoBurn() external payable override onlyToken {
        uint256 gelatoBefore = GELATO.balanceOf(address(this));

        address[] memory path = new address[](2);
        path[0] = address(WPLS);
        path[1] = address(GELATO);

        IUniswapV2Router02 router = IUniswapV2Router02(
            getBestRouter(msg.value, path)
        );

        router.swapExactETHForTokensSupportingFeeOnTransferTokens{
            value: msg.value
        }(0, path, address(this), block.timestamp);

        uint256 gelatoGained = GELATO.balanceOf(address(this)).sub(
            gelatoBefore
        );
        GELATO.transfer(DEAD, gelatoGained);
        totalGelatoBurned = totalGelatoBurned.add(gelatoGained);
    }

    function claimDividend(address user) external override onlyToken {
        address[] memory tokens = new address[](8);
        tokens[0] = rhino;
        tokens[1] = address(WPLS);
        tokens[2] = address(SOLIDX);
        tokens[3] = address(EHEX);
        tokens[4] = address(PHEX);
        tokens[5] = address(GELATO);
        tokens[6] = address(PLSX);
        tokens[7] = address(INC);

        for (uint256 i = 0; i < tokens.length; i++) {
            _distributeDividend(tokens[i], user);
        }
    }

    function claimLpDividend(address user) external override onlyToken {
        address[] memory tokens = new address[](8);
        tokens[0] = rhino;
        tokens[1] = address(WPLS);
        tokens[2] = address(SOLIDX);
        tokens[3] = address(EHEX);
        tokens[4] = address(PHEX);
        tokens[5] = address(GELATO);
        tokens[6] = address(PLSX);
        tokens[7] = address(INC);

        for (uint256 i = 0; i < tokens.length; i++) {
            _distributeLpDividend(tokens[i], user);
        }
    }

    function processDividend(
        address token,
        uint256 gas
    ) external override onlyToken {
        uint256 shareholderCount = shareholders[token].length;
        if (shareholderCount == 0) return;

        uint256 gasUsed = 0;
        uint256 gasLeft = gasleft();
        uint256 iterations = 0;
        while (gasUsed < gas && iterations < shareholderCount) {
            if (dividends[token].currentIndex >= shareholderCount) {
                dividends[token].currentIndex = 0;
            }
            if (
                _shouldDistribute(
                    token,
                    shareholders[token][dividends[token].currentIndex]
                )
            ) {
                _distributeDividend(
                    token,
                    shareholders[token][dividends[token].currentIndex]
                );
            }
            gasUsed = gasUsed.add(gasLeft.sub(gasleft()));
            gasLeft = gasleft();
            dividends[token].currentIndex++;
            iterations++;
        }
    }

    function _distributeDividend(address token, address shareholder) internal inDistribution {
        if (shares[token][shareholder].amount == 0) return;

        uint256 amount = getUnpaidEarnings(token, shareholder);
        if (amount > 0) {
            shareholderClaims[token][shareholder] = block.timestamp;
            shares[token][shareholder].totalRealised = shares[token][
                shareholder
            ].totalRealised.add(amount);
            shares[token][shareholder].totalExcluded = getCumulativeDividends(
                token,
                shares[token][shareholder].amount
            );

            dividends[token].totalDistributed = dividends[token]
                .totalDistributed
                .add(amount);
            if (token == address(WPLS)) {
                (bool success, ) = payable(shareholder).call{
                    value: amount,
                    gas: 50000
                }("");
                success;
            } else {
                IERC20(token).transfer(shareholder, amount);
            }
        }
    }

    function _distributeLpDividend(
        address token,
        address shareholder
    ) internal inDistribution {
        if (lpShares[token][shareholder].amount == 0) return;

        uint256 amount = getLpUnpaidEarnings(token, shareholder);
        if (amount > 0) {
            lpShareholderClaims[token][shareholder] = block.timestamp;
            lpShares[token][shareholder].totalRealised = lpShares[token][
                shareholder
            ].totalRealised.add(amount);
            lpShares[token][shareholder]
                .totalExcluded = getLpCumulativeDividends(
                token,
                lpShares[token][shareholder].amount
            );
            lpDividends[token].totalDistributed = lpDividends[token]
                .totalDistributed
                .add(amount);
            if (token == address(WPLS)) {
                (bool success, ) = payable(shareholder).call{
                    value: amount,
                    gas: 50000
                }("");
                success;
            } else {
                IERC20(token).transfer(shareholder, amount);
            }
        }
    }

    function _shouldDistribute(
        address token,
        address shareholder
    ) internal view returns (bool) {
        return
            shareholderClaims[token][shareholder] + dividends[token].minPeriod <
            block.timestamp &&
            getUnpaidEarnings(token, shareholder) >
            dividends[token].minDistribution;
    }

    function getBestRouter(
        uint256 amountIn,
        address[] memory path
    ) public view returns (address bestRouter) {
        address[] memory routers = new address[](3);
        routers[0] = address(pulseRouterV1);
        routers[1] = address(pulseRouterV2);
        routers[2] = address(nineinchRouter);

        uint256 bestAmountOut = 0;

        for (uint256 i = 0; i < routers.length; i++) {
            try
                IUniswapV2Router02(routers[i]).getAmountsOut(amountIn, path)
            returns (uint256[] memory amountsOut) {
                uint256 amountOut = amountsOut[amountsOut.length - 1];
                if (amountOut > bestAmountOut) {
                    bestAmountOut = amountOut;
                    bestRouter = routers[i];
                }
            } catch {
                continue;
            }
        }
    }

    function getUnpaidEarnings(
        address token,
        address shareholder
    ) public view returns (uint256) {
        if (shares[token][shareholder].amount == 0) {
            return 0;
        }
        uint256 totalDividends = getCumulativeDividends(
            token,
            shares[token][shareholder].amount
        );
        uint256 totalExcluded = shares[token][shareholder].totalExcluded;
        if (totalDividends <= totalExcluded) {
            return 0;
        }
        return totalDividends.sub(totalExcluded);
    }

    function getLpUnpaidEarnings(
        address token,
        address shareholder
    ) public view returns (uint256) {
        if (lpShares[token][shareholder].amount == 0) {
            return 0;
        }
        uint256 totalDividends = getLpCumulativeDividends(
            token,
            lpShares[token][shareholder].amount
        );
        uint256 totalExcluded = lpShares[token][shareholder].totalExcluded;
        if (totalDividends <= totalExcluded) {
            return 0;
        }
        return totalDividends.sub(totalExcluded);
    }

    function getCumulativeDividends(
        address token,
        uint256 share
    ) public view returns (uint256) {
        return
            share.mul(dividends[token].dividendsPerShare).div(
                dividendsPerShareAccuracyFactor
            );
    }

    function getLpCumulativeDividends(
        address token,
        uint256 share
    ) public view returns (uint256) {
        return
            share.mul(lpDividends[token].dividendsPerShare).div(
                dividendsPerShareAccuracyFactor
            );
    }

    function _addShareholder(address shareholder) internal {
        address[8] memory tokens = [
            rhino,
            address(WPLS),
            address(SOLIDX),
            address(EHEX),
            address(PHEX),
            address(GELATO),
            address(PLSX),
            address(INC)
        ];

        for (uint256 i = 0; i < tokens.length; i++) {
            address token = tokens[i];
            shareholderIndexes[token][shareholder] = shareholders[token].length;
            shareholders[token].push(shareholder);
        }
    }

    function _removeShareholder(address shareholder) internal {
        address[8] memory tokens = [
            rhino,
            address(WPLS),
            address(SOLIDX),
            address(EHEX),
            address(PHEX),
            address(GELATO),
            address(PLSX),
            address(INC)
        ];

        for (uint256 i = 0; i < tokens.length; i++) {
            address token = tokens[i];
            uint256 index = shareholderIndexes[token][shareholder];
            address lastShareholder = shareholders[token][
                shareholders[token].length - 1
            ];

            shareholders[token][index] = lastShareholder;
            shareholderIndexes[token][lastShareholder] = index;
            shareholders[token].pop();
        }
    }

    function _addLpShareholder(address shareholder) internal {
        address[8] memory tokens = [
            rhino,
            address(WPLS),
            address(SOLIDX),
            address(EHEX),
            address(PHEX),
            address(GELATO),
            address(PLSX),
            address(INC)
        ];

        for (uint256 i = 0; i < tokens.length; i++) {
            address token = tokens[i];
            lpShareholderIndexes[token][shareholder] = lpShareholders[token]
                .length;
            lpShareholders[token].push(shareholder);
        }
    }

    function _removeLpShareholder(address shareholder) internal {
        address[8] memory tokens = [
            rhino,
            address(WPLS),
            address(SOLIDX),
            address(EHEX),
            address(PHEX),
            address(GELATO),
            address(PLSX),
            address(INC)
        ];

        for (uint256 i = 0; i < tokens.length; i++) {
            address token = tokens[i];
            uint256 length = lpShareholders[token].length;
            uint256 index = lpShareholderIndexes[token][shareholder];

            if (length == 1) {
                delete lpShareholderIndexes[token][shareholder];
                lpShareholders[token].pop();
                continue;
            }

            address lastShareholder = lpShareholders[token][length - 1];

            lpShareholders[token][index] = lastShareholder;
            lpShareholderIndexes[token][lastShareholder] = index;
            lpShareholders[token].pop();
        }
    }

    receive() external payable {}
}

contract RhinoFi is IERC20, ReentrancyGuard, Ownable {
    using SafeMath for uint256;

    RhinoCharging public rhinoCharging;

    address immutable WPLS = 0xA1077a294dDE1B09bB078844df40758a5D0f9a27;
    address immutable SOLIDX = 0x8Da17Db850315A34532108f0f5458fc0401525f6;
    address immutable GELATO = 0x616cb6a245Ed4c11216Ec58D10B6A2E87271845d;
    address immutable EHEX = 0x57fde0a71132198BBeC939B98976993d8D89D225;
    address immutable PHEX = 0x2b591e99afE9f32eAA6214f7B7629768c40Eeb39;
    address immutable PLSX = 0x95B303987A60C71504D99Aa1b13B4DA07b0790ab;
    address immutable INC = 0x2fa878Ab3F87CC1C9737Fc071108F904c0B0C95d;
    address immutable DEAD = 0x000000000000000000000000000000000000dEaD;
    address immutable ZERO = 0x0000000000000000000000000000000000000000;

    string constant _name = "RhinoFi";
    string constant _symbol = "RHINO";
    uint8 constant _decimals = 18;

    uint256 _totalSupply = 1_000_000_000e18; // 1,000,000,000
    uint256 public maxTxAmount = _totalSupply; // 100%

    mapping(address => uint256) _balances;
    mapping(address => mapping(address => uint256)) _allowances;
    mapping(address pairAddress => mapping(address user => uint256 lpBalance))
        public lpBalances; // Tracks user's LP token balances.
    mapping(address pairAddress => bool isPair) public isPair; // Tracks addresses that are trading pairs.
    mapping(address user => uint256 userTotalRhinoInLp)
        public userTotalLpRhinoValue; // Tracks amount of Rhino tokens the user has in all LP positions.
    mapping(address pairAddress => mapping(address users => uint256 userRhinoInLp)) public userLpRhinoValue; // Tracks amount of Rhino tokens the user has in one LP position.
    mapping(address user => uint256 startTime) public holderStartTime; // Tracks the timestamp when the wallet became a holder, which starts his 90 day fee decay timer.

    mapping(address => bool) public isFeeExempt; // Returns true or false if the address is exempted from fees.
    mapping(address => bool) public isTxLimitExempt; // Returns true or false if the address is exempted from TX Limits.
    mapping(address => bool) public isDividendExempt; // Returns true or false if the address is exempted from receiving Reflection dividends.

    uint256 public feeDecayTime = 28 days; // Time after which fees decay to the base rate
    uint256 public baseBuyFee = 600; // 6%
    uint256 public baseSellFee = 2500; // 25%
    uint256 public minBuyFee = 600; // 6%
    uint256 public minSellFee = 600; // 6%

    uint256 public plsReflectionFee = 500; // Percent of fee going to provide PLS reflections.
    uint256 public rhinoReflectionFee = 500; // Percent of fee going to provide Rhino reflections.
    uint256 public solidXReflectionFee = 500; // Percent of fee going to provide SolidX reflections.
    uint256 public eHexReflectionFee = 500; // Percent of fee going to provide eHEX reflections.
    uint256 public pHexReflectionFee = 500; // Percent of fee going to provide pHEX reflections.
    uint256 public gelatoReflectionFee = 500; // Percent of fee going to provide Gelato reflections.
    uint256 public plsxReflectionFee = 1000; // Percent of fee going to provide PLSX reflections.
    uint256 public incReflectionFee = 1000; // Percent of fee going to provide INC reflections.
    uint256 public rhinoBurnFee = 1000; // Percent of fee going to provide burns to Rhino token.
    uint256 public solidXBurnFee = 750; // Percent of fee going to provide burns to SolidX token.
    uint256 public gelatoBurnFee = 750; // Percent of fee going to provide burns to Gelato token.
    uint256 public liquidityFee = 1500; // Percent of fee going to provide automatic Liquidity addition.
    uint256 public genesisFee = 1000; // Percent of fee going to provide Rhino tokens to the Genesis address.

    uint256 public lpReflectionPercent = 3333; // Percent of reflections that will go to LP providers.

    uint256 public constant feeDenominator = 10000;
    bool public feesOnNormalTransfers = true; // If true, the buy fee will apply for regular wallet -> wallet transfers.

    address public autoLiquidityReceiver; // The address that will receive the LP tokens which are minted when auto LP is added.
    address public genesisReceiver; // The genesis wallet.

    IUniswapV2Router02 public immutable pulseRouterV1 =
        IUniswapV2Router02(0x98bf93ebf5c380C0e6Ae8e192A7e2AE08edAcc02);
    IUniswapV2Router02 public immutable pulseRouterV2 =
        IUniswapV2Router02(0x165C3410fC91EF562C50559f7d2289fEbed552d9);
    IUniswapV2Router02 public immutable nineinchRouter =
        IUniswapV2Router02(0xeB45a3c4aedd0F47F345fB4c8A1802BB5740d725);

    address public pulseV2Pair;
    address[] public pairs;
    mapping(address pairAddress => address router) public routerByPair; // Tracks the router used for a pair.

    uint256 public launchedAt;

    DividendDistributor public distributor;
    uint256 distributorGas = 100000; // The amount of gasLimit provided to processDividend function calls.

    bool public swapEnabled = true; // When true, rhino tokens will be swapped back via swapBack() function once swapThreshold is reached.
    uint256 public swapThreshold = _totalSupply / 1000; // 0.1% of the supply will trigger the swapBack() function to trigger.
    bool inSwap; // Bool for swapping modifier.
    bool public emergencyMode = false; // If true, the contract will not swap tokens and will not charge fees.

    modifier swapping() {
        inSwap = true;
        _;
        inSwap = false;
    }
    bool inLp; // Bool for inLiquidity modifier.
    modifier inLiquidity() {
        inLp = true;
        _;
        inLp = false;
    }

    uint256 public totalRhinoBurned; // Tracker for total amount of Rhino tokens burned.
    uint256 public totalPlsLpAdded; // Tracker for total amount of PLS added to LP.

    struct SwapValues {
        uint256 amountRhinoBurn;
        uint256 amountSolidXBurn;
        uint256 amountGelatoBurn;
        uint256 amountRhinoGenesis;
        uint256 amountRhinoSwap;
        uint256 balanceBefore;
        uint256 amountPls;
        uint256 amountPlsLiquidity;
        uint256 amountPlsReflection;
        uint256 amountRhinoReflection;
        uint256 amountSolidXReflection;
        uint256 amountEhexReflection;
        uint256 amountPhexReflection;
        uint256 amountGelatoReflection;
        uint256 amountPlsxReflection;
        uint256 amountIncReflection;
        uint256 amountSolidXToBurn;
        uint256 amountGelatoToBurn;
    }

    struct LiquidityVars {
        uint256 amount0;
        uint256 amount1;
        uint256 amount0Used;
        uint256 amount1Used;
        uint256 lpValueForThisPair;
        uint256 refundETH;
        uint256 refundRhino;
    }

    constructor() Ownable(msg.sender) {
        pulseV2Pair = IUniswapV2Factory(pulseRouterV2.factory()).createPair(
            WPLS,
            address(this)
        );
        distributor = new DividendDistributor();
        _allowances[address(this)][address(pulseRouterV1)] = type(uint256).max;
        _allowances[address(this)][address(pulseRouterV2)] = type(uint256).max;
        _allowances[address(this)][address(nineinchRouter)] = type(uint256).max;
        _allowances[address(this)][address(distributor)] = type(uint256).max;

        pairs.push(pulseV2Pair);
        isPair[pulseV2Pair] = true;
        routerByPair[pulseV2Pair] = address(pulseRouterV2);

        address owner_ = msg.sender;

        isFeeExempt[owner_] = true;
        isTxLimitExempt[owner_] = true;
        isDividendExempt[pulseV2Pair] = true;
        isDividendExempt[address(this)] = true;
        isFeeExempt[address(this)] = true;
        isFeeExempt[address(distributor)] = true;
        isTxLimitExempt[address(this)] = true;
        isTxLimitExempt[address(distributor)] = true;
        isDividendExempt[address(distributor)] = true;
        isDividendExempt[DEAD] = true;
        isDividendExempt[ZERO] = true;

        autoLiquidityReceiver = owner_;
        genesisReceiver = owner_;

        _balances[owner_] = _totalSupply;
        emit Transfer(address(0), owner_, _totalSupply);
    }

    receive() external payable {}

    function totalSupply() external view override returns (uint256) {
        return _totalSupply;
    }

    function decimals() external pure override returns (uint8) {
        return _decimals;
    }

    function symbol() external pure override returns (string memory) {
        return _symbol;
    }

    function name() external pure override returns (string memory) {
        return _name;
    }

    function balanceOf(address account) public view override returns (uint256) {
        return _balances[account];
    }

    function allowance(
        address holder,
        address spender
    ) external view override returns (uint256) {
        return _allowances[holder][spender];
    }

    function approve(
        address spender,
        uint256 amount
    ) public override returns (bool) {
        _allowances[msg.sender][spender] = amount;
        emit Approval(msg.sender, spender, amount);
        return true;
    }

    function transfer(
        address recipient,
        uint256 amount
    ) external override returns (bool) {
        return _transferFrom(msg.sender, recipient, amount);
    }

    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external override returns (bool) {
        if (_allowances[sender][msg.sender] != ~uint256(0)) {
            _allowances[sender][msg.sender] = _allowances[sender][msg.sender]
                .sub(amount, "Insufficient Allowance");
        }

        return _transferFrom(sender, recipient, amount);
    }

    function _transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) internal returns (bool) {
        require(
            launchedAt > 0 || tx.origin == owner(),
            "The contract is not launched yet"
        );

        bool didSwapback;

        if (
            inSwap ||
            launchedAt == 0 ||
            emergencyMode
        ) {
            return _basicTransfer(sender, recipient, amount);
        }
        checkTxLimit(sender, recipient, amount);

        if (
        shouldSwapBack(sender) && 
        !rhinoCharging.swapping() &&
        !distributor.distributing()
        ) {
            swapBack();
            didSwapback = true;
        } else {
            try rhinoCharging.triggerSwap(block.timestamp) {} catch {}
        }

        _balances[sender] = _balances[sender].sub(
            amount,
            "Insufficient Balance"
        );

        if (holderStartTime[recipient] == 0) {
            holderStartTime[recipient] = block.timestamp;
        }

        uint256 amountReceived = shouldTakeFee(sender, recipient)
            ? takeFee(sender, recipient, amount)
            : amount;
        _balances[recipient] = _balances[recipient].add(amountReceived);

        if (!isDividendExempt[sender]) {
            try distributor.setShare(sender, _balances[sender]) {} catch {}
        }
        if (!isDividendExempt[recipient]) {
            try distributor.setShare(recipient, _balances[recipient]) {} catch {}
        }
        
        if (!didSwapback) {
            if (plsReflectionFee > 0) {
                try distributor.processDividend(WPLS, distributorGas) {} catch {}
            }
            if (rhinoReflectionFee > 0) {
                try distributor.processDividend(address(this), distributorGas) {} catch {}
            }
            if (solidXReflectionFee > 0) {
                try distributor.processDividend(SOLIDX, distributorGas) {} catch {}
            }
            if (eHexReflectionFee > 0) {
                try distributor.processDividend(EHEX, distributorGas) {} catch {}
            }
            if (pHexReflectionFee > 0) {
                try distributor.processDividend(PHEX, distributorGas) {} catch {}
            }
            if (gelatoReflectionFee > 0) {
                try distributor.processDividend(GELATO, distributorGas) {} catch {}
            }
            if (plsxReflectionFee > 0) {
                try distributor.processDividend(PLSX, distributorGas) {} catch {}
            }
            if (incReflectionFee > 0) {
                try distributor.processDividend(INC, distributorGas) {} catch {}
            }
        }

        emit Transfer(sender, recipient, amountReceived);
        return true;
    }

    function _basicTransfer(
        address sender,
        address recipient,
        uint256 amount
    ) internal returns (bool) {
        _balances[sender] = _balances[sender].sub(
            amount,
            "Insufficient Balance"
        );
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
        return true;
    }

    function checkTxLimit(
        address sender,
        address recipient,
        uint256 amount
    ) internal view {
        require(
            amount <= maxTxAmount ||
                isTxLimitExempt[sender] ||
                isTxLimitExempt[recipient],
            "TX Limit Exceeded"
        );
    }

    function shouldTakeFee(
        address sender,
        address recipient
    ) internal view returns (bool) {
        if (isFeeExempt[sender] || isFeeExempt[recipient] || launchedAt == 0)
            return false;

        address[] memory liqPairs = pairs;

        for (uint256 i = 0; i < liqPairs.length; i++) {
            if (sender == liqPairs[i] || recipient == liqPairs[i]) return true;
        }

        return feesOnNormalTransfers;
    }

    function getTotalFee(
        address user,
        bool selling
    ) public view returns (uint256) {
        uint256 baseFee = selling ? baseSellFee : baseBuyFee;
        uint256 minFee = selling ? minSellFee : minBuyFee;

        uint256 lastTime = holderStartTime[user];
        uint256 timeElapsed = block.timestamp > lastTime
            ? block.timestamp - lastTime
            : 0;

        if (timeElapsed >= feeDecayTime) {
            return minFee;
        }

        uint256 discount = baseFee.sub(minFee).mul(timeElapsed).div(
            feeDecayTime
        );
        return baseFee.sub(discount);
    }

    function takeFee(
        address sender,
        address recipient,
        uint256 amount
    ) internal returns (uint256) {
        uint256 feeRate = 0;
        if (isSell(recipient)) {
            feeRate = getTotalFee(sender, true);
        } else if (isBuy(sender)) {
            feeRate = getTotalFee(recipient, false);
        } else {
            feeRate = minBuyFee;
        }
        uint256 feeAmount = amount.mul(feeRate).div(feeDenominator);

        _balances[address(this)] = _balances[address(this)].add(feeAmount);
        emit Transfer(sender, address(this), feeAmount);

        return amount.sub(feeAmount);
    }

    function isSell(address recipient) internal view returns (bool) {
        address[] memory liqPairs = pairs;
        for (uint256 i = 0; i < liqPairs.length; i++) {
            if (recipient == liqPairs[i]) return true;
        }
        return false;
    }

    function isBuy(address sender) internal view returns (bool) {
        address[] memory liqPairs = pairs;
        for (uint256 i = 0; i < liqPairs.length; i++) {
            if (sender == liqPairs[i]) return true;
        }
        return false;
    }

    function addLiquidity(
        address otherToken,
        IUniswapV2Pair pairAddress,
        uint256 amountRhino,
        uint256 amountOtherToken,
        uint256 amountRhinoMin,
        uint256 amountOtherTokenMin,
        uint256 deadline
    ) external nonReentrant inLiquidity {
        require(amountRhino > 0, "Invalid Rhino amount");
        require(isPair[address(pairAddress)] == true, "Pair is not supported.");

        if (userLpRhinoValue[address(pairAddress)][msg.sender] > 0) {
            userTotalLpRhinoValue[msg.sender] = userTotalLpRhinoValue[
                msg.sender
            ].sub(userLpRhinoValue[address(pairAddress)][msg.sender]);
            userLpRhinoValue[address(pairAddress)][msg.sender] = 0;
        }

        _transferFrom(msg.sender, address(this), amountRhino);
        IERC20(otherToken).transferFrom(
            msg.sender,
            address(this),
            amountOtherToken
        );
        IERC20(otherToken).approve(
            routerByPair[address(pairAddress)],
            amountOtherToken
        );

        LiquidityVars memory vars;

        (
            uint256 amount0,
            uint256 amount1,
            uint256 liquidity
        ) = IUniswapV2Router02(routerByPair[address(pairAddress)]).addLiquidity(
                address(this),
                otherToken,
                amountRhino,
                amountOtherToken,
                amountRhinoMin,
                amountOtherTokenMin,
                address(this),
                deadline
            );

        vars.amount0Used = amount0;
        vars.amount1Used = amount1;

        if (amountOtherToken.sub(vars.amount1Used) > 0) {
            IERC20(otherToken).transfer(
                msg.sender,
                amountOtherToken.sub(vars.amount1Used)
            );
        }
        if (amountRhino.sub(vars.amount0Used) > 0) {
            _transferFrom(
                address(this),
                msg.sender,
                amountRhino.sub(vars.amount0Used)
            );
        }

        lpBalances[address(pairAddress)][msg.sender] = lpBalances[
            address(pairAddress)
        ][msg.sender].add(liquidity);

        vars.lpValueForThisPair = _computeLpValue(pairAddress, msg.sender);
        userTotalLpRhinoValue[msg.sender] = userTotalLpRhinoValue[msg.sender]
            .add(vars.lpValueForThisPair);
        userLpRhinoValue[address(pairAddress)][msg.sender] = vars
            .lpValueForThisPair;

        try
            distributor.setLpShare(
                msg.sender,
                userTotalLpRhinoValue[msg.sender]
            )
        {} catch {}

        emit LiquidityAdded(
            msg.sender,
            vars.amount0Used,
            vars.amount1Used,
            liquidity
        );
    }

    function addLiquidityETH(
        uint256 amountRhino,
        uint256 amountETHMin,
        uint256 amountRhinoMin,
        uint256 deadline,
        IUniswapV2Pair pairAddress
    ) external payable nonReentrant inLiquidity {
        require(amountRhino > 0, "Invalid Rhino amount");
        require(isPair[address(pairAddress)] == true, "Pair is not supported.");

        if (userLpRhinoValue[address(pairAddress)][msg.sender] > 0) {
            userTotalLpRhinoValue[msg.sender] = userTotalLpRhinoValue[
                msg.sender
            ].sub(userLpRhinoValue[address(pairAddress)][msg.sender]);
            userLpRhinoValue[address(pairAddress)][msg.sender] = 0;
        }

        _transferFrom(msg.sender, address(this), amountRhino);

        LiquidityVars memory vars;

        (
            uint256 amount0,
            uint256 amount1,
            uint256 liquidity
        ) = IUniswapV2Router01(routerByPair[address(pairAddress)])
                .addLiquidityETH{value: msg.value}(
                address(this),
                amountRhino,
                amountRhinoMin,
                amountETHMin,
                address(this),
                deadline
            );

        vars.amount0Used = amount0;
        vars.amount1Used = amount1;

        if (msg.value.sub(vars.amount1Used) > 0) {
            (bool success, ) = payable(msg.sender).call{
                value: msg.value.sub(vars.amount1Used),
                gas: 30000
            }("");
            require(success, "PLS send failed.");
        }
        if (amountRhino.sub(vars.amount0Used) > 0) {
            _transferFrom(
                address(this),
                msg.sender,
                amountRhino.sub(vars.amount0Used)
            );
        }

        lpBalances[address(pairAddress)][msg.sender] = lpBalances[
            address(pairAddress)
        ][msg.sender].add(liquidity);

        vars.lpValueForThisPair = _computeLpValue(pairAddress, msg.sender);
        userTotalLpRhinoValue[msg.sender] = userTotalLpRhinoValue[msg.sender]
            .add(vars.lpValueForThisPair);
        userLpRhinoValue[address(pairAddress)][msg.sender] = vars
            .lpValueForThisPair;

        try
            distributor.setLpShare(
                msg.sender,
                userTotalLpRhinoValue[msg.sender]
            )
        {} catch {}

        emit LiquidityAdded(
            msg.sender,
            vars.amount0Used,
            vars.amount1Used,
            liquidity
        );
    }

    function removeLiquidity(
        uint256 lpAmount,
        IUniswapV2Pair pairAddress,
        uint256 amountRhinoMin,
        uint256 amountOtherTokenMin,
        uint256 deadline
    ) external nonReentrant inLiquidity {
        require(lpAmount > 0, "Invalid LP amount");
        require(
            lpBalances[address(pairAddress)][msg.sender] >= lpAmount,
            "Insufficient LP balance"
        );

        pairAddress.approve(routerByPair[address(pairAddress)], lpAmount);

        LiquidityVars memory vars;

        address otherToken = pairAddress.token0() == address(this)
            ? pairAddress.token1()
            : pairAddress.token0();

        (uint amount0, uint amount1) = IUniswapV2Router01(
            routerByPair[address(pairAddress)]
        ).removeLiquidity(
                address(this),
                otherToken,
                lpAmount,
                amountRhinoMin,
                amountOtherTokenMin,
                address(this),
                deadline
            );

        vars.amount0Used = amount0;
        vars.amount1Used = amount1;

        _transferFrom(address(this), msg.sender, vars.amount0Used);

        if (otherToken == WPLS) {
            IWPLS(WPLS).withdraw(vars.amount1Used);
            (bool success, ) = payable(msg.sender).call{
                value: vars.amount1Used,
                gas: 30000
            }("");
            require(success, "PLS send failed.");
        } else {
            IERC20(otherToken).transfer(msg.sender, vars.amount1Used);
        }

        lpBalances[address(pairAddress)][msg.sender] = lpBalances[
            address(pairAddress)
        ][msg.sender].sub(lpAmount);

        vars.lpValueForThisPair = userLpRhinoValue[address(pairAddress)][
            msg.sender
        ];
        userTotalLpRhinoValue[msg.sender] = userTotalLpRhinoValue[msg.sender]
            .sub(vars.lpValueForThisPair);

        userLpRhinoValue[address(pairAddress)][msg.sender] = _computeLpValue(
            pairAddress,
            msg.sender
        );
        userTotalLpRhinoValue[msg.sender] = userTotalLpRhinoValue[msg.sender]
            .add(userLpRhinoValue[address(pairAddress)][msg.sender]);

        try
            distributor.setLpShare(
                msg.sender,
                userTotalLpRhinoValue[msg.sender]
            )
        {} catch {}

        emit LiquidityRemoved(
            msg.sender,
            vars.amount0Used,
            vars.amount1Used,
            lpAmount
        );
    }

    function emergencyRemoveLiquidity(
        IUniswapV2Pair pairAddress
    ) external nonReentrant inLiquidity {
        require(
            lpBalances[address(pairAddress)][msg.sender] >= 0,
            "Insufficient LP balance"
        );
        require(emergencyMode, "Emergency mode is not enabled");

        uint256 lpAmount = lpBalances[address(pairAddress)][msg.sender];
        lpBalances[address(pairAddress)][msg.sender] = 0;

        pairAddress.transfer(msg.sender, lpAmount);
    }

    function _computeLpValue(
        IUniswapV2Pair pairAddress,
        address user
    ) internal view returns (uint256 lpValue) {
        (uint112 reserve0, uint112 reserve1, ) = pairAddress.getReserves();
        uint256 tokenReserve = pairAddress.token0() == address(this)
            ? uint256(reserve0)
            : uint256(reserve1);
        lpValue = tokenReserve.mul(lpBalances[address(pairAddress)][user]).div(
            pairAddress.totalSupply()
        );
    }

    function getLpTokenValueInRhino(
        address user
    ) public view returns (uint256) {
        return userTotalLpRhinoValue[user];
    }

    function shouldSwapBack(address sender) internal view returns (bool) {
        return
            sender != pulseV2Pair &&
            !inSwap &&
            !inLp &&
            swapEnabled &&
            _balances[address(this)] >= swapThreshold;
    }

    function swapBack() internal swapping inLiquidity {
        SwapValues memory sv;

        sv.amountRhinoReflection = swapThreshold.mul(rhinoReflectionFee).div(
            feeDenominator
        );
        sv.amountRhinoBurn = swapThreshold.mul(rhinoBurnFee).div(
            feeDenominator
        );
        sv.amountRhinoGenesis = swapThreshold.mul(genesisFee).div(
            feeDenominator
        );

        if (sv.amountRhinoReflection > 0) {
            try
                distributor.depositForRhinoReflection(sv.amountRhinoReflection)
            {} catch {}
        }

        if (sv.amountRhinoBurn > 0) {
            _transferFrom(address(this), ZERO, sv.amountRhinoBurn);
            totalRhinoBurned = totalRhinoBurned.add(sv.amountRhinoBurn);
        }

        if (sv.amountRhinoGenesis > 0) {
            _transferFrom(
                address(this),
                genesisReceiver,
                sv.amountRhinoGenesis
            );
        }

        sv.amountRhinoSwap = swapThreshold
            .sub(sv.amountRhinoReflection)
            .sub(sv.amountRhinoBurn)
            .sub(sv.amountRhinoGenesis);

        sv.balanceBefore = address(this).balance;

        address[] memory path = new address[](2);
        path[0] = address(this);
        path[1] = address(WPLS);

        // Attempt the swap
        try
            pulseRouterV2.swapExactTokensForETHSupportingFeeOnTransferTokens(
                sv.amountRhinoSwap,
                0,
                path,
                address(this),
                block.timestamp
            )
        {
            sv.amountPls = address(this).balance.sub(sv.balanceBefore);

            sv.amountPlsLiquidity = sv.amountPls.mul(liquidityFee).div(
                feeDenominator.sub(rhinoReflectionFee).sub(rhinoBurnFee).sub(
                    genesisFee
                )
            );
            sv.amountPlsReflection = sv.amountPls.mul(plsReflectionFee).div(
                feeDenominator.sub(rhinoReflectionFee).sub(rhinoBurnFee).sub(
                    genesisFee
                )
            );
            sv.amountSolidXReflection = sv
                .amountPls
                .mul(solidXReflectionFee)
                .div(
                    feeDenominator
                        .sub(rhinoReflectionFee)
                        .sub(rhinoBurnFee)
                        .sub(genesisFee)
                );
            sv.amountEhexReflection = sv.amountPls.mul(eHexReflectionFee).div(
                feeDenominator.sub(rhinoReflectionFee).sub(rhinoBurnFee).sub(
                    genesisFee
                )
            );
            sv.amountPhexReflection = sv.amountPls.mul(pHexReflectionFee).div(
                feeDenominator.sub(rhinoReflectionFee).sub(rhinoBurnFee).sub(
                    genesisFee
                )
            );
            sv.amountGelatoReflection = sv
                .amountPls
                .mul(gelatoReflectionFee)
                .div(
                    feeDenominator
                        .sub(rhinoReflectionFee)
                        .sub(rhinoBurnFee)
                        .sub(genesisFee)
                );
            sv.amountPlsxReflection = sv.amountPls.mul(plsxReflectionFee).div(
                feeDenominator.sub(rhinoReflectionFee).sub(rhinoBurnFee).sub(
                    genesisFee
                )
            );
            sv.amountIncReflection = sv.amountPls.mul(incReflectionFee).div(
                feeDenominator.sub(rhinoReflectionFee).sub(rhinoBurnFee).sub(
                    genesisFee
                )
            );
            sv.amountSolidXBurn = sv.amountPls.mul(solidXBurnFee).div(
                feeDenominator.sub(rhinoReflectionFee).sub(rhinoBurnFee).sub(
                    genesisFee
                )
            );
            sv.amountGelatoBurn = sv.amountPls.mul(gelatoBurnFee).div(
                feeDenominator.sub(rhinoReflectionFee).sub(rhinoBurnFee).sub(
                    genesisFee
                )
            );

            // Send PLS to Liquidity Receiver
            if (sv.amountPlsLiquidity > 0) {
                (bool success,) = payable(autoLiquidityReceiver).call{
                    value: sv.amountPlsLiquidity
                }("");
                success;
                totalPlsLpAdded = totalPlsLpAdded.add(sv.amountPlsLiquidity);
            }

            // Distribute reflections
            if (sv.amountPlsReflection > 0) {
                try
                    distributor.depositForPlsReflection{
                        value: sv.amountPlsReflection
                    }()
                {} catch {}
            }
            if (sv.amountSolidXReflection > 0) {
                try
                    distributor.depositForReflection{
                        value: sv.amountSolidXReflection
                    }(address(SOLIDX))
                {} catch {}
            }
            if (sv.amountEhexReflection > 0) {
                try
                    distributor.depositForReflection{
                        value: sv.amountEhexReflection
                    }(address(EHEX))
                {} catch {}
            }
            if (sv.amountPhexReflection > 0) {
                try
                    distributor.depositForReflection{
                        value: sv.amountPhexReflection
                    }(address(PHEX))
                {} catch {}
            }
            if (sv.amountGelatoReflection > 0) {
                try
                    distributor.depositForReflection{
                        value: sv.amountGelatoReflection
                    }(address(GELATO))
                {} catch {}
            }
            if (sv.amountPlsxReflection > 0) {
                try
                    distributor.depositForReflection{
                        value: sv.amountPlsxReflection
                    }(address(PLSX))
                {} catch {}
            }
            if (sv.amountIncReflection > 0) {
                try
                    distributor.depositForReflection{
                        value: sv.amountIncReflection
                    }(address(INC))
                {} catch {}
            }
            if (sv.amountSolidXBurn > 0) {
                try
                    distributor.depositForSolidXBurn{
                        value: sv.amountSolidXBurn
                    }()
                {} catch {}
            }
            if (sv.amountGelatoBurn > 0) {
                try
                    distributor.depositForGelatoBurn{
                        value: sv.amountGelatoBurn
                    }()
                {} catch {}
            }

            // If any dust remains in the contract, send it to the owner
            if (address(this).balance > 0) {
                (bool success,) = payable(owner()).call{value: address(this).balance, gas: 30000}(
                    ""
                );
                success;
            }

            emit SwapBackSuccess(sv.amountRhinoSwap);
        } catch Error(string memory e) {
            emit SwapBackFailed(
                string(abi.encodePacked("SwapBack failed with error ", e))
            );
        } catch {
            emit SwapBackFailed(
                "SwapBack failed without an error message from PulseX"
            );
        }
    }
    function launch() external onlyOwner {
        require(launchedAt == 0, "Already launched.");
        launchedAt = block.timestamp;

        try distributor.setShare(address(rhinoCharging), _balances[address(rhinoCharging)]) {} catch {}
        try distributor.setShare(address(owner()), _balances[address(owner())]) {} catch {}
        emit Launched(block.number, block.timestamp);
    }

    function setChargingContract(address chargingContract) external onlyOwner {
        require(chargingContract != address(0), "Invalid address");
        rhinoCharging = RhinoCharging(payable(chargingContract));
        isFeeExempt[address(rhinoCharging)] = true;
        isTxLimitExempt[address(rhinoCharging)] = true;
        isFeeExempt[address(rhinoCharging.rhinoBuyAndBurn())] = true;
        isTxLimitExempt[address(rhinoCharging.rhinoBuyAndBurn())] = true;
        emit ParameterUpdated();
    }

    function setTxLimit(uint256 amount) external onlyOwner {
        require(amount >= _totalSupply / 2000);
        maxTxAmount = amount;
    }

    function setIsDividendExempt(
        address holder,
        bool exempt
    ) external onlyOwner {
        require(holder != address(this) && holder != pulseV2Pair);
        isDividendExempt[holder] = exempt;
        if (exempt) {
            distributor.setShare(holder, 0);
        } else {
            distributor.setShare(holder, _balances[holder]);
        }
    }

    function setIsFeeExempt(address holder, bool exempt) external onlyOwner {
        isFeeExempt[holder] = exempt;
    }

    function setIsTxLimitExempt(
        address holder,
        bool exempt
    ) external onlyOwner {
        isTxLimitExempt[holder] = exempt;
    }

    function setFeeParameters(
        uint256 _baseBuyFee,
        uint256 _baseSellFee,
        uint256 _minBuyFee,
        uint256 _minSellFee,
        uint256 _feeDecayTime
    ) external onlyOwner {
        require(_baseBuyFee >= _minBuyFee, "Buy fee must be >= minimum");
        require(_baseSellFee >= _minSellFee, "Sell fee must be >= minimum");
        require(_feeDecayTime > 0, "Decay time must be positive");
        require(_baseBuyFee <= 2500, "25 Percent max allowed.");
        require(_baseSellFee <= 2500, "25 Percent max allowed.");

        baseBuyFee = _baseBuyFee;
        baseSellFee = _baseSellFee;
        minBuyFee = _minBuyFee;
        minSellFee = _minSellFee;
        feeDecayTime = _feeDecayTime;

        emit FeeParametersUpdated(
            _baseBuyFee,
            _baseSellFee,
            _minBuyFee,
            _minSellFee,
            _feeDecayTime
        );
    }

    function setFeeDistribution(
        uint256[13] calldata feeParams
    ) external onlyOwner {
        uint256 totalFee;
        for (uint256 i = 0; i < feeParams.length; i++) {
            totalFee = totalFee.add(feeParams[i]);
        }
        require(
            totalFee == feeDenominator,
            "Total fees must equal feeDenominator"
        );

        rhinoBurnFee = feeParams[0];
        gelatoBurnFee = feeParams[1];
        solidXBurnFee = feeParams[2];
        genesisFee = feeParams[3];
        plsReflectionFee = feeParams[4];
        rhinoReflectionFee = feeParams[5];
        solidXReflectionFee = feeParams[6];
        eHexReflectionFee = feeParams[7];
        pHexReflectionFee = feeParams[8];
        gelatoReflectionFee = feeParams[9];
        plsxReflectionFee = feeParams[10];
        incReflectionFee = feeParams[11];
        liquidityFee = feeParams[12];

        emit FeeDistributionUpdated(
            feeParams[0],
            feeParams[1],
            feeParams[2],
            feeParams[3],
            feeParams[4],
            feeParams[5],
            feeParams[6],
            feeParams[7],
            feeParams[8],
            feeParams[9],
            feeParams[10],
            feeParams[11],
            feeParams[12]
        );
    }

    function setLpRewardsPercent(
        uint256 newLpReflectionPercent
    ) external onlyOwner {
        lpReflectionPercent = newLpReflectionPercent;
        require(
            lpReflectionPercent <= 5000,
            "No more than 50 percent can be directed to LP providers."
        );
    }

    function setLiquidityFeeReceiver(
        address _autoLiquidityReceiver
    ) external onlyOwner {
        autoLiquidityReceiver = _autoLiquidityReceiver;

        emit ParameterUpdated();
    }

    function setDistributor(address _newDistributor) external onlyOwner {
        require(_newDistributor != address(0), "Invalid address");
        distributor = DividendDistributor(payable(_newDistributor));

        isFeeExempt[address(distributor)] = true;
        isTxLimitExempt[address(distributor)] = true;
        isDividendExempt[address(distributor)] = true;

        _allowances[address(this)][address(distributor)] = type(uint256).max;

        emit ParameterUpdated();
    }

    function setGenesisReceiver(address _newGenesis) external onlyOwner {
        genesisReceiver = _newGenesis;

        emit ParameterUpdated();
    }

    function setSwapBackSettings(
        bool _enabled,
        uint256 _amount
    ) external onlyOwner {
        swapEnabled = _enabled;
        swapThreshold = _amount;

        require(swapThreshold > 0, "Must be greater than zero.");

        emit ParameterUpdated();
    }

    function setDistributionCriteria(
        address token,
        uint256 minPeriod,
        uint256 minDistribution
    ) external onlyOwner {
        distributor.setDistributionCriteria(token, minPeriod, minDistribution);

        emit ParameterUpdated();
    }

    function setDistributorSettings(uint256 gas) external onlyOwner {
        distributorGas = gas;
        require(distributorGas <= 1000000, "Max gas is 1000000");

        emit ParameterUpdated();
    }

    function getCirculatingSupply() public view returns (uint256) {
        return _totalSupply.sub(balanceOf(DEAD)).sub(balanceOf(ZERO));
    }

    function claimDividend() external nonReentrant {
        distributor.claimDividend(msg.sender);
    }

    function claimLpDividend() external nonReentrant {
        distributor.claimLpDividend(msg.sender);
    }

    function getPairs() public view returns (address[] memory) {
        return pairs;
    }

    function setEmergencyMode(bool mode) public onlyOwner {
        emergencyMode = mode;

        emit ParameterUpdated();
    }

    function addPair(address pair, address router) external onlyOwner {
        require(isPair[pair] == false, "Pair already added.");
        require(
            router == address(pulseRouterV1) ||
                router == address(pulseRouterV2) ||
                router == address(nineinchRouter),
            "Invalid router"
        );
        pairs.push(pair);
        isPair[pair] = true;
        routerByPair[pair] = router;
        isDividendExempt[pair] = true;
        distributor.setShare(pair, 0);

        emit ParameterUpdated();
    }

    function removePair(address pair) external onlyOwner {
        require(isPair[pair], "Pair does not exist");

        uint256 indexToRemove;
        bool found = false;
        for (uint256 i = 0; i < pairs.length; i++) {
            if (pairs[i] == pair) {
                indexToRemove = i;
                found = true;
                break;
            }
        }
        require(found, "Pair not found in array");

        pairs[indexToRemove] = pairs[pairs.length - 1];
        routerByPair[pair] = address(0);
        pairs.pop();
        isPair[pair] = false;

        emit ParameterUpdated();
    }

    event AutoLiquify(uint256 amountWPLS, uint256 amountRhino);
    event Launched(uint256 blockNumber, uint256 timestamp);
    event ParameterUpdated();
    event SwapBackSuccess(uint256 amount);
    event SwapBackFailed(string message);
    event LiquidityAdded(
        address indexed user,
        uint256 amountRhino,
        uint256 amountOther,
        uint256 lpAmount
    );
    event LiquidityRemoved(
        address indexed user,
        uint256 amountRhino,
        uint256 amountOther,
        uint256 lpAmount
    );
    event FeeParametersUpdated(
        uint256 baseBuyFee,
        uint256 baseSellFee,
        uint256 minBuyFee,
        uint256 minSellFee,
        uint256 feeDecayTime
    );
    event FeeDistributionUpdated(
        uint256 rhinoBurnPercent,
        uint256 gelatoBurnPercent,
        uint256 solidXBurnPercent,
        uint256 genesisPercent,
        uint256 plsReflectionPercent,
        uint256 rhinoReflectionPercent,
        uint256 solidXReflectionPercent,
        uint256 eHexReflectionPercent,
        uint256 pHexReflectionPercent,
        uint256 gelatoReflectionPercent,
        uint256 plsxReflectionPercent,
        uint256 incReflectionPercent,
        uint256 liquidityPercent
    );
}
        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Address.sol)

pragma solidity ^0.8.20;

import {Errors} from "./Errors.sol";

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert Errors.InsufficientBalance(address(this).balance, amount);
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert Errors.FailedCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {Errors.FailedCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert Errors.InsufficientBalance(address(this).balance, value);
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {Errors.FailedCall}) in case
     * of an unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {Errors.FailedCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {Errors.FailedCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            assembly ("memory-safe") {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert Errors.FailedCall();
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../token/ERC20/IERC20.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../utils/introspection/IERC165.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Errors.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of common custom errors used in multiple contracts
 *
 * IMPORTANT: Backwards compatibility is not guaranteed in future versions of the library.
 * It is recommended to avoid relying on the error API for critical functionality.
 *
 * _Available since v5.1._
 */
library Errors {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error InsufficientBalance(uint256 balance, uint256 needed);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedCall();

    /**
     * @dev The deployment failed.
     */
    error FailedDeployment();

    /**
     * @dev A necessary precompile is missing.
     */
    error MissingPrecompile(address);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
          

pragma solidity >=0.5.0;

interface IUniswapV2Factory {
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);

    function feeTo() external view returns (address);
    function feeToSetter() external view returns (address);

    function getPair(address tokenA, address tokenB) external view returns (address pair);
    function allPairs(uint) external view returns (address pair);
    function allPairsLength() external view returns (uint);

    function createPair(address tokenA, address tokenB) external returns (address pair);

    function setFeeTo(address) external;
    function setFeeToSetter(address) external;
}
          

pragma solidity >=0.5.0;

interface IUniswapV2Pair {
    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    function name() external pure returns (string memory);
    function symbol() external pure returns (string memory);
    function decimals() external pure returns (uint8);
    function totalSupply() external view returns (uint);
    function balanceOf(address owner) external view returns (uint);
    function allowance(address owner, address spender) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);
    function transfer(address to, uint value) external returns (bool);
    function transferFrom(address from, address to, uint value) external returns (bool);

    function DOMAIN_SEPARATOR() external view returns (bytes32);
    function PERMIT_TYPEHASH() external pure returns (bytes32);
    function nonces(address owner) external view returns (uint);

    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external;

    event Mint(address indexed sender, uint amount0, uint amount1);
    event Burn(address indexed sender, uint amount0, uint amount1, address indexed to);
    event Swap(
        address indexed sender,
        uint amount0In,
        uint amount1In,
        uint amount0Out,
        uint amount1Out,
        address indexed to
    );
    event Sync(uint112 reserve0, uint112 reserve1);

    function MINIMUM_LIQUIDITY() external pure returns (uint);
    function factory() external view returns (address);
    function token0() external view returns (address);
    function token1() external view returns (address);
    function getReserves() external view returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);
    function price0CumulativeLast() external view returns (uint);
    function price1CumulativeLast() external view returns (uint);
    function kLast() external view returns (uint);

    function mint(address to) external returns (uint liquidity);
    function burn(address to) external returns (uint amount0, uint amount1);
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external;
    function skim(address to) external;
    function sync() external;

    function initialize(address, address) external;
}
          

pragma solidity >=0.6.2;

interface IUniswapV2Router01 {
    function factory() external pure returns (address);
    function WETH() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETH(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountToken, uint amountETH);
    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETHWithPermit(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountToken, uint amountETH);
    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapExactETHForTokens(uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);
    function swapTokensForExactETH(uint amountOut, uint amountInMax, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapExactTokensForETH(uint amountIn, uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapETHForExactTokens(uint amountOut, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);

    function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);
    function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);
    function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
}
          

pragma solidity >=0.6.2;

import './IUniswapV2Router01.sol';

interface IUniswapV2Router02 is IUniswapV2Router01 {
    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountETH);
    function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountETH);

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable;
    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
}
          

// SPDX-License-Identifier: MIT
pragma solidity 0.8.26;

/* === OZ === */
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

/* === UNISWAP V2 === */
import {IUniswapV2Router02} from "@uniswap/v2-periphery/contracts/interfaces/IUniswapV2Router02.sol";

/* === SYSTEM === */
import {RhinoCharging} from "./RhinoCharging.sol";


/**
 * @title RhinoBuyAndBurn Contract
 * @author BuildTheTech.com
 * @notice This contract receives PLS from a charging contract, and at regular intervals,
 * uses an allocated portion of the PLS to buy RHINO tokens and immediately burn them.
 * The process is triggered by any external user, who receives an incentive for doing so.
 */
contract RhinoBuyAndBurn is ReentrancyGuard, Ownable {
    
    /* ================================================================
                         STATE VARIABLES & CONSTANTS
    ================================================================ */  
    RhinoCharging public rhinoCharging;

    // --- Interval Mechanics ---
    struct Interval {
        uint256 amountAllocated;
        uint256 amountProcessed;
    }
    uint256 public startTimeStamp;
    uint256 public lastBurnIntervalNumber;
    uint256 public lastBurnIntervalStartTimestamp;
    mapping(uint256 => Interval) public plsIntervalsBurn;

    // --- Constants & Immutable ---
    IUniswapV2Router02 public immutable pulseXRouterV1 = IUniswapV2Router02(0x98bf93ebf5c380C0e6Ae8e192A7e2AE08edAcc02);
    IUniswapV2Router02 public immutable pulseXRouterV2 = IUniswapV2Router02(0x165C3410fC91EF562C50559f7d2289fEbed552d9);
    IUniswapV2Router02 public immutable nineinchRouter = IUniswapV2Router02(0xeB45a3c4aedd0F47F345fB4c8A1802BB5740d725);

    address public immutable WPLS;
    address public immutable RHINO;
    address private constant ZERO = 0x000000000000000000000000000000000000dEaD;
    
    uint256 public constant incentiveFeeBps = 150;
    uint256 public constant intervalTime = 30 minutes;

    // --- Configurable Settings ---
    uint256 public dailyAllocationBps;

    // --- Balances and Totals ---
    uint256 public totalPlsForBurning;
    uint256 public totalRhinoBurned;

    /* ================================================================
                                     EVENTS
    ================================================================ */

    event PlsReceived(address indexed from, uint256 amount);
    event BuyAndBurn(
        uint256 plsUsedForSwap,
        uint256 rhinoBurned,
        uint256 incentivePaid,
        address indexed caller
    );
    event SettingsUpdated(string setting, uint256 newValue);


    /* ================================================================
                                     ERRORS
    ================================================================ */

    error NotStartedYet();
    error IntervalAlreadyProcessed();
    error InvalidSetting();
    error NoAllocationAvailable();
    error InvalidInput();

    /* ================================================================
                                   MODIFIERS
    ================================================================ */

    modifier intervalUpdate() {
        _intervalUpdatePlsForBurning();
        _;
    }

    /* ================================================================
                                  CONSTRUCTOR
    ================================================================ */

    constructor(
        address _initialOwner,
        uint32 _startTimestamp,
        address _rhinoAddress,
        address _wplsAddress
    ) Ownable(_initialOwner) {
        require(_rhinoAddress != address(0) && _wplsAddress != address(0), "Invalid token address");

        startTimeStamp = _startTimestamp;
        RHINO = _rhinoAddress;
        WPLS = _wplsAddress;
        rhinoCharging = RhinoCharging(payable(msg.sender));

        dailyAllocationBps = 100;
        lastBurnIntervalStartTimestamp = _startTimestamp;

        IERC20(WPLS).approve(address(pulseXRouterV1), type(uint256).max);
        IERC20(WPLS).approve(address(pulseXRouterV2), type(uint256).max);
        IERC20(WPLS).approve(address(nineinchRouter), type(uint256).max);
        IERC20(RHINO).approve(address(rhinoCharging), type(uint256).max);
    }


    /* ================================================================
                                 CORE LOGIC
    ================================================================ */

    receive() external payable {
        if (
            block.timestamp > startTimeStamp &&
            block.timestamp - lastBurnIntervalStartTimestamp >
            intervalTime
        ) {
            _intervalUpdatePlsForBurning();
        }

        totalPlsForBurning += msg.value;
        emit PlsReceived(msg.sender, msg.value);
    }

    function distributePLSForBurning() external payable {
        if (msg.value == 0) revert InvalidInput();

        if (
            block.timestamp > startTimeStamp &&
            block.timestamp - lastBurnIntervalStartTimestamp >
            intervalTime
        ) {
            _intervalUpdatePlsForBurning();
        }

        totalPlsForBurning += msg.value;
        emit PlsReceived(msg.sender, msg.value);
    }

    function buyAndBurn(uint256 _deadline) external nonReentrant intervalUpdate {
        Interval storage currentInterval = plsIntervalsBurn[lastBurnIntervalNumber];
        if (currentInterval.amountProcessed != 0) revert IntervalAlreadyProcessed();

        uint256 plsToProcess = currentInterval.amountAllocated;
        if (plsToProcess == 0) revert NoAllocationAvailable();
    
        currentInterval.amountProcessed = currentInterval.amountAllocated;

        uint256 incentiveAmount = (plsToProcess * incentiveFeeBps) / 10_000;
        uint256 plsToSwap = plsToProcess - incentiveAmount;

        uint256 rhinoBought = _swapPlsForRhino(plsToSwap, _deadline);
        uint256 halfRhino = rhinoBought / 2;
        if (rhinoBought > 0) {
            _burnRhino(halfRhino);
            rhinoCharging.depositRhinoFromBurn(rhinoBought - halfRhino);
        }

        totalPlsForBurning -= plsToProcess;
        totalRhinoBurned += rhinoBought;

        if (incentiveAmount > 0) {
            (bool success, ) = msg.sender.call{value: incentiveAmount}("");
            require(success, "Incentive payment failed");
        }

        try rhinoCharging.triggerSwap(block.timestamp) {} catch {}

        emit BuyAndBurn(plsToSwap, rhinoBought, incentiveAmount, msg.sender);
    }
    
    /* ================================================================
                              INTERNAL FUNCTIONS
    ================================================================ */

    function _intervalUpdatePlsForBurning() internal {
        if (block.timestamp < startTimeStamp) revert NotStartedYet();

        uint256 timeElapsed = block.timestamp - lastBurnIntervalStartTimestamp;
        if (timeElapsed < intervalTime) return;

        uint256 intervals_per_day = (24 hours) / intervalTime;
        
        uint256 missedIntervals = (timeElapsed / intervalTime) - 1;

        uint256 dailyAllocation = (totalPlsForBurning * dailyAllocationBps) / 10_000;
        uint256 amountPerInterval = dailyAllocation / intervals_per_day;
        
        uint256 totalAmountForInterval = amountPerInterval * (missedIntervals + 1);

        if (totalAmountForInterval > totalPlsForBurning) {
            totalAmountForInterval = uint256(totalPlsForBurning);
        }

        uint256 newIntervalNumber = lastBurnIntervalNumber + missedIntervals + 1;
        
        plsIntervalsBurn[newIntervalNumber] = Interval({
            amountAllocated: totalAmountForInterval,
            amountProcessed: 0
        });

        lastBurnIntervalNumber = newIntervalNumber;
        lastBurnIntervalStartTimestamp = lastBurnIntervalStartTimestamp + ((missedIntervals + 1) * uint32(intervalTime));
    }

    function _swapPlsForRhino(uint256 _plsAmount, uint256 _deadline) internal returns (uint256) {
        if (_plsAmount == 0) return 0;

        address[] memory path = new address[](2);
        path[0] = WPLS;
        path[1] = RHINO;

        address bestRouter = getBestRouter(_plsAmount, path);
        if (bestRouter == address(0)) return 0;

        uint[] memory amounts = IUniswapV2Router02(bestRouter).swapExactETHForTokens{value: _plsAmount}(
            0,
            path,
            address(this),
            _deadline
        );

        return amounts[1];
    }
    
    function _burnRhino(uint256 _rhinoAmount) internal {
        IERC20(RHINO).transfer(ZERO, _rhinoAmount);
    }
    
    /* ================================================================
                             OWNER FUNCTIONS
    ================================================================ */
    
    function setDailyAllocationBps(uint256 _newAllocationBps) external onlyOwner {
        if (_newAllocationBps > 2_500) revert InvalidSetting();
        dailyAllocationBps = _newAllocationBps;
        emit SettingsUpdated("DailyAllocationBps", _newAllocationBps);
    }

    function setChargingContract(address _newChargingContract) external onlyOwner {
        if (_newChargingContract == address(0)) revert InvalidSetting();
        rhinoCharging = RhinoCharging(payable(_newChargingContract));
        emit SettingsUpdated("ChargingContract", uint256(uint160(_newChargingContract)));
    }

    function withdrawTokens(address _token, address _to) external onlyOwner {
        require(_token != RHINO, "Cannot withdraw Rhino tokens");
        uint256 balance = IERC20(_token).balanceOf(address(this));
        require(balance > 0, "No tokens to withdraw");
        IERC20(_token).transfer(_to, balance);
    }

    /* ================================================================
                                VIEW FUNCTIONS
    ================================================================ */

    function getBestRouter(
        uint256 amountIn,
        address[] memory path
    ) public view returns (address bestRouter) {
        address[] memory routers = new address[](3);
        routers[0] = address(pulseXRouterV1);
        routers[1] = address(pulseXRouterV2);
        routers[2] = address(nineinchRouter);

        uint256 bestAmountOut = 0;

        for (uint256 i = 0; i < routers.length; i++) {
            try
                IUniswapV2Router02(routers[i]).getAmountsOut(amountIn, path)
            returns (uint256[] memory amountsOut) {
                uint256 amountOut = amountsOut[amountsOut.length - 1];
                if (amountOut > bestAmountOut) {
                    bestAmountOut = amountOut;
                    bestRouter = routers[i];
                }
            } catch {
                continue;
            }
        }
    }
}
          

// SPDX-License-Identifier: MIT
pragma solidity 0.8.26;

/* === OZ === */
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

/* === UNISWAP V2 === */
import {IUniswapV2Router02} from "@uniswap/v2-periphery/contracts/interfaces/IUniswapV2Router02.sol";

/* === SYSTEM === */
import {RhinoBuyAndBurn} from "./RhinoBuyAndBurn.sol";

interface IMasterChef {
    function deposit(uint256 _pid, uint256 _amount) external;
    function withdraw(uint256 _pid, uint256 _amount) external;
    function userInfo(uint256 _pid, address _user) external view returns (uint256 amount, uint256 rewardDebt);
}

interface IWPLS is IERC20 {
    function deposit() external payable;
    function withdraw(uint wad) external;
}

interface IGelato {
    function _maxTxAmount() external view returns (uint256);
}

/**
 * @title Rhino Charging
 * @author BuildTheTech.com
 * @notice This contract automates the process of collecting token reflections, swapping them to PLS,
 * and deploying the capital into a PulseX yield farm (DAI/WPLS). It operates in adjustable "Charging Cycles."
 */
contract RhinoCharging is Ownable, ReentrancyGuard {
    using SafeERC20 for IERC20;

    struct CycleData {
        uint256 cycle;
        uint256 rhinoBurned;
        uint256 plsEarned;
    }

    uint256 public farmStopPercentage = 50;

    uint256 public currentCycleNumber = 1;
    uint256 public chargingCycleDuration = 28 days;
    uint256 public nextChargingCycleDuration = 28 days;
    uint256 public lastCycleEndTime;
    RhinoBuyAndBurn public rhinoBuyAndBurn;
    uint256 public rhinoChargingBalance;
    uint256 public rhinoChargingBalanceAtCycleStart;
    uint256 public slippageBps;

    uint256 public totalRhinoBurned;
    bool public swapping;
    bool cycleEnding;
    bool inFarming;

    IUniswapV2Router02 public immutable pulseXRouterV1 = IUniswapV2Router02(0x98bf93ebf5c380C0e6Ae8e192A7e2AE08edAcc02);
    IUniswapV2Router02 public immutable pulseXRouterV2 = IUniswapV2Router02(0x165C3410fC91EF562C50559f7d2289fEbed552d9);
    IUniswapV2Router02 public immutable nineinchRouter = IUniswapV2Router02(0xeB45a3c4aedd0F47F345fB4c8A1802BB5740d725);
    IMasterChef public immutable pulseXMasterChef = IMasterChef(0xB2Ca4A66d3e57a5a9A12043B6bAD28249fE302d4);
    uint256 public constant DAI_WPLS_PID = 1;
    uint256 public plsFarmThreshold = 1_000_000e18;

    address public immutable WPLS = 0xA1077a294dDE1B09bB078844df40758a5D0f9a27;
    address public immutable DAI = 0xefD766cCb38EaF1dfd701853BFCe31359239F305;
    address public immutable WPLS_DAI_LP = 0xE56043671df55dE5CDf8459710433C10324DE0aE;

    address immutable ZERO = 0x0000000000000000000000000000000000000000;
    address immutable SOLIDX = 0x8Da17Db850315A34532108f0f5458fc0401525f6;
    address immutable GELATO = 0x616cb6a245Ed4c11216Ec58D10B6A2E87271845d;
    address immutable EHEX = 0x57fde0a71132198BBeC939B98976993d8D89D225;
    address immutable PHEX = 0x2b591e99afE9f32eAA6214f7B7629768c40Eeb39;
    address immutable PLSX = 0x95B303987A60C71504D99Aa1b13B4DA07b0790ab;
    address immutable INC = 0x2fa878Ab3F87CC1C9737Fc071108F904c0B0C95d;
    address immutable RHINO;

    address[] public rewardTokens;
    mapping(address => bool) public approvedRewardTokens;
    mapping(address => uint256) public swapThresholds;
    mapping(address => uint256) public failedSwapAmounts;
    mapping(uint256 => CycleData) public cycleData;
    mapping(uint256 => uint256) public estimatedPlsEarnedThisCycle;

    event TokensSwapped(address indexed token, uint256 amountIn);
    event SwapFailed(address indexed token, uint256 amount);
    event RhinoBurnedOnPerformance(uint256 amount);
    event Farmed(uint256 lpAmount);
    event CycleEnded(uint256 indexed cycleNumber, uint256 plsForwarded, uint256 rhinoBurned);
    event RescuedTokens(address indexed token, uint256 amount);
    event RescuedPLS(uint256 amount);

    modifier inSwap() {
        swapping = true;
        _;
        swapping = false;
    }

    modifier endingCycle() {
        cycleEnding = true;
        _;
        cycleEnding = false;
    }

    modifier farming() {
        inFarming = true;
        _;
        inFarming = false;
    }

    constructor(
        address _initialOwner,
        uint32 _initialCycleDuration,
        uint32 _initialCycleStartTime,
        address _rhinoAddress
    ) Ownable(_initialOwner) {
        rhinoBuyAndBurn = new RhinoBuyAndBurn(_initialOwner, _initialCycleStartTime + _initialCycleDuration, _rhinoAddress, WPLS);
        chargingCycleDuration = _initialCycleDuration;
        lastCycleEndTime = _initialCycleStartTime;
        cycleData[currentCycleNumber] = CycleData({
            cycle: currentCycleNumber,
            rhinoBurned: 0,
            plsEarned: 0
        });

        RHINO = _rhinoAddress;
        slippageBps = 10000;
        
        IERC20(WPLS_DAI_LP).approve(address(pulseXRouterV1), type(uint256).max);
        IERC20(WPLS_DAI_LP).approve(address(pulseXMasterChef), type(uint256).max);
    
        IERC20(WPLS).approve(address(pulseXRouterV1), type(uint256).max);
        IERC20(WPLS).approve(address(pulseXRouterV2), type(uint256).max);
        IERC20(WPLS).approve(address(nineinchRouter), type(uint256).max);
        IERC20(DAI).approve(address(pulseXRouterV1), type(uint256).max);
        IERC20(DAI).approve(address(pulseXRouterV2), type(uint256).max);
        IERC20(DAI).approve(address(nineinchRouter), type(uint256).max);

        _addRewardToken(SOLIDX, 1e18);
        _addRewardToken(GELATO, 200_000e18);
        _addRewardToken(EHEX, 5_000e8);
        _addRewardToken(PHEX, 5_000e8);
        _addRewardToken(PLSX, 500_000e18);
        _addRewardToken(INC, 10e18);
        _addRewardToken(RHINO, 10_000e18);
    }

    receive() external payable {
        if (!cycleEnding && !inFarming) {
            estimatedPlsEarnedThisCycle[currentCycleNumber] += msg.value;
        }
    }

    function depositRhinoFromBurn(uint256 amount) public {
        require(msg.sender == address(rhinoBuyAndBurn), "Only burning contract can deposit RHINO");
        IERC20(RHINO).safeTransferFrom(msg.sender, address(this), amount);
        rhinoChargingBalance += amount;
    }  

    function triggerSwap(uint256 deadline) public {
        if (swapping || cycleEnding) {
            return;
        }
        _triggerSwap(deadline);
    }

    function _triggerSwap(uint256 deadline) internal inSwap {
    uint256 rewardsLength = rewardTokens.length;

    address[] memory path = new address[](2);
    path[1] = WPLS;

    for (uint i = 0; i < rewardsLength; ) {
        address currentToken = rewardTokens[i];
        uint256 balance = IERC20(currentToken).balanceOf(address(this));

        if (currentToken == RHINO) {
            if (balance > rhinoChargingBalance) {
                rhinoChargingBalance = balance;
            }
        } else {
            if (currentToken == GELATO) {
                uint256 maxTx = IGelato(GELATO)._maxTxAmount();
                if (balance > maxTx) {
                    balance = maxTx;
                }
            }
            
            uint256 threshold = swapThresholds[currentToken]; 

            if (balance > threshold) {
                path[0] = currentToken;

                IUniswapV2Router02 router = IUniswapV2Router02(getBestRouter(balance, path));

                if (address(router) != address(0)) {
                    try router.swapExactTokensForETHSupportingFeeOnTransferTokens(
                        balance, 0, path, address(this), deadline
                    ) {} catch {}
                    emit TokensSwapped(currentToken, balance);
                }
            }
        }

        unchecked {
            ++i;
        }
    }

    if (address(this).balance >= plsFarmThreshold && block.timestamp < lastCycleEndTime + ((chargingCycleDuration * farmStopPercentage) / 100) && !cycleEnding && !inFarming) {
        addLiquidityAndFarm(deadline);
    }

    if (block.timestamp >= lastCycleEndTime + chargingCycleDuration && !cycleEnding) {
        endChargingCycle();
    }
}
    
    function addLiquidityAndFarm(uint256 deadline) internal farming {
        uint256 plsBalance = address(this).balance;
        if (plsBalance == 0) return;

        uint256 amountToSwapForDai = plsBalance / 2;
        address[] memory path = new address[](2);
        path[0] = WPLS;
        path[1] = DAI;

        IUniswapV2Router02 router = IUniswapV2Router02(getBestRouter(amountToSwapForDai, path));
        if (address(router) == address(0)) return;

        uint amountOutMin = _getMinAmountOut(router, amountToSwapForDai, path);

        try router.swapExactETHForTokens{value: amountToSwapForDai}(amountOutMin, path, address(this), deadline) {
            uint256 remainingPls = address(this).balance;
            if(remainingPls > 0) {
                IWPLS(WPLS).deposit{value: remainingPls}();
            }

            uint256 daiBalance = IERC20(DAI).balanceOf(address(this));
            uint256 wplsBalance = IWPLS(WPLS).balanceOf(address(this));
            
            if(daiBalance > 0 && wplsBalance > 0) {
                (, , uint liquidity) = pulseXRouterV1.addLiquidity(
                    DAI, WPLS, daiBalance, wplsBalance, 0, 0, address(this), deadline
                );
                pulseXMasterChef.deposit(DAI_WPLS_PID, liquidity);
                emit Farmed(liquidity);
            }
        } catch {}
    }

    function endChargingCycle() internal endingCycle {
        (uint256 lpTokenAmount, ) = pulseXMasterChef.userInfo(DAI_WPLS_PID, address(this));
        if (lpTokenAmount > 0) {
            pulseXMasterChef.withdraw(DAI_WPLS_PID, lpTokenAmount);
        }

        uint256 lpBalance = IERC20(WPLS_DAI_LP).balanceOf(address(this));
        if (lpBalance > 0) {
            pulseXRouterV1.removeLiquidity(
                DAI, WPLS, lpBalance, 0, 0, address(this), block.timestamp
            );
        }
        
        uint256 wplsBalance = IWPLS(WPLS).balanceOf(address(this));
        if(wplsBalance > 0) {
            IWPLS(WPLS).withdraw(wplsBalance);
        }

        uint256 daiBalance = IERC20(DAI).balanceOf(address(this));
        if(daiBalance > 0) {
            address[] memory path = new address[](2);
            path[0] = DAI;
            path[1] = WPLS;

            uint amountOutMin = _getMinAmountOut(pulseXRouterV1, daiBalance, path);
            try pulseXRouterV1.swapExactTokensForETH(daiBalance, amountOutMin, path, address(this), block.timestamp) {} catch {}
        }

        uint256 incBalance = IERC20(INC).balanceOf(address(this));
        if (incBalance > 0) {
            address[] memory path = new address[](2);
            path[0] = INC;
            path[1] = WPLS;

            uint256 amountOutMin = _getMinAmountOut(pulseXRouterV1, incBalance, path);
            try pulseXRouterV1.swapExactTokensForETH(incBalance, amountOutMin, path, address(this), block.timestamp) {} catch {}
        }

        uint256 totalPlsEarnedThisCycle = address(this).balance;
        
        uint256 rhinoToBurn = _calculatePerformanceBurn(totalPlsEarnedThisCycle, rhinoChargingBalanceAtCycleStart);

        if (rhinoToBurn > 0) {
            _burnRhino(rhinoToBurn);
            rhinoChargingBalance -= rhinoToBurn;
            totalRhinoBurned += rhinoToBurn;
            
            emit RhinoBurnedOnPerformance(rhinoToBurn);
        }

        cycleData[currentCycleNumber] = CycleData({
            cycle: currentCycleNumber,
            rhinoBurned: rhinoToBurn,
            plsEarned: totalPlsEarnedThisCycle
        });

        if(totalPlsEarnedThisCycle > 0) {
            try rhinoBuyAndBurn.distributePLSForBurning{value: totalPlsEarnedThisCycle}() {} catch {}
        }
        emit CycleEnded(currentCycleNumber, totalPlsEarnedThisCycle, rhinoToBurn);

        lastCycleEndTime = lastCycleEndTime + chargingCycleDuration;

        if (nextChargingCycleDuration > 0) {
            chargingCycleDuration = nextChargingCycleDuration;
        }

        rhinoChargingBalanceAtCycleStart = rhinoChargingBalance;
        currentCycleNumber++;

        cycleData[currentCycleNumber] = CycleData({
            cycle: currentCycleNumber,
            rhinoBurned: 0,
            plsEarned: 0
        });
        
        estimatedPlsEarnedThisCycle[currentCycleNumber] = address(this).balance;
    }

    function _calculatePerformanceBurn(uint256 totalPlsEarned, uint256 currentRhinoBalance) internal view returns (uint256) {
        if (totalPlsEarned >= rhinoChargingBalanceAtCycleStart) {
            return 0;
        }

        uint256 shortfall = rhinoChargingBalanceAtCycleStart - totalPlsEarned;
        uint256 maxBurnAmount = (currentRhinoBalance * 10) / 100;

        if (shortfall < maxBurnAmount) {
            return shortfall;
        } else {
            return maxBurnAmount;
        }
    }

    function _burnRhino(uint256 amount) internal {
        require(IERC20(RHINO).balanceOf(address(this)) >= amount, "Insufficient RHINO balance");
        IERC20(RHINO).transfer(ZERO, amount);
    }

    function _getMinAmountOut(IUniswapV2Router02 router, uint256 amountIn, address[] memory path) internal view returns (uint256) {
        try router.getAmountsOut(amountIn, path) returns (uint[] memory amounts) {
            return (amounts[amounts.length - 1] * (10_000 - slippageBps)) / 10_000;
        } catch {
            return 0;
        }
    }

    function setNextChargingCycleDuration(uint256 newDurationInDays) external onlyOwner {
        require(newDurationInDays >= 7 && newDurationInDays <= 60, "Duration must be between 7 and 60 days");
        nextChargingCycleDuration = newDurationInDays * 1 days;
    }

    function setFarmStopPercentage(uint256 newPercentage) external onlyOwner {
        require(newPercentage >= 0 && newPercentage <= 100, "Percentage must be between 0 and 100");
        farmStopPercentage = newPercentage;
    }

    function setBuyAndBurnContract(address newBurningContract) external onlyOwner {
        require(newBurningContract != address(0), "Cannot be zero address");
        rhinoBuyAndBurn = RhinoBuyAndBurn(payable(newBurningContract));
    }

    function setSlippageBps(uint256 _newSlippageBps) external onlyOwner {
        require(_newSlippageBps >= 200 && _newSlippageBps <= 10000, "Slippage must be between 2% and 100%");
        slippageBps = _newSlippageBps;
    }

    function overrideRhinoChargingBalanceAtCycleStart(uint256 newBalance) external onlyOwner {
        require(newBalance <= rhinoChargingBalance, "New balance cannot exceed current charging balance");
        rhinoChargingBalanceAtCycleStart = newBalance;
    }

    function _addRewardToken(address tokenAddress, uint256 threshold) internal {
        approvedRewardTokens[tokenAddress] = true;
        swapThresholds[tokenAddress] = threshold;
        rewardTokens.push(tokenAddress);

        IERC20(tokenAddress).approve(address(pulseXRouterV1), type(uint256).max);
        IERC20(tokenAddress).approve(address(pulseXRouterV2), type(uint256).max);
        IERC20(tokenAddress).approve(address(nineinchRouter), type(uint256).max);
    }

    function removeRewardToken(address tokenAddress) external onlyOwner {
        require(approvedRewardTokens[tokenAddress], "Token not approved");
        
        approvedRewardTokens[tokenAddress] = false;
        if (failedSwapAmounts[tokenAddress] > 0) {
            failedSwapAmounts[tokenAddress] = 0;
        }

        for (uint i = 0; i < rewardTokens.length; i++) {
            if (rewardTokens[i] == tokenAddress) {
                rewardTokens[i] = rewardTokens[rewardTokens.length - 1];
                rewardTokens.pop();
                break;
            }
        }
    }

    function setSwapThreshold(address tokenAddress, uint256 threshold) external onlyOwner {
        require(approvedRewardTokens[tokenAddress], "Token not approved");
        swapThresholds[tokenAddress] = threshold;
    }

    function setFarmPlsThreshold(uint256 newThreshold) external onlyOwner {
        require(newThreshold <= 100_000_000e18, "Threshold cannot be too high");
        plsFarmThreshold = newThreshold;
    }

    function depositRhino(uint256 amount) public nonReentrant onlyOwner {
        rhinoChargingBalance += amount;
        IERC20(RHINO).safeTransferFrom(msg.sender, address(this), amount);
        if (rhinoChargingBalanceAtCycleStart == 0) {
            rhinoChargingBalanceAtCycleStart = rhinoChargingBalance;
        }
    }

    function withdrawRhino(uint256 amount) public onlyOwner {
        IERC20(RHINO).safeTransfer(msg.sender, amount);
        if (amount <= rhinoChargingBalance) {
            rhinoChargingBalance -= amount;
        } else {
            rhinoChargingBalance = 0;
        }

        if (amount <= rhinoChargingBalanceAtCycleStart) {
            rhinoChargingBalanceAtCycleStart -= amount;
        } else {
            rhinoChargingBalanceAtCycleStart = 0;
        }
    }

    function getBestRouter(
        uint256 amountIn,
        address[] memory path
    ) public view returns (address bestRouter) {
        address[] memory routers = new address[](3);
        routers[0] = address(pulseXRouterV1);
        routers[1] = address(pulseXRouterV2);
        routers[2] = address(nineinchRouter);

        uint256 bestAmountOut = 0;

        for (uint256 i = 0; i < routers.length; i++) {
            try
                IUniswapV2Router02(routers[i]).getAmountsOut(amountIn, path)
            returns (uint256[] memory amountsOut) {
                uint256 amountOut = amountsOut[amountsOut.length - 1];
                if (amountOut > bestAmountOut) {
                    bestAmountOut = amountOut;
                    bestRouter = routers[i];
                }
            } catch {
                continue;
            }
        }
    }
}