Contract Address Details

// SPDX-License-Identifier: DrDoge - The first useful meme on PulseChain
// DrDoge is proud of you for not trusting a random JPG on the internet! Always check the code!
pragma solidity 0.8.29;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";

// ------------------------------ WHY NOT WRITE THIS HERE -------------------------------- 
/**
 *      DrDoge Code: The code itself is straightforward, there's only battle tested code.
 *      DrDoge Innovation: The innovation lies in the tokenomics, transparency, honesty, and the attempt to do something good.
 * @dev ERC20 token with block-based minting schedule, enriched events, and janitor-only minting.
 *      This contract supports multiple scheduled minting streams with catch-up logic,
 *      detailed events for off-chain indexing, and strict access control for minting.
 *      Scheduled minting is a timelocking replacement. Less code, less bugs, same risk.
 */
contract DrDoge is ERC20Burnable {
    // ------------------------------ EVENTS --------------------------------

    event MintLiquidityPoolStarting(
        address indexed sender,
        address indexed recipient,
        uint256 amount,
        uint256 blockNumber,
        uint256 timestamp
    );
    event MintJustJanitor(
        address indexed sender,
        address indexed recipient,
        uint256 amount,
        uint256 blockNumber,
        uint256 timestamp
    );
    event MintCureCoinAndFLDCClaim(
        address indexed sender,
        address indexed recipient,
        uint256 amount,
        uint256 periodCount,
        uint256 blockNumber,
        uint256 timestamp
    );
    event MintLiquidityPoolStartingSacrificeReward(
        address indexed sender,
        address indexed recipient,
        uint256 amount,
        uint256 periodCount,
        uint256 blockNumber,
        uint256 timestamp
    );
    event MintLiquidityPoolSacrificeSuccessLock(
        address indexed sender,
        address indexed recipient,
        uint256 amount,
        uint256 periodCount,
        uint256 blockNumber,
        uint256 timestamp
    );
    event MintJustYearlyJanitor(
        address indexed sender,
        address indexed recipient,
        uint256 amount,
        uint256 periodCount,
        uint256 blockNumber,
        uint256 timestamp
    );
    event MintLiquidityPoolCommunitySacrificeLock(
        address indexed sender,
        address indexed recipient,
        uint256 amount,
        uint256 periodCount,
        uint256 blockNumber,
        uint256 timestamp
    );
    event MintLiquidityPoolCommunityBuybackLock(
        address indexed sender,
        address indexed recipient,
        uint256 amount,
        uint256 periodCount,
        uint256 blockNumber,
        uint256 timestamp
    );
    event MintStakingReward(
        address indexed sender,
        address indexed recipient,
        uint256 amount,
        uint256 periodCount,
        uint256 blockNumber,
        uint256 timestamp
    );
    event MintScienceReward(
        address indexed sender,
        address indexed recipient,
        uint256 amount,
        uint256 periodCount,
        uint256 blockNumber,
        uint256 timestamp
    );
    event MintLiquidityPoolStartSuccessLock(
        address indexed sender,
        address indexed recipient,
        uint256 amount,
        uint256 blockNumber,
        uint256 timestamp
    );

    // ------------------------------ RECIPIENT ADDRESSES -----------------------

    address public constant RECIPIENT_LIQUIDITY_POOL_STARTING                  = 0xF46b417245F05Bc24e07c3A4AEd9DdDCC0Ea7760;
    address public constant RECIPIENT_LIQUIDITY_POOL_STARTING_SACRIFICE_REWARD = 0xFFD9c98467c07A07A969AD4d411dc33Fb406a35B;
    address public constant RECIPIENT_LIQUIDITY_POOL_SACRIFICE_SUCCESS_LOCK    = 0x509323819a25A79cE0235f4EA81A35576112968D;
    address public constant RECIPIENT_JUST_YEARLY_JANITOR                      = 0xDb0F954DBcc5BBB95De61A24ea9547F4555bE98b;
    address public constant RECIPIENT_LIQUIDITY_POOL_COMMUNITY_SACRIFICE_LOCK  = 0x5E901fe27F2BA5DFba024CB246F4145b74791A6F;
    address public constant RECIPIENT_LIQUIDITY_POOL_COMMUNITY_BUYBACK_LOCK    = 0x58d3fF89F6C27F8E4aB7EAFEebbF1D34837b852b;
    address public constant RECIPIENT_JUST_JANITOR                             = 0x6421Cf34f193609EBD78b7D6DFc75F9B6F738536;
    address public constant RECIPIENT_CURECOIN_AND_FLDC_CLAIM                  = 0x06cB9263aBaA71C84ECce77D62ff7B4A1ce1B60c;
    address public constant RECIPIENT_STAKING_REWARD                           = 0xA92bA7794429357Ef26341a7300Dd090b68a7F03;
    address public constant RECIPIENT_SCIENCE_REWARD                           = 0x99066Af7FA805FD9F37bf88e99a7C45B87d8e725;
    address public constant RECIPIENT_LIQUIDITY_POOL_START_SUCCESS_LOCK        = 0xd11FF2430A8D87A4be9f3292817565939Bd650A1;

    // ------------------------------ STATE VARIABLES ---------------------------

    address public immutable JustAJanitor;   // Only this address may perform minting

    bool    public mintedLiquidityPoolStarting;
    bool    public mintedJustJanitor;
    bool    public mintedLiquidityPoolStartSuccessLock;

    uint256 public cureCoinAndFLDCClaimCount;
    uint256 public liquidityPoolStartingSacrificeRewardCount;
    uint256 public liquidityPoolSacrificeSuccessLockCount;
    uint256 public justYearlyJanitorCount;
    uint256 public liquidityPoolCommunitySacrificeLockCount;
    uint256 public liquidityPoolCommunityBuybackLockCount;
    uint256 public stakingRewardCount;
    uint256 public scienceRewardCount;

    uint256[22] private scienceRewardByYear;

    uint256 public immutable startBlock;

    // ------------------------------ INTERVAL CONSTANTS ------------------------

    uint256 private constant BLOCKS_PER_MONTH      = 259200;   // ~30d @10s/block
    uint256 private constant BLOCKS_PER_YEAR       = 3153600;  // ~365d
    uint256 private constant MAX_SLOTS_PER_TX      = 3;        // Catch-up limit
    uint256 private constant CLAIM_START_DELAY     = 4 * BLOCKS_PER_MONTH; // 4 months delay
    uint256 private constant ONE_MONTH_DELAY_BLOCKS = BLOCKS_PER_MONTH; // Used where 1 month delay is needed

    // ------------------------------ CONSTRUCTOR ------------------------------

    constructor() ERC20("DrDoge", "DRDOGE") {
        JustAJanitor = msg.sender;
        startBlock   = block.number;
        // Science reward schedule for first 21 years (then flat)
        scienceRewardByYear[1]  = 300_000;
        scienceRewardByYear[2]  = 270_000;
        scienceRewardByYear[3]  = 243_000;
        scienceRewardByYear[4]  = 218_700;
        scienceRewardByYear[5]  = 196_830;
        scienceRewardByYear[6]  = 177_147;
        scienceRewardByYear[7]  = 159_432;
        scienceRewardByYear[8]  = 143_489;
        scienceRewardByYear[9]  = 129_140;
        scienceRewardByYear[10] = 116_226;
        scienceRewardByYear[11] = 104_603;
        scienceRewardByYear[12] = 94_143;
        scienceRewardByYear[13] = 84_729;
        scienceRewardByYear[14] = 76_256;
        scienceRewardByYear[15] = 68_630;
        scienceRewardByYear[16] = 61_767;
        scienceRewardByYear[17] = 55_590;
        scienceRewardByYear[18] = 50_031;
        scienceRewardByYear[19] = 45_028;
        scienceRewardByYear[20] = 49_052;
        scienceRewardByYear[21] = 50_000;
    }

    // ------------------------------ MINT FUNCTIONS ---------------------------

    /**
     * @notice Mint initial liquidity pool starting tokens (one-time)
     */
    function mintLiquidityPoolStarting() external {
        require(msg.sender == JustAJanitor, "Only JustAJanitor can mint");
        require(!mintedLiquidityPoolStarting, "LiquidityPoolStarting already minted");
        mintedLiquidityPoolStarting = true;
        uint256 amount = 3_000_000 * 10**decimals();
        _mint(RECIPIENT_LIQUIDITY_POOL_STARTING, amount);
        emit MintLiquidityPoolStarting(msg.sender, RECIPIENT_LIQUIDITY_POOL_STARTING, amount, block.number, block.timestamp);
    }

    /**
     * @notice Mint one-time janitor tokens (one-time)
     */
    function mintJustJanitor() external {
        require(msg.sender == JustAJanitor, "Only JustAJanitor can mint");
        require(!mintedJustJanitor, "JustJanitor already minted");
        mintedJustJanitor = true;
        uint256 amount = 300_000 * 10**decimals();
        _mint(RECIPIENT_JUST_JANITOR, amount);
        emit MintJustJanitor(msg.sender, RECIPIENT_JUST_JANITOR, amount, block.number, block.timestamp);
    }

    /**
     * @notice Mint monthly CureCoin & FLDC claim tokens (after 4-month delay, up to 6 months)
     */
    function mintCureCoinAndFLDCClaim() external {
        require(msg.sender == JustAJanitor, "Only JustAJanitor can mint");
        require(block.number >= startBlock + CLAIM_START_DELAY, "Claiming not started yet");
        require(cureCoinAndFLDCClaimCount < 6, "Claim minting period completed");

        uint256 monthsElapsed = (block.number - startBlock) / BLOCKS_PER_MONTH;
        uint256 availableSlots = monthsElapsed >= 4 ? monthsElapsed - 4 + 1 : 0;
        require(availableSlots > cureCoinAndFLDCClaimCount, "No monthly slot available");

        uint256 toMint = availableSlots - cureCoinAndFLDCClaimCount;
        if (toMint > MAX_SLOTS_PER_TX) {
            toMint = MAX_SLOTS_PER_TX;
        }
        if (cureCoinAndFLDCClaimCount + toMint > 6) {
            toMint = 6 - cureCoinAndFLDCClaimCount;
        }
        cureCoinAndFLDCClaimCount += toMint;

        uint256 amount = toMint * 333_333 * 10**decimals();
        _mint(RECIPIENT_CURECOIN_AND_FLDC_CLAIM, amount);
        emit MintCureCoinAndFLDCClaim(msg.sender, RECIPIENT_CURECOIN_AND_FLDC_CLAIM, amount, cureCoinAndFLDCClaimCount, block.number, block.timestamp);
    }

    /**
     * @notice Mint monthly liquidity pool starting sacrifice rewards (up to 24 months)
     */
    function mintLiquidityPoolStartingSacrificeReward() external {
        require(msg.sender == JustAJanitor, "Only JustAJanitor can mint");
        require(block.number >= startBlock + ONE_MONTH_DELAY_BLOCKS, "Monthly delay not reached");
        require(liquidityPoolStartingSacrificeRewardCount < 24, "StartingSacrificeReward minted out");
        uint256 slots = _monthsSinceStart();
        require(slots > liquidityPoolStartingSacrificeRewardCount, "No monthly slot available");
        uint256 toMint = slots - liquidityPoolStartingSacrificeRewardCount;
        if (toMint > MAX_SLOTS_PER_TX) {
            toMint = MAX_SLOTS_PER_TX;
        }
        if (liquidityPoolStartingSacrificeRewardCount + toMint > 24) {
            toMint = 24 - liquidityPoolStartingSacrificeRewardCount;
        }
        liquidityPoolStartingSacrificeRewardCount += toMint;
        uint256 amount = toMint * 125_000 * 10**decimals();
        _mint(RECIPIENT_LIQUIDITY_POOL_STARTING_SACRIFICE_REWARD, amount);
        emit MintLiquidityPoolStartingSacrificeReward(msg.sender, RECIPIENT_LIQUIDITY_POOL_STARTING_SACRIFICE_REWARD, amount, liquidityPoolStartingSacrificeRewardCount, block.number, block.timestamp);
    }

    /**
     * @notice Mint monthly liquidity pool sacrifice success lock (up to 24 months)
     */
    function mintLiquidityPoolSacrificeSuccessLock() external {
        require(msg.sender == JustAJanitor, "Only JustAJanitor can mint");
        require(block.number >= startBlock + ONE_MONTH_DELAY_BLOCKS, "Monthly delay not reached");
        require(liquidityPoolSacrificeSuccessLockCount < 24, "SacrificeSuccessLock minted out");
        uint256 slots = _monthsSinceStart();
        require(slots > liquidityPoolSacrificeSuccessLockCount, "No monthly slot available");
        uint256 toMint = slots - liquidityPoolSacrificeSuccessLockCount;
        if (toMint > MAX_SLOTS_PER_TX) {
            toMint = MAX_SLOTS_PER_TX;
        }
        if (liquidityPoolSacrificeSuccessLockCount + toMint > 24) {
            toMint = 24 - liquidityPoolSacrificeSuccessLockCount;
        }
        liquidityPoolSacrificeSuccessLockCount += toMint;
        uint256 amount = toMint * 41_650 * 10**decimals();
        _mint(RECIPIENT_LIQUIDITY_POOL_SACRIFICE_SUCCESS_LOCK, amount);
        emit MintLiquidityPoolSacrificeSuccessLock(msg.sender, RECIPIENT_LIQUIDITY_POOL_SACRIFICE_SUCCESS_LOCK, amount, liquidityPoolSacrificeSuccessLockCount, block.number, block.timestamp);
    }

    /**
     * @notice Mint yearly janitor allocation (unlimited years, first mint only after 1 year)
     */
    function mintJustYearlyJanitor() external {
        require(msg.sender == JustAJanitor, "Only JustAJanitor can mint");
        require(block.number >= startBlock + BLOCKS_PER_YEAR, "Yearly minting not started yet");
        uint256 slots = _yearsSinceStart();
        require(slots > justYearlyJanitorCount, "No yearly slot available");
        uint256 toMint = slots - justYearlyJanitorCount;
        if (toMint > MAX_SLOTS_PER_TX) {
            toMint = MAX_SLOTS_PER_TX;
        }
        justYearlyJanitorCount += toMint;
        uint256 amount = toMint * 50_000 * 10**decimals();
        _mint(RECIPIENT_JUST_YEARLY_JANITOR, amount);
        emit MintJustYearlyJanitor(msg.sender, RECIPIENT_JUST_YEARLY_JANITOR, amount, justYearlyJanitorCount, block.number, block.timestamp);
    }

    /**
     * @notice Mint monthly community sacrifice lock (up to 24 months)
     */
    function mintLiquidityPoolCommunitySacrificeLock() external {
        require(msg.sender == JustAJanitor, "Only JustAJanitor can mint");
        require(block.number >= startBlock + ONE_MONTH_DELAY_BLOCKS, "Monthly delay not reached");
        require(liquidityPoolCommunitySacrificeLockCount < 24, "CommunitySacrificeLock minted out");
        uint256 slots = _monthsSinceStart();
        require(slots > liquidityPoolCommunitySacrificeLockCount, "No monthly slot available");
        uint256 toMint = slots - liquidityPoolCommunitySacrificeLockCount;
        if (toMint > MAX_SLOTS_PER_TX) {
            toMint = MAX_SLOTS_PER_TX;
        }
        if (liquidityPoolCommunitySacrificeLockCount + toMint > 24) {
            toMint = 24 - liquidityPoolCommunitySacrificeLockCount;
        }
        liquidityPoolCommunitySacrificeLockCount += toMint;
        uint256 amount = toMint * 125_000 * 10**decimals();
        _mint(RECIPIENT_LIQUIDITY_POOL_COMMUNITY_SACRIFICE_LOCK, amount);
        emit MintLiquidityPoolCommunitySacrificeLock(msg.sender, RECIPIENT_LIQUIDITY_POOL_COMMUNITY_SACRIFICE_LOCK, amount, liquidityPoolCommunitySacrificeLockCount, block.number, block.timestamp);
    }

    /**
     * @notice Mint monthly community buyback lock (up to 24 months)
     */
    function mintLiquidityPoolCommunityBuybackLock() external {
        require(msg.sender == JustAJanitor, "Only JustAJanitor can mint");
        require(block.number >= startBlock + ONE_MONTH_DELAY_BLOCKS, "Monthly delay not reached");
        require(liquidityPoolCommunityBuybackLockCount < 24, "CommunityBuybackLock minted out");
        uint256 slots = _monthsSinceStart();
        require(slots > liquidityPoolCommunityBuybackLockCount, "No monthly slot available");
        uint256 toMint = slots - liquidityPoolCommunityBuybackLockCount;
        if (toMint > MAX_SLOTS_PER_TX) {
            toMint = MAX_SLOTS_PER_TX;
        }
        if (liquidityPoolCommunityBuybackLockCount + toMint > 24) {
            toMint = 24 - liquidityPoolCommunityBuybackLockCount;
        }
        liquidityPoolCommunityBuybackLockCount += toMint;
        uint256 amount = toMint * 83_300 * 10**decimals();
        _mint(RECIPIENT_LIQUIDITY_POOL_COMMUNITY_BUYBACK_LOCK, amount);
        emit MintLiquidityPoolCommunityBuybackLock(msg.sender, RECIPIENT_LIQUIDITY_POOL_COMMUNITY_BUYBACK_LOCK, amount, liquidityPoolCommunityBuybackLockCount, block.number, block.timestamp);
    }

    /**
     * @notice Mint yearly staking rewards (up to 3 years)
     */
    function mintStakingReward() external {
        require(msg.sender == JustAJanitor, "Only JustAJanitor can mint");
        require(block.number >= startBlock + BLOCKS_PER_YEAR, "Yearly delay not reached");
        require(stakingRewardCount < 3, "StakingReward minted out");
        uint256 slots = _yearsSinceStart();
        require(slots > stakingRewardCount, "No yearly slot available");
        uint256 toMint = slots - stakingRewardCount;
        if (toMint > MAX_SLOTS_PER_TX) {
            toMint = MAX_SLOTS_PER_TX;
        }
        if (stakingRewardCount + toMint > 3) {
            toMint = 3 - stakingRewardCount;
        }
        stakingRewardCount += toMint;
        uint256 amount = toMint * 500_000 * 10**decimals();
        _mint(RECIPIENT_STAKING_REWARD, amount);
        emit MintStakingReward(msg.sender, RECIPIENT_STAKING_REWARD, amount, stakingRewardCount, block.number, block.timestamp);
    }

    /**
     * @notice Mint yearly science reward (unlimited, tiered schedule for first 21 years)
     */
    function mintScienceReward() external {
        require(msg.sender == JustAJanitor, "Only JustAJanitor can mint");
        uint256 slots = _yearsSinceStart();
        uint256 slotsToMint = slots - scienceRewardCount;
        if (slotsToMint > MAX_SLOTS_PER_TX) {
            slotsToMint = MAX_SLOTS_PER_TX;
        }
        require(slotsToMint > 0, "No yearly slot available");
        for (uint256 i = 0; i < slotsToMint; i++) { 
            scienceRewardCount++;
            uint256 yearIndex = scienceRewardCount > 21 ? 21 : scienceRewardCount;
            uint256 reward    = scienceRewardByYear[yearIndex] * 10**decimals();
            _mint(RECIPIENT_SCIENCE_REWARD, reward);
            emit MintScienceReward(msg.sender, RECIPIENT_SCIENCE_REWARD, reward, scienceRewardCount, block.number, block.timestamp);
        }
    }

    /**
     * @notice Mint a one-time liquidity pool start success lock allocation
     */
    function mintLiquidityPoolStartSuccessLock() external {
        require(msg.sender == JustAJanitor, "Only JustAJanitor can mint");
        require(!mintedLiquidityPoolStartSuccessLock, "LiqudityPoolStartSuccessLock already minted");
        mintedLiquidityPoolStartSuccessLock = true;
        uint256 amount = 300_000 * 10**decimals();
        _mint(RECIPIENT_LIQUIDITY_POOL_START_SUCCESS_LOCK, amount);
        emit MintLiquidityPoolStartSuccessLock(msg.sender, RECIPIENT_LIQUIDITY_POOL_START_SUCCESS_LOCK, amount, block.number, block.timestamp);
    }

    // ------------------------------ INTERNAL HELPERS ---------------------------

    function _monthsSinceStart() internal view returns (uint256) {
        return ((block.number - startBlock) / BLOCKS_PER_MONTH) + 1;
    }

    function _yearsSinceStart() internal view returns (uint256) {
        return ((block.number - startBlock) / BLOCKS_PER_YEAR) + 1;
    }
}
        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC-1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * Both values are immutable: they can only be set once during construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner`'s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner`'s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance < type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.20;

import {ERC20} from "../ERC20.sol";
import {Context} from "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys a `value` amount of tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 value) public virtual {
        _burn(_msgSender(), value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, deducting from
     * the caller's allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `value`.
     */
    function burnFrom(address account, uint256 value) public virtual {
        _spendAllowance(account, _msgSender(), value);
        _burn(account, value);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}