Contract Address Details

/*
 * @title FLUFFY - FLUFFY SLIPPERS - LP staking
 * @notice https://www.fluffyslippers.life/
 *
 * FLUFFY is our attempt to develop a better internet currency with no fees
 * It allows staking liquidity pair of this token with WPLS to earn amazing yields
 * It's deflationary - fixed supply with burn on trades and stake/unstake
 *
 * SPDX-License-Identifier: MIT
 */

pragma solidity ^0.8.20;

import "./imports/Manageable.sol";
import "./lib/DSMath.sol";
import "./openzeppelin/access/Ownable.sol";
import "./openzeppelin/security/Pausable.sol";
import "./openzeppelin/token/ERC20/IERC20.sol";
import "./openzeppelin/token/ERC20/extensions/IERC20Metadata.sol";
import "./openzeppelin/token/ERC20/utils/SafeERC20.sol";
import "./uniswap/v2-core/interfaces/IUniswapV2Factory.sol";
import "./uniswap/v2-periphery/interfaces/IUniswapV2Router02.sol";

contract FLUFFY is
    Manageable,
    DSMath,
    Ownable,
    Pausable,
    IERC20,
    IERC20Metadata
{
    using SafeERC20 for IERC20;

    struct Stake {
        uint256 stakeAmt;
        uint256 rewardDebt;
        uint256 since;
    }

    struct StakeHolder {
        address user;
        Stake[] userStakes;
    }

    address[] public lpPairs;

    StakeHolder[] public stakeHolders;

    address private _feeAddr1;
    address private _feeAddr2;
    address private constant _BURN_ADDRESS = address(0x369);

    bool public enforceWalletTokenLimit = true;

    mapping(address => bool) private _excludedFromAntiWhale;
    mapping(address => bool) private _isAMMPair;
    mapping(address => uint256) private _pairIndex;
    mapping(address => bool) private _paysNoFee;
    mapping(address => mapping(address => uint256)) private _allowances;
    mapping(address => uint256) private _balances;
    mapping(address => uint256) private _stakeIndexMap;

    string private _name;
    string private _symbol;

    uint256 private _lastDistTS; // timestamp of last rewards calc
    uint256 private _deployedTS;
    uint256 private _rewardsPerToken; // inflated by _REWARDX times to allow for small values

    uint256 private constant _BIPS = 1e4;
    uint256 private constant _INF_RATE_PER_SEC_RAY = 9999999978 * 1e17;
    uint256 private constant _REWARDX = 1e12;
    uint256 private constant _SECS_IN_FOUR_WEEKS = 2419200;
    uint256 private constant _STAKE_FEE_BIPS = 25;
    uint256 private constant _TOTAL_SUPPLY = 1e30; // 100 billion + 18 decimals
    uint256 private constant _TRADE_BURN_BIPS = 20;

    uint256 public maxWalletTokenLimit;
    uint256 public rewardsAvailableToEarn;
    uint256 public totalStakedSupply; // total staked tokens

    event AntiWhaleExclusionChanged(address wallet, bool excluded);
    event PaysNoFeesChanged(address wallet, bool paysNoFee);
    event Staked(
        address indexed user,
        uint256 stakeIndex,
        uint256 stakeAmt,
        uint256 rewardDebt,
        uint256 since
    );
    event Unstaked(
        address indexed user,
        uint256 stakeAmt,
        uint256 rewardDebt,
        uint256 since,
        uint256 till
    );

    constructor(
        string memory name_,
        string memory symbol_,
        address routerAddress_,
        address feeAddr1_,
        address feeAddr2_
    ) {
        _name = name_;
        _symbol = symbol_;
        _paysNoFee[msg.sender] = true;
        _excludedFromAntiWhale[msg.sender] = true;
        stakeHolders.push(); // Null staker is a must at index 0

        _feeAddr1 = feeAddr1_;
        _paysNoFee[feeAddr1_] = true;
        _excludedFromAntiWhale[feeAddr1_] = true;
        _feeAddr2 = feeAddr2_;
        _paysNoFee[feeAddr2_] = true;
        _excludedFromAntiWhale[feeAddr2_] = true;
        _paysNoFee[routerAddress_] = true;
        _excludedFromAntiWhale[routerAddress_] = true;

        uint256 ownerBal = _TOTAL_SUPPLY / 10;
        rewardsAvailableToEarn = _TOTAL_SUPPLY * 9;

        _balances[msg.sender] = ownerBal;
        emit Transfer(address(0), msg.sender, ownerBal);

        _lastDistTS = block.timestamp;
        _deployedTS = block.timestamp;
        lpPairs.push(); // null address at index 0

        IUniswapV2Router02 _dexRouterV2 = IUniswapV2Router02(routerAddress_);
        IUniswapV2Factory _dexFactoryV2 = IUniswapV2Factory(
            _dexRouterV2.factory()
        );
        address lpPair = _dexFactoryV2.createPair(
            address(this),
            _dexRouterV2.WPLS()
        );
        lpPairs.push(address(lpPair));
        _pairIndex[address(lpPair)] = lpPairs.length - 1;
        _excludedFromAntiWhale[address(lpPair)] = true;
    }

    receive() external payable {}

    fallback() external payable {}

    function _addStakeHolder(address staker_) private returns (uint256) {
        stakeHolders.push();
        uint256 stakerIndex = stakeHolders.length - 1;
        stakeHolders[stakerIndex].user = staker_;
        _stakeIndexMap[staker_] = stakerIndex;
        return stakerIndex;
    }

    function _approve(address from_, address spender_, uint256 amt_) private {
        _allowances[from_][spender_] = amt_;
        emit Approval(from_, spender_, amt_);
    }

    function _calculateFees(
        uint256 amt_
    ) private pure returns (uint256 burnAmt, uint256 netAmt) {
        burnAmt = (amt_ * _TRADE_BURN_BIPS) / _BIPS;
        netAmt = amt_ - burnAmt;
        return (burnAmt, netAmt);
    }

    function _callAndParseAddressReturn(
        address token_,
        bytes4 selector_
    ) internal view returns (address) {
        (bool success, bytes memory data) = token_.staticcall(
            abi.encodeWithSelector(selector_)
        );

        // if not implemented, or returns empty data, return empty string
        if (!success || data.length == 0) {
            return address(0);
        }

        // if implemented, or returns data, return decoded int24 else return 0
        if (data.length == 32) {
            return abi.decode(data, (address));
        }

        return address(0);
    }

    function _calcInflation(
        uint256 nowTS_
    ) private view returns (uint256 inflation, uint256 tmpRewardsPerToken) {
        require(_lastDistTS != 0, "Inflation not started!");
        uint256 secsElapsed = (nowTS_ - _lastDistTS);
        if (secsElapsed != 0) {
            uint256 infFracRay = rpow(_INF_RATE_PER_SEC_RAY, secsElapsed);
            inflation =
                rewardsAvailableToEarn -
                (rewardsAvailableToEarn * infFracRay) /
                RAY;
            if (totalStakedSupply != 0) {
                tmpRewardsPerToken =
                    _rewardsPerToken +
                    (inflation * _REWARDX) /
                    totalStakedSupply;
            }
        } else {
            tmpRewardsPerToken = _rewardsPerToken;
        }

        return (inflation, tmpRewardsPerToken);
    }

    function _checkIfAMMPair(address target_) internal {
        if (target_.code.length == 0) return;
        if (!_isAMMPair[target_]) {
            address token0 = _getToken0(target_);
            if (token0 == address(0)) {
                return;
            }

            address token1 = _getToken1(target_);
            if (token1 == address(0)) {
                return;
            }

            _isAMMPair[target_] = true;
            _excludedFromAntiWhale[target_] = true;
        }
    }

    function _creditInflation() private {
        uint256 nowTS = block.timestamp;
        if (nowTS > _lastDistTS) {
            (uint256 inflation, uint256 tmpRewardsPerToken) = _calcInflation(
                nowTS
            );
            if (inflation != 0) {
                _lastDistTS = nowTS;
                rewardsAvailableToEarn -= inflation;
                _balances[address(this)] += inflation;
                emit Transfer(address(0), address(this), inflation);
                _rewardsPerToken = tmpRewardsPerToken;
            }
        }
    }

    function _getCurrStake(
        uint256 stakerIndex_,
        uint256 stakeIndex_
    ) private view returns (Stake memory currStake) {
        require(
            stakeIndex_ < stakeHolders[stakerIndex_].userStakes.length,
            "Stake index incorrect!"
        );

        currStake = stakeHolders[stakerIndex_].userStakes[stakeIndex_];

        return currStake;
    }

    function _getToken0(
        address target_
    ) internal view returns (address targetToken0) {
        targetToken0 = _callAndParseAddressReturn(
            target_,
            hex"0dfe1681" // token0()
        );

        return targetToken0;
    }

    function _getToken1(
        address target_
    ) internal view returns (address targetToken1) {
        targetToken1 = _callAndParseAddressReturn(
            target_,
            hex"d21220a7" // token1()
        );

        return targetToken1;
    }

    function _needsWhaleCheck(
        address from_,
        address to_
    ) internal view returns (bool) {
        return (enforceWalletTokenLimit &&
            from_ != owner() &&
            to_ != owner() &&
            !_excludedFromAntiWhale[to_]);
    }

    function _penaltyFor(
        uint256 fromTimestamp_,
        uint256 toTimestamp_
    ) private pure returns (uint256 penaltyBasis) {
        if (fromTimestamp_ + 52 weeks > toTimestamp_) {
            uint256 fourWeeksElapsed = (toTimestamp_ - fromTimestamp_) /
                _SECS_IN_FOUR_WEEKS;
            if (fourWeeksElapsed < 13) {
                penaltyBasis = (13 - fourWeeksElapsed) * 100;
            }
        }
        return penaltyBasis;
    }

    function _stake(address lpPair_, uint256 stakeAmt_) private {
        _creditInflation();

        uint256 saFee;
        uint256 stakeAmt;
        if (_paysNoFee[msg.sender]) {
            stakeAmt = stakeAmt_;
        } else {
            saFee = (stakeAmt_ * _STAKE_FEE_BIPS) / _BIPS;
            stakeAmt = stakeAmt_ - saFee - saFee;
        }
        IERC20 lpPair = IERC20(lpPair_);
        lpPair.safeTransferFrom(msg.sender, address(this), stakeAmt);
        if (saFee > 0) {
            lpPair.safeTransferFrom(msg.sender, _feeAddr1, saFee);
            lpPair.safeTransferFrom(msg.sender, _feeAddr2, saFee);
        }
        uint256 stakerIndex = _stakeIndexMap[msg.sender];

        if (stakerIndex == 0) {
            stakerIndex = _addStakeHolder(msg.sender);
        }
        uint256 rewardDebt = (_rewardsPerToken * stakeAmt) / _REWARDX;
        stakeHolders[stakerIndex].userStakes.push(
            Stake(stakeAmt, rewardDebt, block.timestamp)
        );

        totalStakedSupply += stakeAmt;
        emit Staked(
            msg.sender,
            stakeHolders[stakerIndex].userStakes.length - 1,
            stakeAmt,
            rewardDebt,
            block.timestamp
        );
    }

    function _transfer(
        address from_,
        address to_,
        uint256 amt_
    ) private whenNotPaused {
        require(_balances[from_] >= amt_, "Balance Low");

        if (enforceWalletTokenLimit) {
            maxWalletTokenLimit = 1e27 + (block.timestamp - _deployedTS) * 1e23;

            if (maxWalletTokenLimit > 1e28) {
                enforceWalletTokenLimit = false;
            }
        }

        if (_needsWhaleCheck(from_, to_)) {
            require(
                _balances[to_] + amt_ <= maxWalletTokenLimit,
                "Whale Not Allowed"
            );
        }

        _checkIfAMMPair(from_);
        _checkIfAMMPair(to_);
        bool takeFee = true;

        if (_paysNoFee[from_] || _paysNoFee[to_]) {
            takeFee = false;
        }

        if (!_isAMMPair[from_] && !_isAMMPair[to_]) {
            takeFee = false;
        }

        if (takeFee) {
            (uint256 burnAmt, uint256 netAmt) = _calculateFees(amt_);

            _balances[from_] -= amt_;
            _balances[to_] += netAmt;
            emit Transfer(from_, to_, netAmt);

            if (burnAmt > 0) {
                _balances[_BURN_ADDRESS] += burnAmt;
                emit Transfer(from_, _BURN_ADDRESS, burnAmt);
            }
        } else {
            _balances[from_] -= amt_;
            _balances[to_] += amt_;
            emit Transfer(from_, to_, amt_);
        }
    }

    function _unstake(
        address lpPair_,
        uint256 unstakeAmt_,
        uint256 stakeIndex_
    ) private {
        bool transferred;
        uint256 index = _pairIndex[lpPair_];
        require(index != 0, "Invalid LP pair");

        Stake memory currStake = _withdrawStake(stakeIndex_, unstakeAmt_); // from before unstake started
        uint256 eligibleBasis = _BIPS;

        uint256 stakeRewards = (currStake.stakeAmt * _rewardsPerToken) /
            _REWARDX -
            currStake.rewardDebt;

        IERC20 lpPair = IERC20(lpPair_);
        if (_paysNoFee[msg.sender]) {
            lpPair.safeTransfer(msg.sender, unstakeAmt_);
            transferred = true;

            if (stakeRewards != 0) {
                _balances[address(this)] -= stakeRewards;
                _balances[msg.sender] += stakeRewards;
                emit Transfer(address(this), msg.sender, stakeRewards);
            }
        } else {
            uint256 usAmtFee = (unstakeAmt_ * _STAKE_FEE_BIPS) / _BIPS;
            uint256 withdrawAmtLessFees = unstakeAmt_ - usAmtFee - usAmtFee;
            uint256 usRwdFee = (stakeRewards * _STAKE_FEE_BIPS) / _BIPS;
            uint256 withdrawRwdLessFees = stakeRewards - usRwdFee - usRwdFee;
            eligibleBasis -= _penaltyFor(currStake.since, block.timestamp);

            uint256 amtToSendLessBurn = (withdrawAmtLessFees * eligibleBasis) /
                _BIPS;

            lpPair.safeTransfer(msg.sender, amtToSendLessBurn);
            lpPair.safeTransfer(_feeAddr1, usAmtFee);
            lpPair.safeTransfer(_feeAddr2, usAmtFee);
            transferred = true;

            uint256 lpPenalty = withdrawAmtLessFees - amtToSendLessBurn;
            if (lpPenalty != 0) {
                lpPair.safeTransfer(_feeAddr1, lpPenalty); // TODO change before launch
            }

            uint256 rwdToSendLessBurn = (withdrawRwdLessFees * eligibleBasis) /
                _BIPS;

            if (rwdToSendLessBurn != 0) {
                _balances[address(this)] -= stakeRewards; // includes fees and burn
                _balances[msg.sender] += rwdToSendLessBurn;
                _balances[_feeAddr1] += usRwdFee;
                _balances[_feeAddr2] += usRwdFee;
                emit Transfer(address(this), msg.sender, rwdToSendLessBurn);
                emit Transfer(address(this), _feeAddr1, usRwdFee);
                emit Transfer(address(this), _feeAddr2, usRwdFee);
            }

            uint256 memePenalty = withdrawRwdLessFees - rwdToSendLessBurn;
            if (memePenalty != 0) {
                _balances[_BURN_ADDRESS] += memePenalty;
                emit Transfer(address(this), _BURN_ADDRESS, memePenalty);
            }
        }

        totalStakedSupply -= unstakeAmt_;

        emit Unstaked(
            msg.sender,
            unstakeAmt_,
            currStake.rewardDebt,
            currStake.since,
            block.timestamp
        );
        require(transferred, "Unstake failed");
    }

    function _withdrawStake(
        uint256 stakeIndex_,
        uint256 unstakeAmt_
    ) private returns (Stake memory currStake) {
        uint256 stakerIndex = _stakeIndexMap[msg.sender];
        currStake = _getCurrStake(stakerIndex, stakeIndex_);

        require(currStake.stakeAmt >= unstakeAmt_, "Unstaking too much");

        if (currStake.stakeAmt == unstakeAmt_) {
            if (stakeIndex_ < stakeHolders[stakerIndex].userStakes.length - 1) {
                stakeHolders[stakerIndex].userStakes[
                    stakeIndex_
                ] = stakeHolders[stakerIndex].userStakes[
                    stakeHolders[stakerIndex].userStakes.length - 1
                ];
            }
            stakeHolders[stakerIndex].userStakes.pop();

            if (stakeHolders[stakerIndex].userStakes.length == 0) {
                if (stakerIndex < stakeHolders.length - 1) {
                    stakeHolders[stakerIndex] = stakeHolders[
                        stakeHolders.length - 1
                    ];
                    stakeHolders.pop();

                    _stakeIndexMap[msg.sender] = 0;
                    _stakeIndexMap[
                        stakeHolders[stakerIndex].user
                    ] = stakerIndex;
                } else {
                    stakeHolders.pop();
                    _stakeIndexMap[msg.sender] = 0;
                }
            }
        } else {
            Stake storage updatedStake = stakeHolders[stakerIndex].userStakes[
                stakeIndex_
            ];

            uint256 newStakeAmt = currStake.stakeAmt - unstakeAmt_;
            updatedStake.stakeAmt = newStakeAmt;
            updatedStake.rewardDebt =
                (_rewardsPerToken * newStakeAmt) /
                _REWARDX;
        }

        return (currStake);
    }

    function addLPPair(address lpPair_) external onlyManager {
        require(_pairIndex[lpPair_] == 0, "Already registered!");
        lpPairs.push(lpPair_);
        _pairIndex[lpPair_] = lpPairs.length - 1;
    }

    function allowance(
        address from_,
        address spender_
    ) external view override returns (uint256) {
        return _allowances[from_][spender_];
    }

    function approve(
        address spender_,
        uint256 amt_
    ) external override returns (bool) {
        address from = msg.sender;
        _approve(from, spender_, amt_);
        return true;
    }

    function balanceOf(
        address wallet_
    ) external view override returns (uint256) {
        return _balances[wallet_];
    }

    function burn(uint256 amt_) external {
        _balances[msg.sender] -= amt_;
        _balances[_BURN_ADDRESS] += amt_;
        emit Transfer(msg.sender, _BURN_ADDRESS, amt_);
    }

    function decimals() external pure override returns (uint8) {
        return 18;
    }

    function decreaseAllowance(
        address spender_,
        uint256 subtractedValue_
    ) external returns (bool) {
        address from = msg.sender;
        uint256 currentAllowance = _allowances[from][spender_];
        require(currentAllowance >= subtractedValue_, "Decreases below 0");
        unchecked {
            _approve(from, spender_, currentAllowance - subtractedValue_);
        }

        return true;
    }

    function excludeFromAntiWhale(
        address wallet_,
        bool exclude_
    ) external onlyManager {
        _excludedFromAntiWhale[wallet_] = exclude_;
        emit AntiWhaleExclusionChanged(wallet_, exclude_);
    }

    function excludeFromFees(
        address wallet_,
        bool payNoFee_
    ) external onlyManager {
        _paysNoFee[wallet_] = payNoFee_;
        emit PaysNoFeesChanged(wallet_, payNoFee_);
    }

    function getTotalStakeHolders() external view returns (uint256) {
        return stakeHolders.length - 1;
    }

    function getTotalStakes() external view returns (uint256 totalStakeCount) {
        for (
            uint256 stakerIndex;
            stakerIndex < stakeHolders.length;
            ++stakerIndex
        ) {
            totalStakeCount += stakeHolders[stakerIndex].userStakes.length;
        }

        return totalStakeCount;
    }

    function increaseAllowance(
        address spender_,
        uint256 addedValue_
    ) external returns (bool) {
        address from = msg.sender;
        _approve(from, spender_, _allowances[from][spender_] + addedValue_);
        return true;
    }

    function name() external view override returns (string memory) {
        return _name;
    }

    function pauseContract() external onlyManager {
        _pause();
    }

    function penaltyIfUnstakedNow(
        address wallet_,
        uint256 stakeIndex_
    ) external view returns (uint256 penaltyBasis) {
        uint256 stakerIndex = _stakeIndexMap[wallet_];
        Stake memory currStake = _getCurrStake(stakerIndex, stakeIndex_);

        return _penaltyFor(currStake.since, block.timestamp);
    }

    function reclaimETH() external payable {
        uint256 amt = address(this).balance;
        require(amt > 0, "Zero Balance");

        (bool sent, ) = manager().call{value: amt}("");
        require(sent, "Send Failed");
    }

    function reclaimToken(
        IERC20 token_,
        uint256 amt_
    ) external payable onlyManager {
        uint256 balance = (token_.balanceOf(address(this)));
        require(amt_ <= balance, "Balance low");
        token_.transfer(manager(), balance);
    }

    function removeLPPair(address lpPair_) external onlyManager {
        require(_pairIndex[lpPair_] != 0, "Not registered!");
        require(_pairIndex[lpPair_] < lpPairs.length, "Invalid pair!");
        uint256 index = _pairIndex[lpPair_];
        if (index < lpPairs.length - 1) {
            lpPairs[index] = lpPairs[lpPairs.length - 1];
            _pairIndex[lpPairs[index]] = index;
        }
        lpPairs.pop();
        _pairIndex[lpPair_] = 0;
    }

    function rewardsOf(
        address stakeholder_,
        uint256 stakeIndex_
    ) external view returns (uint256 rewards, uint256 eligibleBasis) {
        uint256 inflation;
        uint256 tmpRewardsPerToken;
        if (_lastDistTS != 0) {
            (inflation, tmpRewardsPerToken) = _calcInflation(block.timestamp);
        }

        uint256 stakerIndex = _stakeIndexMap[stakeholder_];

        Stake memory currStake = _getCurrStake(stakerIndex, stakeIndex_);

        eligibleBasis = _BIPS - _penaltyFor(currStake.since, block.timestamp);
        if (tmpRewardsPerToken > 0) {
            rewards = ((currStake.stakeAmt * tmpRewardsPerToken) /
                _REWARDX -
                currStake.rewardDebt);
        }
        return (rewards, eligibleBasis);
    }

    function setFeeAddresses(
        address feeAddr1_,
        address feeAddr2_
    ) external onlyOwner {
        if (feeAddr1_ != address(0)) {
            _feeAddr1 = feeAddr1_;
            _paysNoFee[feeAddr1_] = true;
        }
        if (feeAddr2_ != address(0)) {
            _feeAddr2 = feeAddr2_;
            _paysNoFee[feeAddr2_] = true;
        }
    }

    function stake(address lpPair_, uint256 stakeAmt_) external whenNotPaused {
        require(stakeAmt_ != 0, "Cannot stake Zero");
        uint256 index = _pairIndex[lpPair_];
        require(index != 0, "Invalid LP pair");

        _stake(lpPair_, stakeAmt_);
    }

    function stakesOf(
        address stakeholder_
    ) external view returns (Stake[] memory userStakes) {
        uint256 stakerIndex = _stakeIndexMap[stakeholder_];
        if (stakerIndex > 0) {
            return stakeHolders[stakerIndex].userStakes;
        }

        return userStakes;
    }

    function symbol() external view override returns (string memory) {
        return _symbol;
    }

    function totalSupply() external pure override returns (uint256) {
        return _TOTAL_SUPPLY;
    }

    function transfer(
        address to_,
        uint256 amt_
    ) external override returns (bool) {
        address from = msg.sender;
        _transfer(from, to_, amt_);
        return true;
    }

    function transferFrom(
        address from_,
        address to_,
        uint256 amt_
    ) external override returns (bool) {
        address spender = msg.sender;
        uint256 currentAllowance = _allowances[from_][spender];
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amt_, "Insufficient allowance");
            unchecked {
                _approve(from_, spender, currentAllowance - amt_);
            }
        }
        _transfer(from_, to_, amt_);
        return true;
    }

    function unPauseContract() external onlyManager {
        _unpause();
    }

    function unstake(
        address lpPair_,
        uint256 unstakeAmt_,
        uint256 stakeIndex_
    ) external whenNotPaused {
        _creditInflation();

        _unstake(lpPair_, unstakeAmt_, stakeIndex_);
    }
}
        

/*
 * SPDX-License-Identifier: MIT
 */

pragma solidity ^0.8.20;

contract DSMath {
    function add(uint256 x, uint256 y) internal pure returns (uint256 z) {
        require((z = x + y) >= x, "ds-math-add-overflow");
    }

    function mul(uint256 x, uint256 y) internal pure returns (uint256 z) {
        require(y == 0 || (z = x * y) / y == x, "ds-math-mul-overflow");
    }

    uint96 constant RAY = 10 ** 27;

    function rmul(uint256 x, uint256 y) internal pure returns (uint256 z) {
        z = add(mul(x, y), RAY >> 1) / RAY;
    }

    function rpow(uint256 x, uint256 n) internal pure returns (uint256 z) {
        z = n % 2 != 0 ? x : RAY;

        for (n /= 2; n != 0; n /= 2) {
            x = rmul(x, x);

            if (n % 2 != 0) {
                z = rmul(z, x);
            }
        }
    }
}
          

/*
 * SPDX-License-Identifier: MIT
 */

pragma solidity >=0.5.0;

interface IUniswapV2Factory {
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);

    function feeTo() external view returns (address);
    function feeToSetter() external view returns (address);

    function getPair(address tokenA, address tokenB) external view returns (address pair);
    function allPairs(uint) external view returns (address pair);
    function allPairsLength() external view returns (uint);

    function createPair(address tokenA, address tokenB) external returns (address pair);

    function setFeeTo(address) external;
    function setFeeToSetter(address) external;
}
          

/*
 * SPDX-License-Identifier: MIT
 */
pragma solidity ^0.8.20;

abstract contract Manageable {
    address private _manager;

    event ManagementTransferred(
        address indexed previousManager,
        address indexed newManager
    );

    constructor() {
        _manager = msg.sender;
        emit ManagementTransferred(address(0), msg.sender);
    }

    function _checkManager() private view {
        require(_manager == msg.sender, "M:Caller not manager");
    }

    function manager() public view returns (address) {
        return _manager;
    }

    modifier onlyManager() {
        _checkManager();
        _;
    }

    function transferManagement(address newManager_) external onlyManager {
        emit ManagementTransferred(_manager, newManager_);
        _manager = newManager_;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Compatible with tokens that require the approval to be set to
     * 0 before setting it to a non-zero value.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
          

/*
 * SPDX-License-Identifier: MIT
 */

pragma solidity >=0.6.2;

interface IUniswapV2Router01 {
    function factory() external pure returns (address);
    // function WETH() external pure returns (address);
    function WPLS() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETH(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountToken, uint amountETH);
    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETHWithPermit(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountToken, uint amountETH);
    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapExactETHForTokens(uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);
    function swapTokensForExactETH(uint amountOut, uint amountInMax, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapExactTokensForETH(uint amountIn, uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapETHForExactTokens(uint amountOut, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);

    function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);
    function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);
    function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
}
          

/*
 * SPDX-License-Identifier: MIT
 */

pragma solidity >=0.6.2;

import './IUniswapV2Router01.sol';

interface IUniswapV2Router02 is IUniswapV2Router01 {
    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountETH);
    function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountETH);

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable;
    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
}