Contract Address Details

// SPDX-License-Identifier: MIT
// File: IRS/Context.sol



pragma solidity ^0.8.0;

abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }
	
    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
// File: IRS/Ownable.sol



pragma solidity ^0.8.0;


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
// File: IRS/IERC20.sol



pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}
// File: IRS/IERC20Metadata.sol



pragma solidity ^0.8.0;


/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
// File: IRS/ERC20.sol



pragma solidity ^0.8.0;




/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * The default value of {decimals} is 18. To select a different value for
     * {decimals} you should overload it.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless this function is
     * overridden;
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
        }
        _balances[to] += amount;

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        _balances[account] += amount;
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
        }
        _totalSupply -= amount;

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
}
// File: IRS/IPulseX.sol



pragma solidity 0.8.20;

/// @title PulseX Factory Interface
/// @notice Interface for creating liquidity pairs on PulseX
interface IPulseXFactory {
    /// @notice Creates a new trading pair between two tokens
    /// @param tokenA Address of the first token
    /// @param tokenB Address of the second token
    /// @return pair Address of the newly created pair contract
    function createPair(address tokenA, address tokenB) external returns (address pair);
}

/// @title PulseX Router Interface
/// @notice Interface for interacting with PulseX Router for swaps and liquidity
interface IPulseXRouter {
    /// @notice Returns the address of the factory contract
    /// @return Address of the PulseX factory
    function factory() external pure returns (address);

	/**
	 * @notice Swaps an exact amount of input tokens for another ERC20 token
	 * @dev Supports fee-on-transfer tokens
	 * @param amountIn Amount of input tokens to send
	 * @param amountOutMin Minimum amount of output tokens to receive
	 * @param path Array of token addresses (e.g., tokenIn → INC)
	 * @param to Address to receive the output tokens
	 * @param deadline Unix timestamp after which the transaction will revert
	*/
	function swapExactTokensForTokensSupportingFeeOnTransferTokens(
		uint amountIn,
		uint amountOutMin,
		address[] calldata path,
		address to,
		uint deadline
	) external;
	

    /**
	 * @notice Adds liquidity to a token/token pair
	 * @param tokenA Address of the first ERC20 token
	 * @param tokenB Address of the second ERC20 token
	 * @param amountADesired Amount of tokenA to add
	 * @param amountBDesired Amount of tokenB to add
	 * @param amountAMin Minimum amount of tokenA to add (slippage)
	 * @param amountBMin Minimum amount of tokenB to add (slippage)
	 * @param to Address that receives the LP tokens
	 * @param deadline Time after which transaction is invalid
	 * @return amountA Amount of tokenA added
	 * @return amountB Amount of tokenB added
	 * @return liquidity Amount of LP tokens minted
	*/
	function addLiquidity(
		address tokenA,
		address tokenB,
		uint amountADesired,
		uint amountBDesired,
		uint amountAMin,
		uint amountBMin,
		address to,
		uint deadline
	) external returns (uint amountA, uint amountB, uint liquidity);
}

/// @title PulseX Pair Interface
/// @notice Interface for querying pair token addresses in a PulseX liquidity pool
interface IPulseXPair {
    /// @notice Returns the address of token0 in the pair
    /// @return Address of token0
    function token0() external view returns (address);

    /// @notice Returns the address of token1 in the pair
    /// @return Address of token1
    function token1() external view returns (address);
}

// File: IRS/Distributor.sol



pragma solidity ^0.8.0;



/**
 * @title IDistributor
 * @notice Interface for the Dividend Distributor contract.
 */
interface IDistributor {
    /**
     * @notice Sets distribution criteria such as minimum period and minimum distribution.
     * @param minPeriod Minimum time between claims for a shareholder (in seconds).
     * @param minDistribution Minimum amount of reward (in wei) to trigger a distribution.
     */
    function setDistributionCriteria(uint256 minPeriod, uint256 minDistribution) external;

    /**
     * @notice Sets the share of a specific shareholder.
     * @param shareholder Address of the shareholder.
     * @param amount Number of tokens held by the shareholder.
     */
    function setShare(address shareholder, uint256 amount) external;

    /**
     * @notice Deposit tokens (e.g., INC) into the distributor to be shared.
     */
    function deposit(uint256 amount) external;

    /**
     * @notice Distributes rewards to shareholders using the specified gas limit.
     * @param gas Maximum gas to use for distribution loop.
     */
    function process(uint256 gas) external;
	
	/**
	 * @notice Adds liquidity to PulseX with ERC20 tokens (Token + INC)
	 * @param liqudityToken Amount of this token to add
	 * @param liqudityShare Amount of INC to pair with tokens
	*/
	function addLiquidity(uint256 liqudityToken, uint256 liqudityShare) external;
}

/**
 * @title ReentrancyGuard
 * @notice Protects against reentrant calls to functions using a simple status lock.
 */
abstract contract ReentrancyGuard {
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;
    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     */
    modifier nonReentrant() {
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
        _status = _ENTERED;
        _;
        _status = _NOT_ENTERED;
    }
}

/**
 * @title Distributor
 * @notice Manages dividend distribution to token holders proportionally to their share.
 * @dev Only callable by the token contract (owner). Uses ReentrancyGuard to prevent claim loops.
 */
contract Distributor is IDistributor, ReentrancyGuard {
    /// @notice Address of the token contract that owns this distributor.
    address owner;
	
    /**
     * @notice Stores shareholder-specific information for dividend tracking.
     * @param amount Number of shares (tokens) the shareholder holds.
     * @param totalExcluded Cumulative dividends excluded from this shareholder (to avoid double-counting).
     * @param totalRealised Total amount of dividends the shareholder has received.
     */
    struct Share {
        uint256 amount;
        uint256 totalExcluded;
        uint256 totalRealised;
    }
	
	/// @notice INC address
	address public immutable rewardToken;
	
	/// @notice PulseX Router interface
	IPulseXRouter public immutable pulsexRouter;
	
    /// @notice List of all current shareholders.
    address[] shareholders;

    /// @notice Mapping from shareholder address to their index in the `shareholders` array.
    mapping (address => uint256) public shareholderIndexes;

    /// @notice Timestamp of the last claim for each shareholder.
    mapping (address => uint256) public shareholderClaims;

    /// @notice Mapping from address to their share details.
    mapping (address => Share) public shares;

    /// @notice Emitted when the distribution criteria are updated.
    /// @param minPeriod Minimum time between distributions (in seconds).
    /// @param minDistribution Minimum amount of dividends to trigger a distribution (in wei).
    event DistributionCriteriaUpdate(uint256 minPeriod, uint256 minDistribution);

    /// @notice Emitted when new funds are deposited into the distributor.
    /// @param amount Amount of tokens (e.g., INC) deposited.
    event NewFundDeposit(address indexed depositor, uint256 amount);
	
	/// @notice Emitted when dividends are distributed to a shareholder.
	/// @param shareholder The address receiving the dividend.
	/// @param amount The amount of tokens (INC) distributed.
	event DividendDistributed(address indexed shareholder, uint256 amount);

    /// @notice Total number of shares held by all shareholders.
    uint256 public totalShares;

    /// @notice Total amount of dividends that have been deposited.
    uint256 public totalDividends;

    /// @notice Total amount of dividends that have been distributed.
    uint256 public totalDistributed;

    /// @notice Dividends per share scaled by the `dividendsPerShareAccuracyFactor`.
    uint256 public dividendsPerShare;

    /// @notice Factor used to maintain precision when calculating dividends per share.
    uint256 public dividendsPerShareAccuracyFactor = 10 ** 36;

    /// @notice Minimum time between dividend distributions for each shareholder (in seconds).
    uint256 public minPeriod = 10;

    /// @notice Minimum dividend amount (in wei) required to trigger a distribution.
    uint256 public minDistribution = 1 * (10**10);

    /// @notice Current index used to iterate through shareholders during processing.
    uint256 currentIndex;
	
	/**
     * @dev Modifier to restrict access to the contract owner.
     */
	
    modifier onlyOwner() {
        require(msg.sender == owner, "!Token"); _;
    }
	
    constructor (address reward, address router) {
		rewardToken = address(reward);
		pulsexRouter = IPulseXRouter(router);
		owner = msg.sender;
    }
	
	/**
     * @notice Accepts incoming native token transfers (PLS, ETH).
     */
	receive() external payable {}
	
	/**
     * @inheritdoc IDistributor
     */
    function setDistributionCriteria(uint256 _minPeriod, uint256 _minDistribution) external override onlyOwner {
        minPeriod = _minPeriod;
        minDistribution = _minDistribution;
		emit DistributionCriteriaUpdate(minPeriod, minDistribution);
    }
	
	/**
     * @inheritdoc IDistributor
     */
    function setShare(address shareholder, uint256 amount) external override onlyOwner {
        if(shares[shareholder].amount > 0)
		{
			distributeDividend(shareholder);
        }
		if(amount > 0 && shares[shareholder].amount == 0)
		{
            addShareholder(shareholder);
        }
		else if(amount == 0 && shares[shareholder].amount > 0)
		{
           removeShareholder(shareholder);
        }
        totalShares = totalShares - shares[shareholder].amount + amount;
        shares[shareholder].amount = amount;
        shares[shareholder].totalExcluded = getCumulativeDividends(shares[shareholder].amount);
    }

	/**
     * @inheritdoc IDistributor
     */
    function deposit(uint256 amount) external onlyOwner {
		totalDividends += amount;
		dividendsPerShare += ((dividendsPerShareAccuracyFactor * amount) / totalShares);
		
		uint256 balance = IERC20(owner).balanceOf(address(this));
		if(balance > 0)
		{
			try IERC20(owner).transfer(address(owner), balance) {} catch {}
		}
		emit NewFundDeposit(msg.sender, amount);
    }
	
	/**
     * @inheritdoc IDistributor
     */
    function process(uint256 gas) external override onlyOwner {
        uint256 shareholderCount = shareholders.length;

        if(shareholderCount == 0) { return; }

        uint256 gasUsed = 0;
        uint256 gasLeft = gasleft();

        uint256 iterations = 0;

        while(gasUsed < gas && iterations < shareholderCount) {
            if(currentIndex >= shareholderCount)
			{
                currentIndex = 0;
            }
            if(shouldDistribute(shareholders[currentIndex]))
			{
                distributeDividend(shareholders[currentIndex]);
            }
            gasUsed = gasUsed + gasLeft - gasleft();
            gasLeft = gasleft();
            currentIndex++;
            iterations++;
        }
    }

	/**
     * @notice Determines if a shareholder is eligible for a distribution.
     * @param shareholder Address of the shareholder.
     * @return Whether the shareholder should receive a distribution.
	 */
    function shouldDistribute(address shareholder) private view returns (bool) {
        return (shareholderClaims[shareholder] + minPeriod) < block.timestamp && getUnpaidEarnings(shareholder) > minDistribution;
    }
	
	/**
     * @notice Distributes available earnings to a shareholder.
     * @param shareholder Address to distribute to.
     */
    function distributeDividend(address shareholder) private {
        if(shares[shareholder].amount == 0){ return; }
		
        uint256 amount = getUnpaidEarnings(shareholder);
        if(amount > 0) 
		{
			IERC20(rewardToken).transfer(shareholder, amount);
			totalDistributed += amount;
			shareholderClaims[shareholder] = block.timestamp;
			shares[shareholder].totalRealised = shares[shareholder].totalRealised + amount;
			shares[shareholder].totalExcluded = getCumulativeDividends(shares[shareholder].amount);
			emit DividendDistributed(shareholder, amount);
        }
    }
	
	/**
     * @notice Claims available dividends for the sender.
     * @dev Protected by nonReentrant to avoid recursive distribution.
     */
    function claimReward() external nonReentrant {
	   if(shouldDistribute(msg.sender)) 
	   {
		  distributeDividend(msg.sender);
	   }
    }
	
	/**
     * @notice Calculates unpaid earnings for a shareholder.
     * @param shareholder Address of the shareholder.
     * @return The amount of unpaid earnings.
     */
    function getUnpaidEarnings(address shareholder) public view returns (uint256) {
        if(shares[shareholder].amount == 0){ return 0; }

        uint256 shareholderTotalDividends = getCumulativeDividends(shares[shareholder].amount);
        uint256 shareholderTotalExcluded = shares[shareholder].totalExcluded;

        if(shareholderTotalDividends <= shareholderTotalExcluded){ return 0; }
        return shareholderTotalDividends - shareholderTotalExcluded;
    }

	/**
     * @notice Calculates the total dividends for a given amount of shares.
     * @param share The number of shares.
     * @return The total cumulative dividends for those shares.
     */
    function getCumulativeDividends(uint256 share) private view returns (uint256) {
        return share * dividendsPerShare / dividendsPerShareAccuracyFactor;
    }

	/**
     * @notice Adds a shareholder to the list.
     * @param shareholder Address to add.
    */
    function addShareholder(address shareholder) private {
        shareholderIndexes[shareholder] = shareholders.length;
        shareholders.push(shareholder);
    }
	
	/**
     * @notice Removes a shareholder from the list.
     * @param shareholder Address to remove.
    */
    function removeShareholder(address shareholder) private {
        shareholders[shareholderIndexes[shareholder]] = shareholders[shareholders.length-1];
        shareholderIndexes[shareholders[shareholders.length-1]] = shareholderIndexes[shareholder];
        shareholders.pop();
    }
	
	/**
	 * @notice Adds liquidity to PulseX with ERC20 tokens (Token + INC)
	 * @param liqudityToken Amount of this token to add
	 * @param liqudityShare Amount of INC to pair with tokens
	*/
	function addLiquidity(uint256 liqudityToken, uint256 liqudityShare) external onlyOwner {
		IERC20(owner).approve(address(pulsexRouter), liqudityToken);
		IERC20(rewardToken).approve(address(pulsexRouter), liqudityShare);
		
		try pulsexRouter.addLiquidity(
			address(owner),
			address(rewardToken),
			liqudityToken,
			liqudityShare,
			0,
			0,
			address(this),
			block.timestamp
		) {} catch {}
	}
}

// File: IRS/IRS.sol

pragma solidity 0.8.20;






/// @title IRS Token Contract
/// @author 
/// @notice Custom ERC20 token with auto liquidity, reward distribution, and fee mechanisms on PulseChain
/// @dev Uses PulseXRouter for swaps and liquidity. Rewards distributed via custom Distributor contract.
contract IRS is Ownable, ERC20 {

	/// @notice Fee taken for reward distribution
	uint256 public immutable rewardFee;
	
	/// @notice Fee taken for burning
	uint256 public immutable burnFee;
	
	/// @notice Fee taken for adding liquidity
	uint256 public immutable liquidityFee;
	
	/// @notice Total fee that gets swapped (liquidity + reward)
	uint256 private immutable swappableFee;
	
	/// @notice Denominator for fee calculation (e.g. 10000 for basis points)
	uint256 private immutable divider;
	
	/// @notice Denominator for share calculation (e.g. 100 for basis points)
	uint256 private immutable shareDivider;

	/// @notice Gas limit for reward distributor processing
	uint256 public distributorGas;
	
	/// @notice Minimum token threshold before swap and liquify
	uint256 public swapThreshold;
	
	/// @notice Flag indicating if the contract is currently performing a swap
	bool private swapping;
	
	/// @notice Whether trading is enabled
	bool public tradingEnabled;
	
	/// @notice Whether reward distribution is enabled
	bool public distributionEnabled;
	
	/// @notice List of recognized liquidity pair addressess
	address[] public liquidityPairs;
	
	/// @notice Address to which burned tokens are sent
	address public immutable burnWallet;
	
	/// @notice INC address
	address public immutable INCContract;
	
	/// @notice Main PulseX pair address
	address public immutable pulsexPair;
	
	/// @notice PulseX Router interface
	IPulseXRouter public immutable pulsexRouter;
	
	/// @notice Custom reward distributor instance
	Distributor public rewardDistributor;
	
	/// @notice Wallets excluded from fees
    mapping(address => bool) public isExcludedFromFee;
	
	/// @notice Wallets excluded from rewards
    mapping(address => bool) public isExcludedFromReward;
	
	/// @notice Mapping for identifying liquidity pair addresses
	mapping(address => bool) public isLiquidityPair;
	
	/// @notice Shares for each LP pair in the reward calculation
	mapping(address => uint256) public liquidityPairShare;
	
	/// @notice Emitted when the swap threshold is updated
	event SwapThresholdUpdated(uint256 amount);

    /// @notice Emitted when a liquidity pair is added or removed
	event LPPairUpdated(address indexed pair, bool status);

    /// @notice Emitted when a wallet is excluded or included in fees
	event WalletExcludeFromFee(address indexed wallet, bool status);

    /// @notice Emitted when a wallet is excluded or included in rewards
	event WalletExcludedFromReward(address indexed wallet, bool value);

    /// @notice Emitted when reward distribution criteria are updated
	event DistributionCriteriaUpdated(uint256 minPeriod, uint256 minDistribution);

    /// @notice Emitted when the gas limit for distributor is updated
	event DistributorGasUpdated(uint256 distributorGas);

    /// @notice Emitted when trading is enabled
	event TradingEnabled();

    /// @notice Emitted when swapping tokens for INC fails
	event SwapFailed(uint256 tokenAmount);
	
	/// @notice Emitted when reward distribution is enabled or disabled
	event DistributionStatusUpdated(bool status);
	
	/// @notice Emitted when lp share update
	event LPPairShareUpdated(address indexed pair, uint256 newShare);
	
	/// @notice Constructor to initialize token and setup fees, LP, and exclusions
	constructor() ERC20("INC Reward Service", "IRS") {
	
		INCContract = address(0x2fa878Ab3F87CC1C9737Fc071108F904c0B0C95d);
		pulsexRouter = IPulseXRouter(0x165C3410fC91EF562C50559f7d2289fEbed552d9);
		pulsexPair = IPulseXFactory(pulsexRouter.factory()).createPair(address(this), INCContract);
		rewardDistributor = new Distributor(0x2fa878Ab3F87CC1C9737Fc071108F904c0B0C95d, 0x165C3410fC91EF562C50559f7d2289fEbed552d9);
		burnWallet = address(0x0000000000000000000000000000000000000369);
	
		distributionEnabled = true;
		
		rewardFee = 350;
		burnFee = 50;
		liquidityFee = 100;
		swappableFee = (rewardFee + liquidityFee);
		divider = 10000;
		shareDivider = 100;
		
		distributorGas = 250000;
		swapThreshold = 2_000_000 * (10**18);
		
		isLiquidityPair[address(pulsexPair)] = true;
	   
		isExcludedFromFee[address(msg.sender)] = true;
		isExcludedFromFee[address(this)] = true;
		isExcludedFromFee[address(burnWallet)] = true;
	   
		isExcludedFromReward[address(this)] = true;
		isExcludedFromReward[address(pulsexPair)] = true;
		isExcludedFromReward[address(burnWallet)] = true;
		
		liquidityPairs.push(pulsexPair);
		_mint(address(msg.sender), 1_555_369_000_000 * (10**18));
    }
	
	/// @notice Allows the contract to receive native PLS
	receive() external payable {}
	
	/// @notice Updates the minimum token amount before swap is triggered
    /// @param _amount New threshold in token units
	function updateSwapThreshold(uint256 _amount) external onlyOwner {
  	    require(_amount <= totalSupply(), "Amount cannot be over the total supply.");
		require(_amount >= 1000 * (10**18), "Minimum `1000` token per swap required");
		
		swapThreshold = _amount;
		emit SwapThresholdUpdated(_amount);
  	}
	
	/// @notice Excludes or includes a wallet from paying fees
    /// @param _wallet Address of the wallet
    /// @param _status True to exclude, false to include
	function excludeWalletFromFee(address _wallet, bool _status) external onlyOwner {
        require(_wallet != address(0), "Wallet address is not correct");
		require(isExcludedFromFee[_wallet] != _status, "Wallet is already the value of 'status'");
		
		isExcludedFromFee[_wallet] = _status;
		emit WalletExcludeFromFee(_wallet, _status);
    }
	
	/// @notice Enables token trading
	function enableTrading() external onlyOwner {
		require(!tradingEnabled, "Trading already enabled");
		
		tradingEnabled = true;
		emit TradingEnabled();
	}
	
	/// @notice Excludes or includes a wallet from receiving rewards
    /// @param _wallet Address of the wallet
    /// @param _status True to exclude, false to include
	function excludeWalletFromReward(address _wallet, bool _status) external onlyOwner {
	    require(_wallet != address(0), "Zero address");
	    require(isExcludedFromReward[_wallet] != _status, "Wallet is already the value of 'status'");
		
	    isExcludedFromReward[_wallet] = _status;
		if(_status) {
			try rewardDistributor.setShare(_wallet, 0) {} catch {}
        } else {
			_updateShares(_wallet);
        }
	    emit WalletExcludedFromReward(_wallet, _status);
	}
	
	/// @notice Sets the reward distribution timing and minimum thresholds
    /// @param _minPeriod Minimum time between distributions
    /// @param _minDistribution Minimum token amount required for a distribution
	function setDistributionCriteria(uint256 _minPeriod, uint256 _minDistribution) external onlyOwner {
	    require(_minDistribution > 0, "Min. distribution can't be zero");
		
        try rewardDistributor.setDistributionCriteria(_minPeriod, _minDistribution) {} catch {}
		emit DistributionCriteriaUpdated(_minPeriod, _minDistribution);
    }
	
	/// @notice Sets the gas limit for the distributor
    /// @param _gas New gas limit
	function setDistributorGas(uint256 _gas) external onlyOwner {
       require(_gas < 750000, "Gas is greater than limit");
	   
       distributorGas = _gas;
	   emit DistributorGasUpdated(_gas);
    }
	
	/// @notice Enables or disables reward distribution
	/// @param status True to enable, false to disable
	function setDistributionStatus(bool status) external onlyOwner {
		distributionEnabled = status;
		emit DistributionStatusUpdated(status);
	}
	
	/// @notice Adds or removes a liquidity pair
    /// @param _pair The LP token address
    /// @param _status True to add, false to remove
    /// @param _share The share of the LP in reward calculations (basis points)
	function setLiquidityPair(address _pair, bool _status, uint256 _share) external onlyOwner {
        require(isLiquidityPair[_pair] != _status, "Pair is already set to that status");
		require(_pair != address(pulsexPair), "Can't update the status of main pair");
		
		if(_status)
		{
			require(isValidLiquidityPair(_pair), "Invalid liquidity pair");
			require(_share > 0, "Share must be greater than zero");
			
			liquidityPairs.push(_pair);
			isLiquidityPair[_pair] = _status;
			isExcludedFromReward[_pair] = _status;
			liquidityPairShare[_pair] = _share;
		}
		else if(isLiquidityPair[_pair])
		{
			for (uint256 i = 0; i < liquidityPairs.length; i++) {
				if (liquidityPairs[i] == _pair) {
					liquidityPairs[i] = liquidityPairs[liquidityPairs.length - 1];
					liquidityPairs.pop();
					break;
				}
			}
			liquidityPairShare[_pair] = 0;
			isLiquidityPair[_pair] = _status;
			isExcludedFromReward[_pair] = _status;
		}
		emit LPPairUpdated(_pair, _status);
    }
	
	/// @notice Updates the share of an existing liquidity pair
	/// @param _pair The LP token address
	/// @param _newShare The new share value in basis points (must be > 0)
	function updateLiquidityPairShare(address _pair, uint256 _newShare) external onlyOwner {
		require(isLiquidityPair[_pair], "Not a registered liquidity pair");
		require(_newShare > 0, "Share must be greater than zero");

		liquidityPairShare[_pair] = _newShare;
		emit LPPairShareUpdated(_pair, _newShare);
	}
	
	/// @notice Checks if the address is a valid LP pair (includes this token)
    /// @param _pair The LP token address
    /// @return Whether the pair is valid
	function isValidLiquidityPair(address _pair) private view returns (bool) {
		try IPulseXPair(_pair).token0() returns (address token0) {
			address token1 = IPulseXPair(_pair).token1();
			return (token0 == address(this) || token1 == address(this));
		} catch {
			return false;
		}
	}
	
	/// @dev Overridden ERC20 transfer to handle fee collection, swapping, and reward tracking
	function _transfer(address _sender, address _recipient, uint256 _amount) internal override(ERC20) {      
		if (!tradingEnabled) {
			require(_sender == owner() || _recipient == owner(), "Trading not enabled");
		}
		
		if(!swapping && isLiquidityPair[_recipient])  {
			uint256 contractTokenBalance = balanceOf(address(this));
			if(contractTokenBalance >= swapThreshold) {
				swapping = true;
				
				uint256 liqudityToken = (((swapThreshold * liquidityFee) / (swappableFee)) / (2));
				uint256 rewardToken = ((swapThreshold * rewardFee) / (swappableFee));
				uint256 swapToken = (liqudityToken + rewardToken);
				
				uint256 OldBalance = IERC20(INCContract).balanceOf(address(rewardDistributor));
				swapTokensForINC(swapToken);
				uint256 newBalance = IERC20(INCContract).balanceOf(address(rewardDistributor)) - (OldBalance);
				
				uint256 liqudityShare = (newBalance * liqudityToken) / (swapToken);
				uint256 rewardShare = (newBalance - liqudityShare);
				
				if(liqudityShare > 0) {
					super._transfer(address(this), address(rewardDistributor), liqudityToken);
					try rewardDistributor.addLiquidity(liqudityToken, liqudityShare) {} catch {}
				} 
				if(rewardShare > 0) {
					try rewardDistributor.deposit(rewardShare) {} catch {}
				}
				swapping = false;
			}
        }
		
		if(isExcludedFromFee[_sender] || isExcludedFromFee[_recipient] || (!isLiquidityPair[_sender] && !isLiquidityPair[_recipient])) {
			super._transfer(_sender, _recipient, _amount);
		} else {
		    (uint256 _burnFee, uint256 _swappableFee) = collectFee(_amount);
		    if(_swappableFee > 0) {
				super._transfer(_sender, address(this), _swappableFee);
		    }
			if(_burnFee > 0) {
				super._transfer(_sender, address(burnWallet), _burnFee);
		    }
			super._transfer(_sender, _recipient, (_amount - (_swappableFee + _burnFee)));
		}
		if(!isExcludedFromReward[_sender]){ _updateShares(_sender); }
        if(!isExcludedFromReward[_recipient]){ _updateShares(_recipient); }
		if(distributionEnabled){
			try rewardDistributor.process(distributorGas) {} catch {}
		}
    }
	
	/// @notice Updates reward shares for a holder
    /// @param _holder Address of the token or LP holder
	function _updateShares(address _holder) private {
		if (isExcludedFromReward[_holder]) return;
		
		uint256 totalBalance = balanceOf(_holder);
		
		for (uint256 i = 0; i < liquidityPairs.length; i++)  {
			address pair = liquidityPairs[i];
			totalBalance += (((IERC20(pair).balanceOf(_holder) * liquidityPairShare[pair])) / (shareDivider));
		}
		try rewardDistributor.setShare(_holder, totalBalance) {} catch {}
	}
	
	/// @notice Calculates burn and other fee from the amount
    /// @param _amount Token amount
    /// @return burn fee and other fees in tokens
	function collectFee(uint256 _amount) private view returns  (uint256, uint256) {
		uint256 _rewardFee = (_amount * rewardFee) / (divider);
		uint256 _liquidityFee = (_amount * liquidityFee) / (divider);
		uint256 _burnFee = (_amount * burnFee) / (divider);
		
        return (_burnFee, (_rewardFee + _liquidityFee));
    }
	
	/// @notice Swaps tokens to INC via PulseX
    /// @param _tokenAmount Amount of tokens to swap
	function swapTokensForINC(uint256 _tokenAmount) private {
        address[] memory path = new address[](2);
        path[0] = address(this);
		path[1] = INCContract;
		
        _approve(address(this), address(pulsexRouter), _tokenAmount);
        try pulsexRouter.swapExactTokensForTokensSupportingFeeOnTransferTokens(
            _tokenAmount,
            0,
            path,
            address(rewardDistributor),
            block.timestamp
        ){} catch {
			emit SwapFailed(_tokenAmount);
		}
    }

}