Contract Address Details

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.7;

import '@openzeppelin/contracts-upgradeable/security/ReentrancyGuardUpgradeable.sol';
import '@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol';
import '../Library/SwapperUpgradeable.sol';
import '../Library/Rand.sol';
import '../../interfaces/Pulsepot/IPLSP.sol';
import '../../interfaces/Pulsepot/IPLSPStaking.sol';
import '../../interfaces/Pulsepot/IPulsepotBurnPool.sol';
import '../../interfaces/Pulsepot/IParticipation.sol';
import '../../interfaces/IPulseXRouter.sol';
import '../../interfaces/IPRC20.sol';


contract CoinFlip is OwnableUpgradeable, ReentrancyGuardUpgradeable, SwapperUpgradeable {
    enum RoundStatus {
        WAITING,
        STARTED,
        CALCUATING,
        FINISHED,
        CANCELLED
    }
    struct BetToken {
        string name;
        uint8 decimal;
        address tokenAddress;
        uint256 price;
        bool isStable;
        bool isEnabled;
    }
    struct Bet {
        uint256 tokenId;
        uint256 amount;
        uint256 usdAmount;
        address swappedInto;
        uint256 swappedAmount;
    }
    struct Round {
        uint256 roundID;
        uint256 price;
        address creator;
        address opponent;
        uint256 createdAt;
        uint256 endedAt;
        uint256 endBlock;
        uint256 feeAmount;
        uint8 result; // 0: front, 1: back
        uint8 creatorExpectation;
        Bet creatorBet;
        Bet opponentBet;
        RoundStatus status;
    }

    /* Base contracts */

    IPLSP public PLSP;
    IPLSPStaking public PLSPStaking;
    IPulsepotBurnPool public burnPool;
    IPulsepotParticipationPool public participationPool;

    /* Bet Token Infos */

    BetToken[] public betTokens;
    uint256 public PLSPTokenId;

    /* Round Infos */
    
    Round[] public rounds;
    uint256 public roundIds;
    uint256 blockWait;

    /* events */

    event CreatedRound(uint256 roundId, address creator, string tokenName, uint256 usdAmount, uint8 creatorExpectation, uint256 timestamp);
    event EnteredRound(uint256 roundId, address player, string tokenName, uint256 usdAmount, uint256 timestamp);
    event RoundFinished(uint256 roundId, uint8 result, address winner, uint256 ppBonus, uint256 usdAmount, uint256 fee, uint256 plspBurnt);
    event RoundCancelled(uint256 roundId);

    modifier excludeContract() {
        require(msg.sender == tx.origin, 'contract not allowed');
        _;
    }

    function initialize(address _PLSPAddress, address _stakingAddress, address _burnPoolAddress, address _participationAddress, address _routerAddress, address _usdtAddress) public initializer {
        PLSP = IPLSP(_PLSPAddress);
        PLSPStaking = IPLSPStaking(_stakingAddress);
        burnPool = IPulsepotBurnPool(_burnPoolAddress);
        participationPool = IPulsepotParticipationPool(_participationAddress);
        blockWait = 1; // after two blocks
        PLSPTokenId = 3;

        __Ownable_init();
        __ReentrancyGuard_init();
        __Swapper_init(_routerAddress, _usdtAddress);
    }

    function createRound(uint256 tokenId, uint256 usdAmount, uint8 expectation) external payable nonReentrant excludeContract {
        BetToken storage tokenInfo = betTokens[tokenId];
        require(tokenInfo.isEnabled, 'token disabled');
        require(expectation < 2, 'wrong expecation value');

        (address swappedInto, uint256 amount, uint256 swappedAmountOut) = _receive(tokenId, usdAmount);
        rounds.push();

        Round storage newRound = rounds[roundIds];
        newRound.roundID = roundIds;
        newRound.creator = msg.sender;
        newRound.creatorBet.tokenId = tokenId;
        newRound.creatorBet.amount = amount;
        newRound.creatorBet.usdAmount = usdAmount;
        newRound.creatorBet.swappedInto = swappedInto;
        newRound.creatorBet.swappedAmount = swappedAmountOut;
        newRound.creatorExpectation = expectation;
        newRound.createdAt = block.timestamp;
        newRound.status = RoundStatus.STARTED;

        emit CreatedRound(roundIds, msg.sender, tokenInfo.name, usdAmount, expectation, block.timestamp);
        roundIds++;
    }

    function enterRound(uint256 roundId, uint256 tokenId) external payable excludeContract nonReentrant {
        Round storage roundInfo = rounds[roundId];
        BetToken storage tokenInfo = betTokens[tokenId];

        require(roundInfo.status == RoundStatus.STARTED, 'cannot enter');
        require(msg.sender != roundInfo.creator, 'creator');
        
        uint256 usdAmount = roundInfo.price;
        (address swappedInto, uint256 amount, uint256 swappedAmountOut) = _receive(tokenId, usdAmount);

        roundInfo.opponent = msg.sender;
        roundInfo.opponentBet.amount = amount;
        roundInfo.opponentBet.tokenId = tokenId;
        roundInfo.opponentBet.swappedInto = swappedInto;
        roundInfo.opponentBet.usdAmount = usdAmount;
        roundInfo.opponentBet.swappedAmount = swappedAmountOut;
        roundInfo.status = RoundStatus.CALCUATING;
        roundInfo.endedAt = block.timestamp;
        roundInfo.endBlock = block.number;

        emit EnteredRound(roundId, msg.sender, tokenInfo.name, usdAmount, block.timestamp);
    }

    function finishRound(uint256 roundId) external excludeContract nonReentrant {
        Round storage roundInfo = rounds[roundId];
        uint256 seedBlock = roundInfo.endBlock + blockWait;
        require(roundInfo.status == RoundStatus.CALCUATING, 'cannot finish');
        require(block.number > seedBlock, 'should wait for blocks');
        require(roundInfo.creator == msg.sender || roundInfo.opponent == msg.sender, 'only players can finish');

        // Determine winner
        bytes32 seed = blockhash(seedBlock);
        uint256 nonce = RandLibrary.fulFillRandomnessWithSeed(seed);
        uint8 result = uint8(nonce % 2);
        address winner = roundInfo.creator;
        Bet storage winnerBet = roundInfo.creatorBet;

        if (result != roundInfo.creatorExpectation) {
            winner = roundInfo.opponent;
            winnerBet = roundInfo.opponentBet;
        }

        // Take Fees and send rewards
        uint256 totalUSD = roundInfo.price * 2;
        uint256 feeAmount = _calculateFeeAmount(totalUSD, winner);
        uint256 plspAmount = _takeFees(roundId, feeAmount);
        uint256 ppBonus;

        _sendReward(roundId, winner);
        if (winnerBet.tokenId != PLSPTokenId) {
            ppBonus = participationPool.requestPPBonus(winner, totalUSD);
        }
        
        roundInfo.status = RoundStatus.FINISHED;
        
        emit RoundFinished(roundId, result, winner, ppBonus, totalUSD, feeAmount, plspAmount);
    }

    function cancelRound(uint256 roundId) external {
        Round storage roundInfo = rounds[roundId];
        require(msg.sender == roundInfo.creator, 'only creator can cancel');
        require(roundInfo.status == RoundStatus.STARTED, 'cannot cancel');
        
        roundInfo.status = RoundStatus.CANCELLED;
        Bet storage creatorBet = roundInfo.creatorBet;
        _swap(creatorBet.swappedInto, betTokens[creatorBet.tokenId].tokenAddress, creatorBet.swappedAmount, msg.sender);
        emit RoundCancelled(roundId);
    }

    function _sendReward(uint256 roundId, address winner) internal {
        Round storage roundInfo = rounds[roundId];
        Bet storage creatorBet = roundInfo.creatorBet;
        Bet storage opponentBet = roundInfo.opponentBet;

        _swap(creatorBet.swappedInto, betTokens[creatorBet.tokenId].tokenAddress, creatorBet.swappedAmount, winner);
        _swap(opponentBet.swappedInto, betTokens[opponentBet.tokenId].tokenAddress, opponentBet.swappedAmount, winner);
    }

    function _receive(uint256 tokenId, uint256 usdAmount) internal returns (address swappedInto, uint256 amount, uint256 outputAmount) {
        BetToken storage tokenInfo = betTokens[tokenId];
        address tokenAddress = tokenInfo.tokenAddress;
        bool isStable = tokenInfo.isStable;

        uint256 requiredAmount = _getAmountsIn(tokenAddress, usdtAddress, usdAmount)[0];
        if (isStable) {
            requiredAmount = usdAmount * 10 ** tokenInfo.decimal / 10 ** 18;
        }
        
        // receive money
        if (tokenAddress == address(0)) {
            require(msg.value >= requiredAmount, 'not enough pls');

            if (msg.value > requiredAmount) {
                payable(msg.sender).transfer(msg.value - requiredAmount);
            }
        } else {
            IPRC20 token = IPRC20(tokenAddress);
            token.transferFrom(msg.sender, address(this), requiredAmount);
        }

        if (isStable) {
            return (tokenAddress, requiredAmount, requiredAmount);
        }

        _swap(tokenAddress, usdtAddress, requiredAmount, address(this));
        return (usdtAddress, requiredAmount, usdAmount);
    }

    function _takeFees(uint256 roundId, uint256 usdAmount) internal returns (uint256 plspAmount) {
        Round storage roundInfo = rounds[roundId];
        Bet storage betInfo;
        
        if (roundInfo.creatorBet.tokenId != PLSPTokenId) {
            betInfo = roundInfo.creatorBet;
        } else {
            betInfo = roundInfo.opponentBet;
        }

        address swapTokenAddress = betInfo.swappedInto;
        uint256 amount = betInfo.swappedAmount * usdAmount / roundInfo.price;
        betInfo.swappedAmount -= amount;
        plspAmount = _swapFees(swapTokenAddress, amount);
        PLSP.approve(address(burnPool), plspAmount);
        burnPool.deposit(plspAmount);
    }

    function _swapFees(address tokenAddress, uint256 amount) internal returns(uint256) {
        uint256 plspAmount = _swap(tokenAddress, address(PLSP), amount, address(this));
        return plspAmount;
    }

    function _calculateFeeAmount(uint256 totalUSD, address winner) internal view returns (uint256) {
        IPLSPStaking.StakingInfo memory stakingInfo = PLSPStaking.getUserStakingInfo(winner);
        uint256 amount = stakingInfo.totalAmount;
        uint256 fee = 300;

        if (amount >= 76200 * 10 ** 18) {
            fee = 20;
        } else if (amount >= 62000 * 10 ** 18) {
            fee = 40;
        } else if (amount >= 50000 * 10 ** 18) {
            fee = 60;
        } else if (amount >= 32000 * 10 ** 18) {
            fee = 80;
        } else if (amount >= 16000 * 10 ** 18) {
            fee = 100;
        } else if (amount >= 8000 * 10 ** 18) {
            fee = 120;
        } else if (amount >= 4000 * 10 ** 18) {
            fee = 140;
        } else if (amount >= 3500 * 10 ** 18) {
            fee = 160;
        } else if (amount >= 3000 * 10 ** 18) {
            fee = 180;
        } else if (amount >= 2500 * 10 ** 18) {
            fee = 200;
        } else if (amount >= 2000 * 10 ** 18) {
            fee = 220;
        } else if (amount >= 1500 * 10 ** 18) {
            fee = 240;
        } else if (amount >= 1000 * 10 ** 18) {
            fee = 260;
        } else if (amount >= 500 * 10 ** 18) {
            fee = 280;
        } else {
            fee = 300;
        }

        return (totalUSD * fee) / 10000;
    }

    function addBetTokens(BetToken[] memory _newBetTokens) external onlyOwner {
        uint256 length = _newBetTokens.length;

        for (uint256 i = 0; i < length; i++) {
            betTokens.push(_newBetTokens[i]);
            setTokenStable(_newBetTokens[i].tokenAddress, _newBetTokens[i].isStable);
        }
    }

    function getBetTokens() external view returns (BetToken[] memory, uint256[] memory) {
        uint256 length = betTokens.length;

        uint256[] memory prices = new uint256[](length);
        for (uint256 i = 0; i < length; i++) {
            prices[i] = getTokenPrice(betTokens[i].tokenAddress, betTokens[i].decimal);
        }
        return (betTokens, prices);
    }

    function updateBetToken(uint256 tokenId, BetToken memory info) external onlyOwner {
        betTokens[tokenId] = info;
    }
}
        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.7;

import "../utils/ContextUpgradeable.sol";
import "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract OwnableUpgradeable is Initializable, ContextUpgradeable {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    function __Ownable_init() internal onlyInitializing {
        __Ownable_init_unchained();
    }

    function __Ownable_init_unchained() internal onlyInitializing {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.2;

import "../../utils/AddressUpgradeable.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     * @custom:oz-retyped-from bool
     */
    uint8 private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint8 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts. Equivalent to `reinitializer(1)`.
     */
    modifier initializer() {
        bool isTopLevelCall = !_initializing;
        require(
            (isTopLevelCall && _initialized < 1) || (!AddressUpgradeable.isContract(address(this)) && _initialized == 1),
            "Initializable: contract is already initialized"
        );
        _initialized = 1;
        if (isTopLevelCall) {
            _initializing = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * `initializer` is equivalent to `reinitializer(1)`, so a reinitializer may be used after the original
     * initialization step. This is essential to configure modules that are added through upgrades and that require
     * initialization.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     */
    modifier reinitializer(uint8 version) {
        require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
        _initialized = version;
        _initializing = true;
        _;
        _initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     */
    function _disableInitializers() internal virtual {
        require(!_initializing, "Initializable: contract is initializing");
        if (_initialized < type(uint8).max) {
            _initialized = type(uint8).max;
            emit Initialized(type(uint8).max);
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;
import "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuardUpgradeable is Initializable {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    function __ReentrancyGuard_init() internal onlyInitializing {
        __ReentrancyGuard_init_unchained();
    }

    function __ReentrancyGuard_init_unchained() internal onlyInitializing {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library AddressUpgradeable {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly
                /// @solidity memory-safe-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;
import "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.7;

library RandLibrary {
    function fulFillRandomness() internal view returns (uint256) {
        return uint256(uint128(bytes16(keccak256(abi.encodePacked(block.prevrandao, block.timestamp)))));
    }

    function fulFillRandomnessWithSeed(bytes32 seed) internal view returns(uint256) {
        return uint256(uint128(bytes16(keccak256(abi.encodePacked(block.prevrandao, block.timestamp, seed)))));
    }
}
          

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.7;

import '@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol';
import '../../interfaces/IPulseXRouter.sol';
import '../../interfaces/IPRC20.sol';

abstract contract SwapperUpgradeable is Initializable {
    IPulseXRouter02 public router;
    mapping(address => bool) public isTokenStable;
    address public usdtAddress;

    /**
     * @dev Initializes the contract router and usdtAddress
     */
    function __Swapper_init(address _routerAddress, address _usdtAddress) internal onlyInitializing {
        __Swapper_init_unchained(_routerAddress, _usdtAddress);
    }

    function __Swapper_init_unchained(address _routerAddress, address _usdtAddress) internal onlyInitializing {
        router = IPulseXRouter02(_routerAddress);
        usdtAddress = _usdtAddress;
    }

    function setTokenStable(address addr, bool value) internal {
        isTokenStable[addr] = value;
    }

    function getTokenPrice(address tokenAddress, uint256 decimal) public view returns (uint256) {
        uint8 usdtDecimals = IPRC20(usdtAddress).decimals();
        uint256 price;

        if (isTokenStable[tokenAddress]) return 10 ** 18;
        if (tokenAddress == address(0) || tokenAddress == router.WPLS()) {
            address[] memory path = new address[](2);
            path[0] = router.WPLS();
            path[1] = usdtAddress;
            price = router.getAmountsOut(10 ** decimal, path)[1];
        } else {
            address[] memory path = new address[](3);
            path[0] = tokenAddress;
            path[1] = router.WPLS();
            path[2] = usdtAddress;
            price = router.getAmountsOut(10 ** decimal, path)[2];
        }

        return price * 10 ** (18 - usdtDecimals);
    }

    function _swap(address tokenFrom, address tokenTo, uint256 amount, address receiver) internal returns (uint256 outputAmount) {
        if (amount == 0) return outputAmount;
        if (tokenFrom == tokenTo) return amount;

        if (tokenTo != address(0)) {
            if (tokenFrom == address(0)) {
                address[] memory path = new address[](2);
                path[0] = router.WPLS();
                path[1] = tokenTo;
                outputAmount = router.swapExactETHForTokens{ value: amount }(0, path, receiver, block.timestamp)[
                    1
                ];
            } else if (tokenFrom == router.WPLS()) {
                address[] memory path = new address[](2);
                path[1] = router.WPLS();
                path[2] = tokenTo;
                IPRC20(tokenFrom).approve(address(router), amount);
                outputAmount = router.swapExactTokensForTokens(amount, 0, path, receiver, block.timestamp)[1];
            } else {
                address[] memory path = new address[](3);
                path[0] = tokenFrom;
                path[1] = router.WPLS();
                path[2] = tokenTo;
                uint256 prevBalance = IPRC20(tokenTo).balanceOf(receiver);
                IPRC20(tokenFrom).approve(address(router), amount);
                router.swapExactTokensForTokensSupportingFeeOnTransferTokens(
                    amount,
                    0,
                    path,
                    receiver,
                    block.timestamp
                );
                uint256 afterBalance = IPRC20(tokenTo).balanceOf(receiver);
                outputAmount = afterBalance - prevBalance;
            }
        } else {
            address[] memory path = new address[](2);
            path[0] = tokenFrom;
            path[1] = router.WPLS();
            IPRC20(tokenFrom).approve(address(router), amount);
            uint256 prevBalance = receiver.balance;
            router.swapExactTokensForETHSupportingFeeOnTransferTokens(amount, 0, path, receiver, block.timestamp);
            uint256 afterBalance = receiver.balance;
            outputAmount = afterBalance - prevBalance;
        }
    }

    function _getAmountsIn(
        address tokenFrom,
        address tokenTo,
        uint256 amountOut
    ) internal view returns (uint256[] memory amounts) {
        address[] memory path;

        if (tokenFrom == address(0) || tokenFrom == router.WPLS()) {
            path = new address[](2);
            path[0] = router.WPLS();
            path[1] = tokenTo;
        } else {
            path = new address[](3);
            path[0] = tokenFrom;
            path[1] = router.WPLS();
            path[2] = tokenTo;
        }

        amounts = router.getAmountsIn(amountOut, path);
    }

    function _updateUSDTAddress(address addr) internal {
        usdtAddress = addr;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}
          

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.7;

interface IPRC20 {
    function totalSupply() external view returns (uint256);

    function balanceOf(address account) external view returns (uint256);

    function transfer(address recipient, uint256 amount) external returns (bool);

    function allowance(address owner, address spender) external view returns (uint256);

    function approve(address spender, uint256 amount) external returns (bool);

    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    function decimals() external view returns (uint8);

    event Transfer(address indexed from, address indexed to, uint256 value);
    event Approval(address indexed owner, address indexed spender, uint256 value);
}
          

//SPDX-License-Identifier: MIT
pragma solidity >=0.6.2;

interface IPulseXRouter01 {
    function factory() external pure returns (address);

    function WPLS() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);

    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);

    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB);

    function removeLiquidityETH(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountToken, uint amountETH);

    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external returns (uint amountA, uint amountB);

    function removeLiquidityETHWithPermit(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external returns (uint amountToken, uint amountETH);

    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);

    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);

    function swapExactETHForTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable returns (uint[] memory amounts);

    function swapTokensForExactETH(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);

    function swapExactTokensForETH(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);

    function swapETHForExactTokens(
        uint amountOut,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable returns (uint[] memory amounts);

    function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);

    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);

    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);

    function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);

    function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
}

interface IPulseXRouter02 is IPulseXRouter01 {
    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountETH);

    function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external returns (uint amountETH);

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;

    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable;

    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
}
          

// SPDX-License-Identifier: GPL-3.0

pragma solidity ^0.8.7;

interface IPLSP {
    event Approval(address indexed owner, address indexed spender, uint256 value);

    function mint(address to, uint256 amount) external;

    function burn(uint256 amount) external;

    function totalSupply() external view returns (uint256);

    function balanceOf(address account) external view returns (uint256);

    function transfer(address to, uint256 amount) external returns (bool);

    function allowance(address owner, address spender) external view returns (uint256);

    function approve(address spender, uint256 amount) external returns (bool);

    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.7;

interface IPLSPStaking {
    struct Stake {
        uint256 id;
        address user;
        uint256 amount;
        uint256 timestamp;
        uint256 startedUnstakingAt;
        uint256 status; // 0: staking, 1: started unstaking, 2: finished unstaking
    }

    struct StakingInfo {
        uint256 totalAmount;
        uint256 stakeCount;
        uint256[] stakeIds;
    }

    function stakeList(uint256) external view returns (Stake memory);

    function userStakingInfo(address) external view returns (StakingInfo memory);

    function totalAmount() external view returns (uint256);

    function lockTime() external view returns (uint256);

    event UserStakingAmountChanged(address user, uint256 stakingId, uint256 totalAmount, bool isFinished);
    event StartedUnstaking(uint256 id);

    function getUserStakingList(address user) external view returns (Stake[] memory);

    function getUserStakingListByPages(
        address user,
        uint256 start,
        uint256 length
    ) external view returns (Stake[] memory);

    function getUserStakingInfo(address user) external view returns(StakingInfo memory);
}
          

// SPDX-License-Identifier: GPL-3.0

pragma solidity ^0.8.7;

interface IPulsepotParticipationPool {

    function usdRequiredPerWPLSP() external view returns (uint256);
    function requestPPBonus(address receiver, uint256 usdValue) external returns(uint256);
}
          

// SPDX-License-Identifier: GPL-3.0

pragma solidity ^0.8.7;

interface IPulsepotBurnPool {
    event ReceivedFee(address sender, uint256 amount);
    event Burned(uint256 amount);

    function burn() external;

    function deposit(uint256 amount) external;
}