Contract Address Details

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.9;

import { Ownable } from "@openzeppelin/contracts/access/Ownable.sol";
import { Initializable } from "@openzeppelin/contracts/proxy/utils/Initializable.sol";
import { ReentrancyGuard } from "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import { SafeERC20 } from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import { Address } from "@openzeppelin/contracts/utils/Address.sol";

import { IWrappedToken } from "./IWrappedToken.sol";
import { RebasingReflectionToken } from "./RebasingReflectionToken.sol";

uint256 constant M = 1;
uint256 constant N = 8;

// virtual deposit contract with PLS/pWBTC/pDAI/pGRO rewards, with 11% in and out fees, 1% burned, 7% to drip pool, 1% to boosted stakers (boost by depositing pGRO) 2% instant divs
contract RewardDrippingVault is Initializable, Ownable, ReentrancyGuard
{
	using Address for address payable;
	using SafeERC20 for IERC20;

	struct AccountInfo {
		uint256 amount;
		uint256 burned; 
		uint256[M] drip; 
		uint256[M] boost; 
		uint256[M] accDripDebt; 
		uint256[M] accBoostDebt; 
		uint256[N] reward; 
		uint256[N] accRewardDebt;
		bool whitelisted; 
		bool exists; 
		uint256 reserved0;
		uint256 reserved1;
		uint256 reserved2;
	}

	function accountInfoDrip(address _account, uint256 _i) external view returns (uint256 _drip, uint256 _boost, uint256 _accDripDebt, uint256 _accBoostDebt)
	{
		AccountInfo storage _accountInfo = accountInfo[_account];
		return (_accountInfo.drip[_i], _accountInfo.boost[_i], _accountInfo.accDripDebt[_i], _accountInfo.accBoostDebt[_i]);
	}

	function accountInfoReward(address _account, uint256 _i) external view returns (uint256 _reward, uint256 _accRewardDebt)
	{
		AccountInfo storage _accountInfo = accountInfo[_account];
		return (_accountInfo.reward[_i], _accountInfo.accRewardDebt[_i]);
	}

	address constant FURNACE = 0x000000000000000000000000000000000000dEaD;
	address constant BOOST_ADDRESS = 0xcD8dDeE99C0c4Be4cD699661AE9c00C69D1Eb4A8;

	uint256 constant DEFAULT_LAUNCH_TIME = 1729519200; // Thu Jun 06 2024 16:00:00 GMT+0000

	uint256 constant DEFAULT_DRIP_RATE_PER_DAY = 1e16; // 1% per day
	uint256 constant DEFAULT_DRIP_BOOST_RATE_PER_DAY = 1e16; // 0.5% per day

	uint256 constant DAY = 1 days;
	uint256 constant TZ_OFFSET = 16 hours; // UTC-8

	address public reserveToken; // WMM
	address public boostToken; // BoostToken
	address[M] public dripToken;
	address[N] public rewardToken;
	address public wrappedToken;

	uint256 public launchTime;

	uint256[M] public dripRatePerDay;
	uint256[M] public dripBoostRatePerDay;

	bool public whitelistAll;

	uint256 public totalStaked; // total staked balance
	uint256 public totalBurned; // total burned balance

	uint256[M] public totalDrip; // total drip pool balance
	uint256[M] public allocDrip; // total drip pool balance allocated
	uint256[M] public totalBoost; // total boost balance
	uint256[M] public accDripPerShare; 
	uint256[M] public accBoostPerShare; 

	uint256[N] public totalReward; 
	uint256[N] public accRewardPerShare; 

	uint64 public day;

	address[] public accountIndex;
	mapping(address => AccountInfo) public accountInfo;

	function accountIndexLength() external view returns (uint256 _length)
	{
		return accountIndex.length;
	}

	function getAccountByIndex(uint256 _index) external view returns (AccountInfo memory _accountInfo)
	{
		return accountInfo[accountIndex[_index]];
	}

	function today() public view returns (uint64 _today)
	{
		return uint64((block.timestamp + TZ_OFFSET) / DAY);
	}

	modifier hasLaunched()
	{
		require(block.timestamp >= launchTime, "unavailable");
		_;
	}

	constructor(address _reserveToken, address[M] memory _dripToken, address[N] memory _rewardToken, address _boostToken, address _wrappedToken)
	{
		initialize(msg.sender, _reserveToken, _dripToken, _rewardToken, _boostToken, _wrappedToken);
	}

	function initialize(address _owner, address _reserveToken, address[M] memory _dripToken, address[N] memory _rewardToken, address _boostToken, address _wrappedToken) public initializer
	{
		_transferOwnership(_owner);

		launchTime = DEFAULT_LAUNCH_TIME;

		for (uint256 _i = 0; _i < M; _i++) {
			dripRatePerDay[_i] = DEFAULT_DRIP_RATE_PER_DAY;
			dripBoostRatePerDay[_i] = DEFAULT_DRIP_BOOST_RATE_PER_DAY;
		}

		whitelistAll = false;

		totalStaked = 0;
		totalBurned = 0;

		for (uint256 _i = 0; _i < M; _i++) {
			totalDrip[_i] = 0;
			allocDrip[_i] = 0;
			totalBoost[_i] = 0;
			accDripPerShare[_i] = 0;
			accBoostPerShare[_i] = 0;
		}

		for (uint256 _i = 0; _i < N; _i++) {
			totalReward[_i] = 0;
			accRewardPerShare[_i] = 0;
		}

		day = today();

		for (uint256 _i = 0; _i < M; _i++) {
			for (uint256 _j = 0; _j < _i; _j++) {
				require(_dripToken[_i] != _dripToken[_j], "invalid token");
			}
		}
		for (uint256 _i = 0; _i < N; _i++) {
			for (uint256 _j = 0; _j < _i; _j++) {
				require(_rewardToken[_i] != _rewardToken[_j], "invalid token");
			}
		}
		require(_dripToken[0] == _reserveToken, "invalid token");
		for (uint256 _i = 1; _i < M; _i++) {
			bool _found = false;
			for (uint256 _j = 0; _j < N; _j++) {
				if (_dripToken[_i] == _rewardToken[_j]) {
					_found = true;
					break;
				}
			}
			require(_found, "invalid token");
		}
		for (uint256 _i = 0; _i < N; _i++) {
			require(_rewardToken[_i] != _reserveToken, "invalid token");
		}
		require(_wrappedToken != _reserveToken, "invalid token");
		reserveToken = _reserveToken;
		boostToken = _boostToken;
		dripToken = _dripToken;
		rewardToken = _rewardToken;
		wrappedToken = _wrappedToken;

		RebasingReflectionToken(payable(_reserveToken)).updateExcludeFromRewards(false);
	}

	// updates the launch time
	function setLaunchTime(uint256 _launchTime) external onlyOwner
	{
		require(block.timestamp < launchTime, "unavailable");
		require(_launchTime >= block.timestamp, "invalid time");
		launchTime = _launchTime;
	}

	// updates the percentual rate of distribution from the drip pool
	function setDripRatePerDay(uint256 _i, uint256 _dripRatePerDay) external onlyOwner
	{
		require(_i < M, "invalid index");
		require(_dripRatePerDay + dripBoostRatePerDay[_i] <= 100e16, "invalid rate");
		dripRatePerDay[_i] = _dripRatePerDay;
	}

	// updates the percentual rate of distribution from the drip pool
	function setDripBoostRatePerDay(uint256 _i, uint256 _dripBoostRatePerDay) external onlyOwner
	{
		require(_i < M, "invalid index");
		require(dripRatePerDay[_i] + _dripBoostRatePerDay <= 100e16, "invalid rate");
		dripBoostRatePerDay[_i] = _dripBoostRatePerDay;
	}

	// flags all accounts for withdrawing without penalty (useful for migration)
	function updateWhitelistAll(bool _whitelistAll) external onlyOwner
	{
		whitelistAll = _whitelistAll;
	}

	// flags multiple accounts for withdrawing without penalty
	function updateWhitelist(address[] calldata _accounts, bool _whitelisted) external onlyOwner
	{
		for (uint256 _i; _i < _accounts.length; _i++) {
			accountInfo[_accounts[_i]].whitelisted = _whitelisted;
		}
	}

	// this is a safety net method for recovering funds that are not being used
	function recoverFunds(address _token) external onlyOwner nonReentrant
	{
		for (uint256 _i = 0; _i < N; _i++) {
			require(_token != rewardToken[_i], "invalid token");
		}
		uint256 _amount = IERC20(_token).balanceOf(address(this));
		if (_token == reserveToken) _amount -= totalStaked + totalDrip[0] + totalBoost[0];
		require(_amount > 0, "no balance");
		IERC20(_token).safeTransfer(msg.sender, _amount);
	}

	// burns pGRO
	function burn(uint256 _amount) external
	{
		burnOnBehalfOf(_amount, msg.sender);
	}

	// burns pGRO on behalf of another account
	function burnOnBehalfOf(uint256 _amount, address _account) public hasLaunched nonReentrant
	{
		require(_amount > 0, "invalid amount");

		_updateDay();

		_updateAccount(_account, 0, _amount);

		totalBurned += _amount;

		IERC20(boostToken).safeTransferFrom(msg.sender, BOOST_ADDRESS, _amount);

		emit Burn(_account, boostToken, _amount);
	}

	// stakes 4WMM
	function deposit(uint256 _amount) external hasLaunched nonReentrant
	{
		_deposit(msg.sender, _amount, msg.sender);

		emit Deposit(msg.sender, reserveToken, _amount);
	}

	// stakes 4WMM on behalf of another account
	function depositOnBehalfOf(uint256 _amount, address _account) external hasLaunched nonReentrant
	{
		_deposit(msg.sender, _amount, _account);

		emit Deposit(_account, reserveToken, _amount);
	}

	function _deposit(address _sender, uint256 _amount, address _account) internal
	{
		require(_amount > 0, "invalid amount");

		_updateDay();

		if (_sender != address(this)) {
			uint256 _balance = IERC20(reserveToken).balanceOf(address(this));
			IERC20(reserveToken).safeTransferFrom(_sender, address(this), _amount);
			_amount = IERC20(reserveToken).balanceOf(address(this)) - _balance;
		}

		uint256 _1percent = _amount * 1e16 / 100e16;
		uint256 _dripAmount = 9 * _1percent;
		uint256 _netAmount = _amount - (11 * _1percent);

		// 9% accounted for the drip pool
		totalDrip[0] += _dripAmount;

		// 2% instant rewards (only 7% actually go to the drip pool)
		if (totalStaked > 0) {
			accDripPerShare[0] += (2 * _1percent) * 1e36 / totalStaked;
			allocDrip[0] += 2 * _1percent;
		}

		// rewards users for pGRO burned
		if (totalBurned > 0) {
			accBoostPerShare[0] += _1percent * 1e36 / totalBurned;
			totalBoost[0] += _1percent;
		}

		_updateAccount(_account, int256(_netAmount), 0);

		totalStaked += _netAmount;

		IERC20(reserveToken).safeTransfer(FURNACE, _1percent);
	}

	// unstakes 4WMM
	function withdraw(uint256 _amount) external nonReentrant
	{
		require(_amount > 0, "invalid amount");

		AccountInfo storage _accountInfo = accountInfo[msg.sender];
		uint256 _available  = _accountInfo.amount;
		require(_amount <= _available, "insufficient balance");

		_updateDay();

		_updateAccount(msg.sender, -int256(_amount), 0);

		totalStaked -= _amount;

		if (_accountInfo.whitelisted || whitelistAll) {
			IERC20(reserveToken).safeTransfer(msg.sender, _amount);
		} else {
			uint256 _1percent = _amount * 1e16 / 100e16;
			uint256 _dripAmount = 9 * _1percent;
			uint256 _netAmount = _amount - (11 * _1percent);

			// 9% accounted for the drip pool
			totalDrip[0] += _dripAmount;

			// 2% instant rewards (only 7% actually go to the drip pool)
			if (totalStaked > 0) {
				accDripPerShare[0] += (2 * _1percent) * 1e36 / totalStaked;
				allocDrip[0] += 2 * _1percent;
			}

			// rewards users for pGRO burned
			if (totalBurned > 0) {
				accBoostPerShare[0] += _1percent * 1e36 / totalBurned;
				totalBoost[0] += _1percent;
			}

			IERC20(reserveToken).safeTransfer(FURNACE, _1percent);

			IERC20(reserveToken).safeTransfer(msg.sender, _netAmount);
		}

		emit Withdraw(msg.sender, reserveToken, _amount);
	}

	// claims 4WMM/pDAI
	function claimDrip(uint256 _i) external nonReentrant returns (uint256 _dripAmount, uint256 _boostAmount)
	{
		require(_i < M, "invalid index");

		_updateDay();

		_updateAccount(msg.sender, 0, 0);

		AccountInfo storage _accountInfo = accountInfo[msg.sender];

		_dripAmount = _accountInfo.drip[_i];
		_boostAmount = _accountInfo.boost[_i];

		if (_dripAmount > 0) {
			_accountInfo.drip[_i] = 0;

			totalDrip[_i] -= _dripAmount;
			allocDrip[_i] -= _dripAmount;
		}

		if (_boostAmount > 0) {
			_accountInfo.boost[_i] = 0;

			totalBoost[_i] -= _boostAmount;
		}

		uint256 _dripPlusBoostAmount = _dripAmount + _boostAmount;
		if (_dripPlusBoostAmount > 0) {
			_safeTransfer(dripToken[_i], msg.sender, _dripPlusBoostAmount);
		}

		emit Claim(msg.sender, dripToken[_i], _dripAmount);
		emit Claim(msg.sender, dripToken[_i], _boostAmount);

		return (_dripAmount, _boostAmount);
	}

	// claims PLS/pWBTC/pDAI/pGRO
	function claimReward(uint256 _i) external nonReentrant returns (uint256 _rewardAmount)
	{
		require(_i < N, "invalid index");

		_updateDay();

		_updateAccount(msg.sender, 0, 0);

		AccountInfo storage _accountInfo = accountInfo[msg.sender];

		_rewardAmount = _accountInfo.reward[_i];

		if (_rewardAmount > 0) {
			_accountInfo.reward[_i] = 0;

			totalReward[_i] -= _rewardAmount;
		}

		if (_rewardAmount > 0) {
			_safeTransfer(rewardToken[_i], msg.sender, _rewardAmount);
		}

		emit Claim(msg.sender, rewardToken[_i], _rewardAmount);

		return _rewardAmount;
	}

	// claims all (w4MM/pDAI and PLS/pWBTC/pDAI/pGRO)
	function claimAll() external nonReentrant returns (uint256[M] memory _dripAmount, uint256[M] memory _boostAmount, uint256[N] memory _rewardAmount)
	{
		_updateDay();

		_updateAccount(msg.sender, 0, 0);

		AccountInfo storage _accountInfo = accountInfo[msg.sender];

		for (uint256 _i = 0; _i < M; _i++) {
			_dripAmount[_i] = _accountInfo.drip[_i];
			_boostAmount[_i] = _accountInfo.boost[_i];
		}
		for (uint256 _i = 0; _i < N; _i++) {
			_rewardAmount[_i] = _accountInfo.reward[_i];
		}

		for (uint256 _i = 0; _i < M; _i++) {
			if (_dripAmount[_i] > 0) {
				_accountInfo.drip[_i] = 0;

				totalDrip[_i] -= _dripAmount[_i];
				allocDrip[_i] -= _dripAmount[_i];
			}

			if (_boostAmount[_i] > 0) {
				_accountInfo.boost[_i] = 0;

				totalBoost[_i] -= _boostAmount[_i];
			}
		}
		for (uint256 _i = 0; _i < N; _i++) {
			if (_rewardAmount[_i] > 0) {
				_accountInfo.reward[_i] = 0;

				totalReward[_i] -= _rewardAmount[_i];
			}
		}

		for (uint256 _i = 0; _i < M; _i++) {
			uint256 _dripPlusBoostAmount = _dripAmount[_i] + _boostAmount[_i];
			if (_dripPlusBoostAmount > 0) {
				_safeTransfer(dripToken[_i], msg.sender, _dripPlusBoostAmount);
			}
		}
		for (uint256 _i = 0; _i < N; _i++) {
			if (_rewardAmount[_i] > 0) {
				_safeTransfer(rewardToken[_i], msg.sender, _rewardAmount[_i]);
			}
		}

		for (uint256 _i = 0; _i < M; _i++) {
			emit Claim(msg.sender, dripToken[_i], _dripAmount[_i]);
			emit Claim(msg.sender, dripToken[_i], _boostAmount[_i]);
		}
		for (uint256 _i = 0; _i < N; _i++) {
			emit Claim(msg.sender, rewardToken[_i], _rewardAmount[_i]);
		}

		return (_dripAmount, _boostAmount, _rewardAmount);
	}

	// compounds 4WMM
	function compoundDrip(uint256 _i) external nonReentrant returns (uint256 _dripAmount, uint256 _boostAmount)
	{
		require(_i < M, "invalid index");

		require(dripToken[_i] == reserveToken, "invalid token");

		_updateDay();

		_updateAccount(msg.sender, 0, 0);

		AccountInfo storage _accountInfo = accountInfo[msg.sender];

		_dripAmount = _accountInfo.drip[_i];
		_boostAmount = _accountInfo.boost[_i];

		if (_dripAmount > 0) {
			_accountInfo.drip[_i] = 0;

			totalDrip[_i] -= _dripAmount;
			allocDrip[_i] -= _dripAmount;
		}

		if (_boostAmount > 0) {
			_accountInfo.boost[_i] = 0;

			totalBoost[_i] -= _boostAmount;
		}

		uint256 _dripPlusBoostAmount = _dripAmount + _boostAmount;
		if (_dripPlusBoostAmount > 0) {
			_deposit(address(this), _dripPlusBoostAmount, msg.sender);
		}

		emit Compound(msg.sender, dripToken[_i], _dripAmount);
		emit Compound(msg.sender, dripToken[_i], _boostAmount);

		return (_dripAmount, _boostAmount);
	}

	// sends 4WMM/pDAI to the drip pool
	function donateDrip(uint256 _i, uint256 _amount) external nonReentrant
	{
		require(_i < M, "invalid index");

		require(_amount > 0, "invalid amount");

		_updateDay();

		{
		uint256 _balance = IERC20(dripToken[_i]).balanceOf(address(this));
		IERC20(dripToken[_i]).safeTransferFrom(msg.sender, address(this), _amount);
		_amount = IERC20(dripToken[_i]).balanceOf(address(this)) - _balance;
		}

		if (dripToken[_i] == wrappedToken) {
			IWrappedToken(dripToken[_i]).withdraw(_amount);
		}

		totalDrip[_i] += _amount;

		emit DonateDrip(msg.sender, dripToken[_i], _amount);
	}

	// sends PLS/pWBTC/pDAI/pGRO to all stakers
	function rewardAll(uint256 _i, uint256 _amount) external nonReentrant
	{
		require(_i < N, "invalid index");

		require(_amount > 0, "invalid amount");

		_updateDay();

		require (totalStaked > 0, "no deposits");

		{
		uint256 _balance = IERC20(rewardToken[_i]).balanceOf(address(this));
		IERC20(rewardToken[_i]).safeTransferFrom(msg.sender, address(this), _amount);
		_amount = IERC20(rewardToken[_i]).balanceOf(address(this)) - _balance;
		}

		if (rewardToken[_i] == wrappedToken) {
			IWrappedToken(rewardToken[_i]).withdraw(_amount);
		}

		accRewardPerShare[_i] += _amount * 1e18 / totalStaked;

		totalReward[_i] += _amount;

		emit RewardAll(msg.sender, rewardToken[_i], _amount);
	}

	// performs the daily distribution from the drip pool (GRO)
	function updateDay() external nonReentrant
	{
		_updateDay();
	}

	function _updateDay() internal
	{
		uint64 _today = today();

		if (day == _today) return;

		for (uint256 _i = 0; _i < M; _i++) {
			uint256 _ratePerDay = dripRatePerDay[_i] + dripBoostRatePerDay[_i];
			if (_ratePerDay > 0) {
				// calculates the percentage of the drip pool and distributes
				{
					// formula: drip_reward = drip_pool_balance * (1 - (1 - drip_rate_per_day) ^ days_ellapsed)
					uint64 _days = _today - day;
					uint256 _rate = 100e16 - _exp(100e16 - _ratePerDay, _days);
					uint256 _amount = (totalDrip[_i] - allocDrip[_i]) * _rate / 100e16;

					uint256 _amountDrip = _amount * dripRatePerDay[_i] / _ratePerDay;
					if (totalStaked > 0) {
						accDripPerShare[_i] += _amountDrip * 1e36 / totalStaked;
						allocDrip[_i] += _amountDrip;
					}

					uint256 _amountBoost = _amount - _amountDrip;
					if (totalBurned > 0) {
						accBoostPerShare[_i] += _amountBoost * 1e36 / totalBurned;
						totalDrip[_i] -= _amountBoost;
						totalBoost[_i] += _amountBoost;
					}
				}
			}
		}

		if (totalStaked > 0) {
			// claims rewards
			IERC20(reserveToken).safeTransfer(address(this), 0);
			for (uint256 _i = 0; _i < N; _i++) {
				uint256 _amount = _balanceOf(rewardToken[_i], address(this)) - totalReward[_i];
				for (uint256 _j = 1; _j < M; _j++) {
					if (dripToken[_j] == rewardToken[_i]) {
						_amount -= totalDrip[_j] + totalBoost[_j];
						break;
					}
				}
				if (_amount > 0) {
					accRewardPerShare[_i] += _amount * 1e36 / totalStaked;
					totalReward[_i] += _amount;
				}
			}
		}

		day = _today;
	}

	// updates the account balances while accumulating reward/drip/boost using PCS distribution algorithm
	function _updateAccount(address _account, int256 _amount, uint256 _burned) internal
	{
		AccountInfo storage _accountInfo = accountInfo[_account];
		if (!_accountInfo.exists) {
			// adds account to index
			_accountInfo.exists = true;
			accountIndex.push(_account);
		}

		for (uint256 _i = 0; _i < M; _i++) {
			_accountInfo.drip[_i] += _accountInfo.amount * accDripPerShare[_i] / 1e36 - _accountInfo.accDripDebt[_i];
			_accountInfo.boost[_i] += _accountInfo.burned * accBoostPerShare[_i] / 1e36 - _accountInfo.accBoostDebt[_i];
		}
		for (uint256 _i = 0; _i < N; _i++) {
			_accountInfo.reward[_i] += _accountInfo.amount * accRewardPerShare[_i] / 1e36 - _accountInfo.accRewardDebt[_i];
		}
		if (_amount > 0) {
			_accountInfo.amount += uint256(_amount);
		}
		else
		if (_amount < 0) {
			_accountInfo.amount -= uint256(-_amount);
		}
		_accountInfo.burned += _burned;
		for (uint256 _i = 0; _i < M; _i++) {
			_accountInfo.accDripDebt[_i] = _accountInfo.amount * accDripPerShare[_i] / 1e36;
			_accountInfo.accBoostDebt[_i] = _accountInfo.burned * accBoostPerShare[_i] / 1e36;
		}
		for (uint256 _i = 0; _i < N; _i++) {
			_accountInfo.accRewardDebt[_i] = _accountInfo.amount * accRewardPerShare[_i] / 1e36;
		}
	}

	function _balanceOf(address _token, address _account) internal view returns (uint256 _balance)
	{
		return _token == wrappedToken ? payable(_account).balance : IERC20(_token).balanceOf(_account);
	}

	function _safeTransfer(address _token, address _account, uint256 _amount) internal
	{
		_token == wrappedToken ? payable(_account).sendValue(_amount) : IERC20(_token).safeTransfer(_account, _amount);
	}

	// exponentiation with integer exponent
	function _exp(uint256 _x, uint256 _n) internal pure returns (uint256 _y)
	{
		_y = 1e18;
		while (_n > 0) {
			if (_n & 1 != 0) _y = _y * _x / 1e18;
			_n >>= 1;
			_x = _x * _x / 1e18;
		}
		return _y;
	}

	receive() external payable {}

	event Burn(address indexed _account, address indexed _boostToken, uint256 _amount);
	event Deposit(address indexed _account, address indexed _reserveToken, uint256 _amount);
	event Withdraw(address indexed _account, address indexed _reserveToken, uint256 _amount);
	event Claim(address indexed _account, address indexed _reserveToken, uint256 _amount);
	event Compound(address indexed _account, address indexed _reserveToken, uint256 _amount);
	event RewardAll(address indexed _account, address indexed _rewardToken, uint256 _amount);
	event DonateDrip(address indexed _account, address indexed _reserveToken, uint256 _amount);
}
        

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.9;

interface IUniswapV2Router
{
	function factory() external view returns (address _factory);

	function addLiquidity(address _tokenA, address _tokenB, uint256 _amountADesired, uint256 _amountBDesired, uint256 _amountAMin, uint256 _amountBMin, address _to, uint256 _deadline) external returns (uint256 _amountA, uint256 _amountB, uint256 _liquidity);
	function swapExactTokensForTokens(uint256 _amountIn, uint256 _amountOutMin, address[] calldata _path, address _to, uint256 _deadline) external returns (uint256[] memory _amounts);
}
          

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.9;

interface IWrappedToken
{
	function withdraw(uint256 _amount) external;
}
          

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.9;

import { Ownable } from "@openzeppelin/contracts/access/Ownable.sol";
import { ERC20 } from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import { SafeERC20 } from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import { Address } from "@openzeppelin/contracts/utils/Address.sol";

import { IUniswapV2Router } from "./IUniswapV2Router.sol";
import { IUniswapV2Factory } from "./IUniswapV2Factory.sol";
import { IUniswapV2Pair } from "./IUniswapV2Pair.sol";
import { IWrappedToken } from "./IWrappedToken.sol";

uint256 constant N = 8;

contract Silo
{
	using SafeERC20 for IERC20;

	constructor(address[N] memory _rewardTokens)
	{
		for (uint256 _i = 0; _i < N; _i++) {
			IERC20(_rewardTokens[_i]).safeApprove(msg.sender, type(uint256).max);
		}
	}
}

library LibSilo
{
	function createSilo(address[N] memory _rewardTokens) public returns (address _silo)
	{
		return address(new Silo(_rewardTokens));
	}
}

contract RebasingReflectionToken is Ownable, ERC20
{
	using Address for address;
	using Address for address payable;
	using SafeERC20 for IERC20;

	struct AccountInfo {
		bool exists; // existence flag
		bool excludeFromRewards; // whether or not receive rewards
		uint256 activeBalance; // 0 or user's balance
		uint256[N] rewardDebt; // base for reward distribution
		uint256[N] unclaimedReward; // reward balance available for claim
		uint256[N] minimumRewardBalanceToClaim; // minimum unclaimed balance to auto claim
	}

	address constant FURNACE = 0x000000000000000000000000000000000000dEaD;

	address constant INTERNAL_ADDRESS = address(1); // used internally to record pending rebase balances

	uint256 constant BUY_FEE = 6e16; // 6%
	uint256 constant SELL_FEE = 9e16; // 9%

	uint256 constant DEFAULT_LAUNCH_TIME = 1733756400; // Oct 8th 2PM UTC

	bool private bypass_ = false; // internal flag to bypass all token logic
	bool private inswap_ = false; // internal flag to bypass additional token transfer logic

	address public router; // PulseX router V1
	address[N] public pairs; // N pairs liquidity pool adddresses on PulseX V1
	address[][N] public paths; // routes from WMM to reward tokens

	uint256 public launchTime = DEFAULT_LAUNCH_TIME; // timestamp when the trading starts

	uint256 public totalActiveSupply = 0; // sum of active balances for all 8WMM holders

	address[N] public rewardTokens; // 8 reward tokens
	uint256[N] public buybackPercents; // buyback percentage of each token
	address public wrappedToken; // WPLS
	uint256[N] public rewardBalance = [0, 0, 0, 0, 0, 0, 0, 0]; // 8 reward balance
	uint256[N] public accRewardPerShare = [0, 0, 0, 0, 0, 0, 0, 0]; // accumulated reward per share (double precision)
	uint256 public minimumFeeBalanceToBuyback = N * 1000 * 10 / 8; // need to be more than just dust

	address public silo; // holds reward balances

	address[] public accountIndex; // list of all accounts that ever received 8WMM
	mapping(address => AccountInfo) public accountInfo; // account attributes

	function accountIndexLength() external view returns (uint256 _length)
	{
		return accountIndex.length;
	}

	function accountRewardInfo(address _account, uint256 _i) external view returns (uint256 _rewardDebt, uint256 _unclaimedReward, uint256 _minimumRewardBalanceToClaim)
	{
		AccountInfo storage _accountInfo = accountInfo[_account];
		return (_accountInfo.rewardDebt[_i], _accountInfo.unclaimedReward[_i], _accountInfo.minimumRewardBalanceToClaim[_i]);
	}

	constructor(string memory _name, string memory _symbol)
		ERC20(_name, _symbol)
	{
	}

	function initialize(uint256 _supply, address[N] memory _rewardTokens, address _router, address _wrappedToken, uint256[N] memory _buybackPercents, address _owner) external
	{
		require(router == address(0), "already initialized");
		router = _router;

		address _factory = IUniswapV2Router(_router).factory();
		uint256 _totalBuybackPercent = 0;
		for (uint256 _i = 0; _i < N; _i++) {
			address _rewardToken = _rewardTokens[_i];
			uint256 _buybackPercent = _buybackPercents[_i];

			address _pair = IUniswapV2Factory(_factory).createPair(_rewardToken, address(this));

			address[] memory _path = new address[](2);
			_path[0] = address(this);
			_path[1] = _rewardToken;

			pairs[_i] = _pair;
			paths[_i] = _path;
			rewardTokens[_i] = _rewardToken;

			buybackPercents[_i] = _buybackPercent;
			_totalBuybackPercent += _buybackPercent;
		}
		require(_totalBuybackPercent <= 100e16, "invalid percentages");

		wrappedToken = _wrappedToken;

		silo = LibSilo.createSilo(_rewardTokens);

		_approve(address(this), _router, type(uint256).max);

		_mint(_owner, _supply);
		transferOwnership(_owner);
	}

	function updateLaunchTime(uint256 _launchTime) external onlyOwner
	{
		require(_launchTime > block.timestamp, "invalid time");
		launchTime = _launchTime;
		emit UpdateLaunchTime(_launchTime);
	}

	function updateMinimumFeeBalanceToBuyback(uint256 _minimumFeeBalanceToBuyback) external onlyOwner
	{
		minimumFeeBalanceToBuyback = _minimumFeeBalanceToBuyback;
		emit UpdateMinimumFeeBalanceToBuyback(_minimumFeeBalanceToBuyback);
	}

	function updateMinimumRewardBalanceToClaim(uint256[N] memory _minimumRewardBalanceToClaim) external
	{
		AccountInfo storage _accountInfo = accountInfo[msg.sender];
		_accountInfo.minimumRewardBalanceToClaim = _minimumRewardBalanceToClaim;
		emit UpdateMinimumRewardBalanceToClaim(_minimumRewardBalanceToClaim);
	}

	function updateExcludeFromRewards(address _account, bool _excludeFromRewards) external onlyOwner
	{
		_updateAccount(_account);
		AccountInfo storage _accountInfo = accountInfo[_account];
		_accountInfo.excludeFromRewards = _excludeFromRewards;
		_postUpdateAccount(_account);
		emit UpdateExcludeFromRewards(_account, _excludeFromRewards);
	}

	function updateExcludeFromRewards(bool _excludeFromRewards) external
	{
		_updateAccount(msg.sender);
		AccountInfo storage _accountInfo = accountInfo[msg.sender];
		_accountInfo.excludeFromRewards = _excludeFromRewards;
		_postUpdateAccount(msg.sender);
		emit UpdateExcludeFromRewards(msg.sender, _excludeFromRewards);
	}

	function _updateAccount(address _account) internal
	{
		AccountInfo storage _accountInfo = accountInfo[_account];
		if (!_accountInfo.exists) {
			accountIndex.push(_account);
			_accountInfo.exists = true;
			_accountInfo.excludeFromRewards = _account == FURNACE || _account.isContract();
			_accountInfo.activeBalance = 0;
			_accountInfo.rewardDebt = [0, 0, 0, 0, 0, 0, 0, 0];
			_accountInfo.unclaimedReward = [0, 0, 0, 0, 0, 0, 0, 0];
			_accountInfo.minimumRewardBalanceToClaim = [1, 1, 1, 1, 1, 1, 1, 1];
			return;
		}
		
		uint256 _activeBalance = _accountInfo.activeBalance;
		if (_activeBalance > 0) {
				for (uint256 _i = 0; _i < N; _i++) {
					uint256 _rewardDebt = _activeBalance * accRewardPerShare[_i] / 1e36;
					if (_rewardDebt >  _accountInfo.rewardDebt[_i]) {
						uint256 _rewardAmount = _rewardDebt - _accountInfo.rewardDebt[_i];
						_accountInfo.unclaimedReward[_i] += _rewardAmount;
						_accountInfo.rewardDebt[_i] = _rewardDebt;
					}
				}
		}
		
		for (uint256 _i = 0; _i < N; _i++) {
			uint256 _unclaimedReward = _accountInfo.unclaimedReward[_i];
			if (_unclaimedReward >= _accountInfo.minimumRewardBalanceToClaim[_i]) {
				_accountInfo.unclaimedReward[_i] = 0;
				rewardBalance[_i] -= _unclaimedReward;
				address _rewardToken = rewardTokens[_i];
				if (_rewardToken != wrappedToken) {
					IERC20(_rewardToken).safeTransferFrom(silo, _account, _unclaimedReward);
				} else {
					IERC20(_rewardToken).safeTransferFrom(silo, address(this), _unclaimedReward);
					IWrappedToken(_rewardToken).withdraw(_unclaimedReward);
					payable(_account).sendValue(_unclaimedReward);
				}
			}
		}
	}

	function _postUpdateAccount(address _account) internal
	{
		AccountInfo storage _accountInfo = accountInfo[_account];
		uint256 _oldActiveBalance = _accountInfo.activeBalance;
		uint256 _newActiveBalance = _accountInfo.excludeFromRewards ? 0 : balanceOf(_account);
		if (_newActiveBalance != _oldActiveBalance) {
			_accountInfo.activeBalance = _newActiveBalance;
			for (uint256 _i = 0; _i < N; _i++) {
				_accountInfo.rewardDebt[_i] = _newActiveBalance * accRewardPerShare[_i] / 1e36;
			}
			totalActiveSupply -= _oldActiveBalance;
			totalActiveSupply += _newActiveBalance;
		}
	}

	function _transfer(address _from, address _to, uint256 _amount) internal override
	{
		if (bypass_) {
			// internal transfer
			super._transfer(_from, _to, _amount);
			return;
		}

		if (inswap_) {
			// fee selling transfer
			super._transfer(_from, _to, _amount);
			return;
		}

		bool _buying = false;
		bool _selling = false;
		for (uint256 _i = 0; _i < N; _i++) {
			_buying = _buying || _from == pairs[_i];
			_selling = _selling || _to == pairs[_i];
		}

		if (_buying || _selling) {
			// buy/sell
			bool _restricted = block.timestamp < launchTime && (_buying ? _to : _from) != owner();
			require(!_restricted, "unavailable");

			// If the sender is not the owner then fee applies
			uint256 _feeAmount = (_buying ? _to : _from) != owner() ? _amount * (_buying ? BUY_FEE : SELL_FEE) / 100e16 : 0;

			super._transfer(_from, _to, _amount - _feeAmount);
			super._transfer(_from, address(this), _feeAmount);
			return;
		}

		// regular transfer
		super._transfer(_from, _to, _amount);

		// piggyback buyback operation
		uint256 _balance = balanceOf(address(this));
		if (_balance >= minimumFeeBalanceToBuyback) {
			inswap_ = true;
			for (uint256 _i = 0; _i < N; _i ++) {
				uint256 _swapAmount = _balance * buybackPercents[_i] / 100e16;
				IUniswapV2Router(router).swapExactTokensForTokens(_swapAmount, 0, paths[_i], silo, block.timestamp);
				IUniswapV2Pair(pairs[_i]).sync();
			}
			inswap_ = false;
			if (totalActiveSupply > 0) {
				for (uint256 _i = 0; _i < N; _i++) {
					uint256 _rewardBalance = IERC20(rewardTokens[_i]).balanceOf(silo);
					uint256 _rewardAmount = _rewardBalance - rewardBalance[_i];
					if (_rewardAmount > 0) {
						rewardBalance[_i] = _rewardBalance;
						accRewardPerShare[_i] += _rewardAmount * 1e36 / totalActiveSupply;
					}
				}
			}
		}
	}

	function _beforeTokenTransfer(address _from, address _to, uint256 _amount) internal override
	{
		if (bypass_) return;
		if (_from != address(0)) {
			_updateAccount(_from);
		}
		if (_to != address(0)) {
			require(_to != INTERNAL_ADDRESS, "invalid address");
			_updateAccount(_to);
		}
		_amount; // silences warning
	}

	function _afterTokenTransfer(address _from, address _to, uint256 _amount) internal override
	{
		if (bypass_) return;
		if (_from != address(0)) {
			_postUpdateAccount(_from);
		}
		if (_to != address(0)) {
			_postUpdateAccount(_to);
		}
		_amount; // silences warning
	}

	receive() external payable {}

	event UpdateLaunchTime(uint256 _launchTime);
	event UpdateMinimumFeeBalanceToBuyback(uint256 _minimumFeeBalanceToBuyback);
	event UpdateMinimumRewardBalanceToClaim(uint256[N] _minimumRewardBalanceToClaim);
	event UpdateExcludeFromRewards(address indexed _account, bool indexed _excludeFromRewards);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (proxy/utils/Initializable.sol)

pragma solidity ^0.8.0;

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since a proxied contract can't have a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To initialize the implementation contract, you can either invoke the
 * initializer manually, or you can include a constructor to automatically mark it as initialized when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() initializer {}
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     */
    bool private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Modifier to protect an initializer function from being invoked twice.
     */
    modifier initializer() {
        require(_initializing || !_initialized, "Initializable: contract is already initialized");

        bool isTopLevelCall = !_initializing;
        if (isTopLevelCall) {
            _initializing = true;
            _initialized = true;
        }

        _;

        if (isTopLevelCall) {
            _initializing = false;
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * The default value of {decimals} is 18. To select a different value for
     * {decimals} you should overload it.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless this function is
     * overridden;
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `recipient` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * Requirements:
     *
     * - `sender` and `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     * - the caller must have allowance for ``sender``'s tokens of at least
     * `amount`.
     */
    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) public virtual override returns (bool) {
        _transfer(sender, recipient, amount);

        uint256 currentAllowance = _allowances[sender][_msgSender()];
        require(currentAllowance >= amount, "ERC20: transfer amount exceeds allowance");
        unchecked {
            _approve(sender, _msgSender(), currentAllowance - amount);
        }

        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender] + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        uint256 currentAllowance = _allowances[_msgSender()][spender];
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(_msgSender(), spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `sender` to `recipient`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `sender` cannot be the zero address.
     * - `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     */
    function _transfer(
        address sender,
        address recipient,
        uint256 amount
    ) internal virtual {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(sender, recipient, amount);

        uint256 senderBalance = _balances[sender];
        require(senderBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[sender] = senderBalance - amount;
        }
        _balances[recipient] += amount;

        emit Transfer(sender, recipient, amount);

        _afterTokenTransfer(sender, recipient, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        _balances[account] += amount;
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
        }
        _totalSupply -= amount;

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (utils/Address.sol)

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
          

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.9;

interface IUniswapV2Factory
{
	function getPair(address _tokenA, address _tokenB) external view returns (address _pair);

	function createPair(address _tokenA, address _tokenB) external returns (address _pair);
}
          

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity 0.8.9;

interface IUniswapV2Pair
{
	function sync() external;
}