Contract Address Details

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import { OwnableUpgradeable } from "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
import { SwapperUpgradeable } from "../library/SwapperUpgradeable.sol";
import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import { IUFC } from "../interfaces/IUFC.sol";

contract UFCFight is OwnableUpgradeable, SwapperUpgradeable {
	enum RoundStatus {
		WAITING,
		STARTED,
		CLOSED,
		FINISHING,
		FINISHED,
		CANCELING,
		CANCELLED
	}
	struct Bet {
		address player;
		uint256 entryId;
		uint256 amount;
		uint256 timestamp;
	}
	struct Round {
		uint256 roundID;
		string player1Name;
		string player2Name;
		uint256 feeAmount;
		uint256 player1TotalAmount;
		uint256 player2TotalAmount;
		Bet[] player1Bets;
		Bet[] player2Bets;

		uint48 closeAt;
		uint32 player1LastIndex;
		uint32 player2LastIndex;
		uint8 result; // 0: player1, 1: player2, 2: draw
		RoundStatus status;
	}
	IUFC public ufc;
	IERC20 public pspn;
	Round[] public rounds;

	uint256 public roundIds;
	uint256 public entryIds;
	uint256 public chunkSize;

	/* Admin */
	mapping(address => bool) public isAdmin;

	event RoundStarted(uint256 roundId, uint256 closeAt, uint256 timestamp);
	event EnteredRound(uint256 roundId, uint256 entryId, address player, uint256 amount, uint256 expectation, uint256 timestamp);
	event RoundFinished(uint256 roundId, uint8 result, string winner, uint256 totalAmount, uint256 feeAmount, uint256 pspnAmount, uint256 timestamp);
	event FeeTaken(uint256 roundId, uint256 ufcAmount, uint256 pspnAmount, uint256 timestamp);

	function initialize(address ufcAddress, address pspnAddress, address _routerAddress, address _usdtAddress) external initializer {
		ufc = IUFC(ufcAddress);
		pspn = IERC20(pspnAddress);
		isAdmin[msg.sender] = true;

		chunkSize = 100;
		__Ownable_init(msg.sender);
		__Swapper_init(_routerAddress, _usdtAddress);
	}

	modifier onlyAdmin() {
		require(isAdmin[msg.sender] == true, "only admin");
		_;
	}

	modifier excludeContract() {
		require(msg.sender == tx.origin, "contract not allowed");
		_;
	}

	function createRound(string memory player1Name, string memory player2Name, uint256 closeAt) external onlyAdmin {
		rounds.push();
		Round storage roundInfo = rounds[roundIds];
		roundInfo.roundID = roundIds;
		roundInfo.player1Name = player1Name;
		roundInfo.player2Name = player2Name;
		roundInfo.closeAt = uint48(closeAt);
		roundInfo.status = RoundStatus.STARTED;

		emit RoundStarted(roundIds, closeAt, block.timestamp);
		roundIds ++;
	}

	function enterRound(uint256 roundId, uint256 amount, uint256 expectation) external payable excludeContract {
		Round storage roundInfo = rounds[roundId];

		require(roundId < roundIds, "invalid round id");
		require(roundInfo.status == RoundStatus.STARTED, "cannot enter");
		require(roundInfo.closeAt > block.timestamp, "bet closed");
		require(expectation < 2, "invalid expectation");
		require(amount > 0, "invalid usdAmount");

		uint256 newBetId;
		if (expectation == 0) {
			// player1
			newBetId = roundInfo.player1Bets.length;
			roundInfo.player1Bets.push();
			roundInfo.player1TotalAmount += amount;
		} else {
			newBetId = roundInfo.player2Bets.length;
			roundInfo.player2Bets.push();
			roundInfo.player2TotalAmount += amount;
		}

		Bet storage betInfo = expectation == 0 ? roundInfo.player1Bets[newBetId] : roundInfo.player2Bets[newBetId];
		betInfo.player = msg.sender;
		betInfo.entryId = entryIds;
		betInfo.amount = amount;
		betInfo.timestamp = block.timestamp;

		ufc.transferFrom(msg.sender, address(this), amount);

		emit EnteredRound(roundId, entryIds, msg.sender, amount, expectation, block.timestamp);
		entryIds++;
	}

	function finishRound(uint256 roundId, uint8 result) external onlyAdmin excludeContract {
		Round storage roundInfo = rounds[roundId];
		bool isClosed = (roundInfo.status == RoundStatus.STARTED && roundInfo.closeAt <= block.timestamp) || roundInfo.status == RoundStatus.CLOSED;

		require(roundId < roundIds, "invalid round id");
		require(isClosed || roundInfo.status == RoundStatus.FINISHING, "cannot finish");

		// Take Fees and send rewards
		if (roundInfo.status != RoundStatus.FINISHING) {
			string memory winnerName = result == 0 ? roundInfo.player1Name : roundInfo.player2Name;
			uint256 totalAmount = roundInfo.player1TotalAmount + roundInfo.player1TotalAmount;
			uint256 feeAmount = (totalAmount * 3) / 100;
			uint256 pspnAmount = _takeFees(roundId, feeAmount);

			roundInfo.status = RoundStatus.FINISHING;
			roundInfo.result = result;
			roundInfo.feeAmount = feeAmount;

			emit RoundFinished(roundId, result, winnerName, totalAmount, feeAmount, pspnAmount, block.timestamp);
		}

		bool isFinished = _sendReward(roundId);

		if (isFinished) {
			roundInfo.status = RoundStatus.FINISHED;
		}
	}

	function _sendReward(uint256 roundId) internal returns (bool) {
		Round storage roundInfo = rounds[roundId];
		uint8 result = roundInfo.result;

		if (result < 2) {
			// Not draw case
			Bet[] storage bets = result == 0 ? roundInfo.player1Bets : roundInfo.player2Bets;
			uint256 winnerTotalAmount = result == 0 ? roundInfo.player1TotalAmount : roundInfo.player2TotalAmount;
			uint256 totalAmount = ((roundInfo.player1TotalAmount + roundInfo.player2TotalAmount) * 97) / 100;
			uint32 lastIndex = result == 0 ? roundInfo.player1LastIndex : roundInfo.player2LastIndex;
			uint256 length = bets.length;
			uint32 i;

			for (i = 0; i + lastIndex < length && i < chunkSize; i++) {
				uint256 reward = (bets[i + lastIndex].amount * totalAmount) / winnerTotalAmount;
				ufc.transfer(bets[i + lastIndex].player, reward);
			}

			if (result == 0) roundInfo.player1LastIndex = i + lastIndex;
			else roundInfo.player2LastIndex = i + lastIndex;

			if (i + lastIndex == length) {
				return true;
			}
		} else {
			// Draw case
			if (roundInfo.player1LastIndex < roundInfo.player1Bets.length) {
				Bet[] storage bets = roundInfo.player1Bets;
				uint32 lastIndex = roundInfo.player1LastIndex;
				uint256 length = roundInfo.player1Bets.length;
				uint32 i;

				for (i = 0; i + lastIndex < length && i < chunkSize; i++) {
					uint256 reward = (bets[i + lastIndex].amount * 97) / 100;
					ufc.transfer(bets[i + lastIndex].player, reward);
				}
				roundInfo.player1LastIndex = i + lastIndex;
			} else if (roundInfo.player2LastIndex < roundInfo.player2Bets.length) {
				Bet[] storage bets = roundInfo.player2Bets;
				uint32 lastIndex = roundInfo.player2LastIndex;
				uint256 length = roundInfo.player2Bets.length;
				uint32 i;

				for (i = 0; i + lastIndex < length && i < chunkSize; i++) {
					uint256 reward = (bets[i + lastIndex].amount * 97) / 100;
					ufc.transfer(bets[i + lastIndex].player, reward);
				}
				roundInfo.player2LastIndex = i + lastIndex;

				if (i + lastIndex == length) {
					return true;
				}
			} else {
				return true;
			}
		}
		return false;
	}

	function _takeFees(uint256 roundId, uint256 feeAmount) internal returns (uint256 pspnAmount) {
		if (feeAmount == 0) return 0;
		pspnAmount = _swap(address(ufc), address(pspn), feeAmount, address(ufc));
		emit FeeTaken(roundId, feeAmount, pspnAmount, block.timestamp);
	}

	function getRounds() external view returns (Round[] memory) {
		return rounds;
	}

	function setAdmin(address addr, bool value) external onlyOwner {
		isAdmin[addr] = value;
	}

	function getRound(uint256 id) external view returns (Round memory) {
		return rounds[id];
	}
}
        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {ContextUpgradeable} from "../utils/ContextUpgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract OwnableUpgradeable is Initializable, ContextUpgradeable {
    /// @custom:storage-location erc7201:openzeppelin.storage.Ownable
    struct OwnableStorage {
        address _owner;
    }

    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.Ownable")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 private constant OwnableStorageLocation = 0x9016d09d72d40fdae2fd8ceac6b6234c7706214fd39c1cd1e609a0528c199300;

    function _getOwnableStorage() private pure returns (OwnableStorage storage $) {
        assembly {
            $.slot := OwnableStorageLocation
        }
    }

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    function __Ownable_init(address initialOwner) internal onlyInitializing {
        __Ownable_init_unchained(initialOwner);
    }

    function __Ownable_init_unchained(address initialOwner) internal onlyInitializing {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        OwnableStorage storage $ = _getOwnableStorage();
        return $._owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        OwnableStorage storage $ = _getOwnableStorage();
        address oldOwner = $._owner;
        $._owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.20;

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Storage of the initializable contract.
     *
     * It's implemented on a custom ERC-7201 namespace to reduce the risk of storage collisions
     * when using with upgradeable contracts.
     *
     * @custom:storage-location erc7201:openzeppelin.storage.Initializable
     */
    struct InitializableStorage {
        /**
         * @dev Indicates that the contract has been initialized.
         */
        uint64 _initialized;
        /**
         * @dev Indicates that the contract is in the process of being initialized.
         */
        bool _initializing;
    }

    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.Initializable")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 private constant INITIALIZABLE_STORAGE = 0xf0c57e16840df040f15088dc2f81fe391c3923bec73e23a9662efc9c229c6a00;

    /**
     * @dev The contract is already initialized.
     */
    error InvalidInitialization();

    /**
     * @dev The contract is not initializing.
     */
    error NotInitializing();

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint64 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that in the context of a constructor an `initializer` may be invoked any
     * number of times. This behavior in the constructor can be useful during testing and is not expected to be used in
     * production.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        // Cache values to avoid duplicated sloads
        bool isTopLevelCall = !$._initializing;
        uint64 initialized = $._initialized;

        // Allowed calls:
        // - initialSetup: the contract is not in the initializing state and no previous version was
        //                 initialized
        // - construction: the contract is initialized at version 1 (no reininitialization) and the
        //                 current contract is just being deployed
        bool initialSetup = initialized == 0 && isTopLevelCall;
        bool construction = initialized == 1 && address(this).code.length == 0;

        if (!initialSetup && !construction) {
            revert InvalidInitialization();
        }
        $._initialized = 1;
        if (isTopLevelCall) {
            $._initializing = true;
        }
        _;
        if (isTopLevelCall) {
            $._initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: Setting the version to 2**64 - 1 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint64 version) {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        if ($._initializing || $._initialized >= version) {
            revert InvalidInitialization();
        }
        $._initialized = version;
        $._initializing = true;
        _;
        $._initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        _checkInitializing();
        _;
    }

    /**
     * @dev Reverts if the contract is not in an initializing state. See {onlyInitializing}.
     */
    function _checkInitializing() internal view virtual {
        if (!_isInitializing()) {
            revert NotInitializing();
        }
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        if ($._initializing) {
            revert InvalidInitialization();
        }
        if ($._initialized != type(uint64).max) {
            $._initialized = type(uint64).max;
            emit Initialized(type(uint64).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint64) {
        return _getInitializableStorage()._initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _getInitializableStorage()._initializing;
    }

    /**
     * @dev Returns a pointer to the storage namespace.
     */
    // solhint-disable-next-line var-name-mixedcase
    function _getInitializableStorage() private pure returns (InitializableStorage storage $) {
        assembly {
            $.slot := INITIALIZABLE_STORAGE
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.7;

interface IPRC20 {
    function totalSupply() external view returns (uint256);

    function balanceOf(address account) external view returns (uint256);

    function transfer(address recipient, uint256 amount) external returns (bool);

    function allowance(address owner, address spender) external view returns (uint256);

    function approve(address spender, uint256 amount) external returns (bool);

    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    function decimals() external view returns (uint8);

    event Transfer(address indexed from, address indexed to, uint256 value);
    event Approval(address indexed owner, address indexed spender, uint256 value);
}
          

//SPDX-License-Identifier: MIT
pragma solidity >=0.8.2;

interface IPulseXRouter01 {
	function factory() external pure returns (address);

	function WPLS() external pure returns (address);

	function addLiquidity(
		address tokenA,
		address tokenB,
		uint amountADesired,
		uint amountBDesired,
		uint amountAMin,
		uint amountBMin,
		address to,
		uint deadline
	) external returns (uint amountA, uint amountB, uint liquidity);

	function addLiquidityETH(
		address token,
		uint amountTokenDesired,
		uint amountTokenMin,
		uint amountETHMin,
		address to,
		uint deadline
	) external payable returns (uint amountToken, uint amountETH, uint liquidity);

	function removeLiquidity(
		address tokenA,
		address tokenB,
		uint liquidity,
		uint amountAMin,
		uint amountBMin,
		address to,
		uint deadline
	) external returns (uint amountA, uint amountB);

	function removeLiquidityETH(
		address token,
		uint liquidity,
		uint amountTokenMin,
		uint amountETHMin,
		address to,
		uint deadline
	) external returns (uint amountToken, uint amountETH);

	function removeLiquidityWithPermit(
		address tokenA,
		address tokenB,
		uint liquidity,
		uint amountAMin,
		uint amountBMin,
		address to,
		uint deadline,
		bool approveMax,
		uint8 v,
		bytes32 r,
		bytes32 s
	) external returns (uint amountA, uint amountB);

	function removeLiquidityETHWithPermit(
		address token,
		uint liquidity,
		uint amountTokenMin,
		uint amountETHMin,
		address to,
		uint deadline,
		bool approveMax,
		uint8 v,
		bytes32 r,
		bytes32 s
	) external returns (uint amountToken, uint amountETH);

	function swapExactTokensForTokens(
		uint amountIn,
		uint amountOutMin,
		address[] calldata path,
		address to,
		uint deadline
	) external returns (uint[] memory amounts);

	function swapTokensForExactTokens(
		uint amountOut,
		uint amountInMax,
		address[] calldata path,
		address to,
		uint deadline
	) external returns (uint[] memory amounts);

	function swapExactETHForTokens(
		uint amountOutMin,
		address[] calldata path,
		address to,
		uint deadline
	) external payable returns (uint[] memory amounts);

	function swapTokensForExactETH(
		uint amountOut,
		uint amountInMax,
		address[] calldata path,
		address to,
		uint deadline
	) external returns (uint[] memory amounts);

	function swapExactTokensForETH(
		uint amountIn,
		uint amountOutMin,
		address[] calldata path,
		address to,
		uint deadline
	) external returns (uint[] memory amounts);

	function swapETHForExactTokens(
		uint amountOut,
		address[] calldata path,
		address to,
		uint deadline
	) external payable returns (uint[] memory amounts);

	function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);

	function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);

	function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);

	function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);

	function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
}

interface IPulseXRouter02 is IPulseXRouter01 {
	function removeLiquidityETHSupportingFeeOnTransferTokens(
		address token,
		uint liquidity,
		uint amountTokenMin,
		uint amountETHMin,
		address to,
		uint deadline
	) external returns (uint amountETH);

	function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
		address token,
		uint liquidity,
		uint amountTokenMin,
		uint amountETHMin,
		address to,
		uint deadline,
		bool approveMax,
		uint8 v,
		bytes32 r,
		bytes32 s
	) external returns (uint amountETH);

	function swapExactTokensForTokensSupportingFeeOnTransferTokens(
		uint amountIn,
		uint amountOutMin,
		address[] calldata path,
		address to,
		uint deadline
	) external;

	function swapExactETHForTokensSupportingFeeOnTransferTokens(
		uint amountOutMin,
		address[] calldata path,
		address to,
		uint deadline
	) external payable;

	function swapExactTokensForETHSupportingFeeOnTransferTokens(
		uint amountIn,
		uint amountOutMin,
		address[] calldata path,
		address to,
		uint deadline
	) external;
}
          

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.7;

interface IUFC {
    function totalSupply() external view returns (uint256);

    function balanceOf(address account) external view returns (uint256);

    function transfer(address recipient, uint256 amount) external returns (bool);

    function allowance(address owner, address spender) external view returns (uint256);

    function approve(address spender, uint256 amount) external returns (bool);

    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    function decimals() external view returns (uint8);

    function sellTax() external view returns (uint256);
    function buyTax() external view returns (uint256);

    event Transfer(address indexed from, address indexed to, uint256 value);
    event Approval(address indexed owner, address indexed spender, uint256 value);
}
          

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.7;

import "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import "../interfaces/IPulseXRouter.sol";
import "../interfaces/IPRC20.sol";

abstract contract SwapperUpgradeable is Initializable {
	IPulseXRouter02 public router;
	mapping(address => bool) public isTokenStable;
	address public usdtAddress;

	/**
	 * @dev Initializes the contract router and usdtAddress
	 */
	function __Swapper_init(address _routerAddress, address _usdtAddress) internal onlyInitializing {
		__Swapper_init_unchained(_routerAddress, _usdtAddress);
	}

	function __Swapper_init_unchained(address _routerAddress, address _usdtAddress) internal onlyInitializing {
		router = IPulseXRouter02(_routerAddress);
		usdtAddress = _usdtAddress;
	}

	function setTokenStable(address addr, bool value) internal {
		isTokenStable[addr] = value;
	}

	function getTokenPrice(address tokenAddress, uint256 decimal) public view returns (uint256) {
		uint8 usdtDecimals = IPRC20(usdtAddress).decimals();
		if (isTokenStable[tokenAddress]) return 10 ** 18;

		uint256 tokenAmount = 1;

		if (
			tokenAddress == 0x8D36123903f504eB81eEB832727af517c0db26bD ||
			tokenAddress == 0xa27aDe5806Ded801b93499C6fA23cc8dC9AC55EA
		) {
			tokenAmount = 100000;
		}
		(, , uint256 maxAmountOut) = _getOptimizedAmountOut(tokenAddress, usdtAddress, tokenAmount * 10 ** decimal);
		return (maxAmountOut * 10 ** (18 - usdtDecimals)) / tokenAmount;
	}

	function _swap(
		address tokenFrom,
		address tokenTo,
		uint256 amount,
		address receiver
	) internal returns (uint256 outputAmount) {
		if (amount == 0) return outputAmount;
		if (tokenFrom == tokenTo) {
			if (address(this) != receiver) {
				if (tokenFrom == address(0)) {
					payable(receiver).transfer(amount);
				} else {
					IPRC20(tokenFrom).transfer(receiver, amount);
				}
			}
			return amount;
		}

		(IPulseXRouter02 optimalRouter, address[] memory path, uint256 maxAmountOut) = _getOptimizedAmountOut(
			tokenFrom,
			tokenTo,
			amount
		);
		outputAmount = _swapWithRouterParams(tokenFrom, tokenTo, amount, receiver, optimalRouter, path);
	}

	function _swapWithRouterParams(
		address tokenFrom,
		address tokenTo,
		uint256 amount,
		address receiver,
		IPulseXRouter02 optimalRouter,
		address[] memory path
	) internal returns (uint256 outputAmount) {
		address nineInchRouterAddress = 0xeB45a3c4aedd0F47F345fB4c8A1802BB5740d725;

		if (tokenTo != address(0)) {
			uint256 prevBalance = IPRC20(tokenTo).balanceOf(receiver);
			if (tokenFrom == address(0)) {
				optimalRouter.swapExactETHForTokens{ value: amount }(0, path, receiver, block.timestamp);
			} else if (tokenFrom == router.WPLS()) {
				IPRC20(tokenFrom).approve(address(optimalRouter), amount);
				optimalRouter.swapExactTokensForTokens(amount, 0, path, receiver, block.timestamp);
			} else {
				IPRC20(tokenFrom).approve(address(optimalRouter), amount);
				if (address(optimalRouter) != nineInchRouterAddress) {
					optimalRouter.swapExactTokensForTokensSupportingFeeOnTransferTokens(
						amount,
						0,
						path,
						receiver,
						block.timestamp
					);
				} else {
					optimalRouter.swapExactTokensForTokens(amount, 0, path, receiver, block.timestamp);
				}
			}
			uint256 afterBalance = IPRC20(tokenTo).balanceOf(receiver);
			outputAmount = afterBalance - prevBalance;
		} else {
			IPRC20(tokenFrom).approve(address(optimalRouter), amount);
			uint256 prevBalance = receiver.balance;
			optimalRouter.swapExactTokensForETHSupportingFeeOnTransferTokens(amount, 0, path, receiver, block.timestamp);
			uint256 afterBalance = receiver.balance;
			outputAmount = afterBalance - prevBalance;
		}
	}

	function _getPossiblePaths(
		address tokenFrom,
		address tokenTo
	) public view returns (address[] memory pulseXPath, address[] memory nineInchPath) {
		address nineInchTokenAddress = 0x3ca80d83277e721171284667829c686527B8b3c5;
		address wplsAddress = router.WPLS();

		if (tokenTo != wplsAddress && tokenTo != address(0)) {
			if (tokenFrom == address(0) || tokenFrom == wplsAddress) {
				pulseXPath = new address[](2);
				pulseXPath[0] = wplsAddress;
				pulseXPath[1] = tokenTo;
				nineInchPath = new address[](3);
				nineInchPath[0] = wplsAddress;
				nineInchPath[1] = nineInchTokenAddress;
				nineInchPath[2] = tokenTo;
			} else if (tokenFrom == nineInchTokenAddress) {
				pulseXPath = new address[](3);
				pulseXPath[0] = tokenFrom;
				pulseXPath[1] = wplsAddress;
				pulseXPath[2] = tokenTo;
				nineInchPath = new address[](2);
				nineInchPath[0] = nineInchTokenAddress;
				nineInchPath[1] = tokenTo;
			} else {
				pulseXPath = new address[](3);
				pulseXPath[0] = tokenFrom;
				pulseXPath[1] = wplsAddress;
				pulseXPath[2] = tokenTo;
				nineInchPath = new address[](3);
				nineInchPath[0] = tokenFrom;
				nineInchPath[1] = nineInchTokenAddress;
				nineInchPath[2] = tokenTo;
			}
		} else {
			if (tokenFrom == nineInchTokenAddress) {
				pulseXPath = new address[](2);
				pulseXPath[0] = tokenFrom;
				pulseXPath[1] = wplsAddress;
				nineInchPath = new address[](2);
				nineInchPath[0] = nineInchTokenAddress;
				nineInchPath[1] = wplsAddress;
			} else {
				pulseXPath = new address[](2);
				pulseXPath[0] = tokenFrom;
				pulseXPath[1] = wplsAddress;
				nineInchPath = new address[](3);
				nineInchPath[0] = tokenFrom;
				nineInchPath[1] = nineInchTokenAddress;
				nineInchPath[2] = tokenTo;
			}
		}
	}

	function _getAmountOutWithoutException(
		IPulseXRouter02 router,
		address[] memory path,
		uint256 amountIn
	) public view returns (uint256) {
		try router.getAmountsOut(amountIn, path) returns (uint256[] memory amounts) {
			return amounts[amounts.length - 1];
		} catch Error(string memory reason) {
			return 0;
		} catch (bytes memory reason) {
			return 0;
		}
	}

	function _getAmountInWithoutException(
		IPulseXRouter02 router,
		address[] memory path,
		uint256 amountOut
	) public view returns (uint256) {
		try router.getAmountsIn(amountOut, path) returns (uint256[] memory amounts) {
			return amounts[0];
		} catch Error(string memory reason) {
			return 0;
		} catch (bytes memory reason) {
			return 0;
		}
	}

	function _getOptimizedAmountOut(
		address tokenFrom,
		address tokenTo,
		uint256 amountIn
	) public view returns (IPulseXRouter02 router, address[] memory path, uint256 maxAmountOut) {
		IPulseXRouter02 routerV1 = IPulseXRouter02(0x98bf93ebf5c380C0e6Ae8e192A7e2AE08edAcc02);
		IPulseXRouter02 routerV2 = IPulseXRouter02(0x165C3410fC91EF562C50559f7d2289fEbed552d9);
		IPulseXRouter02 nineInchRouter = IPulseXRouter02(0xeB45a3c4aedd0F47F345fB4c8A1802BB5740d725);

		(address[] memory pulseXPath, address[] memory nineInchPath) = _getPossiblePaths(tokenFrom, tokenTo);
		uint256 v1AmountOut = _getAmountOutWithoutException(routerV1, pulseXPath, amountIn);
		uint256 v2AmountOut = _getAmountOutWithoutException(routerV2, pulseXPath, amountIn);
		uint256 nineInchAmountOut = _getAmountOutWithoutException(nineInchRouter, nineInchPath, amountIn);

		if (v1AmountOut != 0 && v1AmountOut > maxAmountOut) {
			router = routerV1;
			path = pulseXPath;
			maxAmountOut = v1AmountOut;
		}
		if (v2AmountOut != 0 && v2AmountOut > maxAmountOut) {
			router = routerV2;
			path = pulseXPath;
			maxAmountOut = v2AmountOut;
		}
		if (nineInchAmountOut != 0 && nineInchAmountOut > maxAmountOut) {
			router = nineInchRouter;
			path = nineInchPath;
			maxAmountOut = nineInchAmountOut;
		}
	}

	function _getOptimizedAmountIn(
		address tokenFrom,
		address tokenTo,
		uint256 amountOut
	) public view returns (IPulseXRouter02 router, address[] memory path, uint256 minAmountIn) {
		IPulseXRouter02 routerV1 = IPulseXRouter02(0x98bf93ebf5c380C0e6Ae8e192A7e2AE08edAcc02);
		IPulseXRouter02 routerV2 = IPulseXRouter02(0x165C3410fC91EF562C50559f7d2289fEbed552d9);
		IPulseXRouter02 nineInchRouter = IPulseXRouter02(0xeB45a3c4aedd0F47F345fB4c8A1802BB5740d725);

		(address[] memory pulseXPath, address[] memory nineInchPath) = _getPossiblePaths(tokenFrom, tokenTo);
		uint256 v1AmountIn = _getAmountInWithoutException(routerV1, pulseXPath, amountOut);
		uint256 v2AmountIn = _getAmountInWithoutException(routerV2, pulseXPath, amountOut);
		uint256 nineInchAmountIn = _getAmountInWithoutException(nineInchRouter, nineInchPath, amountOut);

		if (v1AmountIn != 0 && (minAmountIn == 0 || v1AmountIn < minAmountIn)) {
			router = routerV1;
			path = pulseXPath;
			minAmountIn = v1AmountIn;
		}
		if (v2AmountIn != 0 && (minAmountIn == 0 || v2AmountIn < minAmountIn)) {
			router = routerV2;
			path = pulseXPath;
			minAmountIn = v2AmountIn;
		}
		if (nineInchAmountIn != 0 && (minAmountIn == 0 || nineInchAmountIn < minAmountIn)) {
			router = nineInchRouter;
			path = nineInchPath;
			minAmountIn = nineInchAmountIn;
		}
	}

	function _updateUSDTAddress(address addr) internal {
		usdtAddress = addr;
	}

	/**
	 * @dev This empty reserved space is put in place to allow future versions to add new
	 * variables without shifting down storage in the inheritance chain.
	 * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
	 */
	uint256[47] private __gap;
}