Contract Address Details

// SPDX-License-Identifier: MIT

pragma solidity 0.8.24;


import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/utils/Context.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "./tokens/Liftoff.sol";

/*------------------------------------------------------------------
 *    :::: EXTERNAL_CONTRACT_INTERFACE ::::
 *-----------------------------------------------------------------*/


interface Iv2Router02 {
    function addLiquidityETH(address token, uint256 amountTokenDesired, uint256 amountTokenMin, uint256 amountETHMin, address to, uint256 deadline) external payable returns (uint256 amountToken, uint256 amountETH, uint256 liquidity);
}

interface ILockLiquidityv2 {
    function lockLiquidity(uint256 lockAmount) external returns(bool);
}

interface ItokenBurning {
    function burn(uint256 value) external;
}

interface IIntarsiaConfigProvider {
    function setConfig(uint8 configType, address value) external returns(bool);
    function setTokenConfig(address tokenAddress, uint16 taxValue, uint64 powerValue) external returns(bool);
    function g_AddressArray(uint8 configType) external view returns (address[] memory returnedArray);
    function aa_ticketTokens(uint256 index) external view returns (address);
    function aa_dexV2Routers(uint256 index) external view returns (address);    
    function a_IntarsiaSafe() external view returns (address);
}


/*------------------------------------------------------------------
 *    :::: IGNITION_PHASE_CONTRACT ::::
 *-----------------------------------------------------------------*/


/**
 * @title `Ignition Phase`
 * @dev Handles the Ignition of PULSE for LIFTOFF, addition of PULSE to PulseX LP, and Burning of the remaining tokens.
 *      The Ignition Phase is available between the starting timestamp and the ending timestamp.
 *      The Ignition Phase ends after the end timestamp or once the LIFTOFF supply is drained.
 *      The Ignition rate between PULSE and LIFTOFF decreases with every passing second.
 *      100% of the Pulse used to Ignite Liftoff will be added to a Liquidity Pool for Argyle, Comfy, and Switch tokens.
 *      The addition of Liquidiy is done through this contract.
 *      The LP is Locked for up to 1 year and receipts are sent to a multisig contract.
 *
 */
contract IgnitionPhase is 
    ReentrancyGuard, 
    Context 
{
	
    using SafeERC20 for Liftoff;

    /*------------------------
     *    :::: ENUM ::::
     *-----------------------*/
	
	enum AddressType {
        GtHolder,
        Token,
        PulseXPair,
        LpLock 
    }
    
   /*------------------------
    *  :::: CONSTANTS ::::
    *-----------------------*/
    
    uint256 private constant START_TIMESTAMP = 1751068800; // MAINNET: Sat Jun 28 2025 00:00:00 GMT+0000
	uint256 private constant IGNITE_DURATION = 2592000;
    uint256 private constant IGNITE_MULTIPLIER = 100e3;
	uint256 private constant IGNITE_MAX = IGNITE_MULTIPLIER;
	uint256 private constant IGNITE_MIN = (IGNITE_MULTIPLIER * 1e18) / (1e18 + (IGNITE_DURATION * 1e12));
	uint256 private constant END_TIMESTAMP = START_TIMESTAMP + IGNITE_DURATION;
	
    /*------------------------
     *  :::: CONSTANTS ::::
     *-----------------------*/
    
    IERC20 private immutable GOLDEN_TICKET;
	Liftoff private immutable LIFTOFF_TOKEN;
	address private immutable V2_ROUTER;
	address private immutable MULTISIG;
    IIntarsiaConfigProvider public immutable i_configProvider;

    /*------------------------
     *  :::: MAPPINGS ::::
     *-----------------------*/
     
    mapping(address => bool) private gtHolderMap;
    mapping(address => bool) private tokenMap;
    mapping(address => bool) private dexPairMap;
    mapping(address => bool) private lpLockMap;

   /*----------------------------
    *    :::: ARRAYS ::::
    *---------------------------*/
    
    address[] public listGtHolders;
    address[] public listTokens;
    address[] public listDexPairs;
    address[] public listLockContracts;


/*------------------------------------------------------------------
 *    :::: EVENTS_AND_ERRORS ::::
 *-----------------------------------------------------------------*/


    event TokensIgnited(
        address indexed sender,
        uint256 amountPulse,
        uint256 amountTokens
    );
    
    event LiquidityAdded(
        address indexed sender,
        address token,
        uint256 amountPulse,
        uint256 amountTokens
    );
    
    event LiquidityLocked(
        address indexed sender,
        address lpToken,
        address lpLock,
        uint256 amount
    );
    
    event ReceiptTransferred(
        address indexed sender,
        address receiptToken,
        uint256 amount
    );
    
    event TokensBurned(
        address indexed sender,
        address token,
        uint256 amount
    );
    
    
    error AddressZero_Error();
    error AmountPulse_Error();
    error Amount_Error();
    error Approve_Error();
    error Balance_Error();
    error BalanceofLiftoff_Error();
    error GoldenTicketAllowance_Error();
    error GoldenTicketBalance_Error();
    error GoldenTicketTransfer_Error();
    error InvalidLPToken_Error();
    error InvalidPair_Error();
    error InvalidSender_Error();
    error InvalidToken_Error();
    error IsActive_Error();
    error IsNotActive_Error();
    error InvalidAddressType();
    error LockLiquidity_Error();
    error ReceiveAmount_Error();
    error SetContract_Error();
    error TimeMultiplier_Error();
    error Transfer_Error();
    

/*------------------------------------------------------------------
 *    :::: MODIFIERS ::::
 *-----------------------------------------------------------------*/


   /**
    * @notice Modifier that checks if the contract is currently active based on the start and end timestamps.
    */
    modifier isActive() {
        uint256 timeNow = block.timestamp;
        if (timeNow < START_TIMESTAMP || timeNow > END_TIMESTAMP) revert IsNotActive_Error();
        _;
    }

   
   /**
    * @notice Modifier that checks if the contract is not active.
    */
    modifier isNotActive() {
        if (block.timestamp < END_TIMESTAMP) revert IsActive_Error();
        _;
    }
    
    
   /**
    * @notice Modifier that restricts access to only holders of the Golden Ticket.
    */
    modifier onlyGTHolder() {
    	address sender_ = _msgSender();
        IERC20 goldenTicket_ = GOLDEN_TICKET;
        if (!gtHolderMap[sender_] || sender_ == address(0)) revert InvalidSender_Error();
        if (goldenTicket_.balanceOf(sender_) < 1e18) revert GoldenTicketBalance_Error();
        if (goldenTicket_.allowance(sender_, address(this)) < 1e18) revert GoldenTicketAllowance_Error();
        _;
    }
    
    
/*------------------------------------------------------------------
 *    :::: CONSTRUCTOR ::::
 *-----------------------------------------------------------------*/


   /**
    * @dev Constructs the contract and initializes the state variables.
    *      Initializes the LIFTOFF_TOKEN with the specified name and symbol, and sets up the address maps
    *      and lists for the provided parameters.
    */
    constructor(address _configProviderAddress) {

        if (_configProviderAddress == address(0)) revert AddressZero_Error();
        i_configProvider = IIntarsiaConfigProvider(_configProviderAddress);
            
        address[] memory gtHolders_ = i_configProvider.g_AddressArray(8);
        address[] memory coreTokens_ = i_configProvider.g_AddressArray(5);
        address[] memory coreTokensLP_ = i_configProvider.g_AddressArray(6);
        address[] memory coreTokensLock = i_configProvider.g_AddressArray(7);
        
        GOLDEN_TICKET = IERC20(i_configProvider.aa_ticketTokens(2));
        MULTISIG = i_configProvider.a_IntarsiaSafe();
        V2_ROUTER = i_configProvider.aa_dexV2Routers(0);

        Liftoff.LiftoffTokenConfig memory config = Liftoff.LiftoffTokenConfig({name: "Liftoff", symbol: "LIFTOFF", ignitionPhaseContract: address(this)});
        LIFTOFF_TOKEN = new Liftoff(config);
        address liftoffToken_ = address(LIFTOFF_TOKEN);

        // Process gt holders
        for (uint8 i; i < 6; ) {
            address gtholderAddress = gtHolders_[i];
            if (gtholderAddress != address(0)) {
                gtHolderMap[gtholderAddress] = true;
                listGtHolders.push(gtholderAddress);
            }
            unchecked { ++i; }
        }
        
        // Process core tokens
        for (uint8 i; i < 3; ) {
            address token = coreTokens_[i];
            address tokenLP = coreTokensLP_[i];
            address tokenLock = coreTokensLock[i];
            if (token != address(0) && tokenLP != address(0) && tokenLock != address(0)) {
                listTokens.push(token);
                listDexPairs.push(tokenLP);
                listLockContracts.push(tokenLock);
                tokenMap[token] = true;
                dexPairMap[tokenLP] = true;
                lpLockMap[tokenLock] = true;
            }
            unchecked { ++i; }
        }
        
        tokenMap[liftoffToken_] = true;
        listTokens.push(liftoffToken_);
        
        // Set IgnitionPhase within the Intarsia Config Contract
        if (!i_configProvider.setConfig(4, address(this))) revert SetContract_Error();
        if (!i_configProvider.setTokenConfig(liftoffToken_, 0, 100)) revert SetContract_Error();

        
    }


   /**
    * @notice Allows the contract to receive direct Pulse deposits without triggering token allocation.
    * @dev Stores the Pulse in the contract.
    */
    receive() external payable {}
    

/*------------------------------------------------------------------
 *    :::: EXTERNAL_VIEW_GETTER ::::
 *-----------------------------------------------------------------*/


   /**
    * @notice Checks if a given address is mapped to a specific type.
    * @param addressType The type of address to check (1: gtHolderMap, 2: tokenMap, 3: dexPairMap, 4: lpLockMap).
    * @param addressCheck The address to check against the specified map.
    * @return bool True if the address is mapped, false otherwise.
    */
    function getAddrMaps(
        AddressType addressType, 
        address addressCheck
    ) external view returns (bool) {
        if (addressType == AddressType.GtHolder) return gtHolderMap[addressCheck];
        if (addressType == AddressType.Token) return tokenMap[addressCheck];
        if (addressType == AddressType.PulseXPair) return dexPairMap[addressCheck];
        if (addressType == AddressType.LpLock) return lpLockMap[addressCheck];
        revert InvalidAddressType();
    }


   /**
    * @notice Retrieves the current balance of the contract in both Pulse and token.
    * @return pulsebalance The balance of the contract in Pulse.
    * @return tokenBalance The balance of the contract in tokens.
    */
    function getBalance() external view returns (uint256 pulsebalance, uint256 tokenBalance){
        pulsebalance = address(this).balance;
        tokenBalance = LIFTOFF_TOKEN.balanceOf(address(this));
    }
    
    
   /**
    * @notice Provides the configuration values used in the contract.
    * @return uintValues An array of six unsigned integer configuration values.
    */
    function getConfigUint() external pure returns (uint256[6] memory uintValues) {
        uintValues = [IGNITE_MULTIPLIER, IGNITE_MIN, IGNITE_MAX, IGNITE_DURATION, START_TIMESTAMP, END_TIMESTAMP];
    }


   /**
    * @notice Provides the configuration values used in the contract.
    * @return addressValues An array of three address configuration values.
    */
    function getConfigAddress() external view returns (address[3] memory addressValues) {
        addressValues = [V2_ROUTER, MULTISIG, address(GOLDEN_TICKET)];
    }


   /**
    * @notice Provides the address of the Liftoff Token contract.
    * @return address The Liftoff Token address.
    */
    function getLiftoffAddress() external view returns (address) {
        return address(LIFTOFF_TOKEN);
    }


   /**
    * @notice Calculates the rate and amount of tokens to be received based on the given pulse amount and time.
    * @dev This function is only callable when the contract is active.
    * @param amountPulse The amount of pulses to calculate the token rate for.
    * @param timeCheck The specific time to check the rate; if 0, the current block timestamp is used.
    * @return tokensPerPulse The calculated number of tokens per pulse.
    * @return receiveAmount The total amount of tokens to be received for the given pulse amount.
    */
    function getRateCalc(
        uint256 amountPulse,
        uint256 timeCheck
    ) external view returns (uint256 tokensPerPulse, uint256 receiveAmount){
        uint256 timeNow = timeCheck != 0 ? timeCheck : block.timestamp;
        uint256 startTime = START_TIMESTAMP;
        if (timeNow < startTime || timeNow > END_TIMESTAMP) revert IsNotActive_Error();
        (tokensPerPulse, receiveAmount) = _calcValue(timeNow, amountPulse, startTime);
    }
    
    
   /**
    * @notice Retrieves the current rate and amount of tokens to be received for a standard pulse amount.
    * @dev This function is only callable when the contract is active.
    * @return tokensPerPulse The current number of tokens per pulse.
    * @return receiveAmount The total amount of tokens to be received for a standard pulse amount of 1e18.
    */
    function getRateCurrent() external view isActive returns (uint256 tokensPerPulse, uint256 receiveAmount){
        (tokensPerPulse, receiveAmount) = _calcValue(block.timestamp, 1e18, START_TIMESTAMP);
    }


/*------------------------------------------------------------------
 *    :::: EXTERNAL_PAYABLE ::::
 *-----------------------------------------------------------------*/


   /**
    * @notice Allows users to ignite tokens by sending Pulse to the contract.
    * @dev This function is only callable when the Ignition Phase is active.
    * @dev Emits a TokensIgnited event upon successful token transfer.
    */
    function igniteTokens() external 
        payable 
        isActive 
        nonReentrant 
    {
    	uint256 amountPulse_ = msg.value;
        address sender_ = _msgSender();
       
        if (sender_ == address(0) || sender_ == address(0xA1077a294dDE1B09bB078844df40758a5D0f9a27)) revert InvalidSender_Error();

        Liftoff liftoffToken_ = LIFTOFF_TOKEN;

        ( , uint256 receiveAmount) = _calcValue(block.timestamp, amountPulse_, START_TIMESTAMP);
        
        if (liftoffToken_.balanceOf(address(this)) < receiveAmount) revert BalanceofLiftoff_Error();
        liftoffToken_.safeTransfer(sender_, receiveAmount);
        
        emit TokensIgnited(
            sender_,
            amountPulse_,
            receiveAmount
        );
    }

    
/*------------------------------------------------------------------
 *    :::: EXTERNAL_NON_PAYABLE_GOLDEN_TICKET_FUNCTIONS ::::
 *-----------------------------------------------------------------*/


   /**
    * @notice Allows a Golden Ticket holder to add liquidity to the contract.
    * @dev This function is only callable by a holder of the Golden Ticket and is non-reentrant.
    * @param token The ERC20 token to be added as liquidity.
    * @param amountTkn The amount of the token to add as liquidity.
    * @param amountPulse The amount of Pulse to add as liquidity.
    * @param amountTknMin The minimum amount of tokens to accept.
    * @param amountPulseMin The minimum amount of Pulse to accept.
    * @dev Emits a LiquidityAdded event upon successful addition of liquidity.
    */
    function addLiquidity(
        IERC20 token, 
        uint256 amountTkn, 
        uint256 amountPulse,
        uint256 amountTknMin,
        uint256 amountPulseMin
    ) external 
        onlyGTHolder 
        nonReentrant 
    { 
        address v2Router_ = V2_ROUTER;
        address tokenAddress = address(token);
        
        if (amountTkn == 0 || amountPulse == 0) revert Amount_Error();
        if (!tokenMap[tokenAddress] || tokenAddress == address(0)) revert InvalidToken_Error();
        
        uint256 tokenBalance_ = token.balanceOf(address(this));
        
        if (address(this).balance < amountPulse || tokenBalance_ < amountTkn) revert Balance_Error();
        if (!token.approve(v2Router_, tokenBalance_)) revert Approve_Error();
        
        Iv2Router02(v2Router_).addLiquidityETH{value: amountPulse}(
            tokenAddress,
            amountTkn,
            amountTknMin,
            amountPulseMin,
            address(this),
            block.timestamp + 3600
        );
        
        if (!GOLDEN_TICKET.transferFrom(_msgSender(), address(this), 1e18)) revert GoldenTicketTransfer_Error();
        
        emit LiquidityAdded(_msgSender(),tokenAddress,amountPulse,amountTkn);
    }
    
    
   /**
    * @notice Allows a Golden Ticket holder to lock liquidity in a specified lock contract.
    * @dev This function is only callable by a holder of the Golden Ticket and is non-reentrant.
    * @param lpToken The liquidity pool token to be locked.
    * @param lpLock The address of the liquidity lock contract.
    * @param amount The amount of liquidity pool tokens to lock.
    * @dev Emits a LiquidityLocked event upon successful locking of liquidity.
    */
    function lockLiquidity(
        IERC20 lpToken, 
        address lpLock, 
        uint256 amount
    ) external 
        onlyGTHolder 
        nonReentrant 
    { 
        if (amount < 10000) revert Amount_Error();
        if (lpLock == address(0) || address(lpToken) == address(0)) revert AddressZero_Error();
        if (!dexPairMap[address(lpToken)]) revert InvalidPair_Error();
        if (!lpLockMap[lpLock]) revert InvalidLPToken_Error();
        if (lpToken.balanceOf(address(this)) < amount) revert Balance_Error();
        if (!GOLDEN_TICKET.transferFrom(_msgSender(), address(this), 1e18)) revert GoldenTicketTransfer_Error();
        if (!lpToken.approve(lpLock, amount)) revert Approve_Error();
        if (!ILockLiquidityv2(lpLock).lockLiquidity(amount)) revert LockLiquidity_Error();
        emit LiquidityLocked(_msgSender(),address(lpToken),lpLock,amount);
    }
    
    
   /**
    * @notice Allows a Golden Ticket holder to transfer receipt tokens to a multisig address.
    * @dev This function is only callable by a holder of the Golden Ticket and is non-reentrant.
    * @param receiptToken The ERC20 receipt token to be transferred.
    * @param amount The amount of receipt tokens to transfer.
    * @dev Emits a ReceiptTransferred event upon successful transfer of receipt tokens.
    */
    function transferReceipts(
        IERC20 receiptToken, 
        uint256 amount
    ) external 
        onlyGTHolder 
        nonReentrant 
    { 
        address receiptTokenAddress_ = address(receiptToken);
        if (amount == 0) revert Amount_Error();
        if (!lpLockMap[receiptTokenAddress_] || receiptTokenAddress_ == address(0)) revert InvalidToken_Error();
        if (receiptToken.balanceOf(address(this)) < amount) revert Balance_Error();
        if (!GOLDEN_TICKET.transferFrom(_msgSender(), address(this), 1e18)) revert GoldenTicketTransfer_Error();
        if (!receiptToken.transfer(MULTISIG, amount)) revert Transfer_Error();
        emit ReceiptTransferred(_msgSender(),receiptTokenAddress_,amount);
    }
    

   /**
    * @notice Allows a Golden Ticket holder to burn remaining tokens after the end timestamp.
    * @dev This function is only callable by a holder of the Golden Ticket, Ignition Phase must be completed, and is non-reentrant.
    * @param token The ERC20 token to be burned.
    * @param amount The amount of tokens to burn.
    * @dev Emits a TokensBurned event upon successful burning of tokens.
    */
    function burnRemainingTokens(
        address token,
        uint256 amount
    ) external 
        onlyGTHolder 
        isNotActive 
        nonReentrant 
    {
        if (amount == 0) revert Amount_Error();
        if (!tokenMap[token] || token == address(0)) revert InvalidToken_Error();
        if (IERC20(token).balanceOf(address(this)) < amount) revert Balance_Error();
        if (!GOLDEN_TICKET.transferFrom(_msgSender(), address(this), 1e18)) revert GoldenTicketTransfer_Error();
        ItokenBurning(token).burn(amount);
        emit TokensBurned(_msgSender(),token,amount);
    }


/*------------------------------------------------------------------
 *    :::: PRIVATE_INTERNAL_FUNCTIONS ::::
 *-----------------------------------------------------------------*/

    
   /**
    * @notice Calculates the token value based on the time elapsed and the amount of pulses.
    * @dev This is a private pure function that performs calculations to determine the tokens per pulse and the total amount.
    * @param _timeValue The current or specified time value for the calculation.
    * @param _amountPulse The amount of pulses to be used in the calculation.
    * @param _startTimestamp The starting timestamp for the calculation.
    * @return tokensPerPulse The calculated number of tokens per pulse.
    * @return receiveAmount The total calculated amount of tokens based on the Pulse and time.
    * @dev Reverts if the amount of Pulse is out of bounds, the time multiplier exceeds the allowed duration, or the calculated amount is invalid.
    */
    function _calcValue(
        uint256 _timeValue,
        uint256 _amountPulse,
        uint256 _startTimestamp
    ) private pure returns (uint256, uint256) {
    	
        if (_amountPulse < 1e18 || _amountPulse > 10e24) revert AmountPulse_Error();
        
        uint256 timeMultiplier_ = (_timeValue > _startTimestamp) ? (_timeValue - _startTimestamp) : 0;
        
        if (timeMultiplier_ > IGNITE_DURATION) revert TimeMultiplier_Error();
        
        uint256 tokensPerPulse = (timeMultiplier_ != 0) ? (1e18 + ((timeMultiplier_ * 1e45) / 1e33)) : 1e18; 
        uint256 receiveAmount = (tokensPerPulse != 0) ? ((_amountPulse * IGNITE_MULTIPLIER * 1e40) / tokensPerPulse / 1e22) : 0;
        
        uint256 igniteMin_;
        uint256 igniteMax_;
        
        unchecked {
            igniteMin_ = IGNITE_MIN * _amountPulse;
            igniteMax_ = IGNITE_MAX * _amountPulse;
        }
        
        if (receiveAmount > igniteMax_ || receiveAmount < igniteMin_) revert ReceiveAmount_Error();
        
        return (tokensPerPulse, receiveAmount);

    }


}

        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../utils/introspection/IERC165.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../token/ERC20/IERC20.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC-1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * Both values are immutable: they can only be set once during construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner`'s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner`'s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance < type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.20;

import {ERC20} from "../ERC20.sol";
import {Context} from "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys a `value` amount of tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 value) public virtual {
        _burn(_msgSender(), value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, deducting from
     * the caller's allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `value`.
     */
    function burnFrom(address account, uint256 value) public virtual {
        _spendAllowance(account, _msgSender(), value);
        _burn(account, value);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
          

// SPDX-License-Identifier: MIT

pragma solidity 0.8.24;


import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";


/*-------------------------------------------------------------------------
 *    :::: LIFTOFF_CONTRACT ::::
 *------------------------------------------------------------------------*/


/**
 * @title Liftoff
 * @dev This contract implements an ERC20 token with burnable capabilities.
 * 100% of the total Initial Supply is minted to the Ignition Phase Contract
 * No ownership or additional supply can be minted.
 */
contract Liftoff is 
    ERC20, 
    ERC20Burnable
{
    struct LiftoffTokenConfig {
        address ignitionPhaseContract;
        string name;
        string symbol;
    }
    uint256 public constant totalInitialSupply = 36e30;
    address public immutable ignitionPhaseContract;
    constructor(
        LiftoffTokenConfig memory config
    ) ERC20(config.name, config.symbol) {
        ignitionPhaseContract = config.ignitionPhaseContract;
        _mint(ignitionPhaseContract, totalInitialSupply);
    }
}