Contract Address Details

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.22;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

import "./interfaces/IDEXFactory.sol";
import "./interfaces/IDEXRouter.sol";
import "./interfaces/IDualRewardStaking.sol";
import "./interfaces/IWPLS.sol";

interface IShareDistributor {
    function setShare(address shareholder, uint256 amount) external;
    function deposit() external payable;
    function process(uint256 gasLimit) external;
}

contract DividendDistributor is ReentrancyGuard {
    using SafeERC20 for IERC20;

    struct Share {
        uint256 amount;
        uint256 totalExcluded;
        uint256 totalRealised;
    }

    uint256 internal constant ACC_FACTOR = 1e36;

    address public immutable token;
    address public manager;
    IDEXRouter public immutable router;
    address public immutable WPLS;
    IERC20 public rewardToken;

    address public rewardHop1;
    address public rewardHop2;
    address public rewardHop3;

    mapping(address => Share) internal shares;
    address[] internal shareholders;
    mapping(address => uint256) internal shareholderIndexes;
    mapping(address => uint256) internal shareholderClaims;

    uint256 public totalShares;
    uint256 public totalDividends;
    uint256 public totalDistributed;
    uint256 public dividendsPerShare;

    uint256 public minPeriod = 1 hours;
    uint256 public minDistribution = 1e9;
    uint256 public currentIndex;

    event ManagerUpdated(address indexed oldManager, address indexed newManager);
    event DistributionCriteriaUpdated(uint256 minPeriod, uint256 minDistribution);
    event RewardHopsUpdated(address indexed hop1, address indexed hop2, address indexed hop3);

    modifier onlyToken() {
        require(msg.sender == token, "Distributor: only token");
        _;
    }

    modifier onlyManagerOrToken() {
        require(msg.sender == manager || msg.sender == token, "Distributor: not authorized");
        _;
    }

    constructor(address token_, address manager_, address router_, address rewardToken_) {
        require(token_ != address(0), "Distributor: token zero");
        require(manager_ != address(0), "Distributor: manager zero");
        require(router_ != address(0), "Distributor: router zero");
        require(rewardToken_ != address(0), "Distributor: reward zero");

        token = token_;
        manager = manager_;
        router = IDEXRouter(router_);
        WPLS = router.WPLS();
        rewardToken = IERC20(rewardToken_);
    }

    receive() external payable {}

    function setManager(address newManager) external onlyManagerOrToken {
        require(newManager != address(0), "Distributor: manager zero");
        emit ManagerUpdated(manager, newManager);
        manager = newManager;
    }

    function setDistributionCriteria(uint256 minPeriod_, uint256 minDistribution_) external onlyManagerOrToken {
        minPeriod = minPeriod_;
        minDistribution = minDistribution_;
        emit DistributionCriteriaUpdated(minPeriod_, minDistribution_);
    }

    function setRewardHops(address hop1, address hop2, address hop3) external onlyManagerOrToken {
        rewardHop1 = hop1;
        rewardHop2 = hop2;
        rewardHop3 = hop3;
        emit RewardHopsUpdated(hop1, hop2, hop3);
    }

    function setShare(address shareholder, uint256 amount) public virtual onlyToken {
        _setShare(shareholder, amount);
    }

    function deposit() external payable virtual onlyToken nonReentrant {
        uint256 received = _receiveRewardToken(msg.value);
        _record(received);
    }

    function process(uint256 gasLimit) external onlyToken {
        uint256 shareholderCount = shareholders.length;
        if (shareholderCount == 0) return;

        uint256 gasUsed;
        uint256 gasLeft = gasleft();

        while (gasUsed < gasLimit && shareholderCount > 0) {
            if (currentIndex >= shareholderCount) {
                currentIndex = 0;
            }

            address shareholder = shareholders[currentIndex];
            if (_shouldDistribute(shareholder)) {
                _distribute(shareholder);
            }

            uint256 newGasLeft = gasleft();
            if (gasLeft > newGasLeft) {
                gasUsed += gasLeft - newGasLeft;
            }
            gasLeft = newGasLeft;

            unchecked {
                ++currentIndex;
            }
        }
    }

    function getUnpaidEarnings(address shareholder) external view returns (uint256) {
        return _unpaid(shareholder);
    }

    function shareOf(address shareholder) external view returns (uint256) {
        return shares[shareholder].amount;
    }

    function _setShare(address shareholder, uint256 amount) internal {
        if (shares[shareholder].amount > 0) {
            _distribute(shareholder);
        }

        if (amount > 0 && shares[shareholder].amount == 0) {
            _addShareholder(shareholder);
        } else if (amount == 0 && shares[shareholder].amount > 0) {
            _removeShareholder(shareholder);
        }

        totalShares = totalShares - shares[shareholder].amount + amount;
        shares[shareholder].amount = amount;
        shares[shareholder].totalExcluded = _cumulative(amount);
    }

    function _receiveRewardToken(uint256 amountNative) internal returns (uint256 received) {
        if (amountNative == 0) return 0;

        if (address(rewardToken) == WPLS) {
            IWPLS(WPLS).deposit{value: amountNative}();
            return amountNative;
        }

        uint256 beforeBal = rewardToken.balanceOf(address(this));
        address[] memory path = _buildRewardPath();

        router.swapExactETHForTokensSupportingFeeOnTransferTokens{value: amountNative}(
            0,
            path,
            address(this),
            block.timestamp
        );

        received = rewardToken.balanceOf(address(this)) - beforeBal;
    }

    function _record(uint256 amount) internal virtual {
        if (amount == 0) return;

        totalDividends += amount;
        if (totalShares > 0) {
            dividendsPerShare += (amount * ACC_FACTOR) / totalShares;
        }
    }

    function _shouldDistribute(address shareholder) internal view returns (bool) {
        return shareholderClaims[shareholder] + minPeriod < block.timestamp && _unpaid(shareholder) > minDistribution;
    }

    function _distribute(address shareholder) internal {
        uint256 amount = _unpaid(shareholder);
        if (amount == 0) return;

        totalDistributed += amount;
        shareholderClaims[shareholder] = block.timestamp;
        shares[shareholder].totalRealised += amount;
        shares[shareholder].totalExcluded = _cumulative(shares[shareholder].amount);

        rewardToken.safeTransfer(shareholder, amount);
    }

    function _unpaid(address shareholder) internal view returns (uint256) {
        uint256 shareholderAmount = shares[shareholder].amount;
        if (shareholderAmount == 0) return 0;

        uint256 shareholderTotalDividends = _cumulative(shareholderAmount);
        uint256 shareholderTotalExcluded = shares[shareholder].totalExcluded;

        if (shareholderTotalDividends <= shareholderTotalExcluded) return 0;
        return shareholderTotalDividends - shareholderTotalExcluded;
    }

    function _cumulative(uint256 share) internal view returns (uint256) {
        return (share * dividendsPerShare) / ACC_FACTOR;
    }

    function _addShareholder(address shareholder) internal {
        shareholderIndexes[shareholder] = shareholders.length;
        shareholders.push(shareholder);
    }

    function _removeShareholder(address shareholder) internal {
        uint256 index = shareholderIndexes[shareholder];
        uint256 lastIndex = shareholders.length - 1;

        if (index != lastIndex) {
            address lastHolder = shareholders[lastIndex];
            shareholders[index] = lastHolder;
            shareholderIndexes[lastHolder] = index;
        }

        shareholders.pop();
        delete shareholderIndexes[shareholder];
    }

    function _isValidRewardHop(address hop, address prev) internal view returns (bool) {
        return
            hop != address(0) &&
            hop != prev &&
            hop != WPLS &&
            hop != address(rewardToken);
    }

    function _buildRewardPath() internal view returns (address[] memory path) {
        uint256 len = 2;
        address prev = WPLS;

        if (_isValidRewardHop(rewardHop1, prev)) {
            len++;
            prev = rewardHop1;
        }
        if (_isValidRewardHop(rewardHop2, prev) && rewardHop2 != rewardHop1) {
            len++;
            prev = rewardHop2;
        }
        if (_isValidRewardHop(rewardHop3, prev) && rewardHop3 != rewardHop1 && rewardHop3 != rewardHop2) {
            len++;
        }

        path = new address[](len);
        uint256 i = 0;
        prev = WPLS;
        path[i++] = WPLS;

        if (_isValidRewardHop(rewardHop1, prev)) {
            path[i++] = rewardHop1;
            prev = rewardHop1;
        }
        if (_isValidRewardHop(rewardHop2, prev) && rewardHop2 != rewardHop1) {
            path[i++] = rewardHop2;
            prev = rewardHop2;
        }
        if (_isValidRewardHop(rewardHop3, prev) && rewardHop3 != rewardHop1 && rewardHop3 != rewardHop2) {
            path[i++] = rewardHop3;
        }

        path[i] = address(rewardToken);
    }
}

contract FlexibleRewardDistributor is DividendDistributor {
    using SafeERC20 for IERC20;

    address public deadAddress;
    uint256 public shareEpoch;
    uint256 public pendingDividends;

    mapping(address => uint256) public accountEpoch;

    event DeadAddressUpdated(address indexed oldDead, address indexed newDead);
    event RewardTokenChanged(address indexed oldToken, address indexed newToken, uint256 burnedAmount);
    event SharesWiped(uint256 indexed newEpoch);

    constructor(address token_, address manager_, address router_, address rewardToken_)
        DividendDistributor(token_, manager_, router_, rewardToken_)
    {
        deadAddress = 0x000000000000000000000000000000000000dEaD;
    }

    function setDeadAddress(address newDead) external onlyManagerOrToken {
        require(newDead != address(0), "FlexibleDistributor: zero dead");
        require(newDead != address(this), "FlexibleDistributor: self dead");
        emit DeadAddressUpdated(deadAddress, newDead);
        deadAddress = newDead;
    }

    function changeRewardToken(address newRewardToken) external onlyManagerOrToken nonReentrant {
        require(newRewardToken != address(0), "FlexibleDistributor: reward zero");
        require(newRewardToken != address(rewardToken), "FlexibleDistributor: same reward");

        uint256 burnedAmount = rewardToken.balanceOf(address(this));
        if (burnedAmount > 0) {
            rewardToken.safeTransfer(deadAddress, burnedAmount);
        }

        _wipeAllShares();
        emit RewardTokenChanged(address(rewardToken), newRewardToken, burnedAmount);
        rewardToken = IERC20(newRewardToken);
    }

    function setShare(address shareholder, uint256 amount) public override onlyToken {
        _ensureCurrentEpoch(shareholder);
        _setShare(shareholder, amount);
        _flushPending();
    }

    function _record(uint256 amount) internal override {
        if (amount == 0) return;

        totalDividends += amount;
        pendingDividends += amount;
        _flushPending();
    }

    function _flushPending() internal {
        if (pendingDividends == 0 || totalShares == 0) return;

        dividendsPerShare += (pendingDividends * ACC_FACTOR) / totalShares;
        pendingDividends = 0;
    }

    function _ensureCurrentEpoch(address shareholder) internal {
        if (accountEpoch[shareholder] == shareEpoch) return;

        accountEpoch[shareholder] = shareEpoch;
        shares[shareholder].amount = 0;
        shares[shareholder].totalExcluded = 0;
        shares[shareholder].totalRealised = 0;
        shareholderClaims[shareholder] = 0;
        delete shareholderIndexes[shareholder];
    }

    function _wipeAllShares() internal {
        unchecked {
            ++shareEpoch;
        }

        totalShares = 0;
        totalDividends = 0;
        totalDistributed = 0;
        dividendsPerShare = 0;
        currentIndex = 0;
        pendingDividends = 0;
        delete shareholders;

        emit SharesWiped(shareEpoch);
    }
}

contract BuyBurnDistributor is ReentrancyGuard {
    address public immutable token;
    address public manager;
    IDEXRouter public immutable router;
    address public immutable WPLS;

    address public tokenToBuy;
    address public deadAddress;
    uint256 public buyThreshold;

    address public buyHop1;
    address public buyHop2;
    address public buyHop3;

    event ManagerUpdated(address indexed oldManager, address indexed newManager);
    event TokenToBuyUpdated(address indexed oldToken, address indexed newToken);
    event DeadAddressUpdated(address indexed oldDead, address indexed newDead);
    event BuyThresholdUpdated(uint256 oldThreshold, uint256 newThreshold);
    event BuyHopsUpdated(address indexed hop1, address indexed hop2, address indexed hop3);

    modifier onlyToken() {
        require(msg.sender == token, "BuyBurn: only token");
        _;
    }

    modifier onlyManagerOrToken() {
        require(msg.sender == manager || msg.sender == token, "BuyBurn: not authorized");
        _;
    }

    constructor(address token_, address manager_, address router_, address tokenToBuy_, uint256 buyThreshold_) {
        require(token_ != address(0), "BuyBurn: token zero");
        require(manager_ != address(0), "BuyBurn: manager zero");
        require(router_ != address(0), "BuyBurn: router zero");

        token = token_;
        manager = manager_;
        router = IDEXRouter(router_);
        WPLS = router.WPLS();
        tokenToBuy = tokenToBuy_;
        buyThreshold = buyThreshold_;
        deadAddress = 0x000000000000000000000000000000000000dEaD;
    }

    receive() external payable {}

    function setManager(address newManager) external onlyManagerOrToken {
        require(newManager != address(0), "BuyBurn: manager zero");
        emit ManagerUpdated(manager, newManager);
        manager = newManager;
    }

    function setTokenToBuy(address newToken) external onlyManagerOrToken {
        emit TokenToBuyUpdated(tokenToBuy, newToken);
        tokenToBuy = newToken;
    }

    function setDeadAddress(address newDead) external onlyManagerOrToken {
        require(newDead != address(0), "BuyBurn: dead zero");
        require(newDead != address(this), "BuyBurn: self dead");
        emit DeadAddressUpdated(deadAddress, newDead);
        deadAddress = newDead;
    }

    function setBuyThreshold(uint256 newThreshold) external onlyManagerOrToken {
        emit BuyThresholdUpdated(buyThreshold, newThreshold);
        buyThreshold = newThreshold;
    }

    function setBuyHops(address hop1, address hop2, address hop3) external onlyManagerOrToken {
        buyHop1 = hop1;
        buyHop2 = hop2;
        buyHop3 = hop3;
        emit BuyHopsUpdated(hop1, hop2, hop3);
    }

    function deposit() external payable onlyToken nonReentrant {
        uint256 bal = address(this).balance;
        if (bal == 0 || buyThreshold == 0 || bal < buyThreshold || tokenToBuy == address(0)) return;

        if (tokenToBuy == WPLS) {
            IWPLS(WPLS).deposit{value: bal}();
            IERC20(WPLS).transfer(deadAddress, bal);
            return;
        }

        address[] memory path = _buildBuyPath();

        router.swapExactETHForTokensSupportingFeeOnTransferTokens{value: bal}(
            0,
            path,
            deadAddress,
            block.timestamp
        );
    }

    function _isValidBuyHop(address hop, address prev) internal view returns (bool) {
        return
            hop != address(0) &&
            hop != prev &&
            hop != WPLS &&
            hop != tokenToBuy;
    }

    function _buildBuyPath() internal view returns (address[] memory path) {
        uint256 len = 2;
        address prev = WPLS;

        if (_isValidBuyHop(buyHop1, prev)) {
            len++;
            prev = buyHop1;
        }
        if (_isValidBuyHop(buyHop2, prev) && buyHop2 != buyHop1) {
            len++;
            prev = buyHop2;
        }
        if (_isValidBuyHop(buyHop3, prev) && buyHop3 != buyHop1 && buyHop3 != buyHop2) {
            len++;
        }

        path = new address[](len);
        uint256 i = 0;
        prev = WPLS;
        path[i++] = WPLS;

        if (_isValidBuyHop(buyHop1, prev)) {
            path[i++] = buyHop1;
            prev = buyHop1;
        }
        if (_isValidBuyHop(buyHop2, prev) && buyHop2 != buyHop1) {
            path[i++] = buyHop2;
            prev = buyHop2;
        }
        if (_isValidBuyHop(buyHop3, prev) && buyHop3 != buyHop1 && buyHop3 != buyHop2) {
            path[i++] = buyHop3;
        }

        path[i] = tokenToBuy;
    }
}

contract BrainDaoToken is ERC20, Ownable, ReentrancyGuard {
    using SafeERC20 for IERC20;

    uint256 public constant FEE_DENOMINATOR = 10_000;
    uint256 public constant MAX_TOTAL_FEE_BPS = 3_000;

    IDEXRouter public immutable router;
    address public immutable WPLS;
    address public pair;

    DividendDistributor public mainRewardDistributor;
    FlexibleRewardDistributor public extraRewardDistributor;
    BuyBurnDistributor public buyBurnDistributor;
    IDualRewardStaking public stakingContract;

    address public deadAddress = 0x000000000000000000000000000000000000dEaD;
    address public liquidityReceiver;

    uint256 public stakingMainFee;
    uint256 public stakingExtraFee;
    uint256 public holderMainFee;
    uint256 public holderExtraFee;
    uint256 public buyBurnFee;
    uint256 public liquidityFee;
    uint256 public directBurnFee;
    uint256 public totalFee;

    uint256 public instantERC20Fee;
    address public instantERC20TokenToBuy;

    uint256 public swapThreshold;
    uint256 public maxTxAmount;
    uint256 public distributorGas = 500_000;

    bool public swapEnabled = true;
    bool public autoMintEnabled = true;
    uint256 public autoMintBps = FEE_DENOMINATOR;

    address public hop1Token;
    address public hop2Token;
    address public hop3Token;
    uint8 private _instantHopCursor;

    bool private inSwap;

    mapping(address => bool) public isAMMPair;
    mapping(address => bool) public isFeeExempt;
    mapping(address => bool) public isTxLimitExempt;
    mapping(address => bool) public isDividendExempt;

    event AMMPairUpdated(address indexed pair, bool value);
    event FeeExemptUpdated(address indexed account, bool value);
    event TxLimitExemptUpdated(address indexed account, bool value);
    event DividendExemptUpdated(address indexed account, bool value);
    event StakingContractUpdated(address indexed oldStaking, address indexed newStaking);
    event MainRewardDistributorUpdated(address indexed oldDistributor, address indexed newDistributor);
    event ExtraRewardDistributorUpdated(address indexed oldDistributor, address indexed newDistributor);
    event BuyBurnDistributorUpdated(address indexed oldDistributor, address indexed newDistributor);
    event DeadAddressUpdated(address indexed oldDead, address indexed newDead);
    event LiquidityReceiverUpdated(address indexed oldReceiver, address indexed newReceiver);
    event DistributorGasUpdated(uint256 newGas);
    event SwapBackSettingsUpdated(bool enabled, uint256 threshold);
    event AutoMintSettingsUpdated(bool enabled, uint256 bps);
    event SwapHopsUpdated(address indexed hop1, address indexed hop2, address indexed hop3);
    event InstantERC20SettingsUpdated(uint256 feeBps, address indexed tokenToBuy);
    event FeesUpdated(
        uint256 stakingMainFee,
        uint256 stakingExtraFee,
        uint256 holderMainFee,
        uint256 holderExtraFee,
        uint256 buyBurnFee,
        uint256 liquidityFee,
        uint256 directBurnFee,
        uint256 totalFee
    );

    modifier swapping() {
        inSwap = true;
        _;
        inSwap = false;
    }

    constructor(
        address initialOwner,
        string memory name_,
        string memory symbol_,
        uint256 initialSupply,
        address router_,
        address stakingContract_,
        uint256[7] memory feeConfig
    ) ERC20(name_, symbol_) Ownable(initialOwner) {
        require(router_ != address(0), "BrainDaoToken: router zero");
        require(initialSupply > 0, "BrainDaoToken: supply zero");

        router = IDEXRouter(router_);
        WPLS = router.WPLS();
        pair = IDEXFactory(router.factory()).createPair(address(this), WPLS);
        isAMMPair[pair] = true;
        emit AMMPairUpdated(pair, true);

        liquidityReceiver = initialOwner;

        _approve(address(this), address(router), type(uint256).max);

        _setFees(
            feeConfig[0],
            feeConfig[1],
            feeConfig[2],
            feeConfig[3],
            feeConfig[4],
            feeConfig[5],
            feeConfig[6]
        );

        swapThreshold = initialSupply / 10_000;
        if (swapThreshold == 0) {
            swapThreshold = 1;
        }

        maxTxAmount = initialSupply / 100;
        if (maxTxAmount == 0) {
            maxTxAmount = initialSupply;
        }

        isFeeExempt[initialOwner] = true;
        isTxLimitExempt[initialOwner] = true;
        isTxLimitExempt[address(this)] = true;
        isTxLimitExempt[pair] = true;
        isFeeExempt[address(this)] = true;
        isFeeExempt[address(router)] = true;

        isDividendExempt[address(this)] = true;
        isDividendExempt[pair] = true;
        isDividendExempt[deadAddress] = true;
        isDividendExempt[address(router)] = true;

        _mint(initialOwner, initialSupply);

        if (stakingContract_ != address(0)) {
            _setStakingContract(stakingContract_);
        }

        _syncDistributors(initialOwner);
    }

    receive() external payable {}

    function _update(address from, address to, uint256 amount) internal override {
        if (from == address(0) || to == address(0)) {
            super._update(from, to, amount);
            if (from != address(0)) _syncDistributors(from);
            if (to != address(0)) _syncDistributors(to);
            return;
        }

        if (inSwap) {
            super._update(from, to, amount);
            return;
        }

        if (!isTxLimitExempt[from] && !isTxLimitExempt[to]) {
            require(amount <= maxTxAmount, "BrainDaoToken: tx limit");
        }

        if (_shouldSwapBack(from, to)) {
            _swapBack();
        }

        uint256 amountReceived = amount;
        bool takeFee = (totalFee > 0 || instantERC20Fee > 0) && !isFeeExempt[from] && !isFeeExempt[to];
        bool isBuyFromMainPair = (from == pair && !isAMMPair[to]);

        if (takeFee) {
            uint256 standardContractFeeAmount = totalFee > directBurnFee
                ? (amount * (totalFee - directBurnFee)) / FEE_DENOMINATOR
                : 0;
            uint256 burnAmount = directBurnFee == 0 ? 0 : (amount * directBurnFee) / FEE_DENOMINATOR;
            uint256 instantFeeAmount = instantERC20Fee == 0 ? 0 : (amount * instantERC20Fee) / FEE_DENOMINATOR;

            uint256 totalDeducted = standardContractFeeAmount + burnAmount + instantFeeAmount;
            amountReceived = amount - totalDeducted;

            uint256 contractIn = standardContractFeeAmount + instantFeeAmount;
            if (contractIn > 0) {
                super._update(from, address(this), contractIn);
            }

            if (burnAmount > 0) {
                super._update(from, address(0), burnAmount);
            }

            if (instantFeeAmount > 0 && instantERC20TokenToBuy != address(0)) {
                _swapTokensForERC20AndSendToDead(instantFeeAmount, isBuyFromMainPair);
            }
        }

        super._update(from, to, amountReceived);

        _syncDistributors(from);
        _syncDistributors(to);
        _processDistributors();
    }

    function _shouldSwapBack(address from, address to) internal view returns (bool) {
        return
            swapEnabled &&
            !inSwap &&
            isAMMPair[to] &&
            from != address(this) &&
            balanceOf(address(this)) >= swapThreshold;
    }

    function _swapBack() internal swapping {
        uint256 baseAmount = swapThreshold;
        if (baseAmount == 0) return;

        uint256 contractBalance = balanceOf(address(this));
        if (contractBalance < baseAmount) return;

        uint256 tokensToSwap = baseAmount;
        if (autoMintEnabled && autoMintBps > 0) {
            uint256 mintAmount = (baseAmount * autoMintBps) / FEE_DENOMINATOR;
            if (mintAmount > 0) {
                _mint(address(this), mintAmount);
                tokensToSwap += mintAmount;
            }
        }

        uint256 feeUnits = totalFee - directBurnFee;
        if (feeUnits == 0) return;

        uint256 tokensForLiquidity = liquidityFee == 0 ? 0 : (tokensToSwap * liquidityFee) / feeUnits / 2;
        uint256 tokensForSwap = tokensToSwap - tokensForLiquidity;

        uint256 balanceBefore = address(this).balance;
        address[] memory path = _buildTokenToWplsPath();

        router.swapExactTokensForETHSupportingFeeOnTransferTokens(
            tokensForSwap,
            0,
            path,
            address(this),
            block.timestamp
        );

        uint256 amountNative = address(this).balance - balanceBefore;
        if (amountNative == 0) return;

        uint256 ethUnits = feeUnits - (liquidityFee / 2);
        if (ethUnits == 0) return;

        uint256 nativeForLiquidity = liquidityFee == 0 ? 0 : (amountNative * liquidityFee) / ethUnits / 2;
        uint256 nativeForStakingMain = stakingMainFee == 0 ? 0 : (amountNative * stakingMainFee) / ethUnits;
        uint256 nativeForStakingExtra = stakingExtraFee == 0 ? 0 : (amountNative * stakingExtraFee) / ethUnits;
        uint256 nativeForHolderMain = holderMainFee == 0 ? 0 : (amountNative * holderMainFee) / ethUnits;
        uint256 nativeForHolderExtra = holderExtraFee == 0 ? 0 : (amountNative * holderExtraFee) / ethUnits;
        uint256 nativeForBuyBurnBase = buyBurnFee == 0 ? 0 : (amountNative * buyBurnFee) / ethUnits;

        uint256 distributed = nativeForLiquidity
            + nativeForStakingMain
            + nativeForStakingExtra
            + nativeForHolderMain
            + nativeForHolderExtra
            + nativeForBuyBurnBase;

        uint256 nativeForBuyBurn = nativeForBuyBurnBase + (amountNative - distributed);

        if (nativeForHolderMain > 0 && address(mainRewardDistributor) != address(0)) {
            try mainRewardDistributor.deposit{value: nativeForHolderMain}() {} catch {}
        }
        if (nativeForHolderExtra > 0 && address(extraRewardDistributor) != address(0)) {
            try extraRewardDistributor.deposit{value: nativeForHolderExtra}() {} catch {}
        }
        if (nativeForStakingMain > 0 && address(stakingContract) != address(0)) {
            try stakingContract.topUpMain{value: nativeForStakingMain}() {} catch {}
        }
        if (nativeForStakingExtra > 0 && address(stakingContract) != address(0)) {
            try stakingContract.topUpExtra{value: nativeForStakingExtra}() {} catch {}
        }
        if (nativeForBuyBurn > 0 && address(buyBurnDistributor) != address(0)) {
            try buyBurnDistributor.deposit{value: nativeForBuyBurn}() {} catch {}
        }

        if (tokensForLiquidity > 0 && nativeForLiquidity > 0) {
            try router.addLiquidityETH{value: nativeForLiquidity}(
                address(this),
                tokensForLiquidity,
                0,
                0,
                liquidityReceiver,
                block.timestamp
            ) returns (uint256, uint256, uint256) {
                // no-op
            } catch {}
        }
    }

    function _swapTokensForERC20AndSendToDead(uint256 amount, bool avoidMainPair) internal swapping {
    if (amount == 0) return;

    address tokenOut = instantERC20TokenToBuy;
    if (tokenOut == address(0) || tokenOut == address(this)) return;
    if (deadAddress == address(0)) return;

    uint8 start = _instantHopCursor;
    _instantHopCursor = (start + 1) % 3;

    // Remove empty declarations and directly initialize arrays
    if (tokenOut == hop1Token || tokenOut == hop2Token || tokenOut == hop3Token || tokenOut == WPLS) {
        address[] memory directPath = new address[](2);
        directPath[0] = address(this);
        directPath[1] = tokenOut;

        if (_tryInstantSwap(amount, directPath)) {
            return;
        }
    }

    if (!avoidMainPair) {
        if (tokenOut == WPLS) {
            address[] memory pathWpls = new address[](2);
            pathWpls[0] = address(this);
            pathWpls[1] = WPLS;

            if (_tryInstantSwap(amount, pathWpls)) {
                return;
            }
        } else {
            address[] memory pathDirect = new address[](3);
            pathDirect[0] = address(this);
            pathDirect[1] = WPLS;
            pathDirect[2] = tokenOut;

            if (_tryInstantSwap(amount, pathDirect)) {
                return;
            }
        }
    }

    for (uint8 i = 0; i < 3; i++) {
        address hop = _hopAt((start + i) % 3);
        if (!_isValidInstantHop(hop, tokenOut)) continue;

        if (tokenOut == WPLS) {
            address[] memory path3 = new address[](3);
            path3[0] = address(this);
            path3[1] = hop;
            path3[2] = WPLS;

            if (_tryInstantSwap(amount, path3)) {
                return;
            }
        } else {
            address[] memory path4 = new address[](4);
            path4[0] = address(this);
            path4[1] = hop;
            path4[2] = WPLS;
            path4[3] = tokenOut;

            if (_tryInstantSwap(amount, path4)) {
                return;
            }
        }
    }
}

    function _tryInstantSwap(uint256 amount, address[] memory path) internal returns (bool) {
        try router.swapExactTokensForTokensSupportingFeeOnTransferTokens(
            amount,
            0,
            path,
            deadAddress,
            block.timestamp
        ) {
            return true;
        } catch {
            return false;
        }
    }

    function _syncDistributors(address account) internal {
        if (account == address(0)) return;

        uint256 holderBalance = isDividendExempt[account] ? 0 : balanceOf(account);

        if (address(mainRewardDistributor) != address(0)) {
            try mainRewardDistributor.setShare(account, holderBalance) {} catch {}
        }
        if (address(extraRewardDistributor) != address(0)) {
            try extraRewardDistributor.setShare(account, holderBalance) {} catch {}
        }
    }

    function _processDistributors() internal {
        if (address(mainRewardDistributor) != address(0)) {
            try mainRewardDistributor.process(distributorGas) {} catch {}
        }
        if (address(extraRewardDistributor) != address(0)) {
            try extraRewardDistributor.process(distributorGas) {} catch {}
        }
    }

    function _setFees(
        uint256 stakingMainFee_,
        uint256 stakingExtraFee_,
        uint256 holderMainFee_,
        uint256 holderExtraFee_,
        uint256 buyBurnFee_,
        uint256 liquidityFee_,
        uint256 directBurnFee_
    ) internal {
        stakingMainFee = stakingMainFee_;
        stakingExtraFee = stakingExtraFee_;
        holderMainFee = holderMainFee_;
        holderExtraFee = holderExtraFee_;
        buyBurnFee = buyBurnFee_;
        liquidityFee = liquidityFee_;
        directBurnFee = directBurnFee_;
        totalFee = stakingMainFee_ + stakingExtraFee_ + holderMainFee_ + holderExtraFee_ + buyBurnFee_ + liquidityFee_ + directBurnFee_;

        require(totalFee + instantERC20Fee <= MAX_TOTAL_FEE_BPS, "BrainDaoToken: fee too high");

        emit FeesUpdated(
            stakingMainFee,
            stakingExtraFee,
            holderMainFee,
            holderExtraFee,
            buyBurnFee,
            liquidityFee,
            directBurnFee,
            totalFee
        );
    }

    function _markSystemAddress(address account) internal {
        if (account == address(0)) return;
        isFeeExempt[account] = true;
        isDividendExempt[account] = true;
        isTxLimitExempt[account] = true;
        _syncDistributors(account);
    }

    function _setStakingContract(address newStakingContract) internal {
        address oldStaking = address(stakingContract);
        stakingContract = IDualRewardStaking(newStakingContract);
        _markSystemAddress(newStakingContract);
        emit StakingContractUpdated(oldStaking, newStakingContract);
    }

    function _setMainRewardDistributor(address newDistributor) internal {
        require(
            DividendDistributor(payable(newDistributor)).token() == address(this),
            "BrainDaoToken: wrong main distributor"
        );
        address oldDistributor = address(mainRewardDistributor);
        mainRewardDistributor = DividendDistributor(payable(newDistributor));
        _markSystemAddress(newDistributor);
        emit MainRewardDistributorUpdated(oldDistributor, newDistributor);
    }

    function _setExtraRewardDistributor(address newDistributor) internal {
        require(
            FlexibleRewardDistributor(payable(newDistributor)).token() == address(this),
            "BrainDaoToken: wrong extra distributor"
        );
        address oldDistributor = address(extraRewardDistributor);
        extraRewardDistributor = FlexibleRewardDistributor(payable(newDistributor));
        _markSystemAddress(newDistributor);
        emit ExtraRewardDistributorUpdated(oldDistributor, newDistributor);
    }

    function _setBuyBurnDistributor(address newDistributor) internal {
        require(
            BuyBurnDistributor(payable(newDistributor)).token() == address(this),
            "BrainDaoToken: wrong buyburn distributor"
        );
        address oldDistributor = address(buyBurnDistributor);
        buyBurnDistributor = BuyBurnDistributor(payable(newDistributor));
        _markSystemAddress(newDistributor);
        emit BuyBurnDistributorUpdated(oldDistributor, newDistributor);
    }

    function _isValidSwapHop(address hop, address prev) internal view returns (bool) {
        return
            hop != address(0) &&
            hop != prev &&
            hop != address(this) &&
            hop != WPLS;
    }

    function _buildTokenToWplsPath() internal view returns (address[] memory path) {
        uint256 len = 2;
        address prev = address(this);

        if (_isValidSwapHop(hop1Token, prev)) {
            len++;
            prev = hop1Token;
        }
        if (_isValidSwapHop(hop2Token, prev) && hop2Token != hop1Token) {
            len++;
            prev = hop2Token;
        }
        if (_isValidSwapHop(hop3Token, prev) && hop3Token != hop1Token && hop3Token != hop2Token) {
            len++;
        }

        path = new address[](len);
        uint256 i = 0;
        prev = address(this);
        path[i++] = address(this);

        if (_isValidSwapHop(hop1Token, prev)) {
            path[i++] = hop1Token;
            prev = hop1Token;
        }
        if (_isValidSwapHop(hop2Token, prev) && hop2Token != hop1Token) {
            path[i++] = hop2Token;
            prev = hop2Token;
        }
        if (_isValidSwapHop(hop3Token, prev) && hop3Token != hop1Token && hop3Token != hop2Token) {
            path[i++] = hop3Token;
        }

        path[i] = WPLS;
    }

    function _isValidInstantHop(address hop, address tokenOut) internal view returns (bool) {
        return
            hop != address(0) &&
            hop != address(this) &&
            hop != WPLS &&
            hop != tokenOut;
    }

    function _hopAt(uint8 idx) internal view returns (address) {
        if (idx == 0) return hop1Token;
        if (idx == 1) return hop2Token;
        return hop3Token;
    }

    function setStakingContract(address newStakingContract) external onlyOwner {
        require(newStakingContract != address(0), "BrainDaoToken: staking zero");
        _setStakingContract(newStakingContract);
    }

    function setMainRewardDistributor(address newDistributor) external onlyOwner {
        require(newDistributor != address(0), "BrainDaoToken: distributor zero");
        _setMainRewardDistributor(newDistributor);
        _syncDistributors(owner());
    }

    function setExtraRewardDistributor(address newDistributor) external onlyOwner {
        require(newDistributor != address(0), "BrainDaoToken: distributor zero");
        _setExtraRewardDistributor(newDistributor);
        _syncDistributors(owner());
    }

    function setBuyBurnDistributor(address newDistributor) external onlyOwner {
        require(newDistributor != address(0), "BrainDaoToken: distributor zero");
        _setBuyBurnDistributor(newDistributor);
    }

    function setFees(
        uint256 stakingMainFee_,
        uint256 stakingExtraFee_,
        uint256 holderMainFee_,
        uint256 holderExtraFee_,
        uint256 buyBurnFee_,
        uint256 liquidityFee_,
        uint256 directBurnFee_
    ) external onlyOwner {
        _setFees(
            stakingMainFee_,
            stakingExtraFee_,
            holderMainFee_,
            holderExtraFee_,
            buyBurnFee_,
            liquidityFee_,
            directBurnFee_
        );
    }

    function setInstantERC20Settings(uint256 feeBps, address tokenToBuy_) external onlyOwner {
        require(totalFee + feeBps <= MAX_TOTAL_FEE_BPS, "BrainDaoToken: instant fee too high");
        require(tokenToBuy_ != address(this), "BrainDaoToken: instant self");
        if (feeBps > 0) {
            require(tokenToBuy_ != address(0), "BrainDaoToken: instant token zero");
        }

        instantERC20Fee = feeBps;
        instantERC20TokenToBuy = tokenToBuy_;
        emit InstantERC20SettingsUpdated(feeBps, tokenToBuy_);
    }

    function setAMMPair(address pair_, bool value) external onlyOwner {
        require(pair_ != address(0), "BrainDaoToken: pair zero");
        isAMMPair[pair_] = value;
        if (value) {
            isDividendExempt[pair_] = true;
            _syncDistributors(pair_);
        }
        emit AMMPairUpdated(pair_, value);
    }

    function setFeeExempt(address account, bool value) external onlyOwner {
        isFeeExempt[account] = value;
        emit FeeExemptUpdated(account, value);
    }

    function setTxLimitExempt(address account, bool value) external onlyOwner {
        isTxLimitExempt[account] = value;
        emit TxLimitExemptUpdated(account, value);
    }

    function setDividendExempt(address account, bool value) external onlyOwner {
        require(account != address(this), "BrainDaoToken: self exempt");
        require(!isAMMPair[account], "BrainDaoToken: pair exempt");
        isDividendExempt[account] = value;
        _syncDistributors(account);
        emit DividendExemptUpdated(account, value);
    }

    function setDistributorGas(uint256 gasLimit) external onlyOwner {
        require(gasLimit <= 1_500_000, "BrainDaoToken: gas too high");
        distributorGas = gasLimit;
        emit DistributorGasUpdated(gasLimit);
    }

    function setDistributionCriteria(
        uint256 mainMinPeriod,
        uint256 mainMinDistribution,
        uint256 extraMinPeriod,
        uint256 extraMinDistribution
    ) external onlyOwner {
        require(address(mainRewardDistributor) != address(0), "BrainDaoToken: main distributor unset");
        require(address(extraRewardDistributor) != address(0), "BrainDaoToken: extra distributor unset");
        mainRewardDistributor.setDistributionCriteria(mainMinPeriod, mainMinDistribution);
        extraRewardDistributor.setDistributionCriteria(extraMinPeriod, extraMinDistribution);
    }

    function setSwapBackSettings(bool enabled, uint256 threshold) external onlyOwner {
        require(threshold > 0, "BrainDaoToken: threshold zero");
        swapEnabled = enabled;
        swapThreshold = threshold;
        emit SwapBackSettingsUpdated(enabled, threshold);
    }

    function setAutoMintSettings(bool enabled, uint256 mintBps) external onlyOwner {
        require(mintBps <= FEE_DENOMINATOR, "BrainDaoToken: mint too high");
        autoMintEnabled = enabled;
        autoMintBps = mintBps;
        emit AutoMintSettingsUpdated(enabled, mintBps);
    }

    function setSwapHops(address hop1, address hop2, address hop3) external onlyOwner {
        hop1Token = hop1;
        hop2Token = hop2;
        hop3Token = hop3;
        emit SwapHopsUpdated(hop1, hop2, hop3);
    }

    function setMainRewardHops(address hop1, address hop2, address hop3) external onlyOwner {
        require(address(mainRewardDistributor) != address(0), "BrainDaoToken: main distributor unset");
        mainRewardDistributor.setRewardHops(hop1, hop2, hop3);
    }

    function setExtraRewardHops(address hop1, address hop2, address hop3) external onlyOwner {
        require(address(extraRewardDistributor) != address(0), "BrainDaoToken: extra distributor unset");
        extraRewardDistributor.setRewardHops(hop1, hop2, hop3);
    }

    function setBuyBurnHops(address hop1, address hop2, address hop3) external onlyOwner {
        require(address(buyBurnDistributor) != address(0), "BrainDaoToken: buyburn distributor unset");
        buyBurnDistributor.setBuyHops(hop1, hop2, hop3);
    }

    function setMaxTxAmount(uint256 amount) external onlyOwner {
        require(amount > 0, "BrainDaoToken: max tx zero");
        maxTxAmount = amount;
    }

    function setDeadAddress(address newDead) external onlyOwner {
        require(newDead != address(0), "BrainDaoToken: dead zero");
        require(newDead != address(this), "BrainDaoToken: dead self");

        address oldDead = deadAddress;
        deadAddress = newDead;
        isDividendExempt[newDead] = true;

        if (address(extraRewardDistributor) != address(0)) {
            extraRewardDistributor.setDeadAddress(newDead);
        }
        if (address(buyBurnDistributor) != address(0)) {
            buyBurnDistributor.setDeadAddress(newDead);
        }

        emit DeadAddressUpdated(oldDead, newDead);
    }

    function setLiquidityReceiver(address newReceiver) external onlyOwner {
        require(newReceiver != address(0), "BrainDaoToken: receiver zero");
        emit LiquidityReceiverUpdated(liquidityReceiver, newReceiver);
        liquidityReceiver = newReceiver;
    }

    function setBuyBurnToken(address newToken) external onlyOwner {
        require(address(buyBurnDistributor) != address(0), "BrainDaoToken: buyburn distributor unset");
        buyBurnDistributor.setTokenToBuy(newToken);
    }

    function setBuyBurnThreshold(uint256 newThreshold) external onlyOwner {
        require(address(buyBurnDistributor) != address(0), "BrainDaoToken: buyburn distributor unset");
        buyBurnDistributor.setBuyThreshold(newThreshold);
    }

    function setExtraRewardToken(address newToken) external onlyOwner {
        require(address(extraRewardDistributor) != address(0), "BrainDaoToken: extra distributor unset");
        extraRewardDistributor.changeRewardToken(newToken);
    }

    function manualProcessDistributors(uint256 gasLimit) external {
        if (address(mainRewardDistributor) != address(0)) {
            mainRewardDistributor.process(gasLimit);
        }
        if (address(extraRewardDistributor) != address(0)) {
            extraRewardDistributor.process(gasLimit);
        }
    }

    function manualSyncShares(address[] calldata accounts) external onlyOwner {
        uint256 length = accounts.length;
        for (uint256 i = 0; i < length; ) {
            _syncDistributors(accounts[i]);
            unchecked {
                ++i;
            }
        }
    }

    function rescueForeignToken(address token, uint256 amount) external onlyOwner {
        require(token != address(this), "BrainDaoToken: no self rescue");
        IERC20(token).safeTransfer(owner(), amount);
    }

    function rescueNative(uint256 amount) external onlyOwner {
        (bool ok, ) = payable(owner()).call{value: amount}("");
        require(ok, "BrainDaoToken: native rescue failed");
    }
}
        

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IWPLS {
    function deposit() external payable;
    function withdraw(uint256 amount) external;

    function totalSupply() external view returns (uint256);
    function balanceOf(address account) external view returns (uint256);

    function transfer(address to, uint256 amount) external returns (bool);
    function approve(address spender, uint256 amount) external returns (bool);
    function allowance(address owner, address spender) external view returns (uint256);
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IDualRewardStaking {
    function topUpMain() external payable;
    function topUpExtra() external payable;
    function topUpBoth(uint256 mainBps) external payable;
    function notifyRewardAmount(uint256 reward) external;
    function notifyRewardAmount2(uint256 reward) external;
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IDEXRouter {
    function factory() external view returns (address);
    function WPLS() external view returns (address);

    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external;

    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external payable;

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external;

    

    function addLiquidityETH(
        address token,
        uint256 amountTokenDesired,
        uint256 amountTokenMin,
        uint256 amountETHMin,
        address to,
        uint256 deadline
    )
        external
        payable
        returns (
            uint256 amountToken,
            uint256 amountETH,
            uint256 liquidity
        );
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IDEXFactory {
    function createPair(address tokenA, address tokenB) external returns (address pair);
    function getPair(address tokenA, address tokenB) external view returns (address pair);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/IERC165.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/StorageSlot.sol)
// This file was procedurally generated from scripts/generate/templates/StorageSlot.js.

pragma solidity ^0.8.20;

/**
 * @dev Library for reading and writing primitive types to specific storage slots.
 *
 * Storage slots are often used to avoid storage conflict when dealing with upgradeable contracts.
 * This library helps with reading and writing to such slots without the need for inline assembly.
 *
 * The functions in this library return Slot structs that contain a `value` member that can be used to read or write.
 *
 * Example usage to set ERC-1967 implementation slot:
 * ```solidity
 * contract ERC1967 {
 *     // Define the slot. Alternatively, use the SlotDerivation library to derive the slot.
 *     bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
 *
 *     function _getImplementation() internal view returns (address) {
 *         return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
 *     }
 *
 *     function _setImplementation(address newImplementation) internal {
 *         require(newImplementation.code.length > 0);
 *         StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
 *     }
 * }
 * ```
 *
 * TIP: Consider using this library along with {SlotDerivation}.
 */
library StorageSlot {
    struct AddressSlot {
        address value;
    }

    struct BooleanSlot {
        bool value;
    }

    struct Bytes32Slot {
        bytes32 value;
    }

    struct Uint256Slot {
        uint256 value;
    }

    struct Int256Slot {
        int256 value;
    }

    struct StringSlot {
        string value;
    }

    struct BytesSlot {
        bytes value;
    }

    /**
     * @dev Returns an `AddressSlot` with member `value` located at `slot`.
     */
    function getAddressSlot(bytes32 slot) internal pure returns (AddressSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `BooleanSlot` with member `value` located at `slot`.
     */
    function getBooleanSlot(bytes32 slot) internal pure returns (BooleanSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `Bytes32Slot` with member `value` located at `slot`.
     */
    function getBytes32Slot(bytes32 slot) internal pure returns (Bytes32Slot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `Uint256Slot` with member `value` located at `slot`.
     */
    function getUint256Slot(bytes32 slot) internal pure returns (Uint256Slot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `Int256Slot` with member `value` located at `slot`.
     */
    function getInt256Slot(bytes32 slot) internal pure returns (Int256Slot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `StringSlot` with member `value` located at `slot`.
     */
    function getStringSlot(bytes32 slot) internal pure returns (StringSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` representation of the string storage pointer `store`.
     */
    function getStringSlot(string storage store) internal pure returns (StringSlot storage r) {
        assembly ("memory-safe") {
            r.slot := store.slot
        }
    }

    /**
     * @dev Returns a `BytesSlot` with member `value` located at `slot`.
     */
    function getBytesSlot(bytes32 slot) internal pure returns (BytesSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` representation of the bytes storage pointer `store`.
     */
    function getBytesSlot(bytes storage store) internal pure returns (BytesSlot storage r) {
        assembly ("memory-safe") {
            r.slot := store.slot
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.5.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

import {StorageSlot} from "./StorageSlot.sol";

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 *
 * IMPORTANT: Deprecated. This storage-based reentrancy guard will be removed and replaced
 * by the {ReentrancyGuardTransient} variant in v6.0.
 *
 * @custom:stateless
 */
abstract contract ReentrancyGuard {
    using StorageSlot for bytes32;

    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.ReentrancyGuard")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 private constant REENTRANCY_GUARD_STORAGE =
        0x9b779b17422d0df92223018b32b4d1fa46e071723d6817e2486d003becc55f00;

    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _reentrancyGuardStorageSlot().getUint256Slot().value = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    /**
     * @dev A `view` only version of {nonReentrant}. Use to block view functions
     * from being called, preventing reading from inconsistent contract state.
     *
     * CAUTION: This is a "view" modifier and does not change the reentrancy
     * status. Use it only on view functions. For payable or non-payable functions,
     * use the standard {nonReentrant} modifier instead.
     */
    modifier nonReentrantView() {
        _nonReentrantBeforeView();
        _;
    }

    function _nonReentrantBeforeView() private view {
        if (_reentrancyGuardEntered()) {
            revert ReentrancyGuardReentrantCall();
        }
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        _nonReentrantBeforeView();

        // Any calls to nonReentrant after this point will fail
        _reentrancyGuardStorageSlot().getUint256Slot().value = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _reentrancyGuardStorageSlot().getUint256Slot().value = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _reentrancyGuardStorageSlot().getUint256Slot().value == ENTERED;
    }

    function _reentrancyGuardStorageSlot() internal pure virtual returns (bytes32) {
        return REENTRANCY_GUARD_STORAGE;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.5.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        if (!_safeTransfer(token, to, value, true)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        if (!_safeTransferFrom(token, from, to, value, true)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _safeTransfer(token, to, value, false);
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _safeTransferFrom(token, from, to, value, false);
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        if (!_safeApprove(token, spender, value, false)) {
            if (!_safeApprove(token, spender, 0, true)) revert SafeERC20FailedOperation(address(token));
            if (!_safeApprove(token, spender, value, true)) revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that relies on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that relies on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Oppositely, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity `token.transfer(to, value)` call, relaxing the requirement on the return value: the
     * return value is optional (but if data is returned, it must not be false).
     *
     * @param token The token targeted by the call.
     * @param to The recipient of the tokens
     * @param value The amount of token to transfer
     * @param bubble Behavior switch if the transfer call reverts: bubble the revert reason or return a false boolean.
     */
    function _safeTransfer(IERC20 token, address to, uint256 value, bool bubble) private returns (bool success) {
        bytes4 selector = IERC20.transfer.selector;

        assembly ("memory-safe") {
            let fmp := mload(0x40)
            mstore(0x00, selector)
            mstore(0x04, and(to, shr(96, not(0))))
            mstore(0x24, value)
            success := call(gas(), token, 0, 0x00, 0x44, 0x00, 0x20)
            // if call success and return is true, all is good.
            // otherwise (not success or return is not true), we need to perform further checks
            if iszero(and(success, eq(mload(0x00), 1))) {
                // if the call was a failure and bubble is enabled, bubble the error
                if and(iszero(success), bubble) {
                    returndatacopy(fmp, 0x00, returndatasize())
                    revert(fmp, returndatasize())
                }
                // if the return value is not true, then the call is only successful if:
                // - the token address has code
                // - the returndata is empty
                success := and(success, and(iszero(returndatasize()), gt(extcodesize(token), 0)))
            }
            mstore(0x40, fmp)
        }
    }

    /**
     * @dev Imitates a Solidity `token.transferFrom(from, to, value)` call, relaxing the requirement on the return
     * value: the return value is optional (but if data is returned, it must not be false).
     *
     * @param token The token targeted by the call.
     * @param from The sender of the tokens
     * @param to The recipient of the tokens
     * @param value The amount of token to transfer
     * @param bubble Behavior switch if the transfer call reverts: bubble the revert reason or return a false boolean.
     */
    function _safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value,
        bool bubble
    ) private returns (bool success) {
        bytes4 selector = IERC20.transferFrom.selector;

        assembly ("memory-safe") {
            let fmp := mload(0x40)
            mstore(0x00, selector)
            mstore(0x04, and(from, shr(96, not(0))))
            mstore(0x24, and(to, shr(96, not(0))))
            mstore(0x44, value)
            success := call(gas(), token, 0, 0x00, 0x64, 0x00, 0x20)
            // if call success and return is true, all is good.
            // otherwise (not success or return is not true), we need to perform further checks
            if iszero(and(success, eq(mload(0x00), 1))) {
                // if the call was a failure and bubble is enabled, bubble the error
                if and(iszero(success), bubble) {
                    returndatacopy(fmp, 0x00, returndatasize())
                    revert(fmp, returndatasize())
                }
                // if the return value is not true, then the call is only successful if:
                // - the token address has code
                // - the returndata is empty
                success := and(success, and(iszero(returndatasize()), gt(extcodesize(token), 0)))
            }
            mstore(0x40, fmp)
            mstore(0x60, 0)
        }
    }

    /**
     * @dev Imitates a Solidity `token.approve(spender, value)` call, relaxing the requirement on the return value:
     * the return value is optional (but if data is returned, it must not be false).
     *
     * @param token The token targeted by the call.
     * @param spender The spender of the tokens
     * @param value The amount of token to transfer
     * @param bubble Behavior switch if the transfer call reverts: bubble the revert reason or return a false boolean.
     */
    function _safeApprove(IERC20 token, address spender, uint256 value, bool bubble) private returns (bool success) {
        bytes4 selector = IERC20.approve.selector;

        assembly ("memory-safe") {
            let fmp := mload(0x40)
            mstore(0x00, selector)
            mstore(0x04, and(spender, shr(96, not(0))))
            mstore(0x24, value)
            success := call(gas(), token, 0, 0x00, 0x44, 0x00, 0x20)
            // if call success and return is true, all is good.
            // otherwise (not success or return is not true), we need to perform further checks
            if iszero(and(success, eq(mload(0x00), 1))) {
                // if the call was a failure and bubble is enabled, bubble the error
                if and(iszero(success), bubble) {
                    returndatacopy(fmp, 0x00, returndatasize())
                    revert(fmp, returndatasize())
                }
                // if the return value is not true, then the call is only successful if:
                // - the token address has code
                // - the returndata is empty
                success := and(success, and(iszero(returndatasize()), gt(extcodesize(token), 0)))
            }
            mstore(0x40, fmp)
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity >=0.6.2;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.5.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * Both values are immutable: they can only be set once during construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /// @inheritdoc IERC20
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /// @inheritdoc IERC20
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /// @inheritdoc IERC20
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner`'s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation sets the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the `transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner`'s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance < type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.5.0) (interfaces/draft-IERC6093.sol)

pragma solidity >=0.8.4;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-721.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC-1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC20.sol)

pragma solidity >=0.4.16;

import {IERC20} from "../token/ERC20/IERC20.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC165.sol)

pragma solidity >=0.4.16;

import {IERC165} from "../utils/introspection/IERC165.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC1363.sol)

pragma solidity >=0.6.2;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}