Contract Address Details

// SPDX-License-Identifier: MIT
pragma solidity 0.8.23;

import {ReentrancyGuard} from "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

import "@interfaces/IPandaStaking.sol";

//====================MASTERCHEF=======================//

// MasterChef is the master of HEX. He can make HEX and he is a fair guy.
//
// Note that it's ownable and the owner wields tremendous power. The ownership
// will be transferred to a governance smart contract once HEX is sufficiently
// distributed and the community can show to govern itself.
//
// Have fun reading it. Hopefully it's bug-free. God bless.

contract PandaStaking is Ownable, ReentrancyGuard, IPandaStaking {
    using SafeERC20 for IERC20;

    // Info of each user.
    struct UserInfo {
        uint256 amount; // How many LP tokens the user has provided.
        mapping(address => int256) rewardDebt; // Reward debt per token. See explanation below.
        //
        // We do some fancy math here. Basically, any point in time, the amount of tokens
        // entitled to a user but is pending to be distributed is:
        //
        //   pending reward = (effectiveShares * pool.accTokenPerShareX18[token]) - user.rewardDebt[token]
        //   where effectiveShares = user.amount * durationMultiplier[user.durationWeeks]
        //
        // Whenever a user deposits or withdraws LP tokens to a pool. Here's what happens:
        //   1. The pool's `accTokenPerShareX18` gets updated for each reward token.
        //   2. User receives the pending rewards sent to his/her address.
        //   3. User's `amount` gets updated.
        //   4. User's `rewardDebt` gets updated for each token.
        uint256 stakedAt;
        uint256 durationWeeks; // Staking duration in weeks chosen by user
    }

    // Info of each pool.
    struct PoolInfo {
        IERC20 lpToken; // Address of LP token contract.
        uint256 allocPoint; // How many allocation points assigned to this pool. ALPHAs to distribute per second.
        uint256 lastRewardTime; // Last timestamp number that rewards distribution occurs.
        mapping(address => uint256) accTokenPerShareX18; // Accumulated tokens per share per token, times 1e18.
        uint256 lpSupply; // Total effective shares in the pool (sum of user.amount * multiplier for all users)
    }

    IERC20 public immutable hexToken; // HEX = 0x2b591e99afE9f32eAA6214f7B7629768c40Eeb39

    // Info of each pool.
    PoolInfo[] public poolInfo;
    // Info of each user that stakes LP tokens.
    mapping(uint256 => mapping(address => UserInfo)) public userInfo;
    // Total allocation points. Must be the sum of all allocation points in all pools.
    uint256 public totalAllocPoint = 0;

    // Historical share rate tracking for APY calculations (per pool and token)
    mapping(uint256 => mapping(address => uint256)) public accTokenPerShareThreeDaysAgo; // accTokenPerShareX18 value 3 days ago
    mapping(uint256 => mapping(address => uint256)) public lastSnapshotTime; // Last time snapshot was taken per pool and token
    uint256 constant THREE_DAYS = 3 days;

    // Multiple reward tokens support
    IERC20[] public rewardTokens; // List of all reward tokens
    mapping(address => bool) public isRewardToken; // Check if token is a reward token
    mapping(address => uint256) public undistributedRewards; // Undistributed rewards per token

    // Duration multipliers (in weeks -> multiplier scaled by 1e18)
    // 1 week -> 1.03x (1030000000000000000)
    // 5 weeks -> 1.10x (1100000000000000000)
    // 10 weeks -> 2.00x (2000000000000000000)
    // 25 weeks -> 5.45x (5450000000000000000)
    // 52 weeks -> 22.56x (22560000000000000000)
    mapping(uint256 => uint256) public durationMultiplier; // weeks -> multiplier (1e18)
    uint256[] public validDurations; // List of valid duration options in weeks

    event Deposit(address indexed user, uint256 indexed pid, uint256 amount);
    event Withdraw(address indexed user, uint256 indexed pid, uint256 amount);
    event Harvest(address indexed user, uint256 indexed pid, uint256 amount);
    event AddPool(uint256 indexed pid, address lpToken, uint256 allocPoint);
    event SetPool(uint256 indexed pid, address lpToken, uint256 allocPoint);
    event UpdateStartTime(uint256 newStartBlock);
    event LogUpdatePool(uint256 indexed pid, uint256 lastRewardTime, uint256 lpSupply, uint256 accHEXPerShareX18);
    event RewardTokenAdded(address indexed token);
    event RewardTokenRemoved(address indexed token);
    event RewardsDistributed(address indexed token, uint256 amount);
    event DurationMultiplierSet(uint256 indexed durationWeeks, uint256 multiplier);

    constructor(address _hexToken, address _owner) Ownable(_owner) {
        hexToken = IERC20(_hexToken);

        // Add HEX as the first reward token
        rewardTokens.push(IERC20(_hexToken));
        isRewardToken[_hexToken] = true;

        // Initialize duration multipliers
        _setDurationMultiplier(1, 1.0e18); // 1 week -> 1.00x
        _setDurationMultiplier(2, 1.03e18); // 2 week -> 1.00x
        _setDurationMultiplier(5, 1.1e18); // 5 weeks -> 1.10x
        _setDurationMultiplier(10, 2.0e18); // 10 weeks -> 2.00x
        _setDurationMultiplier(25, 5.45e18); // 25 weeks -> 5.45x
        _setDurationMultiplier(52, 22.56e18); // 52 weeks -> 22.56x
    }

    // Internal function to set duration multiplier
    function _setDurationMultiplier(uint256 _weeks, uint256 _multiplier) internal {
        durationMultiplier[_weeks] = _multiplier;
        validDurations.push(_weeks);

        emit DurationMultiplierSet(_weeks, _multiplier);
    }

    function poolLength() external view returns (uint256) {
        return poolInfo.length;
    }

    mapping(IERC20 => bool) public poolExistence;

    modifier nonDuplicated(IERC20 _lpToken) {
        require(poolExistence[_lpToken] == false, "nonDuplicated: duplicated");
        _;
    }

    // Add a new lp to the pool. Can only be called by the owner.
    function add(uint256 _allocPoint, IERC20 _lpToken, bool _withUpdate) external onlyOwner nonDuplicated(_lpToken) {
        // valid ERC20 token
        _lpToken.balanceOf(address(this));

        if (_withUpdate) {
            massUpdatePools();
        }

        // update pools total alloc points
        totalAllocPoint = totalAllocPoint + _allocPoint;

        poolExistence[_lpToken] = true;

        // Push empty struct first (structs with mappings must be in storage)
        poolInfo.push();
        uint256 pid = poolInfo.length - 1;

        // Set fields on storage struct
        PoolInfo storage newPool = poolInfo[pid];
        newPool.lpToken = _lpToken;
        newPool.allocPoint = _allocPoint;
        newPool.lastRewardTime = block.timestamp;
        newPool.lpSupply = 0;

        emit AddPool(pid, address(_lpToken), _allocPoint);
    }

    // Update the given pool's allocation point. Can only be called by the owner.
    function setPoolAllocPoints(uint256 _pid, uint256 _allocPoint, bool _withUpdate) external onlyOwner {
        if (_withUpdate) {
            massUpdatePools();
        }
        totalAllocPoint = totalAllocPoint - poolInfo[_pid].allocPoint + _allocPoint;
        poolInfo[_pid].allocPoint = _allocPoint;

        emit SetPool(_pid, address(poolInfo[_pid].lpToken), _allocPoint);
    }

    // Add a new reward token. Can only be called by the owner.
    function addRewardToken(address _token) external onlyOwner {
        require(address(_token) != address(0), "Invalid token");
        require(!isRewardToken[_token], "Token already added");

        bool isPresent = false;
        for (uint256 i = 0; i < rewardTokens.length; ++i) {
            if (address(rewardTokens[i]) == address(_token)) {
                isPresent = true;
                break;
            }
        }

        if (!isPresent) {
            rewardTokens.push(IERC20(_token));
        }

        isRewardToken[_token] = true;

        emit RewardTokenAdded(address(_token));
    }

    // Remove a reward token. Can only be called by the owner.
    function removeRewardToken(address _token) external onlyOwner {
        require(isRewardToken[_token], "Token not found");
        require(address(_token) != address(hexToken), "Cannot remove HEX token");

        isRewardToken[_token] = false;

        emit RewardTokenRemoved(address(_token));
    }

    function rewardTokenCount() external view returns (uint256) {
        return rewardTokens.length;
    }

    // Update reward variables for all pools. Be careful of gas spending!
    function massUpdatePools() public {
        uint256 length = poolInfo.length;
        for (uint256 pid = 0; pid < length; ++pid) {
            updatePool(pid);
        }
    }

    // Update reward variables of the given pool to be up-to-date.
    function updatePool(uint256 _pid) public {
        PoolInfo storage pool = poolInfo[_pid];

        uint256 lpSupply = pool.lpSupply;
        if (lpSupply == 0 || pool.allocPoint == 0) {
            pool.lastRewardTime = block.timestamp;
            return;
        }

        // Update accumulation for each reward token
        uint256 length = rewardTokens.length;

        uint256 activeTotalAllocPoint = getActiveTotalAllocPoint();

        for (uint256 i = 0; i < length; ++i) {
            address token = address(rewardTokens[i]);
            uint256 undistributed = undistributedRewards[token];
            if (undistributed > 0) {
                uint256 poolReward = (undistributed * pool.allocPoint) / activeTotalAllocPoint;
                pool.accTokenPerShareX18[token] = pool.accTokenPerShareX18[token] + (poolReward * 1e18) / lpSupply;
            }

            // Update snapshot for APY calculations if 3 days have passed
            _updateShareRateSnapshot(_pid, token, pool.accTokenPerShareX18[token]);
        }

        pool.lastRewardTime = block.timestamp;

        emit LogUpdatePool(_pid, pool.lastRewardTime, lpSupply, pool.accTokenPerShareX18[address(hexToken)]);
    }

    // Get the total allocation points of the active pools
    function getActiveTotalAllocPoint() public view returns (uint256) {
        uint256 activeTotalAllocPoint = 0;

        for (uint256 pid = 0; pid < poolInfo.length; pid++) {
            if (poolInfo[pid].lpSupply == 0) {
                continue;
            }
            activeTotalAllocPoint += poolInfo[pid].allocPoint;
        }

        return activeTotalAllocPoint;
    }

    // Get accTokenPerShare for a specific token and pool (for external queries)
    function getAccTokenPerShare(uint256 _pid, address _token) external view returns (uint256) {
        return poolInfo[_pid].accTokenPerShareX18[_token];
    }

    // Get rewardDebt for a specific token, pool, and user (for external queries)
    function getRewardDebt(uint256 _pid, address _user, address _token) external view returns (int256) {
        return userInfo[_pid][_user].rewardDebt[_token];
    }

    // Get valid durations array
    function getValidDurations() external view returns (uint256[] memory) {
        return validDurations;
    }

    // Get user's staking info
    function getUserStakeInfo(uint256 _pid, address _user)
        external
        view
        returns (
            uint256 amount,
            uint256 durationWeeks,
            uint256 stakedAt,
            uint256 unlockTime,
            bool canWithdraw,
            uint256 effectiveShares
        )
    {
        UserInfo storage user = userInfo[_pid][_user];
        amount = user.amount;
        durationWeeks = user.durationWeeks;
        stakedAt = user.stakedAt;
        uint256 durationSeconds = durationWeeks * 7 days;
        unlockTime = stakedAt + durationSeconds;
        // canWithdraw is only true if user has staked (stakedAt > 0) and unlock time has passed
        canWithdraw = stakedAt > 0 && block.timestamp >= unlockTime;
        effectiveShares = getEffectiveShares(_pid, _user);
    }

    // Distribute rewards for a single token to the pools.
    function distributeRewards(address _token, uint256 _amount) public {
        require(isRewardToken[_token], "Token not a reward token");

        IERC20(_token).safeTransferFrom(msg.sender, address(this), _amount);

        undistributedRewards[_token] = _amount;
        massUpdatePools();
        undistributedRewards[_token] = 0;

        emit RewardsDistributed(address(_token), _amount);
    }

    // Internal function to update share rate snapshots for APY calculations
    function _updateShareRateSnapshot(uint256 _pid, address _token, uint256 _currentAccTokenPerShare) internal {
        uint256 currentTime = block.timestamp;

        // Initialize if first time
        if (lastSnapshotTime[_pid][_token] == 0) {
            lastSnapshotTime[_pid][_token] = currentTime;
            accTokenPerShareThreeDaysAgo[_pid][_token] = _currentAccTokenPerShare;
            return;
        }

        // Update 3-day-ago snapshot if 3 days have passed since last snapshot
        if (currentTime >= lastSnapshotTime[_pid][_token] + THREE_DAYS) {
            // Store the current value as the new snapshot (this will be the "3 days ago" value)
            accTokenPerShareThreeDaysAgo[_pid][_token] = _currentAccTokenPerShare;
            lastSnapshotTime[_pid][_token] = currentTime;
        }
    }

    // Get effective shares for a user (amount * multiplier)
    function getEffectiveShares(uint256 _pid, address _user) public view returns (uint256) {
        UserInfo storage user = userInfo[_pid][_user];
        if (user.amount == 0 || user.durationWeeks == 0) {
            return user.amount; // No multiplier if no stake or no duration set
        }
        uint256 multiplier = durationMultiplier[user.durationWeeks];
        return (user.amount * multiplier) / 1e18;
    }

    // View function to see pending rewards for a specific token.
    function pendingReward(uint256 _pid, address _user, address _token) external view returns (uint256) {
        require(isRewardToken[_token], "Token not a reward token");

        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][_user];
        uint256 accTokenPerShare = pool.accTokenPerShareX18[_token];

        // Use effective shares (amount * multiplier)
        uint256 effectiveShares = getEffectiveShares(_pid, _user);
        int256 accumulated = int256(effectiveShares * accTokenPerShare / 1e18);

        return uint256(accumulated - user.rewardDebt[_token]);
    }

    // View function to see all pending rewards.
    function pendingRewards(uint256 _pid, address _user)
        external
        view
        returns (address[] memory tokens, uint256[] memory amounts)
    {
        uint256 length = rewardTokens.length;
        tokens = new address[](length);
        amounts = new uint256[](length);

        for (uint256 i = 0; i < length; ++i) {
            tokens[i] = address(rewardTokens[i]);
            amounts[i] = this.pendingReward(_pid, _user, address(rewardTokens[i]));
        }
    }

    // Stake LP tokens to MasterChef for reward allocation.
    // @param _durationWeeks The staking duration in weeks (must be a valid duration)
    function deposit(uint256 _pid, uint256 _amount, uint256 _durationWeeks) external nonReentrant {
        _deposit(_pid, _amount, _durationWeeks);
    }

    // Overloaded deposit function for backward compatibility (uses 1 week default)
    function deposit(uint256 _pid, uint256 _amount) external nonReentrant {
        // Default to 0 week if no duration specified
        _deposit(_pid, _amount, 1);
    }

    // Internal deposit function
    function _deposit(uint256 _pid, uint256 _amount, uint256 _durationWeeks) internal {
        require(durationMultiplier[_durationWeeks] > 0, "Invalid duration");

        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];
        updatePool(_pid);

        // Harvest all pending rewards
        if (user.amount > 0) {
            _harvestRewards(_pid, msg.sender, msg.sender);
        }

        if (_amount > 0) {
            uint256 balanceBefore = pool.lpToken.balanceOf(address(this));
            pool.lpToken.safeTransferFrom(address(msg.sender), address(this), _amount);
            _amount = pool.lpToken.balanceOf(address(this)) - balanceBefore;

            // If this is a new deposit or user wants to change duration, set new duration
            if (user.amount == 0 || user.durationWeeks != _durationWeeks) {
                require(user.amount == 0, "Cannot change duration on existing stake");
                user.durationWeeks = _durationWeeks;
            }

            user.stakedAt = block.timestamp;

            // Calculate effective shares for the new amount
            uint256 multiplier = durationMultiplier[user.durationWeeks];
            uint256 effectiveSharesAdded = (_amount * multiplier) / 1e18;

            user.amount = user.amount + _amount;
            // Update lpSupply with effective shares (not raw amount)
            pool.lpSupply = pool.lpSupply + effectiveSharesAdded;
        }

        // Update reward debt for all tokens (using effective shares)
        _updateRewardDebt(_pid, msg.sender);

        emit Deposit(msg.sender, _pid, _amount);
    }

    // Withdraw LP tokens and harvest rewards from MasterChef.
    function withdraw(uint256 _pid, uint256 _amount) external nonReentrant {
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];

        require(user.amount >= _amount, "withdraw: not enough amount");

        // Check if user's chosen duration has passed
        require(block.timestamp >= user.stakedAt + user.durationWeeks * 7 days, "withdraw: duration not yet passed");

        updatePool(_pid);

        // Harvest all pending rewards
        _harvestRewards(_pid, msg.sender, msg.sender);

        if (_amount > 0) {
            // Calculate effective shares for the amount being withdrawn
            uint256 multiplier = durationMultiplier[user.durationWeeks];
            uint256 effectiveSharesRemoved = (_amount * multiplier) / 1e18;

            user.amount = user.amount - _amount;
            pool.lpToken.safeTransfer(address(msg.sender), _amount);
            // Update lpSupply by removing effective shares (not raw amount)
            pool.lpSupply = pool.lpSupply - effectiveSharesRemoved;
        }

        // If fully withdrawn, reset duration
        if (user.amount == 0) {
            user.durationWeeks = 0;
        }

        // Update reward debt for all tokens
        _updateRewardDebt(_pid, msg.sender);

        emit Withdraw(msg.sender, _pid, _amount);
    }

    // Harvest proceeds for transaction sender to `to`.
    function harvest(uint256 _pid, address _to) public nonReentrant {
        UserInfo storage user = userInfo[_pid][msg.sender];

        // Check if user's chosen duration has passed (can harvest after duration)
        uint256 durationSeconds = user.durationWeeks * 7 days;
        require(block.timestamp >= user.stakedAt + durationSeconds, "harvest: duration not yet passed");

        updatePool(_pid);
        _harvestRewards(_pid, msg.sender, _to);
        _updateRewardDebt(_pid, msg.sender);
    }

    // Withdraw LP tokens from MasterChef and harvest proceeds for transaction sender to `to`.
    function withdrawAndHarvest(uint256 _pid, uint256 _amount, address _to) public nonReentrant {
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];

        require(user.amount >= _amount, "withdrawAndHarvest: not good");

        // Check if user's chosen duration has passed
        uint256 durationSeconds = user.durationWeeks * 7 days;
        require(block.timestamp >= user.stakedAt + durationSeconds, "withdrawAndHarvest: duration not yet passed");

        updatePool(_pid);

        // Harvest all pending rewards
        _harvestRewards(_pid, msg.sender, _to);

        if (_amount > 0) {
            // Calculate effective shares for the amount being withdrawn
            uint256 multiplier = durationMultiplier[user.durationWeeks];
            uint256 effectiveSharesRemoved = (_amount * multiplier) / 1e18;

            user.amount = user.amount - _amount;
            pool.lpToken.safeTransfer(_to, _amount);
            // Update lpSupply by removing effective shares (not raw amount)
            pool.lpSupply = pool.lpSupply - effectiveSharesRemoved;
        }

        // If fully withdrawn, reset duration
        if (user.amount == 0) {
            user.durationWeeks = 0;
        }

        // Update reward debt for all tokens
        _updateRewardDebt(_pid, msg.sender);

        emit Withdraw(msg.sender, _pid, _amount);
    }

    // Internal function to harvest all pending rewards for a user
    function _harvestRewards(uint256 _pid, address _user, address _to) internal {
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][_user];

        if (user.amount == 0) return;

        // Calculate effective shares (amount * multiplier)
        uint256 effectiveShares = getEffectiveShares(_pid, _user);
        uint256 length = rewardTokens.length;

        for (uint256 i = 0; i < length; ++i) {
            IERC20 token = rewardTokens[i];

            // If user deposited after token was removed, set his reward debt to the current accTokenPerShare
            if (isRewardToken[address(token)] == false && user.rewardDebt[address(token)] == 0) {
                user.rewardDebt[address(token)] =
                    int256(effectiveShares * pool.accTokenPerShareX18[address(token)] / 1e18);
                continue;
            }

            int256 accumulated = int256(effectiveShares * pool.accTokenPerShareX18[address(token)] / 1e18);
            int256 pending = accumulated - user.rewardDebt[address(token)];

            if (pending > 0) {
                uint256 pendingAmount = uint256(pending);
                _safeTokenTransfer(token, _to, pendingAmount);
                emit Harvest(_user, _pid, pendingAmount);
            }
        }
    }

    // Internal function to update reward debt for all tokens
    function _updateRewardDebt(uint256 _pid, address _user) internal {
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][_user];

        // Calculate effective shares (amount * multiplier)
        uint256 effectiveShares = getEffectiveShares(_pid, _user);
        uint256 length = rewardTokens.length;
        for (uint256 i = 0; i < length; ++i) {
            address token = address(rewardTokens[i]);
            user.rewardDebt[token] = int256(effectiveShares * pool.accTokenPerShareX18[token] / 1e18);
        }
    }

    // Safe token transfer function, just in case if rounding error causes pool to not have enough tokens.
    function _safeTokenTransfer(IERC20 _token, address _to, uint256 _amount) internal {
        uint256 tokenBal = _token.balanceOf(address(this));
        uint256 transferAmount = _amount > tokenBal ? tokenBal : _amount;

        if (transferAmount > 0) {
            _token.safeTransfer(_to, transferAmount);
        }
    }

    // Get pool info for a specific pool
    function getPoolInfo(uint256 _pid)
        external
        view
        returns (address lpToken, uint256 allocPoint, uint256 lastRewardTime, uint256 lpSupply)
    {
        PoolInfo storage pool = poolInfo[_pid];

        lpToken = address(pool.lpToken);
        allocPoint = pool.allocPoint;
        lastRewardTime = pool.lastRewardTime;
        lpSupply = pool.lpSupply;
    }

    /// @notice Calculate APY based on share rate increase over the last 3 days
    /// @param _pid Pool ID
    /// @param _token Reward token address
    /// @return apyBpsX18 APY in basis points (10000 = 100%)
    /// @dev Formula: ((accTokenPerShareNow / accTokenPerShareThreeDaysAgo) ^ (365/3) - 1) * 100
    function calculateEstimatedAPY(uint256 _pid, address _token) external view returns (uint256 apyBpsX18) {
        require(isRewardToken[_token], "Token not a reward token");
        PoolInfo storage pool = poolInfo[_pid];

        if (pool.lpSupply == 0 || pool.allocPoint == 0) {
            return 0;
        }

        // Get current accTokenPerShare (need to update pool first to get latest value)
        // Note: This is a view function, so we use the stored value
        uint256 accTokenPerShareNow = pool.accTokenPerShareX18[_token];
        uint256 accTokenPerShareSnapshot = accTokenPerShareThreeDaysAgo[_pid][_token];

        // If we don't have 3 days of history yet, return 0
        if (lastSnapshotTime[_pid][_token] == 0 || block.timestamp < lastSnapshotTime[_pid][_token] + THREE_DAYS) {
            return 0;
        }

        // Prevent division by zero
        if (accTokenPerShareSnapshot == 0) {
            return 0;
        }

        // Formula: ((accTokenPerShareNow / accTokenPerShareSnapshot) ^ (365/3) - 1) * 100
        // Calculate growth ratio: (accTokenPerShareNow * 1e18) / accTokenPerShareSnapshot
        // Note: Both values are already scaled by 1e18, so ratio represents the growth factor
        uint256 ratio = (accTokenPerShareNow * 1e18) / accTokenPerShareSnapshot;

        if (ratio > 1e18) {
            uint256 ratioMinusOne = ratio - 1e18; // 3-day yield scaled by 1e18
            // APY in basis points: ((ratio - 1e18) * 365 * 10000) / 3
            apyBpsX18 = (ratioMinusOne * 365 * 100) / 3;
        } else {
            apyBpsX18 = 0; // No growth or negative growth
        }
    }
}
        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Errors.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of common custom errors used in multiple contracts
 *
 * IMPORTANT: Backwards compatibility is not guaranteed in future versions of the library.
 * It is recommended to avoid relying on the error API for critical functionality.
 *
 * _Available since v5.1._
 */
library Errors {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error InsufficientBalance(uint256 balance, uint256 needed);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedCall();

    /**
     * @dev The deployment failed.
     */
    error FailedDeployment();

    /**
     * @dev A necessary precompile is missing.
     */
    error MissingPrecompile(address);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../utils/introspection/IERC165.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../token/ERC20/IERC20.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Address.sol)

pragma solidity ^0.8.20;

import {Errors} from "./Errors.sol";

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert Errors.InsufficientBalance(address(this).balance, amount);
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert Errors.FailedCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {Errors.FailedCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert Errors.InsufficientBalance(address(this).balance, value);
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {Errors.FailedCall}) in case
     * of an unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {Errors.FailedCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {Errors.FailedCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            assembly ("memory-safe") {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert Errors.FailedCall();
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
          

// SPDX-License-Identifier: MIT
pragma solidity 0.8.23;

interface IPandaStaking {
    function distributeRewards(address _token, uint256 _amount) external;
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}