Contract Address Details

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.19;

import "https://raw.githubusercontent.com/OpenZeppelin/openzeppelin-contracts/v4.9.3/contracts/token/ERC20/IERC20.sol";
import "https://raw.githubusercontent.com/OpenZeppelin/openzeppelin-contracts/v4.9.3/contracts/token/ERC20/utils/SafeERC20.sol";
import "https://raw.githubusercontent.com/OpenZeppelin/openzeppelin-contracts/v4.9.3/contracts/security/ReentrancyGuard.sol";
import "https://raw.githubusercontent.com/OpenZeppelin/openzeppelin-contracts/v4.9.3/contracts/security/Pausable.sol";
import "https://raw.githubusercontent.com/OpenZeppelin/openzeppelin-contracts/v4.9.3/contracts/access/Ownable.sol";

interface IPMINTToken {
    function notifyDividend(uint256 amount) external;
    function consumeDividend(address account) external returns (uint256);
    function pendingDividend(address account) external view returns (uint256);
    function registerPair(address pair) external;
    function burn(uint256 amount) external;
    function balanceOf(address account) external view returns (uint256);
    function approve(address spender, uint256 amount) external returns (bool);
    function transfer(address to, uint256 amount) external returns (bool);
}

interface IUniswapV2Router02 {
    function addLiquidity(
        address tokenA, address tokenB,
        uint256 amountADesired, uint256 amountBDesired,
        uint256 amountAMin, uint256 amountBMin,
        address to, uint256 deadline
    ) external returns (uint256 amountA, uint256 amountB, uint256 liquidity);

    function swapExactTokensForTokens(
        uint256 amountIn, uint256 amountOutMin,
        address[] calldata path, address to, uint256 deadline
    ) external returns (uint256[] memory amounts);
}

interface IUniswapV2Pair {
    function getReserves() external view returns (uint112, uint112, uint32);
    function token0() external view returns (address);
}

contract PMINTMining is ReentrancyGuard, Pausable, Ownable {
    using SafeERC20 for IERC20;

    uint256 public constant INITIAL_RATE           = 3;
    uint256 public constant LOCK_DURATION          = 24 hours;
    uint256 public constant MAX_CYCLES             = 32;
    uint256 public constant INITIAL_CYCLE_EMISSION = 10_500_000 * 1e18;
    uint256 public constant MINER_PMINT_SHARE      = 85;
    uint256 public constant LP_PMINT_SHARE         = 15;
    uint256 public constant SEED_ALLOCATION        = 100_000 * 1e18;

    uint256 public constant LP_BPS                 = 300;
    uint256 public constant DIVIDEND_BPS           = 300;
    uint256 public constant BUYBACK_BPS            = 200;
    uint256 public constant REFERRAL_BPS           = 100;
    uint256 public constant TREASURY_BPS           = 100;

    uint256 public constant MIN_DIVIDEND_CLAIM     = 5   * 1e18;
    uint256 public constant MIN_BUYBACK            = 100 * 1e18;
    uint256 public constant BUYBACK_MAX_IMPACT_BPS = 1500;

    uint256 public constant FLUSH_COOLDOWN         = 10 minutes;
    uint256 public constant MAX_FLUSH_AMOUNT       = 20_000 * 1e18;
    uint256 public constant FLUSH_SLIPPAGE_MIN_BPS = 9500;
    uint256 public constant OVERMINT_MULTIPLIER    = 2;
    uint256 public constant FLUSH_PRICE_TOLERANCE  = 10;

    IERC20  public immutable pdai;
    address public immutable pulseXRouter;
    address public immutable treasury;

    IPMINTToken public pmint;
    address     public pairPDAI;
    address     public pairPLS;
    bool        public seedAllocated;

    uint256 public currentCycle         = 1;
    uint256 public currentRate          = INITIAL_RATE;
    uint256 public cycleRemainingMiners;
    uint256 public cycleRemainingLP;

    uint256 public accumulatedPDAIForLP;
    uint256 public buybackAccumulator;
    uint256 public dividendReserve;
    uint256 public totalOutstandingMinerPDAI;

    uint256 public lastFlushTime;
    uint256 public lastFlushBlock;

    uint256 private _nextCode = 1;
    mapping(uint256 => address) public codeToWallet;
    mapping(address => uint256) public walletToCode;
    mapping(address => address) public referrer;
    mapping(address => bool)    public hasMined;

    struct MinerPosition {
        uint256 pdaiToReturn;
        uint256 pmintReward;
        uint256 unlockTime;
        bool    claimed;
    }
    mapping(address => MinerPosition[]) public positions;

    event Mined(address indexed miner, uint256 positionId, uint256 pdaiIn, uint256 pmintOut, uint256 unlock);
    event Claimed(address indexed miner, uint256 positionId, uint256 pdaiOut, uint256 pmintOut);
    event CycleAdvanced(uint256 cycle, uint256 rate);
    event LiquidityAdded(uint256 pdaiIn, uint256 pmintIn, uint256 pmintBurned);
    event BuybackExecuted(uint256 pdaiIn, uint256 pmintBurned);
    event DividendClaimed(address indexed account, uint256 amount);
    event CodeGenerated(address indexed wallet, uint256 code);

    constructor(address _pdai, address _pulseXRouter, address _treasury) {
        require(_pdai != address(0) && _pulseXRouter != address(0) && _treasury != address(0));
        pdai         = IERC20(_pdai);
        pulseXRouter = _pulseXRouter;
        treasury     = _treasury;
        cycleRemainingMiners = (INITIAL_CYCLE_EMISSION * MINER_PMINT_SHARE) / 100;
        cycleRemainingLP     = (INITIAL_CYCLE_EMISSION * LP_PMINT_SHARE)    / 100;
    }

    function setTokenAddress(address _pmint) external onlyOwner {
        require(address(pmint) == address(0) && _pmint != address(0));
        pmint = IPMINTToken(_pmint);
    }

    function allocateSeedPMINT() external onlyOwner {
        require(!seedAllocated && address(pmint) != address(0));
        seedAllocated = true;
        IERC20(address(pmint)).safeTransfer(msg.sender, SEED_ALLOCATION);
    }

    function setupPairPDAI(address pair) external onlyOwner {
        require(pairPDAI == address(0) && pair != address(0) && address(pmint) != address(0));
        pairPDAI = pair;
        pmint.registerPair(pair);
    }

    function setupPairPLS(address pair) external onlyOwner {
        require(pairPLS == address(0) && pair != address(0) && address(pmint) != address(0));
        pairPLS = pair;
        pmint.registerPair(pair);
    }

    function mine(uint256 pdaiAmount, uint256 referralCode)
        external nonReentrant whenNotPaused
    {
        require(address(pmint) != address(0));
        require(pdaiAmount > 0);
        require(currentCycle <= MAX_CYCLES);
        require(cycleRemainingMiners > 0);

        if (!hasMined[msg.sender] && referralCode != 0) _setReferrer(msg.sender, referralCode);

        if (walletToCode[msg.sender] == 0) {
            uint256 code = _nextCode++;
            walletToCode[msg.sender] = code;
            codeToWallet[code]       = msg.sender;
            emit CodeGenerated(msg.sender, code);
        }

        hasMined[msg.sender] = true;

        uint256 grossPMINT = pdaiAmount / currentRate;
        require(grossPMINT > 0);

        uint256 actualPMINT = grossPMINT;
        uint256 actualPDAI  = pdaiAmount;

        if (grossPMINT > cycleRemainingMiners) {
            actualPMINT = cycleRemainingMiners;
            actualPDAI  = actualPMINT * currentRate;
        }

        uint256 excessPDAI   = pdaiAmount - actualPDAI;
        uint256 lpPDAI       = (actualPDAI * LP_BPS)      / 10_000;
        uint256 dividendPDAI = (actualPDAI * DIVIDEND_BPS) / 10_000;
        uint256 buybackPDAI  = (actualPDAI * BUYBACK_BPS)  / 10_000;
        uint256 referralPDAI = (actualPDAI * REFERRAL_BPS) / 10_000;
        uint256 treasuryPDAI = (actualPDAI * TREASURY_BPS) / 10_000;
        uint256 pdaiToReturn = actualPDAI - lpPDAI - dividendPDAI - buybackPDAI - referralPDAI - treasuryPDAI;

        cycleRemainingMiners      -= actualPMINT;
        accumulatedPDAIForLP      += lpPDAI;
        dividendReserve           += dividendPDAI;
        buybackAccumulator        += buybackPDAI;
        totalOutstandingMinerPDAI += pdaiToReturn;

        uint256 posId = positions[msg.sender].length;
        positions[msg.sender].push(MinerPosition({
            pdaiToReturn : pdaiToReturn,
            pmintReward  : actualPMINT,
            unlockTime   : block.timestamp + LOCK_DURATION,
            claimed      : false
        }));

        pdai.safeTransferFrom(msg.sender, address(this), pdaiAmount);
        if (excessPDAI   > 0) pdai.safeTransfer(msg.sender, excessPDAI);
        if (treasuryPDAI > 0) pdai.safeTransfer(treasury, treasuryPDAI);
        if (dividendPDAI > 0) pmint.notifyDividend(dividendPDAI);
        if (referralPDAI > 0) _distributeReferral(msg.sender, referralPDAI);

        emit Mined(msg.sender, posId, actualPDAI, actualPMINT, block.timestamp + LOCK_DURATION);

        if (cycleRemainingMiners == 0) _advanceCycle();
    }

    function claim(uint256 positionId) external nonReentrant {
        require(address(pmint) != address(0));
        require(positionId < positions[msg.sender].length);
        MinerPosition storage pos = positions[msg.sender][positionId];
        require(!pos.claimed);
        require(block.timestamp >= pos.unlockTime);

        pos.claimed = true;
        if (pos.pdaiToReturn <= totalOutstandingMinerPDAI)
            totalOutstandingMinerPDAI -= pos.pdaiToReturn;
        else
            totalOutstandingMinerPDAI = 0;

        if (pos.pdaiToReturn > 0) pdai.safeTransfer(msg.sender, pos.pdaiToReturn);
        if (pos.pmintReward  > 0) IERC20(address(pmint)).safeTransfer(msg.sender, pos.pmintReward);

        emit Claimed(msg.sender, positionId, pos.pdaiToReturn, pos.pmintReward);
    }

    function flushLP() external nonReentrant {
        require(address(pmint) != address(0));
        require(pairPDAI != address(0));
        require(accumulatedPDAIForLP > 0);
        require(block.number > lastFlushBlock);
        require(block.timestamp >= lastFlushTime + FLUSH_COOLDOWN);
        require(cycleRemainingLP > 0);
        require(isSolvent());

        uint256 pmintPerPDAI = _getLivePMINTPerPDAI();
        require(pmintPerPDAI * currentRate * FLUSH_PRICE_TOLERANCE >= 1e18);
        require(pmintPerPDAI * currentRate <= 1e18 * FLUSH_PRICE_TOLERANCE);

        uint256 flushAmount = accumulatedPDAIForLP > MAX_FLUSH_AMOUNT
            ? MAX_FLUSH_AMOUNT : accumulatedPDAIForLP;

        uint256 expectedPmint = (flushAmount * pmintPerPDAI) / 1e18;
        uint256 pmintBuffer   = expectedPmint * OVERMINT_MULTIPLIER;
        if (pmintBuffer > cycleRemainingLP) pmintBuffer = cycleRemainingLP;
        require(pmintBuffer > 0);

        uint256 pdaiMin  = (flushAmount   * FLUSH_SLIPPAGE_MIN_BPS) / 10_000;
        uint256 pmintMin = (expectedPmint * FLUSH_SLIPPAGE_MIN_BPS) / 10_000;

        uint256 pdaiBefore  = pdai.balanceOf(address(this));
        uint256 pmintBefore = IERC20(address(pmint)).balanceOf(address(this));

        lastFlushBlock = block.number;
        lastFlushTime  = block.timestamp;

        IERC20(address(pmint)).approve(pulseXRouter, pmintBuffer);
        pdai.approve(pulseXRouter, flushAmount);

        try IUniswapV2Router02(pulseXRouter).addLiquidity(
            address(pdai), address(pmint),
            flushAmount, pmintBuffer,
            pdaiMin, pmintMin,
            address(this), block.timestamp + 30 minutes
        ) returns (uint256, uint256, uint256) {

            uint256 pdaiConsumed = pdaiBefore  - pdai.balanceOf(address(this));
            uint256 pmintUsed    = pmintBefore - IERC20(address(pmint)).balanceOf(address(this));
            uint256 pmintBurned  = pmintBuffer > pmintUsed ? pmintBuffer - pmintUsed : 0;

            if (pdaiConsumed <= accumulatedPDAIForLP) accumulatedPDAIForLP -= pdaiConsumed;
            else accumulatedPDAIForLP = 0;

            if (pmintBurned > 0) pmint.burn(pmintBurned);

            if (pmintUsed <= cycleRemainingLP) cycleRemainingLP -= pmintUsed;
            else cycleRemainingLP = 0;

            pdai.approve(pulseXRouter, 0);
            IERC20(address(pmint)).approve(pulseXRouter, 0);
            emit LiquidityAdded(pdaiConsumed, pmintUsed, pmintBurned);

        } catch {
            pdai.approve(pulseXRouter, 0);
            IERC20(address(pmint)).approve(pulseXRouter, 0);
        }
    }

    function executeBuyback() external nonReentrant {
        require(pairPDAI != address(0));
        require(buybackAccumulator >= MIN_BUYBACK);
        require(isSolvent());

        (uint256 reservePDAI, ) = _getPairReservesPDAI();
        require(reservePDAI > 0);

        uint256 maxBuy    = (reservePDAI * BUYBACK_MAX_IMPACT_BPS) / (10_000 - BUYBACK_MAX_IMPACT_BPS);
        uint256 buyAmount = buybackAccumulator > maxBuy ? maxBuy : buybackAccumulator;
        if (buyAmount < MIN_BUYBACK) return;

        address[] memory path = new address[](2);
        path[0] = address(pdai);
        path[1] = address(pmint);

        uint256 pmintBefore = IERC20(address(pmint)).balanceOf(address(this));
        pdai.approve(pulseXRouter, buyAmount);

        try IUniswapV2Router02(pulseXRouter).swapExactTokensForTokens(
            buyAmount, 0, path, address(this), block.timestamp + 30 minutes
        ) returns (uint256[] memory) {
            uint256 pmintReceived = IERC20(address(pmint)).balanceOf(address(this)) - pmintBefore;
            buybackAccumulator   -= buyAmount;
            if (pmintReceived > 0) pmint.burn(pmintReceived);
            pdai.approve(pulseXRouter, 0);
            emit BuybackExecuted(buyAmount, pmintReceived);
        } catch {
            pdai.approve(pulseXRouter, 0);
        }
    }

    function claimDividend() external nonReentrant {
        uint256 owed = pmint.consumeDividend(msg.sender);
        require(owed >= MIN_DIVIDEND_CLAIM);
        require(dividendReserve >= owed);
        dividendReserve -= owed;
        pdai.safeTransfer(msg.sender, owed);
        emit DividendClaimed(msg.sender, owed);
    }

    function isSolvent() public view returns (bool) {
        uint256 liabilities = totalOutstandingMinerPDAI + dividendReserve
                            + accumulatedPDAIForLP + buybackAccumulator;
        return pdai.balanceOf(address(this)) >= liabilities;
    }

    function getPositionCount(address miner) external view returns (uint256) {
        return positions[miner].length;
    }

    function getPosition(address miner, uint256 id) external view returns (MinerPosition memory) {
        return positions[miner][id];
    }

    function estimatePMINT(uint256 pdaiAmount) external view returns (uint256) {
        if (currentRate == 0 || cycleRemainingMiners == 0) return 0;
        uint256 gross = pdaiAmount / currentRate;
        return gross > cycleRemainingMiners ? cycleRemainingMiners : gross;
    }

    function pendingDividend(address account) external view returns (uint256) {
        return pmint.pendingDividend(account);
    }

    function _getLivePMINTPerPDAI() internal view returns (uint256) {
        (uint256 rPDAI, uint256 rPMINT) = _getPairReservesPDAI();
        if (rPDAI == 0) return 1e18 / currentRate;
        return (rPMINT * 1e18) / rPDAI;
    }

    function _getPairReservesPDAI() internal view returns (uint256 rPDAI, uint256 rPMINT) {
        if (pairPDAI == address(0)) return (0, 0);
        try IUniswapV2Pair(pairPDAI).getReserves() returns (uint112 r0, uint112 r1, uint32) {
            address t0;
            try IUniswapV2Pair(pairPDAI).token0() returns (address _t0) { t0 = _t0; }
            catch { return (0, 0); }
            rPDAI  = t0 == address(pdai) ? uint256(r0) : uint256(r1);
            rPMINT = t0 == address(pdai) ? uint256(r1) : uint256(r0);
        } catch { return (0, 0); }
    }

    function _setReferrer(address miner, uint256 code) internal {
        address ref = codeToWallet[code];
        if (ref == address(0) || ref == miner || !hasMined[ref]) return;
        address check = ref;
        for (uint8 i = 0; i < 3; i++) {
            if (check == miner) return;
            check = referrer[check];
            if (check == address(0)) break;
        }
        referrer[miner] = ref;
    }

    function _distributeReferral(address miner, uint256 total) internal {
        address l1 = referrer[miner];
        address l2 = l1 != address(0) ? referrer[l1] : address(0);
        address l3 = l2 != address(0) ? referrer[l2] : address(0);
        uint256 a1 = (total * 50) / 100;
        uint256 a2 = (total * 30) / 100;
        _payRef(l1, a1);
        _payRef(l2, a2);
        _payRef(l3, total - a1 - a2);
    }

    function _payRef(address to, uint256 amount) internal {
        if (amount == 0) return;
        pdai.safeTransfer((to != address(0) && hasMined[to]) ? to : treasury, amount);
    }

    function _advanceCycle() internal {
        if (currentCycle >= MAX_CYCLES) return;
        currentCycle++;
        currentRate *= 2;
        uint256 newEmission = INITIAL_CYCLE_EMISSION >> (currentCycle - 1);
        uint256 available   = IERC20(address(pmint)).balanceOf(address(this));
        if (newEmission > available) newEmission = available;
        cycleRemainingMiners  = (newEmission * MINER_PMINT_SHARE) / 100;
        cycleRemainingLP     += (newEmission * LP_PMINT_SHARE)    / 100;
        emit CycleAdvanced(currentCycle, currentRate);
    }

    function pause()   external onlyOwner { _pause(); }
    function unpause() external onlyOwner { _unpause(); }

    function recoverToken(address token, uint256 amount) external onlyOwner {
        require(token != address(pmint) && token != address(pdai));
        IERC20(token).safeTransfer(owner(), amount);
    }

    receive() external payable { revert(); }
}
        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}