Contract Address Details

// SPDX-License-Identifier: UNLICENSED

pragma solidity 0.8.16;


// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)
/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
/**
 * @title FeeSplitter
 */
contract FeeSplitter {
    address payable private recipient1;
    address payable private recipient2;
    address payable private recipient3;
    bool private initialized;

    constructor() {
        // Contructor not used. Deploy script will call this.initialize()
        initialized = false;
    }

    function initialize(
        address payable _recipient1,
        address payable _recipient2,
        address payable _recipient3
    )
        public
    {
        require(initialized == false, "Already initialized");

        recipient1 = _recipient1;
        recipient2 = _recipient2;
        recipient3 = _recipient3;

        initialized = true;
    }

    receive() external payable {
        _splitNative(msg.value);
    }

    error SplitNativeFailed(
        bool recipient1,
        bool recipient2,
        bool recipient3
    );

    function _splitNative(uint256 value)
        private
    {
        require(initialized == true, "Uninitialized");

        uint256 prevBalance = address(this).balance - value;

        // @dev any remainder will be included in next split
        uint256 splitAmount = 0;
        unchecked { splitAmount = (value + prevBalance) / 3; }

        if (splitAmount > 0) {
            (bool sent1,/* data */) = recipient1.call{value: splitAmount}("");
            (bool sent2,/* data */) = recipient2.call{value: splitAmount}("");
            (bool sent3,/* data */) = recipient3.call{value: splitAmount}("");
            if (!(sent1 && sent2 && sent3)) revert SplitNativeFailed(sent1, sent2, sent3);
        }
    }

    function splitERC20(address tokenAddress) public returns (bool) {
        require(initialized == true, "Uninitialized");
        require(tokenAddress.code.length > 0, "not a token");
        
        IERC20 token = IERC20(tokenAddress);
        uint256 balance = token.balanceOf(address(this));
        uint256 splitAmount;

        // @dev any remainder will be included in next split
        unchecked { splitAmount = balance / 3; } // underflow/remainder acceptable

        token.transfer(recipient1, splitAmount);
        token.transfer(recipient2, splitAmount);
        token.transfer(recipient3, splitAmount);

        return true;
    }
}