Contract Address Details

// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// File: @openzeppelin/contracts/access/Ownable.sol


// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// File: @openzeppelin/contracts/security/ReentrancyGuard.sol


// OpenZeppelin Contracts (last updated v4.8.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

// File: @openzeppelin/contracts/utils/Address.sol


// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// File: @openzeppelin/contracts/token/ERC20/extensions/draft-IERC20Permit.sol


// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// File: @openzeppelin/contracts/token/ERC20/IERC20.sol


// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// File: @openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol


// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;




/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// File: @openzeppelin/contracts/utils/introspection/IERC165.sol


// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// File: @openzeppelin/contracts/utils/introspection/ERC165.sol


// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;


/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// File: @openzeppelin/contracts/interfaces/IERC2981.sol


// OpenZeppelin Contracts (last updated v4.6.0) (interfaces/IERC2981.sol)

pragma solidity ^0.8.0;


/**
 * @dev Interface for the NFT Royalty Standard.
 *
 * A standardized way to retrieve royalty payment information for non-fungible tokens (NFTs) to enable universal
 * support for royalty payments across all NFT marketplaces and ecosystem participants.
 *
 * _Available since v4.5._
 */
interface IERC2981 is IERC165 {
    /**
     * @dev Returns how much royalty is owed and to whom, based on a sale price that may be denominated in any unit of
     * exchange. The royalty amount is denominated and should be paid in that same unit of exchange.
     */
    function royaltyInfo(uint256 tokenId, uint256 salePrice)
        external
        view
        returns (address receiver, uint256 royaltyAmount);
}

// File: @openzeppelin/contracts/token/common/ERC2981.sol


// OpenZeppelin Contracts (last updated v4.7.0) (token/common/ERC2981.sol)

pragma solidity ^0.8.0;



/**
 * @dev Implementation of the NFT Royalty Standard, a standardized way to retrieve royalty payment information.
 *
 * Royalty information can be specified globally for all token ids via {_setDefaultRoyalty}, and/or individually for
 * specific token ids via {_setTokenRoyalty}. The latter takes precedence over the first.
 *
 * Royalty is specified as a fraction of sale price. {_feeDenominator} is overridable but defaults to 10000, meaning the
 * fee is specified in basis points by default.
 *
 * IMPORTANT: ERC-2981 only specifies a way to signal royalty information and does not enforce its payment. See
 * https://eips.ethereum.org/EIPS/eip-2981#optional-royalty-payments[Rationale] in the EIP. Marketplaces are expected to
 * voluntarily pay royalties together with sales, but note that this standard is not yet widely supported.
 *
 * _Available since v4.5._
 */
abstract contract ERC2981 is IERC2981, ERC165 {
    struct RoyaltyInfo {
        address receiver;
        uint96 royaltyFraction;
    }

    RoyaltyInfo private _defaultRoyaltyInfo;
    mapping(uint256 => RoyaltyInfo) private _tokenRoyaltyInfo;

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(IERC165, ERC165) returns (bool) {
        return interfaceId == type(IERC2981).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @inheritdoc IERC2981
     */
    function royaltyInfo(uint256 _tokenId, uint256 _salePrice) public view virtual override returns (address, uint256) {
        RoyaltyInfo memory royalty = _tokenRoyaltyInfo[_tokenId];

        if (royalty.receiver == address(0)) {
            royalty = _defaultRoyaltyInfo;
        }

        uint256 royaltyAmount = (_salePrice * royalty.royaltyFraction) / _feeDenominator();

        return (royalty.receiver, royaltyAmount);
    }

    /**
     * @dev The denominator with which to interpret the fee set in {_setTokenRoyalty} and {_setDefaultRoyalty} as a
     * fraction of the sale price. Defaults to 10000 so fees are expressed in basis points, but may be customized by an
     * override.
     */
    function _feeDenominator() internal pure virtual returns (uint96) {
        return 10000;
    }

    /**
     * @dev Sets the royalty information that all ids in this contract will default to.
     *
     * Requirements:
     *
     * - `receiver` cannot be the zero address.
     * - `feeNumerator` cannot be greater than the fee denominator.
     */
    function _setDefaultRoyalty(address receiver, uint96 feeNumerator) internal virtual {
        require(feeNumerator <= _feeDenominator(), "ERC2981: royalty fee will exceed salePrice");
        require(receiver != address(0), "ERC2981: invalid receiver");

        _defaultRoyaltyInfo = RoyaltyInfo(receiver, feeNumerator);
    }

    /**
     * @dev Removes default royalty information.
     */
    function _deleteDefaultRoyalty() internal virtual {
        delete _defaultRoyaltyInfo;
    }

    /**
     * @dev Sets the royalty information for a specific token id, overriding the global default.
     *
     * Requirements:
     *
     * - `receiver` cannot be the zero address.
     * - `feeNumerator` cannot be greater than the fee denominator.
     */
    function _setTokenRoyalty(
        uint256 tokenId,
        address receiver,
        uint96 feeNumerator
    ) internal virtual {
        require(feeNumerator <= _feeDenominator(), "ERC2981: royalty fee will exceed salePrice");
        require(receiver != address(0), "ERC2981: Invalid parameters");

        _tokenRoyaltyInfo[tokenId] = RoyaltyInfo(receiver, feeNumerator);
    }

    /**
     * @dev Resets royalty information for the token id back to the global default.
     */
    function _resetTokenRoyalty(uint256 tokenId) internal virtual {
        delete _tokenRoyaltyInfo[tokenId];
    }
}

// File: contracts/marketplace/Marketplace.sol


pragma solidity 0.8.17;







contract Marketplace is ReentrancyGuard {
    using SafeERC20 for IERC20;

    enum SaleType {
        FIXED,
        AUCTION,
        NONE,
        OFFER
    }

    enum ItemStatus {
        /* Buy Now */
        SALE_START,
        SALE_REMOVED,
        SALE_SUCCESS,
        /* Auction */
        AUCTION_START,
        AUCTION_SUCCESS,
        AUCTION_REMOVED,
        AUCTION_NEW_BID,
        /* ROYALTY */
        ROYALTY_UPDATED,
        /* SPONTANEOUS OFFER */
        OFFER_START,
        OFFER_SUCCESS,
        OFFER_REMOVED
    }

    struct Royalty {
        address receiver;
        uint256 basisPoints;
    }

    struct Item {
        SaleType saleType;
        uint256 price;
        address tokenAddress;
        address seller;
        address buyer;
        uint256 promiseStartTime; // When the item was created
        /* These are used for auction only */
        uint256 endTime;
        address bidder;
        uint256 bidAmount;
        /* These are used for erc1155 */
        uint256 quantity;
        /* For Private Sale */
        address[] addressesForPrivateSaleList;
    }

    struct Payout {
        uint256 sellerPayout;
        address tokenAddress;
        uint256 marketFee;
        Royalty royalty;
    }

    event MarketplaceEvent(
        ItemStatus itemStatus,
        address collectionAddress,
        uint256 tokenId,
        Item item,
        Payout payout
    );

    event NewTokenEvent(
        address tokenAddress,
        uint256 floorPrice
    );

    event Withdrawal(address walletAddress, uint256 amount, address tokenAddress);

    // Allowed Token Addresses
    mapping (address => uint256) public allowedTokenAddresses;
   
    // ContractAddress => Royalty
    mapping(address => Royalty) public royalties;
    uint256 public maxPrivateSaleListLength = 100;
    uint256 public maxRoyaltyBasisPoints = 1000; 
    uint256 public minWaitTimeToCancel = 3600;

    // AUCTION
    uint256 public minBidIncrementPercent = 10;
    uint256 public minAuctionLength = 3600;
    uint256 public maxAuctionLength = 31449600;

    uint256 public marketPercent = 225;
    uint256 public marketPercentMint = 150;
    address public feeSplitterAddress;
    address public wizard;

    address public mintTokenAddress;
    
    // Wallet Address => Erc20Addres(0 for PLS) => Amount
    mapping(address => mapping(address => uint256)) public pendingWithdrawals;

    modifier onlyWizard() {
        require(
            msg.sender == wizard,
            "Not Wizard"
        );
        _;
    }

    /**
     * @notice Modifier to check if bid conditions are met before allowing a bid
     * @dev Checks the validity of an auction bid before it can be made
     * @param _item Item object containing details of the item being bid on
     */
    modifier checkBidValidity(uint256 _bidAmount, Item memory _item) {
        // Require that the sale type is auction
        require(_item.saleType == SaleType.AUCTION, "Incorrect sale type");

        // Require that the item is actually for sale
        require(_item.seller != address(0), "Item is not on sale");

        // Require that the auction has not ended
        require(_item.endTime != 0, "Auction ended");

        // Require that the auction has not yet ended
        require(block.timestamp <= _item.endTime, "Auction completed");

        
        // Check if we have a previous bid. If not previous bid, the bid can be made at the initial sale price
        if (_item.bidAmount == 0) {
            // Require that the bid amount meets the minimum price
            require(_bidAmount >= _item.price, "Min price not met");

        } else {
            // Require that the bid amount is higher than the current highest bid plus the minimum bid increment
            require(
                _bidAmount >=
                    _item.bidAmount +
                        ((_item.bidAmount * minBidIncrementPercent) / 100),
                "Bid too low"
            );
        }

        _;
    }

    /**
     * @notice Modifier to check if auction conditions are met before creating a new auction
     * @dev Checks the validity of auction parameters before creating a new auction
     * @param _minPrice Minimum price for the auction
     * @param _endTime End time for the auction
     */
    modifier checkAuctionValidity(uint256 _minPrice, uint256 _endTime, address _tokenAddress) {

        uint256 floorPrice = allowedTokenAddresses[_tokenAddress];

        require (floorPrice > 0, "Invalid token address");

        // Require that the minimum price for the auction meets the floor price
        require(_minPrice >= floorPrice, "Min price not met");

        // Require that the auction length is greater than the minimum allowed length
        require(
            _endTime > block.timestamp + minAuctionLength,
            "Auction min length not met"
        );

        // Require that the auction length is less than the maximum allowed length
        require(
            _endTime < block.timestamp + maxAuctionLength,
            "Auction max length not met"
        );

        _;
    }

    /**
     * @notice Creates a new instance of the Marketplace contract
     * @dev Initializes the contract with the addresses of the marketPercentDecreaser and feeSplitterAddress
     * @param _wizard Address wizard
     * @param _feeSplitterAddress Address of the fee splitter contract
     */
    constructor(address _wizard, address _feeSplitterAddress, address _mintTokenAddress) {
        require(_wizard != address(0), "Invalid address");
        require(_feeSplitterAddress != address(0), "Invalid address");
        require(_mintTokenAddress != address(0), "Invalid address");

        wizard = _wizard;
        feeSplitterAddress = _feeSplitterAddress;
        mintTokenAddress = _mintTokenAddress;

        // address(0) is used to represent native PLS
        address allowedAddress = address(0);

        allowedTokenAddresses[allowedAddress] = 1 ether;

        // HEX
        allowedAddress = 0x2b591e99afE9f32eAA6214f7B7629768c40Eeb39;
        allowedTokenAddresses[allowedAddress] = 100000000; // 1
   
        // PEPE
        allowedAddress = 0x6982508145454Ce325dDbE47a25d4ec3d2311933;
        allowedTokenAddresses[allowedAddress] = 1000000000000000000000000; // 1,000,000
    
        // SHIB
        allowedAddress = 0x95aD61b0a150d79219dCF64E1E6Cc01f0B64C4cE;
        allowedTokenAddresses[allowedAddress] = 1000000000000000000000000; // 1,000,000

        // XEN
        allowedAddress = 0x06450dEe7FD2Fb8E39061434BAbCFC05599a6Fb8;
        allowedTokenAddresses[allowedAddress] = 10000000000000000000000000; // 10,000,000
 
        // HDRN
        allowedAddress = 0x3819f64f282bf135d62168C1e513280dAF905e06;
        allowedTokenAddresses[allowedAddress] = 1000000000000000; // 1,000,000

        // ICSA
        allowedAddress = 0xfc4913214444aF5c715cc9F7b52655e788A569ed;
        allowedTokenAddresses[allowedAddress] = 1000000000; // 1
  
        // MAXI
        allowedAddress = 0x0d86EB9f43C57f6FF3BC9E23D8F9d82503f0e84b;
        allowedTokenAddresses[allowedAddress] = 100000000; // 1
 
        // DECI
        allowedAddress = 0x6b32022693210cD2Cfc466b9Ac0085DE8fC34eA6;
        allowedTokenAddresses[allowedAddress] = 100000000; // 1

        // LUCKY
        allowedAddress = 0x6B0956258fF7bd7645aa35369B55B61b8e6d6140;
        allowedTokenAddresses[allowedAddress] = 100000000; // 1

        // TRIO
        allowedAddress = 0xF55cD1e399e1cc3D95303048897a680be3313308;
        allowedTokenAddresses[allowedAddress] = 100000000; // 1
  
        // BASE
        allowedAddress = 0xe9f84d418B008888A992Ff8c6D22389C2C3504e0;
        allowedTokenAddresses[allowedAddress] = 100000000; // 1

        // MINT
        allowedAddress = _mintTokenAddress;
        allowedTokenAddresses[allowedAddress] = 1 ether;
  
        // TIME
        allowedAddress = 0xCA35638A3fdDD02fEC597D8c1681198C06b23F58;
        allowedTokenAddresses[allowedAddress] = 1 ether; // 1
   
        // PHUX
        allowedAddress = 0x9663c2d75ffd5F4017310405fCe61720aF45B829;
        allowedTokenAddresses[allowedAddress] = 1 ether; // 1

        // MORE
        allowedAddress = 0xbEEf3bB9dA340EbdF0f5bae2E85368140d7D85D0;
        allowedTokenAddresses[allowedAddress] = 1 ether; // 1

        // PP
        allowedAddress = 0x9565c2036963697786705120Fc59310F747bCfD0;
        allowedTokenAddresses[allowedAddress] = 10000000000000000000000; // 10,000
 
        // WAIT
        allowedAddress = 0x26179a4d4B58b4456F28d19507546596c9058ee5;
        allowedTokenAddresses[allowedAddress] = 100000000; // 1
 
        // TEXAN
        allowedAddress = 0xcFCFfE432A48dB53F59c301422d2EdD77B2A88d7;
        allowedTokenAddresses[allowedAddress] = 10000000000000000000000; // 10,000
 

    }

    /**
     * @notice Send funds to the proper addresses after a sale
     * @dev Calculates and distributes the funds from a sale to the seller, royalty receiver, and fee splitter
     * @param _seller Address of the seller
     * @param _price Amount of funds to be distributed
     * @param _collectionAddress Address of the collection contract
     * @param _tokenId ID of the token being sold
     * @return _payout A Payout object containing information about the amounts distributed
     */
    function payout(
        address _seller,
        uint256 _price,
        address _tokenAddress,
        address _collectionAddress,
        uint256 _tokenId
    ) internal returns (Payout memory _payout) {
        // Calculate market fee
        
        uint256 marketFee;
        if (_tokenAddress == mintTokenAddress) {
            marketFee = (_price * marketPercentMint) / 10000;
        } else {
            marketFee = (_price * marketPercent) / 10000;
        }

        // Calculate royalty amount and receiver
        uint256 royaltyAmount;
        address royaltyReceiver;

        // Check if collection has royalty using ERC2981
        if (isERC2981(_collectionAddress)) {
            (royaltyReceiver, royaltyAmount) = ERC2981(_collectionAddress)
                .royaltyInfo(_tokenId, _price);

           require(royaltyAmount < _price - marketFee, "Royalty too high");
        } else {
            royaltyAmount =
                (_price * royalties[_collectionAddress].basisPoints) /
                10000;
            royaltyReceiver = royalties[_collectionAddress].receiver;
        }

        // Calculate amount to send to seller
        uint256 sellerAmount = (_price - marketFee) - royaltyAmount;

        // amount to seller
        pendingWithdrawals[_seller][_tokenAddress] += sellerAmount;

        // Send royalty amount to receiver
        if (royaltyAmount > 0) {
            pendingWithdrawals[royaltyReceiver][_tokenAddress] += royaltyAmount;
        }

        // Send market fee to fee splitter.
        if (_tokenAddress == address(0)) {
            (bool success, ) = payable(feeSplitterAddress).call{value: marketFee}("");
            require(success, "Transfer failed");
        } else {
            // Transfer the marketplace fee to the feeSplitterAddress
            IERC20(_tokenAddress).safeTransfer(feeSplitterAddress, marketFee);
        }

        // Return Payout object with information about the amounts distributed
        return Payout(sellerAmount, _tokenAddress, marketFee, royalties[_collectionAddress]);
    }

    function isTokenAllowed(address _tokenAddress) public view returns (bool) {
        return allowedTokenAddresses[_tokenAddress] > 0;
    }

    /**
     * @notice Update the market fee percentage
     * @dev Updates the market fee percentage to a new value
     * @param _marketPercent New value for the market fee percentage
     */
    function setMarketPercent(uint256 _marketPercent) public onlyWizard {
        require(_marketPercent <= 369, "Fee not in range");

        marketPercent = _marketPercent;
    }

    /**
     * @notice Set or update the royalty for a collection
     * @dev Sets or updates the royalty for a collection to a new value
     * @param _collectionAddress Address of the collection to set the royalty for
     * @param _royaltyInBasisPoints New royalty value, in basis points (1 basis point = 0.01%)
     */
    function createOrUpdateRoyalty(
        address _collectionAddress,
        uint256 _royaltyInBasisPoints,
        address receiver
    ) public nonReentrant {
        require(
            _royaltyInBasisPoints <= maxRoyaltyBasisPoints,
            "Royalties cannot exceed maximum"
        );

        require(receiver != address(0), "receiver is not set");

        // Check if the royalty already exists and is being increased
        if (royalties[_collectionAddress].receiver != address(0)) {
            require(
                _royaltyInBasisPoints <=
                    royalties[_collectionAddress].basisPoints,
                "Royalties cannot be increased"
            );
        }

        // Check that the caller is the owner/creator of the collection contract
        require(
            Ownable(_collectionAddress).owner() == msg.sender,
            "Unauthorized"
        );

        // Create a new Royalty object with the given value and store it in the royalties mapping
        Royalty memory royalty = Royalty(receiver, _royaltyInBasisPoints);
        royalties[_collectionAddress] = royalty;

        // Emit a MarketplaceEvent with information about the royalty update
        address[] memory addressesForPrivateSaleList = new address[](0);
        emit MarketplaceEvent(
            ItemStatus.ROYALTY_UPDATED,
            _collectionAddress,
            0,
            Item(
                SaleType.NONE,
                0,
                address(0),
                address(0),
                address(0),
                0,
                0,
                address(0),
                0,
                0,
                addressesForPrivateSaleList
            ),
            Payout(0, address(0), 0, royalty)
        );
    }

    /**
     * @dev If this is a private sale, check that the sender is in the list of addresses
     * @param _item item
     */
    function checkPrivateSale(Item memory _item) internal view {
        if (_item.addressesForPrivateSaleList.length > 0) {
            bool foundMatch = false;

            for (
                uint256 i = 0;
                i < _item.addressesForPrivateSaleList.length;
                i++
            ) {
                if (_item.addressesForPrivateSaleList[i] == msg.sender) {
                    foundMatch = true;
                }
            }

            require(foundMatch, "Not allowed in private sale.");
        }
    }

    /**
     * @dev Check that the length of the private sale list is not too long
     * @param _addressesForPrivateSaleList Array of addresses for the private sale list
     */
    function checkPrivateSaleListLength(
        address[] memory _addressesForPrivateSaleList
    ) internal view {
        require(
            _addressesForPrivateSaleList.length <= maxPrivateSaleListLength,
            "Private sale list too long"
        );
    }

    /**
     * @dev Reimburse the previous bidder for an item
     * @param _item The item to reimburse the bidder for
     */
    function reimbursePreviousBidder(Item memory _item) internal {
        if (_item.bidAmount > 0) {
            // Set the amount to zero before transferring to protect against reentrancy attacks
            uint256 _amount = _item.bidAmount;
            _item.bidAmount = 0;

            pendingWithdrawals[_item.bidder][_item.tokenAddress] += _amount;
        }
    }

    /**
     * @dev Allow a user to retrieve funds for a specified receiver
     */
    function withdraw(address[] memory tokenAddresses, address receiver) external nonReentrant {

        for (uint256 i = 0; i < tokenAddresses.length; i++) {
            uint256 funds = pendingWithdrawals[receiver][tokenAddresses[i]];

            // Withdraw funds
            if (funds > 0) {
                // Delete the stored funds from the mapping
                delete pendingWithdrawals[receiver][tokenAddresses[i]];

                // Are we transfering PLS or an ERC20 token?
                if (tokenAddresses[i] == address(0)) {
                    // Transfer the funds to the caller
                    (bool success, ) = payable(receiver).call{value: funds}("");
                    require(success, "Transfer failed.");
                } else {
                    IERC20(tokenAddresses[i]).safeTransfer(receiver, funds);
                }

                emit Withdrawal(receiver, funds, tokenAddresses[i]);
            }

        }
        
    }

    /**
     * @dev Check if an auction can end
     * @param item The item to check if the auction can end for
     */
    function checkIfAuctionCanEnd(Item memory item) internal view {
        // Check if there is a bid on the item
        if (item.bidAmount == 0) {

            // If there is no bid, the auction can only end after a certain waiting period has elapsed
            require(
                item.promiseStartTime + minWaitTimeToCancel < block.timestamp,
                "Too early to cancel"
            );
        } else {
            // If there is a bid on the item, the auction can only end after the item's end time has passed
            require(block.timestamp > item.endTime, "Auction has not ended");
        }
    }

    /**
     * @notice This function checks if a given contract is ERC2981 compliant
     * @dev This function is called internally and cannot be accessed outside the contract
     * @param _contract The address of the contract to check
     * @return A boolean indicating whether the contract is ERC2981 compliant or not
     */
    function isERC2981(address _contract) internal view returns (bool) {
        try ERC2981(_contract).royaltyInfo(0, 0) returns (address, uint256) {
            return true;
        } catch {
            return false;
        }
    }

    /**
     * @notice This function adds an token address to the allowed list
     * @param erc20Address The address of the token (address(0) for PLS))
     * @param floorPrice The floor price of the token
     */
    function addTokenAddress(address erc20Address, uint256 floorPrice) external onlyWizard {

        require(floorPrice > 0, "Floor price to low");
        require(allowedTokenAddresses[erc20Address] == 0, "Token Already Exists");

        allowedTokenAddresses[erc20Address] = floorPrice;
        emit NewTokenEvent(erc20Address, floorPrice); 
    }
}

// File: @openzeppelin/contracts/token/ERC721/IERC721.sol


// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;


/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// File: contracts/marketplace/ERC721Marketplace.sol


pragma solidity 0.8.17;






contract ERC721Marketplace is Marketplace {
    using SafeERC20 for IERC20;

    // ContractAddress => TokenId => Item
    mapping(address => mapping(uint256 => Item)) public items;

    /**
     * @notice Creates a new instance of an ERC721 Marketplace
     * @dev Initializes the Marketplace contract with the provided admin and payee addresses and royalty percentage
     * @param _wizard Address of the market percent decreaser contract
     * @param _feeSplitterAddress Address of the fee splitter contract
     * @param _mintTokenAddress Address of the mint token contract
     */
    constructor(
        address _wizard,
        address _feeSplitterAddress,
        address _mintTokenAddress
    ) Marketplace(_wizard, _feeSplitterAddress, _mintTokenAddress) {     
    }

    /**
     * @notice Lists an item for sale in the marketplace
     * @dev Adds the item to the list of items for sale and sets its price, sale type, and status
     * @param _collectionAddress The address of the collection to which the item belongs
     * @param _tokenId The ID of the item to be listed
     * @param _price The sale price of the item
     * @param privateSaleList The list of addresses to which the item can be sold at a private price
     */
    function putOnSale(
        address _collectionAddress,
        uint256 _tokenId,
        uint256 _price,
        address _tokenAddress,
        address[] calldata privateSaleList
    ) public nonReentrant {

        uint256 floorPrice = allowedTokenAddresses[_tokenAddress];

        require (floorPrice > 0, "floorPrice invalid");

        // Ensure the item is listed above or equal to the floor price
        require(_price >= floorPrice, "floorPrice not met");

        // Get the item from storage using its collection address and token ID
        Item memory item = items[_collectionAddress][_tokenId];

        // If the item is on offer, reimburse the previous bidder
        if (item.saleType == SaleType.OFFER) {
            reimbursePreviousBidder(item);
        } else {
            // If the item is not on offer, ensure it is not already listed
            require(item.seller == address(0), "Item listed");
        }

        // Add the item to the list of items for sale
        listForSale(
            _collectionAddress,
            _tokenId,
            _price,
            _tokenAddress,
            SaleType.FIXED,
            ItemStatus.SALE_START,
            0,
            privateSaleList
        );
    }

    /**
     * @notice Remove a listing for an item in the marketplace
     * @dev Allows the owner of a listed item to remove the item from the marketplace
     * @param _collectionAddress The address of the collection to which the item belongs
     * @param _tokenId The ID of the item to be removed from sale
     */
    function takeOffSale(
        address _collectionAddress,
        uint256 _tokenId
    ) public nonReentrant {
        // Get the item from storage using its collection address and token ID
        Item memory item = items[_collectionAddress][_tokenId];

        // Ensure that the caller is the owner of the item
        require(item.seller == msg.sender, "Not owner of item");

        // Ensure that the minimum time has passed since the item was listed before it can be removed from sale
        require(
            block.timestamp > item.promiseStartTime + minWaitTimeToCancel,
            "Too early to cancel"
        );

        // Transfer the NFT back to the seller
        IERC721 tokenContract = IERC721(_collectionAddress);
        tokenContract.transferFrom(address(this), msg.sender, _tokenId);

        // Delete the item from the list of items for sale
        delete items[_collectionAddress][_tokenId];

        // Emit an event indicating that the sale was removed
        // item.buyer == address(0) because it was taken off sale
        emit MarketplaceEvent(
            ItemStatus.SALE_REMOVED,
            _collectionAddress,
            _tokenId,
            item,
            Payout(0, item.tokenAddress, 0, Royalty(address(0), 0))
        );
    }

    /**
     * @notice Create an auction for an item in the marketplace
     * @dev Allows the owner of an item to create an auction for it, with a specified starting price and end time
     * @param _collectionAddress The address of the collection to which the item belongs
     * @param _tokenId The ID of the item to be auctioned
     * @param _minPrice The starting price of the auction
     * @param _endTime The timestamp at which the auction will end
     * @param privateSaleList The list of addresses to which the item can be sold at a private price
     */
    function putOnAuction(
        address _collectionAddress,
        uint256 _tokenId,
        uint256 _minPrice,
        address _tokenAddress,
        uint256 _endTime,
        address[] calldata privateSaleList
    ) public nonReentrant checkAuctionValidity(_minPrice, _endTime, _tokenAddress) {
  
        // Get the item from storage using its collection address and token ID
        Item memory item = items[_collectionAddress][_tokenId];

        // If the item is on offer, reimburse the previous bidder
        if (item.saleType == SaleType.OFFER) {
            reimbursePreviousBidder(item);
        } else {
            // If the item is not on offer, ensure it is not already listed
            require(item.seller == address(0), "Item already listed");
        }

        // Add the item to the list of items for sale as an auction
        listForSale(
            _collectionAddress,
            _tokenId,
            _minPrice,
            _tokenAddress,
            SaleType.AUCTION,
            ItemStatus.AUCTION_START,
            _endTime,
            privateSaleList
        );
    }

    /**
     * @notice Place a bid on an item listed for auction in the marketplace
     * @dev Allows a buyer to place a bid on an item listed for auction in the marketplace
     * @param _collectionAddress The address of the collection to which the item belongs
     * @param _tokenId The ID of the item to place a bid on
     */
    function createBid(
        address _collectionAddress,
        uint256 _tokenId,
        uint256 _bidAmount
    )
        external
        payable
        nonReentrant
        checkBidValidity(_bidAmount, items[_collectionAddress][_tokenId])
    { 
        // Get the item from storage using its collection address and token ID
        Item memory item = items[_collectionAddress][_tokenId];

        // Check if the item is part of a private sale
        checkPrivateSale(item);

        // Refund the previous bidder
        reimbursePreviousBidder(item);

        // Update the item with the new bidder
        item.bidder = msg.sender;

        if (item.tokenAddress == address(0)) {
            item.bidAmount = msg.value; // PLS Bid

            require(msg.value == _bidAmount, "Bid amount incorrect");
        } else {
            item.bidAmount = _bidAmount; // ERC20 Bid
            IERC20(item.tokenAddress).safeTransferFrom(msg.sender, address(this), _bidAmount);
        }

        // Update the item in storage
        items[_collectionAddress][_tokenId] = item;

        // Emit an event indicating a new bid has been placed on the item
        emit MarketplaceEvent(
            ItemStatus.AUCTION_NEW_BID,
            _collectionAddress,
            _tokenId,
            item,
            Payout(0, item.tokenAddress, 0, Royalty(address(0), 0))
        );
    }

    /**
     * @notice End an auction for an item in the marketplace
     * @dev Allows the owner of an item listed for auction to end the auction, and transfers the item to the highest bidder
     * @param _collectionAddress The address of the collection to which the item belongs
     * @param _tokenId The ID of the item whose auction is ending
     */
    function endAuction(
        address _collectionAddress,
        uint256 _tokenId
    )
        public
        nonReentrant
    {
        require(items[_collectionAddress][_tokenId].saleType == SaleType.AUCTION, "Incorrect type");
        
        // Get the item from storage using its collection address and token ID
        Item memory item = items[_collectionAddress][_tokenId];
        uint256 winningBidAmount = item.bidAmount;

        // If there are no bids, the auction can be cancelled if minWaitTimeToCancel has passed
        checkIfAuctionCanEnd(item);

        // Get the token contract for the item's collection
        IERC721 tokenContract = IERC721(_collectionAddress);

        // Initialize the item status as auction success
        ItemStatus itemStatus = ItemStatus.AUCTION_SUCCESS;

        if (winningBidAmount == 0) {
            // No Bids

            // Transfer the NFT back to the seller
            tokenContract.transferFrom(address(this), item.seller, _tokenId);

            // Set the item status to auction removed
            itemStatus = ItemStatus.AUCTION_REMOVED;
        } else {
            // Set the buyer of the item to the highest bidder
            item.buyer = item.bidder;

            // Transfer the asset to the contract address.
            transferNFTAssets(_collectionAddress, _tokenId, address(this), item.buyer);
        }

        // Set the sale price of the item to the winning bid amount
        item.price = item.bidAmount;

        // Mark the sale as complete
        completeSale(itemStatus, _collectionAddress, _tokenId, item);
    }

    /**
     * @dev List an item for sale in the marketplace
     * @notice Allows the owner of an item to list it for sale in the marketplace
     * @param _collectionAddress The address of the collection to which the item belongs
     * @param _tokenId The ID of the item to list for sale
     * @param _price The price at which to sell the item
     * @param saleType The type of sale to list the item for
     * @param itemStatus The status of the item after being listed for sale
     * @param _endTime The timestamp at which the sale or auction will end
     * @param addressesForPrivateSaleList The list of addresses to which the item can be sold at a private price
     */
    function listForSale(
        address _collectionAddress,
        uint256 _tokenId,
        uint256 _price,
        address _tokenAddress,
        SaleType saleType,
        ItemStatus itemStatus,
        uint256 _endTime,
        address[] memory addressesForPrivateSaleList
    ) private {
        // Ensure the length of the private sale list is not greater than the maximum allowed
        checkPrivateSaleListLength(addressesForPrivateSaleList);

        // Transfer the NFT to the marketplace contract
        IERC721(_collectionAddress).transferFrom(
            msg.sender,
            address(this),
            _tokenId
        );

        // Create a new item object and add it to storage
        Item memory item = Item(
            saleType,
            _price,
            _tokenAddress,
            msg.sender,
            address(0),
            block.timestamp,
            _endTime,
            address(0),
            0,
            1,
            addressesForPrivateSaleList
        );
        items[_collectionAddress][_tokenId] = item;

        // Emit an event indicating that the item has been listed for sale
        emit MarketplaceEvent(
            itemStatus,
            _collectionAddress,
            _tokenId,
            item,
            Payout(0, _tokenAddress, 0, Royalty(address(0), 0))
        );
    }

    /**
     * @dev Complete a sale of an item in the marketplace
     * @notice Allows the owner of an item to complete a sale of it in the marketplace
     * @param _itemStatus The status of the item after the sale is completed
     * @param _collectionAddress The address of the collection to which the item belongs
     * @param _tokenId The ID of the item being sold
     * @param _item The item being sold
     */
    function completeSale(
        ItemStatus _itemStatus,
        address _collectionAddress,
        uint256 _tokenId,
        Item memory _item
    ) private {
        // Check if the item is on the private sale list
        if (_item.saleType == SaleType.FIXED ) {
            checkPrivateSale(_item);
        }

        // Remove the item from storage
        delete items[_collectionAddress][_tokenId];

        // Calculate the payout for the sale
        Payout memory itemPayout;
        if (
            _itemStatus == ItemStatus.SALE_SUCCESS ||
            _itemStatus == ItemStatus.AUCTION_SUCCESS ||
            _itemStatus == ItemStatus.OFFER_SUCCESS
        ) {
            itemPayout = payout(
                _item.seller,
                _item.price,
                _item.tokenAddress,
                _collectionAddress,
                _tokenId
            );
        }

        // Emit an event indicating that the sale is complete
        emit MarketplaceEvent(
            _itemStatus,
            _collectionAddress,
            _tokenId,
            _item,
            itemPayout
        );
    }

    /**
     * @dev Transfer all assets for a sale.
     * @param _collectionAddress NFT collection address
     * @param _tokenId token ID of the NFT
     * @param _owner address of the NFT owner
     * @param buyer address of the NFT buyer
     */
    function transferNFTAssets(
        address _collectionAddress,
        uint256 _tokenId,
        address _owner,
        address buyer
    ) private {
        IERC721 tokenContract = IERC721(_collectionAddress);
        // Transfer the NFT to the buyer address
        tokenContract.transferFrom(_owner, buyer, _tokenId);
    }

    /**
     * @dev Revoke an offer made on an item.
     * @param _collectionAddress NFT collection address
     * @param _tokenId token ID of the NFT
     */
    function revokeOffer(
        address _collectionAddress,
        uint256 _tokenId
    ) nonReentrant external {
        Item memory item = items[_collectionAddress][_tokenId];

        require(item.saleType == SaleType.OFFER, "Not an offer");
        require(item.buyer == msg.sender, "No offer to revoke");
        require(
            block.timestamp > item.promiseStartTime + minWaitTimeToCancel,
            "Too early to cancel"
        );

        // Remove the item from the marketplace
        delete items[_collectionAddress][_tokenId];

        // Reimburse the previous bidder
        reimbursePreviousBidder(item);

        // Emit an event for the offer being revoked
        emit MarketplaceEvent(
            ItemStatus.OFFER_REMOVED,
            _collectionAddress,
            _tokenId,
            item,
            Payout(0, item.tokenAddress, 0, Royalty(address(0), 0))
        );
    }

    /**
     * @notice This function allows a user to make an offer on an NFT item
     * @dev This function can be accessed externally and is non-reentrant
     * @param _collectionAddress The address of the NFT collection
     * @param _tokenId The ID of the NFT item
     */
    function makeOffer(
        address _collectionAddress,
        uint256 _tokenId
    ) external nonReentrant payable {
        // Retrieve the item object from storage
        Item memory item = items[_collectionAddress][_tokenId];

        // Ensure that the item is not already listed for sale
        require(
            item.saleType == SaleType.OFFER || item.seller == address(0),
            "Item already listed"
        );

        // Get the current owner of the item
        address currentOwner = IERC721(_collectionAddress).ownerOf(_tokenId);

        // Ensure that the sender is not the current owner of the item
        require(currentOwner != msg.sender, "Item not owned");

        // Ensure that the offer amount is sufficient
        require(
            msg.value >= 1 ether &&
                msg.value >= item.bidAmount + (item.bidAmount * minBidIncrementPercent) / 100,
            "Insufficient offer amount"
        );

        // Reimburse the previous bidder if there was one
        reimbursePreviousBidder(item);

        // Update the item details with the new offer
        item.saleType = SaleType.OFFER;
        item.bidAmount = msg.value;
        item.bidder = msg.sender;
        item.seller = currentOwner;
        item.buyer = msg.sender;
        item.promiseStartTime = block.timestamp;

        // Update the item object in storage
        items[_collectionAddress][_tokenId] = item;

        // Emit an event to indicate that the offer has been made
        emit MarketplaceEvent(
            ItemStatus.OFFER_START,
            _collectionAddress,
            _tokenId,
            item,
            Payout(0, item.tokenAddress, 0, Royalty(address(0), 0))
        );
    }

    /**
     * @notice This function allows a seller to accept an offer on an NFT item
     * @dev This function can be accessed externally and is non-reentrant
     * @param _collectionAddress The address of the NFT collection
     * @param _tokenId The ID of the NFT item
     */
    function acceptOffer(
        address _collectionAddress,
        uint256 _tokenId
    ) external nonReentrant {
        // Retrieve the item object from storage
        Item memory item = items[_collectionAddress][_tokenId];
        
        // Ensure that the item is listed as an offer
        require(item.saleType == SaleType.OFFER, "No offer available");

        // Transfer the assets to the buyer
        transferNFTAssets(_collectionAddress, _tokenId, msg.sender, item.buyer);

        // Set the sale price of the item to the winning offer amount and the seller
        item.price = item.bidAmount;
        item.seller = msg.sender;

        // Complete the sale and update the analytics
        completeSale(
            ItemStatus.OFFER_SUCCESS,
            _collectionAddress,
            _tokenId,
            item
        );
    }

    /**
     * @dev Puts multiple tokens on sale.
     * @param _collectionAddress The address of the collection.
     * @param _tokenIds An array of token IDs to put on sale.
     * @param _prices An array of sale prices for the tokens.
     * @param _tokenAddresses An array of ERC20 token addresses for the tokens.
     * @param privateSaleList An array of addresses for private sales (optional).
     */
    function bulkPutOnSale(
        address _collectionAddress,
        uint256[] memory _tokenIds,
        uint256[] memory _prices,
        address[] memory _tokenAddresses,
        address[] calldata privateSaleList
    ) external {
        // Make sure that tokenIds, prices and _tokenAddresses match
        require(_tokenIds.length == _prices.length, "Length mismatch");
        require(_prices.length == _tokenAddresses.length, "Length mismatch");

        // Iterate over each tokenId
        for (uint256 i = 0; i < _tokenIds.length; i++) {
            // Call the putOnSale function for the current tokenId
            putOnSale(
                _collectionAddress,
                _tokenIds[i],
                _prices[i],
                _tokenAddresses[i],
                privateSaleList
            );
        }
    }

    /**
     * @dev Takes multiple tokens off sale.
     * @param _collectionAddress The address of the collection.
     * @param _tokenIds An array of token IDs to take off sale.
     */
    function bulkTakeOffSale(
        address _collectionAddress,
        uint256[] memory _tokenIds
    ) external {
        // Iterate over each tokenId
        for (uint256 i = 0; i < _tokenIds.length; i++) {
            // Call the takeOffSale function for the current tokenId
            takeOffSale(_collectionAddress, _tokenIds[i]);
        }
    }

    /**
     * @dev Puts multiple tokens on auction.
     * @param _collectionAddress The address of the collection.
     * @param _tokenIds An array of token IDs to put on auction.
     * @param _minPrices An array of minimum auction prices for the tokens.
     * @param _tokenAddresses An array of ERC20 token addresses.
     * @param _endTimes An array of end times for the auctions.
     * @param privateSaleList An array of addresses for private sales (optional).
     */
    function bulkPutOnAuction(
        address _collectionAddress,
        uint256[] memory _tokenIds,
        uint256[] memory _minPrices,
        address[] memory _tokenAddresses,
        uint256[] memory _endTimes,
        address[] calldata privateSaleList
    ) external {
        // Make sure that tokenIds, minPrices, _tokenAddresses and _endTimes match length
        require(
            _tokenIds.length == _minPrices.length && 
            _tokenIds.length == _tokenAddresses.length &&
            _tokenIds.length == _endTimes.length, 
            "Length mismatch"
        );

        // Iterate over each tokenId
        for (uint256 i = 0; i < _tokenIds.length; i++) {

            address tokenAddress = _tokenAddresses[i];

            // Call the putOnAuction function for the current tokenId
            putOnAuction(
                _collectionAddress,
                _tokenIds[i],
                _minPrices[i],
                tokenAddress,
                _endTimes[i],
                privateSaleList
            );
        }
    }

    /**
     * @dev Takes multiple tokens off auction.
     * @param _collectionAddress The address of the collection.
     * @param _tokenIds An array of token IDs to take off auction.
     */
    function bulkEndAuction(
        address _collectionAddress,
        uint256[] memory _tokenIds
    ) external {
        // Iterate over each tokenId
        for (uint256 i = 0; i < _tokenIds.length; i++) {
            // Call the endAuction function for the current tokenId
            endAuction(
                _collectionAddress,
                _tokenIds[i]
            );
        }
    }

    /**
     * @dev Buy multiple tokens
     * @param _collectionAddress The address of the collection.
     * @param _tokenIds An array of token IDs to put on auction.
     */
    function buy(
        address _collectionAddress,
        uint256[] memory _tokenIds
    ) external payable nonReentrant {
        uint256 totalAmountPls = 0;
        // Iterate over each tokenId
        for (uint256 i = 0; i < _tokenIds.length; i++) {
            // Are we buying this item in PLS
            address tokenAddress = items[_collectionAddress][_tokenIds[i]].tokenAddress;
            uint256 price = items[_collectionAddress][_tokenIds[i]].price;

            if (tokenAddress == address(0)) {
                //calculate total amount for items being sold for PLS
                totalAmountPls += price;
            } else {
                // Transfer ERC20 tokens to this contract
                IERC20(tokenAddress).safeTransferFrom(msg.sender, address(this), price);
            }

            // Call the buy function for the current tokenId
            _buy(_collectionAddress, _tokenIds[i]);
        }

        // Make sure that the total price for items bought with PLS is equal to the amount sent
        require(totalAmountPls == 0 || msg.value == totalAmountPls, "Incorrect");
    }

        /**
     * @notice Buy an item that is listed for sale in the marketplace
     * @dev Allows a buyer to purchase an item listed for sale in the marketplace, and transfers the asset to the buyer's address
     * @param _collectionAddress The address of the collection to which the item belongs
     * @param _tokenId The ID of the item to be purchased
     */
    function _buy(
        address _collectionAddress,
        uint256 _tokenId
    )
        internal
    {
        // Get the item from storage using its collection address and token ID
        Item memory item = items[_collectionAddress][_tokenId];

        require(item.seller != address(0), "Item not on sale");
        
        require(item.saleType == SaleType.FIXED, "Incorrect type");

        // Set the buyer address of the item to the address of the buyer.
        item.buyer = msg.sender;

        // Transfer the asset to the buyer address.
        transferNFTAssets(_collectionAddress, _tokenId, address(this), item.buyer);

        // Mark the sale as complete.
        completeSale(
            ItemStatus.SALE_SUCCESS,
            _collectionAddress,
            _tokenId,
            item
        );
    }
}