Contract Address Details

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";
import "./TaxableToken.sol";

/** @title Janus - ERC20 Token with DeFi functionality and transaction fees applied to DEX interactions
 * @dev This contract extends OpenZeppelin's ERC20 and Ownable contracts.
 *      It includes transaction fee mechanisms and the ability to mint new tokens.
 */
contract Janus is ERC20, Ownable, TaxableToken {
    /// @notice The Investment Pool percentage enforceable, also expressed in basis points.
    uint256 public investmentPoolPercentage = 7000;

    /// @notice Total PLS tokens collected as fees and not yet redistributed.
    uint256 public undistributedPls;

    /// @notice The HLX token address which is involved in mint transactions as fees.
    address public hlxAddress;

    /// @notice Conversion rate from payment in native currency (like ETH) to HLX token fees.
    uint256 public plsRate;

    /// @notice Custom error to indicate insufficient payment in PLS for the operations required.
    error insufficientPLS();

    /**  @notice Constructs the Janus ERC20 Token
     * @param _hlxAddress The address of the HLX token used for fee mechanisms.
     * @param _plsRate The rate used to convert payment in native currency to HLX token fees.
     */
    constructor(
        address _hlxAddress,
        uint256 _plsRate,
        address swapRouter_,
        FeeConfiguration memory feeConfiguration_,
        uint256 numTokensToSwap,
        address _investmentPoolAddress,
        address _teamAddress
    )
        ERC20("Janus", "JNS")
        TaxableToken(
            true,
            numTokensToSwap * 10 ** decimals(),
            swapRouter_,
            feeConfiguration_,
            _investmentPoolAddress,
            _teamAddress
        )
    {
        hlxAddress = _hlxAddress;
        plsRate = _plsRate;
        _mint(msg.sender, 420000000000 * 10 ** decimals());
    }

    /**  @notice Mints new tokens to a specified address after collecting protocol fees in HLX tokens.
     * @param to The address to receive the newly minted tokens.
     * @param amount The amount of tokens to mint.
     */
    function mint(address to, uint256 amount) public payable {
        _protocolFees(amount);
        _mint(to, amount);
        if (autoProcessFees) distributeFees();
    }

    /** @notice Sets the address of the HLX Token.
     * @param _hlxAddress The new Token address.
     */
    function setHLXAddress(address _hlxAddress) public onlyOwner {
        if (_hlxAddress == address(0)) revert Janus_ZeroAddress();
        hlxAddress = _hlxAddress;
    }

    /** @notice Sets the distribution percentages for the investment pool.
     * @param _percentage New percentage for the investment pool.
     */
    function setInvestmentPoolPercentage(uint256 _percentage) public onlyOwner {
        if (!(_percentage > 0 && _percentage <= 10000))
            revert Janus_InvalidValue();
        investmentPoolPercentage = _percentage;
    }

    /** @notice Updates the PLS rate for fee calculations.
     * @param _plsRate The new rate for converting payment in native currency to HLX token fees.
     */
    function setPLSRate(uint256 _plsRate) public onlyOwner {
        if (!(_plsRate > 0)) revert Janus_InvalidValue();
        plsRate = _plsRate;
    }

    /**
     * @dev process fees
     * only callable by `owner()`
     */
    function processFees(address pair) external override onlyOwner {
        _processFees(pair);
    }

    /**
     * @dev add/remove a LP
     * only callable by `owner()`
     */
    function setIsLpPool(
        address pairAddress,
        bool isLp
    ) external override onlyOwner {
        _setIsLpPool(pairAddress, isLp);
    }

    /**
     * @dev add LP Pool RouterAddress
     * only callable by `owner()`
     */
    function setLpPoolRouter(
        address routerAddress,
        address pairAddress
    ) external override onlyOwner {
        _setLpPoolRouter(routerAddress, pairAddress);
    }

    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal override(ERC20, TaxableToken) {
        super._transfer(from, to, amount);
    }

    /** @notice Transfers tokens between two addresses on behalf of a third party, with fee deductions if interacting through a DEX.
     * @param sender The address sending the tokens.
     * @param recipient The address receiving the tokens.
     * @param amount The total amount of tokens to be transferred.
     * @return bool Returns true if the transfer was successful.
     */
    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) public override returns (bool) {
        _spendAllowance(sender, _msgSender(), amount);
        super._transfer(sender, recipient, amount);
        return true;
    }

    /** @notice Collects protocol fees in HLX tokens, adds to the undistributed HLX pool.
     * @param amount The amount of HLX tokens to collect as fees.
     * @dev Reverts if the value sent is less than the required amount converted at `plsRate`.
     */
    function _protocolFees(uint256 amount) private {
        if (msg.value < (amount * plsRate) / 1 ether) {
            revert insufficientPLS();
        }
        // Transfer HLX From user to contract
        IERC20(hlxAddress).transferFrom(_msgSender(), address(this), amount);

        //Burns recieved HLX
        ERC20Burnable(hlxAddress).burn(amount);

        undistributedPls += msg.value;
    }

    /** @notice Distributes collected PLS to the investment pool and team address.
     */
    function distributeFees() public {
        if (undistributedPls == 0) {
            _distribute(0, 0);
            return;
        }
        uint256 investmentPoolShare = (undistributedPls *
            investmentPoolPercentage) / FEE_PRECISION;
        uint256 teamShare = undistributedPls - investmentPoolShare;

        undistributedPls = 0; // Reset the undistributed PLS after distribution

        if (investmentPoolAddress != address(0) && teamAddress != address(0)) {
            _distribute(investmentPoolShare, teamShare);
        } else {
            revert Janus_AddressesNoSet();
        }
    }

    /**
     * @dev Enable/Disable autoProcessFees on transfer
     * only callable by `owner()`
     */
    function setAutoprocessFees(bool autoProcess) external override onlyOwner {
        if (autoProcessFees == autoProcess) revert Janus_AlreadySet();
        autoProcessFees = autoProcess;
    }

    /**
     * @dev add/remove an address to the tax exclusion list
     * only callable by `owner()`
     */
    function setIsExcludedFromFees(
        address account,
        bool excluded
    ) external override onlyOwner {
        _setIsExcludedFromFees(account, excluded);
    }

    /**
     * @dev set the liquidity owner
     * only callable by `owner()`
     */
    function setLiquidityOwner(address newOwner) external override onlyOwner {
        liquidityOwner = newOwner;
    }

    /**
     * @dev set the number of tokens to swap
     * only callable by `owner()`
     */
    function setNumTokensToSwap(uint256 amount) external override onlyOwner {
        numTokensToSwap = amount;
    }

    /**
     * @dev update the fee configurations
     * only callable by `owner()`
     */
    function setFeeConfiguration(
        FeeConfiguration calldata configuration
    ) external override onlyOwner {
        _setFeeConfiguration(configuration);
    }

    /**
     * @dev update the swap router
     * only callable by `owner()`
     */
    function setSwapRouter(address newRouter) external override onlyOwner {
        _setSwapRouter(newRouter);
    }
}
        

// SPDX-License-Identifier: MIT
pragma solidity >=0.6.2;

interface IPulseXRouter01 {
    function factory() external pure returns (address);
    function WPLS() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    )
        external
        payable
        returns (uint amountToken, uint amountETH, uint liquidity);
    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETH(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountToken, uint amountETH);
    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETHWithPermit(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external returns (uint amountToken, uint amountETH);
    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapExactETHForTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable returns (uint[] memory amounts);
    function swapTokensForExactETH(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapExactTokensForETH(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapETHForExactTokens(
        uint amountOut,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable returns (uint[] memory amounts);

    function quote(
        uint amountA,
        uint reserveA,
        uint reserveB
    ) external pure returns (uint amountB);
    function getAmountOut(
        uint amountIn,
        uint reserveIn,
        uint reserveOut
    ) external pure returns (uint amountOut);
    function getAmountIn(
        uint amountOut,
        uint reserveIn,
        uint reserveOut
    ) external pure returns (uint amountIn);
    function getAmountsOut(
        uint amountIn,
        address[] calldata path
    ) external view returns (uint[] memory amounts);
    function getAmountsIn(
        uint amountOut,
        address[] calldata path
    ) external view returns (uint[] memory amounts);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address from, address to, uint256 amount) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(address from, address to, uint256 amount) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 amount) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(address from, address to, uint256 amount) internal virtual {}
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.0;

import "../ERC20.sol";
import "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys `amount` tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 amount) public virtual {
        _burn(_msgSender(), amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, deducting from the caller's
     * allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `amount`.
     */
    function burnFrom(address account, uint256 amount) public virtual {
        _spendAllowance(account, _msgSender(), amount);
        _burn(account, amount);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
          

// SPDX-License-Identifier: MIT
pragma solidity >=0.5.0;

interface IPulseXFactory {
    event PairCreated(
        address indexed token0,
        address indexed token1,
        address pair,
        uint
    );

    function feeTo() external view returns (address);
    function feeToSetter() external view returns (address);

    function getPair(
        address tokenA,
        address tokenB
    ) external view returns (address pair);
    function allPairs(uint) external view returns (address pair);
    function allPairsLength() external view returns (uint);

    function createPair(
        address tokenA,
        address tokenB
    ) external returns (address pair);

    function setFeeTo(address) external;
    function setFeeToSetter(address) external;
}
          

// SPDX-License-Identifier: MIT
pragma solidity >=0.5.0;

interface IPulseXPair {
    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    function name() external pure returns (string memory);
    function symbol() external pure returns (string memory);
    function decimals() external pure returns (uint8);
    function totalSupply() external view returns (uint);
    function balanceOf(address owner) external view returns (uint);
    function allowance(
        address owner,
        address spender
    ) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);
    function transfer(address to, uint value) external returns (bool);
    function transferFrom(
        address from,
        address to,
        uint value
    ) external returns (bool);

    function DOMAIN_SEPARATOR() external view returns (bytes32);
    function PERMIT_TYPEHASH() external pure returns (bytes32);
    function nonces(address owner) external view returns (uint);

    function permit(
        address owner,
        address spender,
        uint value,
        uint deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    event Mint(
        address indexed sender,
        uint amount0,
        uint amount1,
        address indexed senderOrigin
    );
    event Burn(
        address indexed sender,
        uint amount0,
        uint amount1,
        address indexed to,
        address indexed senderOrigin
    );
    event Swap(
        address indexed sender,
        uint amount0In,
        uint amount1In,
        uint amount0Out,
        uint amount1Out,
        address indexed to
    );
    event Sync(uint112 reserve0, uint112 reserve1);

    function MINIMUM_LIQUIDITY() external pure returns (uint);
    function factory() external view returns (address);
    function token0() external view returns (address);
    function token1() external view returns (address);
    function getReserves()
        external
        view
        returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);
    function price0CumulativeLast() external view returns (uint);
    function price1CumulativeLast() external view returns (uint);
    function kLast() external view returns (uint);

    function mint(
        address to,
        address senderOrigin
    ) external returns (uint liquidity);
    function burn(
        address to,
        address senderOrigin
    ) external returns (uint amount0, uint amount1);
    function swap(
        uint amount0Out,
        uint amount1Out,
        address to,
        bytes calldata data
    ) external;
    function skim(address to) external;
    function sync() external;

    function initialize(address, address) external;
}
          

// SPDX-License-Identifier: MIT
pragma solidity >=0.6.2;
import "./IPulseXRouter01.sol";

interface IPulseXRouter02 is IPulseXRouter01 {
    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountETH);
    function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external returns (uint amountETH);

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable;
    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
}
          

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./PulseX/IPulseXRouter02.sol";
import "./PulseX/IPulseXFactory.sol";
import "./PulseX/IPulseXPair.sol";
import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

error Janus_ZeroAddress();
error Janus_AlreadySet();
error Janus_InvalidRouter();
error Janus_InvalidFactory();
error Janus_InvalidPair();
error Janus_InvalidBuyFee();
error Janus_InvalidSellFee();
error Janus_InvalidFeeShare();
error Janus_TransferAmountZero();
error Janus_InvalidValue();
error Janus_AddressesNoSet();
/*
 * TaxableToken: Add a tax on buy, sell or transfer
 */
abstract contract TaxableToken is ERC20, Ownable {
    struct FeeConfiguration {
        uint16 buyFees; // fees applied during buys, from 0 to 2000 (ie, 100 = 1%)
        uint16 sellFees; // fees applied during sells, from 0 to 2000 (ie, 100 = 1%)
        uint16 burnFeeRatio; // from 0 to 10000 (ie 8000 = 80% of the fee collected are burned)
        uint16 liquidityFeeRatio; // from 0 to 10000 (ie 8000 = 80% of the fee collected are added back to liquidity)
        uint16 daoFeeRatio; // from 0 to 10000 (ie 8000 = 80% of the fee collected are sent to DAO)
        uint16 devFeeRatio; // from 0 to 10000 (ie 8000 = 80% of the fee collected are sent to DEV)
    }

    address public constant BURN_ADDRESS =
        address(0x000000000000000000000000000000000000dEaD);
    uint16 public constant MAX_FEE = 2000; // max 20% fees
    uint16 public constant FEE_PRECISION = 10000;

    /// @notice Address of the investment pool where collected fees could be sent.
    address public investmentPoolAddress;

    /// @notice Address of the team where another portion of the collected fees will be sent.
    address public teamAddress;

    /// @notice Stores amount of tokens collected as tax for distribution
    uint256 public undistributedJNS;

    // swap config
    IPulseXRouter02 public swapRouter;
    address public swapPair;
    address public liquidityOwner;

    // fees
    bool private _processingFees;
    bool public autoProcessFees;
    uint256 public numTokensToSwap; // amount of tokens to collect before processing fees (default to 0.05% of supply)
    FeeConfiguration public feeConfiguration;

    mapping(address => bool) private _excludedFromFees;
    mapping(address => bool) private _lpPools;
    mapping(address => uint256) private _tokenAmountForLp;
    mapping(address => IPulseXRouter02) private _lpPoolsSwapRouter;

    event FeeConfigurationUpdated(FeeConfiguration configuration);
    event SwapRouterUpdated(address indexed router, address indexed pair);
    event ExcludedFromFees(address indexed account, bool excluded);
    event SetLpPool(address indexed pairAddress, bool isLp);
    event SetLpPoolRouter(
        address indexed routerAddress,
        address indexed pairAddress
    );
    event InvestmentPoolAddressUpdated(address indexed _investmentPoolAddress);
    event TeamAddressUpdated(address indexed _teamAddress);

    modifier lockTheSwap() {
        _processingFees = true;
        _;
        _processingFees = false;
    }

    constructor(
        bool autoProcessFees_,
        uint256 numTokensToSwap_,
        address swapRouter_,
        FeeConfiguration memory feeConfiguration_,
        address _investmentPoolAddress,
        address _teamAddress
    ) {
        numTokensToSwap = numTokensToSwap_;
        autoProcessFees = autoProcessFees_;

        liquidityOwner = _msgSender();

        // Create a uniswap pair for this new token
        swapRouter = IPulseXRouter02(swapRouter_);
        swapPair = _pairFor(
            swapRouter.factory(),
            address(this),
            swapRouter.WPLS()
        );
        _lpPools[swapPair] = true;
        _lpPoolsSwapRouter[swapPair] = swapRouter;

        // configure addresses excluded from fee
        _setIsExcludedFromFees(_msgSender(), true);
        _setIsExcludedFromFees(address(this), true);

        // configure fees
        _setFeeConfiguration(feeConfiguration_);
        _setInvestmentPoolAddress(_investmentPoolAddress);
        _setTeamAddress(_teamAddress);
    }

    // receive ETH when swaping
    receive() external payable {}

    function isExcludedFromFees(address account) public view returns (bool) {
        return _excludedFromFees[account];
    }

    function setInvestmentPoolAddress(
        address _InvestmentPoolAddress
    ) external onlyOwner {
        _setInvestmentPoolAddress(_InvestmentPoolAddress);
    }

    function setTeamAddress(address _teamAddress) external onlyOwner {
        _setTeamAddress(_teamAddress);
    }

    function _setIsExcludedFromFees(address account, bool excluded) internal {
        if (_excludedFromFees[account] == excluded) revert Janus_AlreadySet();
        _excludedFromFees[account] = excluded;
        emit ExcludedFromFees(account, excluded);
    }

    function _setInvestmentPoolAddress(
        address _investmentPoolAddress
    ) internal {
        if (_investmentPoolAddress == address(0)) revert Janus_ZeroAddress();
        investmentPoolAddress = _investmentPoolAddress;
    }

    function _setTeamAddress(address _teamAddress) internal {
        if (_teamAddress == address(0)) revert Janus_ZeroAddress();
        teamAddress = _teamAddress;
    }

    function _setIsLpPool(address pairAddress, bool isLp) internal {
        if (_lpPools[pairAddress] == isLp) revert Janus_AlreadySet();
        _lpPools[pairAddress] = isLp;
        emit SetLpPool(pairAddress, isLp);
    }

    function _setLpPoolRouter(
        address _routerAddress,
        address _pairAddress
    ) internal {
        if (_routerAddress == address(0)) revert Janus_ZeroAddress();
        _lpPoolsSwapRouter[_pairAddress] = IPulseXRouter02(_routerAddress);
        emit SetLpPoolRouter(_routerAddress, _pairAddress);
    }

    function isLpPool(address pairAddress) public view returns (bool) {
        return _lpPools[pairAddress];
    }

    function lpPoolRouter(address pairAddress) public view returns (address) {
        return address(_lpPoolsSwapRouter[pairAddress]);
    }

    function tokenForLpPool(address pairAddress) public view returns (uint256) {
        return _tokenAmountForLp[pairAddress];
    }

    function _setSwapRouter(address _newRouter) internal {
        if (_newRouter == address(0)) revert Janus_InvalidRouter();

        swapRouter = IPulseXRouter02(_newRouter);
        IPulseXFactory factory = IPulseXFactory(swapRouter.factory());
        if (address(factory) == address(0)) revert Janus_InvalidFactory();

        address weth = swapRouter.WPLS();
        swapPair = factory.getPair(address(this), weth);
        if (swapPair == address(0)) {
            swapPair = factory.createPair(address(this), weth);
        }

        if (swapPair == address(0)) revert Janus_InvalidPair();
        emit SwapRouterUpdated(address(swapRouter), swapPair);
    }

    function _setFeeConfiguration(
        FeeConfiguration memory configuration
    ) internal {
        if (!(configuration.buyFees <= MAX_FEE)) revert Janus_InvalidBuyFee();
        if (!(configuration.sellFees <= MAX_FEE)) revert Janus_InvalidSellFee();

        uint16 totalShare = configuration.burnFeeRatio +
            configuration.liquidityFeeRatio +
            configuration.daoFeeRatio +
            configuration.devFeeRatio;
        if (!(totalShare == 0 || totalShare == FEE_PRECISION))
            revert Janus_InvalidFeeShare();

        feeConfiguration = configuration;
        emit FeeConfigurationUpdated(configuration);
    }

    function _processFees(address pair) internal lockTheSwap {
        uint256 tokenAmount = _tokenAmountForLp[pair];
        uint256 contractTokenBalance = balanceOf(address(this));
        IPulseXRouter02 pairRouter = _lpPoolsSwapRouter[pair];
        if (contractTokenBalance >= tokenAmount) {
            uint256 liquidityAmount = (tokenAmount * // taxAmount is 67% here  lets say 67 tokens  out of 100 after burn amount was subtracted and burned
                feeConfiguration.liquidityFeeRatio) / // 33% for liquidity 33 tokens for liqudity
                (FEE_PRECISION - feeConfiguration.burnFeeRatio); // FEE_PRECISION is for 100% but this subtracts 33% from 100% from FEE_PRECISION making it 67% so (67 * 33) / (100 - 33) = 33
            undistributedJNS += tokenAmount - liquidityAmount; // now the remaining amount after liquidity 33% is 34%. this 34% is then divided to team/DAO 67-33 = 34 left

            (uint256 reserve0, uint256 reserve1, ) = IPulseXPair(pair)
                .getReserves();

            uint256 swapAmount;
            address tokenOut;
            if (IPulseXPair(pair).token0() == address(this)) {
                // swap from token0 to token1
                swapAmount = getSwapAmount(reserve0, liquidityAmount);
                tokenOut = IPulseXPair(pair).token1();
            } else {
                // swap from token1 to token0
                swapAmount = getSwapAmount(reserve1, liquidityAmount);
                tokenOut = IPulseXPair(pair).token0();
            }

            // swap tokens
            if (swapAmount > 0 && balanceOf(swapPair) != 0) {
                bool swapForETH;

                if (tokenOut == swapRouter.WPLS()) {
                    swapForETH = true;
                }

                // capture the contract's current balance of token
                uint256 initialBalanceTokenOut;
                if (swapForETH) {
                    initialBalanceTokenOut = address(this).balance;
                } else {
                    initialBalanceTokenOut = IERC20(tokenOut).balanceOf(
                        address(this)
                    );
                }

                uint256 liquidityTokenAmount = liquidityAmount - swapAmount;

                _swapTokens(tokenOut, swapAmount, 0, swapForETH, pairRouter);

                // how much did we just swap into?
                uint256 tokensOutReceived;
                if (swapForETH) {
                    tokensOutReceived =
                        address(this).balance -
                        initialBalanceTokenOut;
                } else {
                    tokensOutReceived =
                        IERC20(tokenOut).balanceOf(address(this)) -
                        initialBalanceTokenOut;
                }
                if (tokensOutReceived > 0) {
                    _addLiquidity(
                        liquidityTokenAmount,
                        tokensOutReceived,
                        tokenOut,
                        swapForETH,
                        pairRouter
                    );
                }
            }
            _tokenAmountForLp[pair] -= tokenAmount;
        }
    }

    function sqrt(uint256 y) private pure returns (uint256 z) {
        if (y > 3) {
            z = y;
            uint256 x = y / 2 + 1;
            while (x < z) {
                z = x;
                x = (y / x + x) / 2;
            }
        } else if (y != 0) {
            z = 1;
        }
    }

    /*
    s = optimal swap amount
    r = amount of reserve for token a
    a = amount of token a the user currently has (not added to reserve yet)
    f = swap fee percent
    s = (sqrt(((2 - f)r)^2 + 4(1 - f)ar) - (2 - f)r) / (2(1 - f))
    */
    function getSwapAmount(uint256 r, uint256 a) public pure returns (uint256) {
        return (sqrt(r * (r * 3988009 + a * 3988000)) - r * 1997) / 1994;
    }

    /// @dev Swap tokens for eth
    function _swapTokens(
        address to,
        uint256 tokenAmount,
        uint256 minAmountOut,
        bool swapForETH,
        IPulseXRouter02 pairRouter
    ) private {
        // generate the swap pair path of token -> weth
        address[] memory path = new address[](2);
        path[0] = address(this);
        path[1] = to;

        _approve(address(this), address(pairRouter), tokenAmount);

        if (swapForETH) {
            // make the swap
            pairRouter.swapExactTokensForETHSupportingFeeOnTransferTokens(
                tokenAmount,
                minAmountOut,
                path,
                address(this),
                block.timestamp + 600
            );
        } else {
            uint[] memory amounts = pairRouter.swapExactTokensForTokens(
                tokenAmount,
                minAmountOut,
                path,
                liquidityOwner,
                block.timestamp + 600
            );
            IERC20(to).transferFrom(liquidityOwner, address(this), amounts[1]);
        }
    }

    /// @dev Add liquidity
    function _addLiquidity(
        uint256 tokenAmount,
        uint256 ethAmount,
        address _token,
        bool addETH,
        IPulseXRouter02 pairRouter
    ) private {
        // approve token transfer to cover all possible scenarios
        _approve(address(this), address(pairRouter), tokenAmount);
        IERC20(_token).approve(address(pairRouter), ethAmount);
        if (addETH) {
            // add the liquidity
            pairRouter.addLiquidityETH{value: ethAmount}(
                address(this),
                tokenAmount,
                0, // slippage is unavoidable
                0, // slippage is unavoidable
                liquidityOwner,
                block.timestamp
            );
        } else {
            pairRouter.addLiquidity(
                address(this),
                _token,
                tokenAmount,
                ethAmount,
                0,
                0,
                liquidityOwner,
                block.timestamp
            );
        }
    }

    // calculates the CREATE2 address for a pair without making any external calls
    function _pairFor(
        address factory,
        address tokenA,
        address tokenB
    ) internal pure returns (address pair) {
        (address token0, address token1) = tokenA < tokenB
            ? (tokenA, tokenB)
            : (tokenB, tokenA);
        pair = address(
            uint160(
                uint(
                    keccak256(
                        abi.encodePacked(
                            hex"ff",
                            factory,
                            keccak256(abi.encodePacked(token0, token1)),
                            hex"5dff1ac2d132f5ac2841294c6e9fc0ebafae8d447fac7996ef21c21112f411f1" // init code hash
                        )
                    )
                )
            )
        );
    }

    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual override {
        if (!(amount > 0)) revert Janus_TransferAmountZero();

        uint256 taxFee = 0;
        bool processFee = !_processingFees && autoProcessFees;

        if (!_processingFees) {
            bool fromExcluded = isExcludedFromFees(from);
            bool toExcluded = isExcludedFromFees(to);

            bool fromLP = isLpPool(from);
            bool toLP = isLpPool(to);

            if (fromLP && !toLP && !toExcluded && to != address(swapRouter)) {
                // buy fee
                taxFee = feeConfiguration.buyFees;
            } else if (toLP && !fromExcluded && !toExcluded) {
                // sell fee
                taxFee = feeConfiguration.sellFees;
            }
        }

        // // process fees
        if (processFee && taxFee > 0 && !_lpPools[from]) {
            uint256 contractTokenBalanceForPool = _tokenAmountForLp[to];
            if (contractTokenBalanceForPool >= numTokensToSwap) {
                _processFees(to);
            }
        }

        if (taxFee > 0) {
            uint256 taxAmount = (amount * taxFee) / FEE_PRECISION;
            uint256 sendAmount = amount - taxAmount;
            uint256 burnAmount = (taxAmount * feeConfiguration.burnFeeRatio) /
                FEE_PRECISION;

            if (burnAmount > 0) {
                taxAmount -= burnAmount;
                super._transfer(from, BURN_ADDRESS, burnAmount);
            }

            if (taxAmount > 0) {
                super._transfer(from, address(this), taxAmount);
                if (isLpPool(to)) {
                    _tokenAmountForLp[to] += taxAmount;
                } else {
                    _tokenAmountForLp[from] += taxAmount;
                }
            }

            if (sendAmount > 0) {
                super._transfer(from, to, sendAmount);
            }
        } else {
            super._transfer(from, to, amount);
        }
    }

    function _distribute(
        uint256 _investmentPoolShare,
        uint256 _teamShare
    ) internal {
        uint256 amount = undistributedJNS;
        if (amount >= numTokensToSwap) {
            uint256 initialBalance = address(this).balance;

            _swapTokens(swapRouter.WPLS(), amount, 0, true, swapRouter);

            amount = (address(this).balance - initialBalance);

            uint256 investmentPoolShare = (amount *
                feeConfiguration.daoFeeRatio) /
                (FEE_PRECISION -
                    (feeConfiguration.burnFeeRatio +
                        feeConfiguration.liquidityFeeRatio));

            uint256 teamShare = amount - investmentPoolShare;

            undistributedJNS = 0; // Reset the undistributed JNS before distribution

            payable(investmentPoolAddress).transfer(
                investmentPoolShare + _investmentPoolShare
            );
            payable(teamAddress).transfer(teamShare + _teamShare);
        } else if (_investmentPoolShare != 0) {
            payable(investmentPoolAddress).transfer(_investmentPoolShare);
            payable(teamAddress).transfer(_teamShare);
        }
    }

    function setAutoprocessFees(bool autoProcess) external virtual;

    function setIsLpPool(address pairAddress, bool isLp) external virtual;

    function setLpPoolRouter(
        address routerAddress,
        address pairAddress
    ) external virtual;

    function setIsExcludedFromFees(
        address account,
        bool excluded
    ) external virtual;

    function processFees(address pair) external virtual;

    function setLiquidityOwner(address newOwner) external virtual;

    function setNumTokensToSwap(uint256 amount) external virtual;

    function setFeeConfiguration(
        FeeConfiguration calldata configuration
    ) external virtual;

    function setSwapRouter(address newRouter) external virtual;
}

// Lp swap Router public function